configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3 # Minimum version of autoconf required
   4 AC_PREREQ(2.62)
   5
   6 # UPDATING VERSION NUMBERS FOR RELEASES
   7 #
   8 # libalpm:
   9 # current
  10 #   The most recent interface number that this library implements.
  11 # revision
  12 #   The implementation number of the current interface.
  13 # age
  14 #   The difference between the newest and oldest interfaces that this library
  15 #   implements. In other words, the library implements all the interface
  16 #   numbers in the range from number current - age to current.
  17 #
  18 # 1. Start with version information of `0:0:0' for each libtool library.
  19 # 2. Update the version information only immediately before a public release of
  20 #    your software. More frequent updates are unnecessary, and only guarantee
  21 #    that the current interface number gets larger faster.
  22 # 3. If the library source code has changed at all since the last update, then
  23 #    increment revision (`c:r:a' becomes `c:r+1:a').
  24 # 4. If any interfaces have been added, removed, or changed since the last
  25 #    update, increment current, and set revision to 0.
  26 # 5. If any interfaces have been added since the last public release, then
  27 #    increment age.
  28 # 6. If any interfaces have been removed since the last public release, then
  29 #    set age to 0.
  30 #
  31 # pacman:
  32 #   Extreme huge major changes:
  33 #     pacman_version_major += 1
  34 #     pacman_version_minor = 0
  35 #     pacman_version_micro = 0
  36 #
  37 #   Real releases:
  38 #     pacman_version_minor += 1
  39 #     pacman_version_micro = 0
  40 #
  41 #   Bugfix releases:
  42 #     pacman_version_micro += 1
  43
  44 m4_define([lib_current], [7])
  45 m4_define([lib_revision], [3])
  46 m4_define([lib_age], [0])
  47
  48 m4_define([pacman_version_major], [4])
  49 m4_define([pacman_version_minor], [0])
  50 m4_define([pacman_version_micro], [3])
  51 m4_define([pacman_version],
  52           [pacman_version_major.pacman_version_minor.pacman_version_micro])
  53
  54 # Autoconf initialization
  55 AC_INIT([pacman], [pacman_version], [pacman-dev@archlinux.org])
  56 AC_CONFIG_SRCDIR([config.h.in])
  57 AC_CONFIG_HEADERS([config.h])
  58 AC_CONFIG_MACRO_DIR([m4])
  59 AC_CONFIG_AUX_DIR([build-aux])
  60
  61 AC_CANONICAL_HOST
  62 AM_INIT_AUTOMAKE([1.11])
  63 AM_SILENT_RULES([yes])
  64
  65 LT_INIT
  66 LIB_VERSION=`expr lib_current - lib_age`.lib_age.lib_revision
  67 LIB_VERSION_INFO="lib_current:lib_revision:lib_age"
  68
  69 # Set subsitution values for version stuff in Makefiles and anywhere else,
  70 # and put LIB_VERSION in config.h
  71 AC_SUBST(LIB_VERSION)
  72 AC_SUBST(LIB_VERSION_INFO)
  73 AC_DEFINE_UNQUOTED([LIB_VERSION], ["$LIB_VERSION"], [libalpm version number])
  74
  75 # Help line for root directory
  76 AC_ARG_WITH(root-dir,
  77         AS_HELP_STRING([--with-root-dir=path], [set the location of the root operating directory]),
  78         [ROOTDIR=$withval], [ROOTDIR=/])
  79
  80 # Help line for package extension
  81 AC_ARG_WITH(pkg-ext,
  82         AS_HELP_STRING([--with-pkg-ext=ext], [set the file extension used by packages]),
  83         [PKGEXT=$withval], [PKGEXT=.pkg.tar.gz])
  84
  85 # Help line for source package directory
  86 AC_ARG_WITH(src-ext,
  87         AS_HELP_STRING([--with-src-ext=ext], [set the file extension used by source packages]),
  88         [SRCEXT=$withval], [SRCEXT=.src.tar.gz])
  89
  90 # Help line for buildscript filename
  91 AC_ARG_WITH(buildscript,
  92         AS_HELP_STRING([--with-buildscript=name], [set the build script name used by makepkg]),
  93         [BUILDSCRIPT=$withval], [BUILDSCRIPT=PKGBUILD])
  94
  95 # Help line for changing shell used to run install scriptlets
  96 AC_ARG_WITH(scriptlet-shell,
  97         AS_HELP_STRING([--with-scriptlet-shell=shell],
  98                 [set the full path to the shell used to run install scriptlets]),
  99         [SCRIPTLET_SHELL=$withval], [SCRIPTLET_SHELL=/bin/sh])
 100
 101 # Help line for using OpenSSL
 102 AC_ARG_WITH(openssl,
 103         AS_HELP_STRING([--with-openssl], [use OpenSSL crypto implementations instead of internal routines]),
 104         [], [with_openssl=check])
 105
 106 # Help line for using gpgme
 107 AC_ARG_WITH(gpgme,
 108         AS_HELP_STRING([--with-gpgme], [use GPGME for PGP signature verification]),
 109         [], [with_gpgme=check])
 110
 111 # Help line for using libcurl
 112 AC_ARG_WITH(curl,
 113         AS_HELP_STRING([--with-libcurl], [use libcurl for the internal downloader]),
 114         [], [with_curl=check])
 115
 116 # Help line for documentation
 117 AC_ARG_ENABLE(doc,
 118         AS_HELP_STRING([--disable-doc], [prevent make from looking at doc/ dir]),
 119         [wantdoc=$enableval], [wantdoc=yes])
 120
 121 # Help line for doxygen
 122 AC_ARG_ENABLE(doxygen,
 123         AS_HELP_STRING([--enable-doxygen], [build your own API docs via Doxygen]),
 124         [wantdoxygen=$enableval], [wantdoxygen=no])
 125
 126 # Help line for debug
 127 AC_ARG_ENABLE(debug,
 128         AS_HELP_STRING([--enable-debug], [enable debugging support]),
 129         [debug=$enableval], [debug=no])
 130
 131 # Help line for using git version in pacman version string
 132 AC_ARG_ENABLE(git-version,
 133         AS_HELP_STRING([--enable-git-version],
 134                 [enable use of git version in version string if available]),
 135         [wantgitver=$enableval], [wantgitver=no])
 136
 137 # Enable large file support if available (must be enabled before
 138 # testing compilation against gpgme).
 139 AC_SYS_LARGEFILE
 140
 141 # Checks for programs.
 142 AC_PROG_AWK
 143 AC_PROG_CC_C99
 144 AC_PROG_INSTALL
 145 AC_CHECK_PROGS([PYTHON], [python2.7 python2.6 python2.5 python2 python], [false])
 146 AC_PATH_PROGS([BASH_SHELL], [bash bash4 bash3], [false])
 147
 148 # find installed gettext
 149 AM_GNU_GETTEXT([external], [need-ngettext])
 150 AM_GNU_GETTEXT_VERSION(0.13.1)
 151
 152 AC_CHECK_LIB([m], [fabs], ,
 153         AC_MSG_ERROR([libm is needed to compile pacman!]))
 154
 155 # Check for libarchive
 156 PKG_CHECK_MODULES(LIBARCHIVE, [libarchive >= 2.8.0], ,
 157         AC_MSG_ERROR([*** libarchive >= 2.8.0 is needed to compile pacman!]))
 158
 159 # Check for OpenSSL
 160 have_openssl=no
 161 if test "x$with_openssl" != "xno"; then
 162         PKG_CHECK_MODULES(LIBSSL, [libssl libcrypto],
 163                 [AC_DEFINE(HAVE_LIBSSL, 1, [Define if libcrypto is available]) have_openssl=yes], have_openssl=no)
 164         if test "x$have_openssl" = xno -a "x$with_openssl" = xyes; then
 165                 AC_MSG_ERROR([*** openssl support requested but libraries not found])
 166         fi
 167 fi
 168 AM_CONDITIONAL(HAVE_LIBSSL, [test "$have_openssl" = "yes"])
 169
 170 # Check for libcurl
 171 have_libcurl=no
 172 if test "x$with_libcurl" != "xno"; then
 173         PKG_CHECK_MODULES(LIBCURL, [libcurl >= 7.19.4],
 174                 [AC_DEFINE(HAVE_LIBCURL, 1, [Define if libcurl is available]) have_libcurl=yes], have_libcurl=no)
 175         if test "x$have_libcurl" = xno -a "x$with_libcurl" = xyes; then
 176                 AC_MSG_ERROR([*** libcurl >= 7.19.4 is required for internal downloader support])
 177         fi
 178 fi
 179 AM_CONDITIONAL(HAVE_LIBCURL, [test "$have_libcurl" = "yes"])
 180
 181 # Check for gpgme
 182 AC_MSG_CHECKING(whether to link with libgpgme)
 183 AS_IF([test "x$with_gpgme" != "xno"],
 184         [AC_MSG_RESULT([yes])],
 185         [AC_MSG_RESULT([no])])
 186
 187 have_gpgme=no
 188 AS_IF([test "x$with_gpgme" != "xno"],
 189         [AM_PATH_GPGME([1.3.0],
 190                 [LIBS_save="$LIBS"
 191                 CPPFLAGS_save="$CPPFLAGS"
 192                 CFLAGS_save="$CFLAGS"
 193
 194                 LIBS="$LIBS $GPGME_LIBS"
 195                 CPPFLAGS="$CPPFLAGS $GPGME_CPPFLAGS"
 196                 CFLAGS="$CFLAGS $GPGME_CFLAGS"
 197
 198                 AC_MSG_CHECKING([for sane gpgme])
 199                 AC_LINK_IFELSE(
 200                         [AC_LANG_PROGRAM(
 201                                 [[#include <gpgme.h>]],
 202                                 [[return gpgme_check_version("1.3.0");]])],
 203                         [AC_MSG_RESULT([yes])
 204                         have_gpgme=yes
 205                         AC_DEFINE([HAVE_LIBGPGME], [1], [Define if gpgme should be used to provide GPG signature support.])],
 206                         [AC_MSG_RESULT([no])
 207                         have_gpgme=no
 208                         unset GPGME_LIBS
 209                         unset GPGME_CFLAGS]
 210                         AS_IF([test "x$with_gpgme" = "xyes"],
 211                                 [AC_MSG_FAILURE([*** gpgme >= 1.3.0 is needed for GPG signature support])])
 212                         )],
 213                 [with_gpgme=no])]
 214                 [LIBS="$LIBS_save"
 215                 CPPFLAGS="$CPPFLAGS_save"
 216                 CFLAGS="$CFLAGS_save"
 217                 unset CPPFLAGS_save
 218                 unset CFLAGS_save])
 219 AS_IF([test "x$have_gpgme" = xno -a "x$with_gpgme" = xyes],
 220         [AC_MSG_FAILURE([--with-gpgme was given, but gpgme was not found])])
 221 AM_CONDITIONAL([HAVE_LIBGPGME], [test "x$have_gpgme" = "xyes"])
 222
 223 # Checks for header files.
 224 AC_CHECK_HEADERS([fcntl.h float.h glob.h libintl.h limits.h locale.h \
 225                   mntent.h netinet/in.h netinet/tcp.h \
 226                   stddef.h string.h sys/ioctl.h \
 227                   sys/mnttab.h sys/mount.h \
 228                   sys/param.h sys/statvfs.h sys/time.h sys/types.h \
 229                   sys/ucred.h syslog.h termios.h wchar.h])
 230
 231 # Checks for typedefs, structures, and compiler characteristics.
 232 AC_C_INLINE
 233 AC_TYPE_INT64_T
 234 AC_TYPE_MODE_T
 235 AC_TYPE_OFF_T
 236 AC_TYPE_PID_T
 237 AC_TYPE_SIZE_T
 238 AC_TYPE_SSIZE_T
 239 AC_STRUCT_TM
 240 AC_TYPE_UID_T
 241 AC_STRUCT_DIRENT_D_TYPE
 242 PATH_MAX_DEFINED
 243
 244 # Checks for library functions.
 245 AC_FUNC_FORK
 246 AC_FUNC_GETMNTENT
 247 AC_FUNC_LSTAT_FOLLOWS_SLASHED_SYMLINK
 248 AC_FUNC_MALLOC
 249 AC_FUNC_MKTIME
 250 AC_FUNC_STRCOLL
 251 AC_CHECK_FUNCS([dup2 getcwd geteuid getmntinfo gettimeofday memmove memset \
 252                 mkdir realpath regcomp rmdir setenv setlocale strcasecmp \
 253                 strchr strcspn strdup strerror strndup strrchr strsep strstr \
 254                 strtol swprintf tcflush wcwidth uname])
 255 AC_CHECK_MEMBERS([struct stat.st_blksize],,,[[#include <sys/stat.h>]])
 256
 257 # For the diskspace code
 258 FS_STATS_TYPE
 259 AC_CHECK_MEMBERS([struct statvfs.f_flag],,,[[#include <sys/statvfs.h>]])
 260 AC_CHECK_MEMBERS([struct statfs.f_flags],,,[[#include <sys/param.h>
 261                   #include <sys/mount.h>]])
 262
 263 # Check if we can use symbol visibility support in GCC
 264 GCC_VISIBILITY_CC
 265 # Check if we have -fgnu89-inline flag
 266 GCC_GNU89_INLINE_CC
 267
 268 # Host-dependant definitions
 269 SIZECMD="stat -c %s"
 270 SEDINPLACE="sed -i"
 271 STRIP_BINARIES="--strip-all"
 272 STRIP_SHARED="--strip-unneeded"
 273 STRIP_STATIC="--strip-debug"
 274 case "${host_os}" in
 275         *bsd*)
 276                 SIZECMD="stat -f %z"
 277                 SEDINPLACE="sed -i \"\""
 278                 ;;
 279         cygwin*)
 280                 host_os_cygwin=yes
 281                 AC_DEFINE([CYGWIN], [1], [Define if host OS is cygwin])
 282                 ;;
 283         darwin*)
 284                 host_os_darwin=yes
 285                 SIZECMD="/usr/bin/stat -f %z"
 286                 SEDINPLACE="/usr/bin/sed -i ''"
 287                 STRIP_BINARIES=""
 288                 STRIP_SHARED="-S"
 289                 STRIP_STATIC="-S"
 290                 ;;
 291 esac
 292
 293 AM_CONDITIONAL([CYGWIN], test "x$host_os_cygwin" = "xyes")
 294 AM_CONDITIONAL([DARWIN], test "x$host_os_darwin" = "xyes")
 295 AC_PATH_PROGS([DUPATH], [du], [du], [/usr/bin$PATH_SEPARATOR/bin] )
 296 AC_SUBST(SIZECMD)
 297 AC_SUBST(SEDINPLACE)
 298 AC_SUBST(STRIP_BINARIES)
 299 AC_SUBST(STRIP_SHARED)
 300 AC_SUBST(STRIP_STATIC)
 301
 302 # Variables plugged into makepkg.conf
 303 CARCH="${host%%-*}"
 304 CHOST="${host}"
 305 AC_SUBST(CARCH)
 306 AC_SUBST(CHOST)
 307
 308 # Check for documentation support and status
 309 AC_CHECK_PROGS([ASCIIDOC], [asciidoc])
 310 AC_MSG_CHECKING([for building documentation])
 311 if test "x$wantdoc" = "xyes" ; then
 312         if test $ASCIIDOC ; then
 313                 AC_MSG_RESULT([yes, enabled by configure])
 314         else
 315                 asciidoc="(warning : asciidoc not installed)"
 316                 AC_MSG_RESULT([yes $asciidoc])
 317         fi
 318         wantdoc=yes
 319 else
 320         AC_MSG_RESULT([no, disabled by configure])
 321         wantdoc=no
 322 fi
 323 AM_CONDITIONAL(WANT_DOC, test "x$wantdoc" = "xyes")
 324
 325 # Check for doxygen support and status
 326 AC_CHECK_PROGS([DOXYGEN], [doxygen])
 327 AC_MSG_CHECKING([for doxygen])
 328 if test "x$wantdoxygen" = "xyes" ; then
 329         if test $DOXYGEN ; then
 330                 AC_MSG_RESULT([yes])
 331                 usedoxygen=yes
 332         else
 333                 AC_MSG_RESULT([no, doxygen missing])
 334                 usedoxygen=no
 335         fi
 336 else
 337         AC_MSG_RESULT([no, disabled by configure])
 338         usedoxygen=no
 339 fi
 340 AM_CONDITIONAL(USE_DOXYGEN, test "x$usedoxygen" = "xyes")
 341
 342 # Enable or disable debug code
 343 AC_MSG_CHECKING(for debug mode request)
 344 if test "x$debug" = "xyes" ; then
 345         AC_MSG_RESULT(yes)
 346         AC_DEFINE([PACMAN_DEBUG], , [Enable debug code])
 347         # Check for -fstack-protector availability
 348         GCC_STACK_PROTECT_LIB
 349         GCC_STACK_PROTECT_CC
 350         GCC_FORTIFY_SOURCE_CC
 351         WARNING_CFLAGS="-g -Wall -Werror"
 352 else
 353         AC_MSG_RESULT(no)
 354         WARNING_CFLAGS="-Wall"
 355 fi
 356
 357 # Enable or disable use of git version in pacman version string
 358 AC_MSG_CHECKING(whether to use git version if available)
 359 if test "x$wantgitver" = "xyes" ; then
 360         AC_CHECK_PROGS([GIT], [git])
 361         AC_CHECK_FILE([.git/], hasgitdir=yes)
 362         if test $GIT -a "x$hasgitdir" = "xyes"; then
 363                 AC_MSG_RESULT([yes])
 364                 usegitver=yes
 365                 AC_DEFINE([USE_GIT_VERSION], , [Use GIT version in version string])
 366         else
 367                 AC_MSG_RESULT([no, git or .git dir missing])
 368                 usegitver=no
 369         fi
 370 else
 371         AC_MSG_RESULT([no, disabled by configure])
 372         usegitver=no
 373 fi
 374 AM_CONDITIONAL(USE_GIT_VERSION, test "x$usegitver" = "xyes")
 375
 376 # Set root directory
 377 AC_SUBST(ROOTDIR)
 378 AC_DEFINE_UNQUOTED([ROOTDIR], "$ROOTDIR", [The location of the root operating directory])
 379 # Set package file extension
 380 AC_SUBST(PKGEXT)
 381 AC_DEFINE_UNQUOTED([PKGEXT], "$PKGEXT", [The file extension used by pacman packages])
 382 # Set source package file extension
 383 AC_SUBST(SRCEXT)
 384 AC_DEFINE_UNQUOTED([SRCEXT], "$SRCEXT", [The file extension used by pacman source packages])
 385 # Set makepkg build script name
 386 AC_SUBST(BUILDSCRIPT)
 387 AC_DEFINE_UNQUOTED([BUILDSCRIPT], "$BUILDSCRIPT", [The build script name used by makepkg])
 388 # Set shell used by install scriptlets
 389 AC_SUBST(SCRIPTLET_SHELL)
 390 AC_DEFINE_UNQUOTED([SCRIPTLET_SHELL], "$SCRIPTLET_SHELL", [The full path of the shell used to run install scriptlets])
 391
 392 # Configuration files
 393 AC_CONFIG_FILES([
 394 lib/libalpm/Makefile
 395 lib/libalpm/po/Makefile.in
 396 src/pacman/Makefile
 397 src/pacman/po/Makefile.in
 398 src/util/Makefile
 399 scripts/Makefile
 400 scripts/po/Makefile.in
 401 doc/Makefile
 402 etc/Makefile
 403 test/pacman/Makefile
 404 test/pacman/tests/Makefile
 405 test/util/Makefile
 406 contrib/Makefile
 407 Makefile
 408 ])
 409 AC_OUTPUT
 410
 411 echo "
 412 ${PACKAGE_NAME}:
 413
 414   Build information:
 415     source code location   : ${srcdir}
 416     prefix                 : ${prefix}
 417     sysconfdir             : $(eval echo ${sysconfdir})
 418        conf file           : $(eval echo ${sysconfdir})/pacman.conf
 419     localstatedir          : $(eval echo ${localstatedir})
 420        database dir        : $(eval echo ${localstatedir})/lib/pacman/
 421        cache dir           : $(eval echo ${localstatedir})/cache/pacman/pkg/
 422
 423     compiler               : ${CC}
 424     preprocessor flags     : ${CPPFLAGS}
 425     compiler flags         : ${WARNING_CFLAGS} ${CFLAGS}
 426     defines                : ${DEFS}
 427     library flags          : ${LIBS} ${LIBSSL_LIBS} ${LIBARCHIVE_LIBS} ${LIBCURL_LIBS} ${GPGME_LIBS}
 428     linker flags           : ${LDFLAGS}
 429
 430     Architecture           : ${CARCH}
 431     Host Type              : ${CHOST}
 432     Filesize command       : ${SIZECMD}
 433     In-place sed command   : ${SEDINPLACE}
 434
 435     libalpm version        : ${LIB_VERSION}
 436     libalpm version info   : ${LIB_VERSION_INFO}
 437     pacman version         : ${PACKAGE_VERSION}
 438     using git version      : ${usegitver}
 439
 440   Directory and file information:
 441     root working directory : ${ROOTDIR}
 442     package extension      : ${PKGEXT}
 443     source pkg extension   : ${SRCEXT}
 444     build script name      : ${BUILDSCRIPT}
 445
 446   Compilation options:
 447     Use libcurl            : ${have_libcurl}
 448     Use GPGME              : ${have_gpgme}
 449     Use OpenSSL            : ${have_openssl}
 450     Run make in doc/ dir   : ${wantdoc} ${asciidoc}
 451     Doxygen support        : ${usedoxygen}
 452     debug support          : ${debug}
 453 "
 454
 455 # vim:set ts=2 sw=2 noet: