t/codingstd/c_macro_args.t

   1 #! perl
   2 # Copyright (C) 2008-2010, Parrot Foundation.
   3 # $Id$
   4
   5 use strict;
   6 use warnings;
   7
   8 use lib qw( . lib ../lib ../../lib );
   9 use Test::More tests => 1;
  10 use Parrot::Distribution;
  11
  12 =head1 NAME
  13
  14 t/codingstd/c_macro_args.t
  15
  16 =head1 SYNOPSIS
  17
  18     # test all files
  19     % prove t/codingstd/c_macro_args.t
  20
  21     # test specific files
  22     % perl t/codingstd/c_macro_args.t src/foo.t include/parrot/bar.h
  23
  24 =head1 DESCRIPTION
  25
  26 Checks that no C source file in the distribution has unsafe macro args.
  27
  28 =head1 SEE ALSO
  29
  30 L<docs/pdds/pdd07_codingstd.pod>
  31
  32 =cut
  33
  34 my $DIST = Parrot::Distribution->new();
  35 my @files = @ARGV ? <@ARGV> : $DIST->get_c_language_files();
  36
  37 check_macro_args(@files);
  38
  39 sub check_macro_args {
  40     my @files = @_;
  41
  42     my @defines;
  43     foreach my $file (@files) {
  44         my $path = @ARGV ? $file : $file->path();
  45         my $buf = $DIST->slurp($path);
  46         $buf =~ s{ (?:
  47                        (?: ' (?: \\\\ | \\' | [^'] )* ' )  # remove ' string
  48                      | (?: " (?: \\\\ | \\" | [^"] )* " )  # remove " string
  49                      | /\*[^@] .*? \*/                     # remove C comment
  50                    )
  51                 }{}gsx;
  52
  53         # combine lines extended with \\n
  54         $buf =~ s/\\\n//g;
  55
  56         while ( $buf =~ m{ ^ \s* \# \s* define \s+ ([a-zA-Z_]+)  \( ([^)]+) \)  ([^\n]*) }smgx ) {
  57             my ($macro,$args,$definition) = ($1, $2, $3);
  58             # for each of these args, verify it's wrapped in parens each time
  59             # it's referenced in the definition.
  60             if ($definition ne "") {
  61                 foreach my $arg (split /\s*,\s*/, $args) {
  62
  63                     # skip args that are code blocks
  64                     next if $arg eq '_code';
  65
  66                     # eliminate any properly formed usage of the macro arg
  67                     $definition =~ s/\Q($arg)//g;
  68                     $definition =~ s/\Q[$arg]//g;
  69                     $definition =~ s/\Q<$arg>//g;
  70
  71                     # eliminate concatenations
  72                     $definition =~ s/\Q$arg ##//g;
  73                     $definition =~ s/\Q## $arg//g;
  74
  75                     # eliminate stringifications
  76                     $definition =~ s/\Q#$arg//g;
  77
  78                     # eliminate args used as types
  79                     $definition =~ s/\Q$arg\E[ ]+\*//g;
  80
  81                     # eliminate all function argument instrumentation macros
  82                     next if $definition =~ m/\*@[\w ]+@\*/;
  83
  84                     # eliminate args used as function names
  85                     # (this match is naive, but it catches the one place where
  86                     # this is used)
  87                     $definition =~ s/\Q$arg\E\([^)]*\)//g;
  88
  89                     # eliminate macros that deal with flags, since they're special
  90                     next if $macro =~ m/(TEST|SET|CLEAR)$/;
  91
  92                     # skip those two varargs macros, already called as TRACE_PRINTF((args))
  93                     next if $macro =~ m/^TRACE_PRINTF(_VAL|_ALIGN)?$/;
  94
  95                     # Any remaining usage must be improper
  96                     if ($definition =~ m/\b\Q$arg\E\b/) {
  97                         push (@defines, "$path: $macro has unwrapped arg: $arg\n");
  98                     }
  99                 }
 100             }
 101         }
 102     }
 103
 104     my $ndefines = scalar @defines;
 105     is( $ndefines, 0, 'Check for unwrapped macro arguments' )
 106         or diag( "$ndefines unsafe macro args found:\n@defines\nThat's $ndefines of 'em!" );
 107 }
 108
 109 # Local Variables:
 110 #   mode: cperl
 111 #   cperl-indent-level: 4
 112 #   fill-column: 100
 113 # End:
 114 # vim: expandtab shiftwidth=4: