workspace/plasma/applets/kickoff/CMakeLists.txt

   1 #######################################################################################
   2 # Kickoff Library
   3
   4 if(STRIGI_STRIGIQTDBUSCLIENT_LIBRARY)
   5     set(HAVE_STRIGIDBUS 1)
   6 endif(STRIGI_STRIGIQTDBUSCLIENT_LIBRARY)
   7
   8 configure_file(core/config-kickoff-applets.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-kickoff-applets.h)
   9
  10 set(libkickoff_SRCS
  11     core/kickoffmodel.cpp
  12     core/kickoffabstractmodel.cpp
  13     core/kickoffproxymodel.cpp
  14     core/applicationmodel.cpp
  15     core/favoritesmodel.cpp
  16     core/leavemodel.cpp
  17     core/models.cpp
  18     core/recentapplications.cpp
  19     core/recentlyusedmodel.cpp
  20     core/searchmodel.cpp
  21     core/systemmodel.cpp
  22     core/urlitemlauncher.cpp
  23     core/itemhandlers.cpp
  24 )
  25
  26 qt4_add_dbus_adaptor(libkickoff_SRCS core/org.kde.kickoff.xml core/applicationmodel.h Kickoff::ApplicationModel)
  27 qt4_add_dbus_adaptor(libkickoff_SRCS core/org.kde.kickoff.recent.xml core/recentlyusedmodel.h Kickoff::RecentlyUsedModel)
  28
  29 set(screensaver_xml ${KDEBASE_WORKSPACE_SOURCE_DIR}/krunner/dbus/org.freedesktop.ScreenSaver.xml)
  30 QT4_ADD_DBUS_INTERFACE(libkickoff_SRCS ${screensaver_xml} screensaver_interface)
  31 set(krunner_xml ${KDEBASE_WORKSPACE_SOURCE_DIR}/krunner/dbus/org.kde.krunner.App.xml)
  32 QT4_ADD_DBUS_INTERFACE(libkickoff_SRCS ${krunner_xml} krunner_interface)
  33 set(ksmserver_xml ${KDEBASE_WORKSPACE_SOURCE_DIR}/ksmserver/org.kde.KSMServerInterface.xml)
  34 QT4_ADD_DBUS_INTERFACE(libkickoff_SRCS ${ksmserver_xml} ksmserver_interface)
  35
  36 if(NOT WIN32)
  37     set(Kickoff_LIBS ${KDE4_KIO_LIBS} ${KDE4_KFILE_LIBS} ${KDE4_SOLID_LIBS} solidcontrol kworkspace)
  38 else(NOT WIN32)
  39     set(Kickoff_LIBS ${KDE4_KIO_LIBS} ${KDE4_KFILE_LIBS} ${KDE4_SOLID_LIBS} solidcontrol)
  40 endif(NOT WIN32)
  41 if(HAVE_STRIGIDBUS)
  42      set ( Kickoff_LIBS ${Kickoff_LIBS} ${STRIGI_STRIGIQTDBUSCLIENT_LIBRARY} )
  43 endif(HAVE_STRIGIDBUS)
  44
  45 include_directories( ${STRIGI_INCLUDE_DIR} )
  46
  47 kde4_add_library(libkickoff SHARED ${libkickoff_SRCS})
  48 target_link_libraries(libkickoff ${KDE4_PLASMA_LIBS} solidcontrol ${Kickoff_LIBS})
  49 install(TARGETS libkickoff DESTINATION ${INSTALL_TARGETS_DEFAULT_ARGS})
  50
  51 #######################################################################################
  52 # Kickoff Plasma Applet
  53
  54 set(Applet_SRCS
  55     ui/brandingbutton.cpp
  56     ui/contextmenufactory.cpp
  57     ui/flipscrollview.cpp
  58     ui/itemdelegate.cpp
  59     ui/contentareacap.cpp
  60     ui/launcher.cpp
  61     ui/searchbar.cpp
  62     ui/tabbar.cpp
  63     ui/urlitemview.cpp
  64     applet/applet.cpp
  65 )
  66 kde4_add_plugin(plasma_applet_launcher ${Applet_SRCS})
  67 target_link_libraries(plasma_applet_launcher ${KDE4_PLASMA_LIBS} solidcontrol ${Kickoff_LIBS} libkickoff)
  68 install(TARGETS plasma_applet_launcher DESTINATION ${PLUGIN_INSTALL_DIR})
  69 install(FILES applet/plasma-applet-launcher.desktop DESTINATION ${SERVICES_INSTALL_DIR})
  70
  71 #######################################################################################
  72 # Kickoff Simple KMenu Plasma Applet
  73
  74 set(SimpleApplet_SRCS simpleapplet/menuview.cpp simpleapplet/simpleapplet.cpp)
  75 kde4_add_plugin(plasma_applet_simplelauncher ${SimpleApplet_SRCS})
  76 target_link_libraries(plasma_applet_simplelauncher ${KDE4_PLASMA_LIBS} solidcontrol ${Kickoff_LIBS} libkickoff)
  77 install(TARGETS plasma_applet_simplelauncher DESTINATION ${PLUGIN_INSTALL_DIR})
  78 install(FILES simpleapplet/plasma-applet-simplelauncher.desktop DESTINATION ${SERVICES_INSTALL_DIR})
  79
  80 # Kickoff Standalone Test Application
  81 #IF (CMAKE_BUILD_TYPE MATCHES Debug)
  82 #    set(Application_SRCS ${Kickoff_SRCS} main.cpp)
  83 #    kde4_add_executable(kickoff ${Application_SRCS})
  84 #    target_link_libraries(kickoff ${KDE4_PLASMA_LIBS} ${Kickoff_LIBS})
  85 #    install(TARGETS kickoff ${INSTALL_TARGETS_DEFAULT_ARGS})
  86 #ENDIF (CMAKE_BUILD_TYPE MATCHES Debug)