apps/konsole/src/CMakeLists.txt

   1
   2 ### Compile-time features
   3 macro_optional_find_package(XKB)
   4 macro_bool_to_01(X11_Xrender_FOUND HAVE_XRENDER)
   5 macro_log_feature(XKB_FOUND "XKB" "X keyboard extension" "http://www.x.org" FALSE "" "Gives Konsole better keyboard support.")
   6
   7 configure_file (config-konsole.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-konsole.h )
   8
   9 ### Tests
  10     add_subdirectory(tests)
  11
  12 ### Font Embedder
  13
  14     set(fontembedder_SRCS fontembedder.cpp )
  15     kde4_add_executable(fontembedder ${fontembedder_SRCS})
  16     target_link_libraries(fontembedder  ${KDE4_KIO_LIBS} )
  17
  18 ### Line graphics font
  19
  20     option(KONSOLE_GENERATE_LINEFONT "Konsole: regenerate LineFont file" OFF)
  21
  22     if(KONSOLE_GENERATE_LINEFONT)
  23             add_custom_command(OUTPUT ${CMAKE_SOURCE_DIR}/LineFont.h
  24                            COMMAND ${CMAKE_CURRENT_BINARY_DIR}/fontembedder
  25                            ARGS ${CMAKE_SOURCE_DIR}/LineFont.src
  26                            DEPENDS ${CMAKE_SOURCE_DIR}/LineFont.src )
  27     endif(KONSOLE_GENERATE_LINEFONT)
  28
  29 ### Konsole source files shared between embedded terminal and main application
  30
  31     qt4_add_dbus_adaptor( sessionadaptors_SRCS
  32                           org.kde.konsole.Session.xml
  33                           Session.h
  34                           Konsole::Session )
  35
  36     set(konsole_COMMON_SRCS
  37         ${sessionadaptors_SRCS}
  38         BlockArray.cpp
  39         BookmarkHandler.cpp
  40         ColorScheme.cpp
  41         ColorSchemeEditor.cpp
  42         CopyInputDialog.cpp
  43         EditProfileDialog.cpp
  44         Emulation.cpp
  45         Filter.cpp
  46         History.cpp
  47         HistorySizeDialog.cpp
  48         IncrementalSearchBar.cpp
  49         KeyBindingEditor.cpp
  50         KeyboardTranslator.cpp
  51         ManageProfilesDialog.cpp
  52         ProcessInfo.cpp
  53         Profile.cpp
  54         ProfileList.cpp
  55         ProfileListWidget.cpp
  56         Pty.cpp
  57         RemoteConnectionDialog.cpp
  58         Screen.cpp
  59         ScreenWindow.cpp
  60         Session.cpp
  61         SessionController.cpp
  62         SessionManager.cpp
  63         ShellCommand.cpp
  64         TabTitleFormatAction.cpp
  65         TerminalCharacterDecoder.cpp
  66         TerminalDisplay.cpp
  67         ViewContainer.cpp
  68         ViewManager.cpp
  69         ViewProperties.cpp
  70         ViewSplitter.cpp
  71         Vt102Emulation.cpp
  72         WarningBox.cpp
  73         XKB.cpp
  74         ZModemDialog.cpp
  75         konsole_wcwidth.cpp
  76     )
  77
  78     set(konsole_LIBS
  79         ${KDE4_KPTY_LIBRARY}
  80         ${KDE4_KIO_LIBS}
  81         ${QT_QTXML_LIBRARY}
  82         ${KDE4_KNOTIFYCONFIG_LIBRARY}
  83         ${X11_LIBRARIES}
  84     )
  85
  86     # XRender library for true transparency support
  87     if(X11_Xrender_FOUND)
  88         list(APPEND konsole_LIBS ${X11_Xrender_LIB})
  89     endif(X11_Xrender_FOUND)
  90
  91 # doesn't seem to be needed
  92 #    if(X11_XTest_FOUND)
  93 #        list(APPEND konsole_LIBS ${X11_XTest_LIB})
  94 #    endif(X11_XTest_FOUND)
  95
  96 ### Konsole Application
  97
  98     set(konsole_KDEINIT_SRCS
  99         ${konsole_COMMON_SRCS}
 100         Application.cpp
 101         MainWindow.cpp
 102         main.cpp
 103     )
 104
 105     kde4_add_ui_files(konsole_KDEINIT_SRCS
 106                   ColorSchemeEditor.ui
 107                   CopyInputDialog.ui
 108                   EditProfileDialog.ui
 109                   KeyBindingEditor.ui
 110                   ManageProfilesDialog.ui
 111                   RemoteConnectionDialog.ui
 112                  )
 113
 114     kde4_add_kdeinit_executable( konsole ${konsole_KDEINIT_SRCS})
 115     target_link_libraries(kdeinit_konsole ${konsole_LIBS})
 116
 117     install(TARGETS kdeinit_konsole  ${INSTALL_TARGETS_DEFAULT_ARGS} )
 118     install(TARGETS konsole          ${INSTALL_TARGETS_DEFAULT_ARGS})
 119
 120 ### Embedded Konsole KPart
 121
 122     set(konsolepart_PART_SRCS
 123       ${konsole_COMMON_SRCS}
 124       Part.cpp
 125    )
 126
 127     kde4_add_plugin(konsolepart WITH_PREFIX ${konsolepart_PART_SRCS})
 128     set_target_properties(konsolepart PROPERTIES DEFINE_SYMBOL KONSOLE_PART)
 129     target_link_libraries(konsolepart ${KDE4_KPARTS_LIBS} ${konsole_LIBS})
 130     install(TARGETS konsolepart  DESTINATION ${PLUGIN_INSTALL_DIR} )
 131
 132 ### konsoleprofile command-line tool
 133
 134     install(FILES konsoleprofile PERMISSIONS OWNER_READ
 135                                          OWNER_WRITE
 136                                          OWNER_EXECUTE
 137                                          GROUP_EXECUTE
 138                                          GROUP_READ
 139                                          WORLD_READ
 140                                          WORLD_EXECUTE DESTINATION ${BIN_INSTALL_DIR})