contrib/hstore_plperl/meson.build

   1 # Copyright (c) 2022-2024, PostgreSQL Global Development Group
   2
   3 if not perl_dep.found()
   4   subdir_done()
   5 endif
   6
   7 hstore_plperl_sources = files(
   8   'hstore_plperl.c',
   9 )
  10
  11 if host_system == 'windows'
  12   hstore_plperl_sources += rc_lib_gen.process(win32ver_rc, extra_args: [
  13     '--NAME', 'hstore_plperl',
  14     '--FILEDESC', 'hstore_plperl - hstore transform for plperl',])
  15 endif
  16
  17 hstore_plperl = shared_module('hstore_plperl',
  18   hstore_plperl_sources,
  19   include_directories: [plperl_inc, hstore_inc],
  20   kwargs: contrib_mod_args + {
  21     'dependencies': [perl_dep, contrib_mod_args['dependencies']],
  22     'install_rpath': ':'.join(mod_install_rpaths + ['@0@/CORE'.format(archlibexp)]),
  23     'build_rpath': '@0@/CORE'.format(archlibexp),
  24   },
  25 )
  26 contrib_targets += hstore_plperl
  27
  28 install_data(
  29   'hstore_plperl.control',
  30   'hstore_plperl--1.0.sql',
  31   kwargs: contrib_data_args,
  32 )
  33
  34 install_data(
  35   'hstore_plperlu.control',
  36   'hstore_plperlu--1.0.sql',
  37   kwargs: contrib_data_args,
  38 )
  39
  40 tests += {
  41   'name': 'hstore_plperl',
  42   'sd': meson.current_source_dir(),
  43   'bd': meson.current_build_dir(),
  44   'regress': {
  45     'sql': [
  46       'hstore_plperl',
  47       'hstore_plperlu',
  48       'create_transform',
  49     ],
  50   },
  51 }