src/port/meson.build

   1 # Copyright (c) 2022-2023, PostgreSQL Global Development Group
   2
   3 pgport_sources = [
   4   'bsearch_arg.c',
   5   'chklocale.c',
   6   'inet_net_ntop.c',
   7   'noblock.c',
   8   'path.c',
   9   'pg_bitutils.c',
  10   'pg_strong_random.c',
  11   'pgcheckdir.c',
  12   'pgmkdirp.c',
  13   'pgsleep.c',
  14   'pgstrcasecmp.c',
  15   'pgstrsignal.c',
  16   'pqsignal.c',
  17   'qsort.c',
  18   'qsort_arg.c',
  19   'quotes.c',
  20   'snprintf.c',
  21   'strerror.c',
  22   'tar.c',
  23   'thread.c',
  24 ]
  25
  26 if host_system == 'windows'
  27   pgport_sources += files(
  28     'dirmod.c',
  29     'kill.c',
  30     'open.c',
  31     'system.c',
  32     'win32dlopen.c',
  33     'win32env.c',
  34     'win32error.c',
  35     'win32fdatasync.c',
  36     'win32getrusage.c',
  37     'win32link.c',
  38     'win32ntdll.c',
  39     'win32pread.c',
  40     'win32pwrite.c',
  41     'win32security.c',
  42     'win32setlocale.c',
  43     'win32stat.c',
  44   )
  45 elif host_system == 'cygwin'
  46   pgport_sources += files(
  47     'dirmod.c',
  48   )
  49 endif
  50
  51 if cc.get_id() == 'msvc'
  52   pgport_sources += files(
  53     'dirent.c',
  54     'win32gettimeofday.c',
  55   )
  56 endif
  57
  58 # Replacement functionality to be built if corresponding configure symbol
  59 # is false
  60 replace_funcs_neg = [
  61   ['explicit_bzero'],
  62   ['getopt'],
  63   ['getopt_long'],
  64   ['getpeereid'],
  65   ['inet_aton'],
  66   ['mkdtemp'],
  67   ['preadv', 'HAVE_DECL_PREADV'],
  68   ['pwritev', 'HAVE_DECL_PWRITEV'],
  69   ['strlcat'],
  70   ['strlcpy'],
  71   ['strnlen'],
  72 ]
  73
  74 if host_system != 'windows'
  75   replace_funcs_neg += [['pthread_barrier_wait']]
  76 endif
  77
  78 # Replacement functionality to be built if corresponding configure symbol
  79 # is true
  80 replace_funcs_pos = [
  81   # x86/x64
  82   ['pg_crc32c_sse42', 'USE_SSE42_CRC32C'],
  83   ['pg_crc32c_sse42', 'USE_SSE42_CRC32C_WITH_RUNTIME_CHECK', 'crc'],
  84   ['pg_crc32c_sse42_choose', 'USE_SSE42_CRC32C_WITH_RUNTIME_CHECK'],
  85   ['pg_crc32c_sb8', 'USE_SSE42_CRC32C_WITH_RUNTIME_CHECK'],
  86
  87   # arm / aarch64
  88   ['pg_crc32c_armv8', 'USE_ARMV8_CRC32C'],
  89   ['pg_crc32c_armv8', 'USE_ARMV8_CRC32C_WITH_RUNTIME_CHECK', 'crc'],
  90   ['pg_crc32c_armv8_choose', 'USE_ARMV8_CRC32C_WITH_RUNTIME_CHECK'],
  91   ['pg_crc32c_sb8', 'USE_ARMV8_CRC32C_WITH_RUNTIME_CHECK'],
  92
  93   # generic fallback
  94   ['pg_crc32c_sb8', 'USE_SLICING_BY_8_CRC32C'],
  95 ]
  96
  97 pgport_cflags = {'crc': cflags_crc}
  98 pgport_sources_cflags = {'crc': []}
  99
 100 foreach f : replace_funcs_neg
 101   func = f.get(0)
 102   varname = f.get(1, 'HAVE_@0@'.format(func.to_upper()))
 103   filename = '@0@.c'.format(func)
 104
 105   val = '@0@'.format(cdata.get(varname, 'false'))
 106   if val == 'false' or val == '0'
 107     pgport_sources += files(filename)
 108   endif
 109 endforeach
 110
 111 foreach f : replace_funcs_pos
 112   func = f.get(0)
 113   varname = f.get(1, 'HAVE_@0@'.format(func.to_upper()))
 114   filename = '@0@.c'.format(func)
 115
 116   val = '@0@'.format(cdata.get(varname, 'false'))
 117   if val == 'true' or val == '1'
 118     src = files(filename)
 119     if f.length() > 2
 120       pgport_sources_cflags += {f[2]: pgport_sources_cflags[f[2]] + src}
 121     else
 122       pgport_sources += src
 123     endif
 124   endif
 125 endforeach
 126
 127
 128 if (host_system == 'windows' or host_system == 'cygwin') and \
 129   (cc.get_id() != 'msvc' or cc.version().version_compare('<14.0'))
 130
 131   # Cygwin and (apparently, based on test results) Mingw both
 132   # have a broken strtof(), so substitute its implementation.
 133   # That's not a perfect fix, since it doesn't avoid double-rounding,
 134   # but we have no better options.
 135   pgport_sources += files('strtof.c')
 136   message('On @0@ with compiler @1@ @2@ we will use our strtof wrapper.'.format(
 137     host_system, cc.get_id(), cc.version()))
 138 endif
 139
 140
 141
 142 # Build pgport once for backend, once for use in frontend binaries, and once
 143 # for use in shared libraries
 144 pgport = {}
 145 pgport_variants = {
 146   '_srv': internal_lib_args + {
 147     'dependencies': [backend_port_code],
 148   },
 149   '': default_lib_args + {
 150     'dependencies': [frontend_port_code],
 151   },
 152   '_shlib': default_lib_args + {
 153     'pic': true,
 154     'dependencies': [frontend_port_code],
 155   },
 156 }
 157
 158 foreach name, opts : pgport_variants
 159
 160   # Build internal static libraries for sets of files that need to be built
 161   # with different cflags
 162   cflag_libs = []
 163   foreach cflagname, sources : pgport_sources_cflags
 164     if sources.length() == 0
 165       continue
 166     endif
 167     c_args = opts.get('c_args', []) + pgport_cflags[cflagname]
 168     cflag_libs += static_library('libpgport@0@_@1@'.format(name, cflagname),
 169       sources,
 170       c_pch: pch_c_h,
 171       kwargs: opts + {
 172         'c_args': c_args,
 173         'build_by_default': false,
 174         'install': false,
 175       },
 176     )
 177   endforeach
 178
 179   lib = static_library('libpgport@0@'.format(name),
 180       pgport_sources,
 181       link_with: cflag_libs,
 182       c_pch: pch_c_h,
 183       kwargs: opts + {
 184         'dependencies': opts['dependencies'] + [ssl],
 185       }
 186     )
 187   pgport += {name: lib}
 188 endforeach
 189
 190 pgport_srv = pgport['_srv']
 191 pgport_static = pgport['']
 192 pgport_shlib = pgport['_shlib']