contrib/postgres_fdw/meson.build

   1 # Copyright (c) 2022-2025, PostgreSQL Global Development Group
   2
   3 postgres_fdw_sources = files(
   4   'connection.c',
   5   'deparse.c',
   6   'option.c',
   7   'postgres_fdw.c',
   8   'shippable.c',
   9 )
  10
  11 if host_system == 'windows'
  12   postgres_fdw_sources += rc_lib_gen.process(win32ver_rc, extra_args: [
  13     '--NAME', 'postgres_fdw',
  14     '--FILEDESC', 'postgres_fdw - foreign data wrapper for PostgreSQL',])
  15 endif
  16
  17 postgres_fdw = shared_module('postgres_fdw',
  18   postgres_fdw_sources,
  19   kwargs: contrib_mod_args + {
  20     'dependencies': contrib_mod_args['dependencies'] + [libpq],
  21   },
  22 )
  23 contrib_targets += postgres_fdw
  24
  25 install_data(
  26   'postgres_fdw.control',
  27   'postgres_fdw--1.0.sql',
  28   'postgres_fdw--1.0--1.1.sql',
  29   'postgres_fdw--1.1--1.2.sql',
  30   kwargs: contrib_data_args,
  31 )
  32
  33 tests += {
  34   'name': 'postgres_fdw',
  35   'sd': meson.current_source_dir(),
  36   'bd': meson.current_build_dir(),
  37   'regress': {
  38     'sql': [
  39       'postgres_fdw',
  40       'query_cancel',
  41     ],
  42     'regress_args': ['--dlpath', meson.build_root() / 'src/test/regress'],
  43   },
  44   'tap': {
  45     'tests': [
  46       't/001_auth_scram.pl',
  47     ],
  48   },
  49 }