doc/src/sgml/stylesheet-text.xsl

   1 <?xml version='1.0'?>
   2 <xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
   3                 version='1.0'
   4                 xmlns="http://www.w3.org/1999/xhtml">
   5
   6 <xsl:import href="http://docbook.sourceforge.net/release/xsl/current/xhtml/docbook.xsl"/>
   7 <xsl:import href="stylesheet-common.xsl" />
   8
   9 <!-- The customizations here are somewhat random in order to make the text
  10      output look good. -->
  11
  12 <!-- no section numbers or ToC -->
  13 <xsl:param name="chapter.autolabel" select="0"/>
  14 <xsl:param name="section.autolabel" select="0"/>
  15 <xsl:param name="generate.toc"></xsl:param>
  16
  17 <!-- don't need them, and they mess up formatting -->
  18 <xsl:template match="indexterm">
  19 </xsl:template>
  20
  21 <xsl:template match="step">
  22   <li>
  23     <xsl:call-template name="common.html.attributes"/>
  24     <xsl:call-template name="id.attribute"/>
  25 <!-- messes up formatting
  26     <xsl:call-template name="anchor"/>
  27 -->
  28     <xsl:apply-templates/>
  29   </li>
  30 </xsl:template>
  31
  32 <!-- produce "ASCII markup" for emphasis and such -->
  33
  34 <xsl:template match="emphasis">
  35   <xsl:text>*</xsl:text>
  36   <xsl:apply-templates/>
  37   <xsl:text>*</xsl:text>
  38 </xsl:template>
  39
  40 <xsl:template match="para/command|para/filename|para/option|para/replaceable">
  41   <xsl:call-template name="gentext.startquote"/>
  42   <xsl:apply-templates/>
  43   <xsl:call-template name="gentext.endquote"/>
  44 </xsl:template>
  45
  46 <xsl:template match="filename/replaceable|firstterm">
  47   <xsl:apply-templates/>
  48 </xsl:template>
  49
  50 <!-- tweak formatting for note, warning, etc. -->
  51 <xsl:template name="nongraphical.admonition">
  52   <div>
  53     <xsl:call-template name="common.html.attributes">
  54       <xsl:with-param name="inherit" select="1"/>
  55     </xsl:call-template>
  56     <xsl:call-template name="id.attribute"/>
  57
  58     <xsl:if test="$admon.textlabel != 0 or title or info/title">
  59       <p>
  60         <b>
  61           <xsl:call-template name="anchor"/>
  62           <xsl:apply-templates select="." mode="object.title.markup"/>:
  63         </b>
  64       </p>
  65     </xsl:if>
  66
  67     <xsl:apply-templates/>
  68   </div>
  69 </xsl:template>
  70
  71 <!-- horizontal rules before titles (matches old DSSSL style) -->
  72
  73 <xsl:template match="sect1/title
  74                     |sect1/info/title
  75                     |sect1info/title"
  76               mode="titlepage.mode" priority="2">
  77   <hr/>
  78   <xsl:call-template name="section.title"/>
  79 </xsl:template>
  80
  81 <xsl:template match="sect2/title
  82                     |sect2/info/title
  83                     |sect2info/title"
  84               mode="titlepage.mode" priority="2">
  85   <hr/>
  86   <xsl:call-template name="section.title"/>
  87 </xsl:template>
  88
  89 <xsl:template match="sect3/title
  90                     |sect3/info/title
  91                     |sect3info/title"
  92               mode="titlepage.mode" priority="2">
  93   <hr/>
  94   <xsl:call-template name="section.title"/>
  95 </xsl:template>
  96
  97 </xsl:stylesheet>