src/pl/plpython/meson.build

   1 # Copyright (c) 2022-2024, PostgreSQL Global Development Group
   2
   3 if not python3_dep.found()
   4   subdir_done()
   5 endif
   6
   7 plpython_sources = files(
   8   'plpy_cursorobject.c',
   9   'plpy_elog.c',
  10   'plpy_exec.c',
  11   'plpy_main.c',
  12   'plpy_planobject.c',
  13   'plpy_plpymodule.c',
  14   'plpy_procedure.c',
  15   'plpy_resultobject.c',
  16   'plpy_spi.c',
  17   'plpy_subxactobject.c',
  18   'plpy_typeio.c',
  19   'plpy_util.c',
  20 )
  21
  22 plpython_sources += custom_target('spiexceptions.h',
  23   input: files('../../backend/utils/errcodes.txt'),
  24   output: 'spiexceptions.h',
  25   command: [perl, files('generate-spiexceptions.pl'), '@INPUT@'],
  26   capture: true,
  27 )
  28
  29
  30 # FIXME: need to duplicate import library ugliness?
  31 plpython_inc = include_directories('.')
  32
  33 if host_system == 'windows'
  34   plpython_sources += rc_lib_gen.process(win32ver_rc, extra_args: [
  35     '--NAME', 'plpython3',
  36     '--FILEDESC', 'PL/Python - procedural language',])
  37 endif
  38
  39 plpython = shared_module('plpython3',
  40   plpython_sources,
  41   c_pch: pch_postgres_h,
  42   include_directories: [plpython_inc, postgres_inc],
  43   kwargs: pg_mod_args + {
  44     'dependencies': [python3_dep, pg_mod_args['dependencies']],
  45   },
  46 )
  47 pl_targets += plpython
  48
  49 # FIXME: Only install the relevant versions
  50 install_data(
  51   'plpython3u.control',
  52   'plpython3u--1.0.sql',
  53   install_dir: dir_data_extension,
  54 )
  55
  56 install_headers(
  57   'plpy_cursorobject.h',
  58   'plpy_elog.h',
  59   'plpy_exec.h',
  60   'plpy_main.h',
  61   'plpy_planobject.h',
  62   'plpy_plpymodule.h',
  63   'plpy_procedure.h',
  64   'plpy_resultobject.h',
  65   'plpy_spi.h',
  66   'plpy_subxactobject.h',
  67   'plpy_typeio.h',
  68   'plpy_util.h',
  69   'plpython.h',
  70   'plpython_system.h',
  71   install_dir: dir_include_server,
  72 )
  73
  74 plpython_regress = [
  75   'plpython_schema',
  76   'plpython_populate',
  77   'plpython_test',
  78   'plpython_do',
  79   'plpython_global',
  80   'plpython_import',
  81   'plpython_spi',
  82   'plpython_newline',
  83   'plpython_void',
  84   'plpython_call',
  85   'plpython_params',
  86   'plpython_setof',
  87   'plpython_record',
  88   'plpython_trigger',
  89   'plpython_types',
  90   'plpython_error',
  91   'plpython_ereport',
  92   'plpython_unicode',
  93   'plpython_quote',
  94   'plpython_composite',
  95   'plpython_subtransaction',
  96   'plpython_transaction',
  97   'plpython_drop',
  98 ]
  99
 100 tests += {
 101   'name': 'plpython',
 102   'sd': meson.current_source_dir(),
 103   'bd': meson.current_build_dir(),
 104   'regress': {
 105     'sql': plpython_regress,
 106   },
 107 }
 108
 109 subdir('po', if_found: libintl)