src/test/modules/injection_points/meson.build

   1 # Copyright (c) 2022-2024, PostgreSQL Global Development Group
   2
   3 if not get_option('injection_points')
   4   subdir_done()
   5 endif
   6
   7 injection_points_sources = files(
   8   'injection_points.c',
   9   'injection_stats.c',
  10   'injection_stats_fixed.c',
  11 )
  12
  13 if host_system == 'windows'
  14   injection_points_sources += rc_lib_gen.process(win32ver_rc, extra_args: [
  15     '--NAME', 'injection_points',
  16     '--FILEDESC', 'injection_points - facility for injection points',])
  17 endif
  18
  19 injection_points = shared_module('injection_points',
  20   injection_points_sources,
  21   kwargs: pg_test_mod_args,
  22 )
  23 test_install_libs += injection_points
  24
  25 test_install_data += files(
  26   'injection_points.control',
  27   'injection_points--1.0.sql',
  28 )
  29
  30 tests += {
  31   'name': 'injection_points',
  32   'sd': meson.current_source_dir(),
  33   'bd': meson.current_build_dir(),
  34   'regress': {
  35     'sql': [
  36       'injection_points',
  37       'reindex_conc',
  38     ],
  39     'regress_args': ['--dlpath', meson.build_root() / 'src/test/regress'],
  40     # The injection points are cluster-wide, so disable installcheck
  41     'runningcheck': false,
  42   },
  43   'isolation': {
  44     'specs': [
  45       'basic',
  46       'inplace',
  47     ],
  48   },
  49   'tap': {
  50     'env': {
  51       'enable_injection_points': get_option('injection_points') ? 'yes' : 'no',
  52     },
  53     'tests': [
  54       't/001_stats.pl',
  55     ],
  56   },
  57 }