CMakeLists.txt

   1 cmake_minimum_required(VERSION 3.2)
   2
   3 # http://www.cmake.org/cmake/help/v3.0/policy/CMP0042.html
   4 if (POLICY CMP0042)
   5         cmake_policy (SET CMP0042 NEW)
   6 endif()
   7
   8 if (POLICY CMP0072)
   9         cmake_policy (SET CMP0072 OLD)
  10 endif()
  11
  12 project (piglit)
  13
  14 list(APPEND CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/cmake/Modules")
  15
  16 INCLUDE (GNUInstallDirs)
  17 INCLUDE (CheckCCompilerFlag)
  18 INCLUDE (CheckCSourceCompiles)
  19 INCLUDE (CheckCXXCompilerFlag)
  20 INCLUDE (CheckFunctionExists)
  21 INCLUDE (CheckSymbolExists)
  22 INCLUDE (CheckIncludeFile)
  23 INCLUDE (FindPkgConfig)
  24
  25 set(CMAKE_EXPORT_COMPILE_COMMANDS ON)
  26
  27 find_package(Threads)
  28 find_package(PNG)
  29 if(PNG_FOUND)
  30         add_definitions(-DPIGLIT_HAS_PNG)
  31 endif(PNG_FOUND)
  32 find_package(X11)
  33 if(X11_FOUND)
  34         set(PIGLIT_HAS_X11 True)
  35         add_definitions(-DPIGLIT_HAS_X11)
  36 endif()
  37
  38 if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
  39         set(PIGLIT_BUILD_GLES_TESTS_DEFAULT ON)
  40         set(PIGLIT_BUILD_VK_TESTS_DEFAULT ON)
  41 else()
  42         set(PIGLIT_BUILD_GLES_TESTS_DEFAULT OFF)
  43         set(PIGLIT_BUILD_VK_TESTS_DEFAULT OFF)
  44 endif()
  45
  46 option(PIGLIT_SSE2 "Build with SSE2 support on 32-bit x86 architecture" ON)
  47
  48 option(PIGLIT_BUILD_GL_TESTS "Build tests for OpenGL" ON)
  49 option(PIGLIT_BUILD_GLES1_TESTS "Build tests for OpenGL ES1" ${PIGLIT_BUILD_GLES_TESTS_DEFAULT})
  50 option(PIGLIT_BUILD_GLES2_TESTS "Build tests for OpenGL ES2" ${PIGLIT_BUILD_GLES_TESTS_DEFAULT})
  51 option(PIGLIT_BUILD_GLES3_TESTS "Build tests for OpenGL ES3" ${PIGLIT_BUILD_GLES_TESTS_DEFAULT})
  52 option(PIGLIT_BUILD_CL_TESTS "Build tests for OpenCL" OFF)
  53 option(PIGLIT_BUILD_VK_TESTS "Build tests for Vulkan" ${PIGLIT_BUILD_VK_TESTS_DEFAULT})
  54
  55 if(PIGLIT_BUILD_GL_TESTS)
  56         find_package(OpenGL REQUIRED)
  57 endif()
  58
  59 if(${CMAKE_SYSTEM_NAME} MATCHES "Linux")
  60         option(PIGLIT_USE_WAFFLE "Use Waffle in place of GLUT" ON)
  61 else()
  62         option(PIGLIT_USE_WAFFLE "Use Waffle in place of GLUT" OFF)
  63 endif()
  64
  65 if(PIGLIT_USE_WAFFLE)
  66         if (NOT WIN32)
  67                 pkg_check_modules(Waffle REQUIRED waffle-1)
  68
  69                 if(NOT Waffle_FOUND)
  70                         message(FATAL_ERROR "Failed to find Waffle. If Waffle "
  71                         "is not packaged for your distribution, you can get "
  72                         "it at https://gitlab.freedesktop.org/mesa/waffle."
  73                 )
  74                 endif()
  75
  76                 # Check the installed waffle version.
  77                 #
  78                 # We cannot reliably check the version with pkg_check_modules(), but
  79                 # instead must check the version manually as below. The problem is that,
  80                 # if one passes a required version to pkg_check_modules(), CMake
  81                 # validates the required version at most once for the lifetime of the
  82                 # source tree.  If someone changes the required version by editing the
  83                 # CMakeLists, CMake fails to detect the new requirement.
  84                 set(Waffle_REQUIRED_VERSION "1.6.0")
  85                 if(Waffle_VERSION VERSION_LESS Waffle_REQUIRED_VERSION)
  86                         message(FATAL_ERROR "Found waffle-${Waffle_VERSION}, but "
  87                         "piglit requires waffle-${Waffle_REQUIRED_VERSION}")
  88                 endif()
  89         else ()
  90                 find_path(Waffle_INCLUDE_DIRS waffle.h)
  91                 find_library(Waffle_LDFLAGS waffle-1)
  92                 if(Waffle_INCLUDE_DIRS AND Waffle_LDFLAGS)
  93                         set(Waffle_FOUND TRUE)
  94                 else()
  95                         message(FATAL_ERROR "Failed to find Waffle. Get and build Waffle from "
  96                                 "https://gitlab.freedesktop.org/mesa/waffle and set "
  97                                 "Waffle_INCLUDE_DIRS and Waffle_LDFLAGS variables accordingly."
  98                         )
  99                 endif()
 100         endif ()
 101
 102         add_definitions(-DPIGLIT_USE_WAFFLE)
 103         add_definitions(-DWAFFLE_API_VERSION=0x0103)
 104 else()
 105         find_package(GLUT REQUIRED)
 106
 107         # The 'REQUIRED' above correctly produces an error for
 108         # OpenGL, but there's a bug involving FindGLUT.cmake
 109         # that fails to produce the error as of CMake 2.8.5.
 110         #
 111         # Instead, CMake keeps going and eventually spams
 112         # the console with a message for every target that used
 113         # e.g. the ${GLUT_INCLUDE_DIR} variable. So it
 114         # prints a line for basically every single test in piglit.
 115         #
 116         # Work around the bug and error out quickly here instead.
 117         if (NOT GLUT_FOUND)
 118                 message(FATAL_ERROR "GLUT library not found")
 119         endif()
 120 endif(PIGLIT_USE_WAFFLE)
 121
 122 if(PIGLIT_BUILD_GLES1_TESTS AND NOT PIGLIT_USE_WAFFLE)
 123         message(FATAL_ERROR "Option PIGLIT_BUILD_GLES1_TESTS requires PIGLIT_USE_WAFFLE")
 124 endif(PIGLIT_BUILD_GLES1_TESTS AND NOT PIGLIT_USE_WAFFLE)
 125
 126 if(PIGLIT_BUILD_GLES2_TESTS AND NOT PIGLIT_USE_WAFFLE)
 127         message(FATAL_ERROR "Option PIGLIT_BUILD_GLES2_TESTS requires PIGLIT_USE_WAFFLE")
 128 endif(PIGLIT_BUILD_GLES2_TESTS AND NOT PIGLIT_USE_WAFFLE)
 129
 130 if(PIGLIT_BUILD_GLES3_TESTS AND NOT PIGLIT_USE_WAFFLE)
 131         message(FATAL_ERROR "Option PIGLIT_BUILD_GLES3_TESTS requires PIGLIT_USE_WAFFLE")
 132 endif(PIGLIT_BUILD_GLES3_TESTS AND NOT PIGLIT_USE_WAFFLE)
 133
 134 if(PIGLIT_BUILD_CL_TESTS)
 135         find_package(OpenCL 1.2 REQUIRED)
 136 endif(PIGLIT_BUILD_CL_TESTS)
 137
 138 IF(${CMAKE_SYSTEM_NAME} MATCHES "Linux")
 139         if(X11_FOUND AND OPENGL_gl_LIBRARY AND PIGLIT_BUILD_GLX_TESTS)
 140                 set(PIGLIT_HAS_GLX True)
 141                 add_definitions(-DPIGLIT_HAS_GLX)
 142         endif()
 143
 144         pkg_check_modules(GBM QUIET gbm>=17.1)
 145         if(GBM_FOUND)
 146                 set(PIGLIT_HAS_GBM True)
 147                 add_definitions(-DPIGLIT_HAS_GBM)
 148                 set(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} ${GBM_LIBRARIES})
 149                 CHECK_FUNCTION_EXISTS(gbm_bo_map PIGLIT_HAS_GBM_BO_MAP)
 150                 if (PIGLIT_HAS_GBM_BO_MAP)
 151                         add_definitions(-DPIGLIT_HAS_GBM_BO_MAP)
 152                 endif()
 153                 CHECK_FUNCTION_EXISTS(gbm_bo_get_fd_for_plane PIGLIT_HAS_GBM_BO_GET_FD_FOR_PLANE)
 154                 if (PIGLIT_HAS_GBM_BO_GET_FD_FOR_PLANE)
 155                         add_definitions(-DPIGLIT_HAS_GBM_BO_GET_FD_FOR_PLANE)
 156                 endif()
 157         endif(GBM_FOUND)
 158
 159         pkg_check_modules(WAYLAND QUIET wayland-client)
 160         if (WAYLAND_FOUND)
 161                 set(PIGLIT_HAS_WAYLAND True)
 162                 add_definitions(-DPIGLIT_HAS_WAYLAND)
 163
 164                 FIND_LIBRARY(HAVE_XKBCOMMON NAMES xkbcommon)
 165                 if(NOT HAVE_XKBCOMMON)
 166                         message(FATAL_ERROR "Wayland support requires xkbcommon. "
 167                                 "Failed to find xkbcommon library.")
 168                 endif()
 169                 pkg_check_modules(XKBCOMMON QUIET xkbcommon)
 170         endif()
 171
 172         pkg_check_modules(LIBDRM QUIET libdrm)
 173         pkg_check_modules(XCB QUIET xcb)
 174         pkg_check_modules(XCB_DRI2 QUIET xcb-dri2)
 175         pkg_check_modules(GLPROTO QUIET glproto)
 176         pkg_check_modules(LIBVULKAN QUIET vulkan)
 177 ELSEIF(${CMAKE_SYSTEM_NAME} MATCHES "Windows")
 178         if (PIGLIT_USE_WAFFLE)
 179                 set(PIGLIT_HAS_WGL True)
 180                 add_definitions(-DPIGLIT_HAS_WGL)
 181         endif()
 182 ENDIF()
 183
 184 if(PIGLIT_BUILD_VK_TESTS)
 185
 186 if (NOT LIBVULKAN_FOUND)
 187         message(FATAL_ERROR "libvulkan required by vulkan tests not found")
 188 endif()
 189
 190 find_program(GLSLANG_VALIDATOR NAMES glslangValidator)
 191
 192 if (NOT GLSLANG_VALIDATOR)
 193         message(FATAL_ERROR "glslangValidator required by vulkan tests not found")
 194 endif()
 195
 196 endif(PIGLIT_BUILD_VK_TESTS)
 197
 198 IF(PIGLIT_HAS_GLX)
 199         option(PIGLIT_BUILD_GLX_TESTS "Build tests that require GLX" ON)
 200 ELSE()
 201         option(PIGLIT_BUILD_GLX_TESTS "Build tests that require GLX" OFF)
 202 ENDIF()
 203
 204 IF(PIGLIT_HAS_WGL)
 205         option(PIGLIT_BUILD_WGL_TESTS "Build tests that require WGL" ON)
 206 ELSE()
 207         option(PIGLIT_BUILD_WGL_TESTS "Build tests that require WGL" OFF)
 208 ENDIF()
 209
 210
 211 # Choose to build tests that use dma_buf.
 212 #
 213 # Piglit's dma_buf utilities require xcb-dri2 to gain DRM authentication, and
 214 # gbm_bo_map() to be available for generating dma_bufs, and libdrm for fourcc
 215 # definitions.
 216 #
 217 if(LIBDRM_FOUND AND LIBDRM_VERSION VERSION_GREATER "2.4.97" AND XCB_DRI2_FOUND AND PIGLIT_HAS_GBM_BO_MAP)
 218         set(PIGLIT_BUILD_DMA_BUF_TESTS_IS_VALID true)
 219 else()
 220         set(PIGLIT_BUILD_DMA_BUF_TESTS_IS_VALID false)
 221 endif()
 222
 223 if(PIGLIT_BUILD_DMA_BUF_TESTS_IS_VALID)
 224         option(PIGLIT_BUILD_DMA_BUF_TESTS "Build tests that use dma_buf" ON)
 225 else()
 226         option(PIGLIT_BUILD_DMA_BUF_TESTS "Build tests that use dma_buf" OFF)
 227 endif()
 228
 229 # If the users has updated PIGLIT_BUILD_DMA_BUF_TESTS in the CMakeCache, then
 230 # we need to validate it.
 231 if(PIGLIT_BUILD_DMA_BUF_TESTS AND NOT PIGLIT_BUILD_DMA_BUF_TESTS_IS_VALID)
 232         message(FATAL_ERROR
 233                 "PIGLIT_BUILD_DMA_BUF_TESTS require libdrm, "
 234                 "gbm_bo_map(), libdrm>=2.4.98 and xcb-dri2")
 235 endif()
 236
 237 IF(PIGLIT_BUILD_GLX_TESTS)
 238         pkg_check_modules(GLPROTO REQUIRED glproto)
 239 ENDIF()
 240
 241 if (NOT Python_ADDITIONAL_VERSIONS)
 242         set(Python_ADDITIONAL_VERSIONS 3.11 3.10 3.9 3.8 3.7 3.6)
 243 endif()
 244 find_package(PythonInterp REQUIRED)
 245 find_package(PythonNumpy 1.7.0 REQUIRED)
 246 find_package(PythonMako 1.0.2 REQUIRED)
 247
 248 find_package(bash-completion NO_MODULE)
 249
 250 # Default to compiling with debug information (`gcc -g`):
 251 if(NOT CMAKE_BUILD_TYPE)
 252         SET(CMAKE_BUILD_TYPE Debug CACHE STRING
 253         "May be one of: None Debug RelWithDebInfo Release MinSizeRel" FORCE)
 254 endif(NOT CMAKE_BUILD_TYPE)
 255
 256 if (NOT MSVC)
 257         if (PIGLIT_SSE2 AND CMAKE_SYSTEM_PROCESSOR MATCHES "(x86)|(X86)")
 258                 # enables SSE2 and precision used on x86-64 by default
 259                 SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -msse2 -mfpmath=sse")
 260                 SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -msse2 -mfpmath=sse")
 261         else()
 262                 # degrade performance a bit, but enforce required precision
 263                 SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -ffloat-store")
 264                 SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -ffloat-store")
 265         endif()
 266         CHECK_C_COMPILER_FLAG("-Wall" C_COMPILER_FLAG_WALL)
 267         IF (C_COMPILER_FLAG_WALL)
 268                 SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wall")
 269         ENDIF (C_COMPILER_FLAG_WALL)
 270         CHECK_CXX_COMPILER_FLAG("-Wall" CXX_COMPILER_FLAG_WALL)
 271         IF (CXX_COMPILER_FLAG_WALL)
 272                 SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wall")
 273         ENDIF (CXX_COMPILER_FLAG_WALL)
 274
 275         # Target C99.  GCC's default is gnu11 for 5.0 and newer, gnu89 for
 276         # older versions.
 277         check_c_compiler_flag ("-std=gnu99" C_COMPILER_FLAG_STD_GNU99)
 278         if (C_COMPILER_FLAG_STD_GNU99)
 279                 set (CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -std=gnu99")
 280         endif ()
 281         # MSVC does not support C99 variable length arrays
 282         CHECK_C_COMPILER_FLAG("-Werror=vla" C_COMPILER_FLAG_WEVLA)
 283         IF (C_COMPILER_FLAG_WEVLA)
 284                 SET (CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Werror=vla")
 285         ENDIF ()
 286         # GCC allows void pointer arithmetic, but it is not part of ISO C and
 287         # in particular MSVC will throw `C2036: 'void *' : unknown size`
 288         check_c_compiler_flag ("-Werror=pointer-arith" C_COMPILER_FLAG_WEPOINTER_ARITH)
 289         if (C_COMPILER_FLAG_WEPOINTER_ARITH)
 290                 set (CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Werror=pointer-arith")
 291         endif ()
 292         # MSVC only supports C99 variadic macros.  It doesn't support the
 293         # non-standard GNU named variadic macro syntax that's documented in
 294         # https://gcc.gnu.org/onlinedocs/cpp/Variadic-Macros.html
 295         #
 296         # XXX: on older GCC version this option has no effect unless -Wpedantic
 297         # is set, but this should be fixed on future GCC versions, per
 298         # https://gcc.gnu.org/ml/gcc-patches/2014-04/msg01459.html
 299         check_c_compiler_flag ("-Werror=variadic-macros" C_COMPILER_FLAG_WVARIADIC_MACROS)
 300         if (C_COMPILER_FLAG_WVARIADIC_MACROS)
 301                 set (CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Werror=variadic-macros")
 302         endif ()
 303
 304         CHECK_CXX_COMPILER_FLAG("-Wno-narrowing" CXX_COMPILER_FLAG_WNO_NARROWING)
 305         IF (CXX_COMPILER_FLAG_WNO_NARROWING)
 306                 SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wno-narrowing")
 307         ENDIF (CXX_COMPILER_FLAG_WNO_NARROWING)
 308 else ()
 309         # Adjust warnings
 310         add_definitions (-W3)
 311         add_definitions (-wd4018) # signed/unsigned mismatch
 312         add_definitions (-wd4244) # conversion from 'type1' to 'type2', possible loss of data
 313         add_definitions (-wd4305) # truncation from 'type1' to 'type2'
 314         add_definitions (-wd4800) # forcing value to bool 'true' or 'false' (performance warning)
 315
 316         add_definitions (-D_CRT_SECURE_NO_DEPRECATE -D_CRT_SECURE_NO_WARNINGS -D_CRT_NONSTDC_NO_WARNINGS)
 317         add_definitions (-D_SCL_SECURE_NO_DEPRECATE -D_SCL_SECURE_NO_WARNINGS)
 318 endif ()
 319
 320 if (MINGW)
 321         # Match MSVC default stack size
 322         set (CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -Wl,--stack,1048576")
 323 endif ()
 324
 325 if (${CMAKE_C_COMPILER_ID} STREQUAL "SunPro")
 326         # Use C++ to link C files.
 327         # http://developers.sun.com/solaris/articles/mixing.html#linking
 328         # Modified rule from Modules/CMakeCInformation.cmake.
 329         set (CMAKE_C_LINK_EXECUTABLE
 330                 "<CMAKE_CXX_COMPILER> <FLAGS> <CMAKE_C_LINK_FLAGS> <LINK_FLAGS> <OBJECTS> -o <TARGET> <LINK_LIBRARIES>")
 331 endif()
 332
 333 # Always enable GNU C extensions.  Non-GNU platforms will need to
 334 # define wrappers for them.
 335 add_definitions(-D_GNU_SOURCE)
 336
 337 if (WIN32)
 338         # MSVC & MinGW only define & use APIENTRY
 339         add_definitions (-DGLAPIENTRY=__stdcall)
 340
 341         # Avoid namespace pollution when including windows.h
 342         # http://support.microsoft.com/kb/166474
 343         add_definitions (-DWIN32_LEAN_AND_MEAN=1)
 344
 345         # Don't define min/max macros
 346         add_definitions (-DNOMINMAX)
 347
 348         # Even more no min/max macros
 349         add_definitions (-D_CRT_DECLARE_NONSTDC_NAMES=0)
 350
 351         # Define M_PI and others
 352         add_definitions (-D_USE_MATH_DEFINES)
 353 endif (WIN32)
 354
 355 if (APPLE)
 356         # Don't warn about using deprecated OpenGL/GLUT functions.
 357         # TODO: It would be nice to silence just the deprecation macros from
 358         # OpenGLAvailability.h as opposed to all deprecated functions.
 359         set (CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wno-deprecated-declarations")
 360         set (CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wno-deprecated-declarations")
 361 endif ()
 362
 363 if (OPENGL_FOUND)
 364         if (APPLE)
 365                 find_path(GLEXT_INCLUDE_DIR
 366                         NAMES OpenGL/glext.h
 367                         PATHS ${OPENGL_INCLUDE_DIR}
 368                         DOC "Include for OpenGL/glext.h on OSX"
 369                 )
 370         else (APPLE)
 371                 find_path(GLEXT_INCLUDE_DIR
 372                         NAMES GL/glext.h
 373                         PATHS ${OPENGL_INCLUDE_DIR}
 374                         DOC "Include for GL/glext.h"
 375                 )
 376         endif (APPLE)
 377 endif()
 378
 379 if(CMAKE_USE_PTHREADS_INIT)
 380         set(PIGLIT_HAS_PTHREADS true)
 381         add_definitions(-DPIGLIT_HAS_PTHREADS)
 382 endif()
 383
 384 FIND_LIBRARY(HAVE_LIBRT NAMES rt)
 385 if(HAVE_LIBRT)
 386         set(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} rt)
 387 endif()
 388
 389 check_c_source_compiles(
 390         "
 391         #define _POSIX_C_SOURCE 199309L
 392         #include <time.h>
 393         int main() { return clock_gettime(CLOCK_MONOTONIC, NULL); }
 394         "
 395         PIGLIT_HAS_POSIX_CLOCK_MONOTONIC
 396 )
 397
 398 if(PIGLIT_HAS_PTHREADS AND PIGLIT_HAS_POSIX_CLOCK_MONOTONIC)
 399         check_c_source_compiles(
 400                 "
 401                 #include <signal.h>
 402                 #include <time.h>
 403                 static void timeout(union sigval val) { }
 404                 int main() {
 405                         struct sigevent sev = {
 406                                 .sigev_notify = SIGEV_THREAD,
 407                                 .sigev_notify_function = timeout,
 408                         };
 409                         timer_t timerid;
 410                         return timer_create(CLOCK_MONOTONIC, &sev, &timerid);
 411                 }
 412                 "
 413                 PIGLIT_HAS_POSIX_TIMER_NOTIFY_THREAD
 414         )
 415 endif()
 416
 417 set(CMAKE_REQUIRED_LIBRARIES)
 418
 419 if(PIGLIT_HAS_POSIX_CLOCK_MONOTONIC)
 420         add_definitions(-DPIGLIT_HAS_POSIX_CLOCK_MONOTONIC)
 421 endif()
 422
 423 if(PIGLIT_HAS_POSIX_TIMER_NOTIFY_THREAD)
 424         add_definitions(-DPIGLIT_HAS_POSIX_TIMER_NOTIFY_THREAD)
 425 endif()
 426
 427 if(GBM_FOUND)
 428 FIND_LIBRARY(HAVE_LIBCACA NAMES caca)
 429 if(HAVE_LIBCACA)
 430         set(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} caca)
 431         add_definitions(-DPIGLIT_HAS_LIBCACA)
 432 endif(HAVE_LIBCACA)
 433 endif(GBM_FOUND)
 434
 435 if(PIGLIT_USE_WAFFLE AND ${CMAKE_SYSTEM_NAME} STREQUAL "Linux")
 436         pkg_check_modules(EGL egl)
 437 endif()
 438
 439 if(EGL_FOUND)
 440         set(PIGLIT_HAS_EGL True)
 441         add_definitions(-DPIGLIT_HAS_EGL)
 442         include_directories(${EGL_INCLUDE_DIRS})
 443         add_definitions (${EGL_CFLAGS_OTHER})
 444 endif()
 445
 446 if(PIGLIT_BUILD_GLES1_TESTS AND NOT EGL_FOUND)
 447         message(FATAL_ERROR "Option PIGLIT_BUILD_GLES1_TESTS requires EGL. "
 448                             "Failed to find EGL library.")
 449 endif()
 450
 451 if(PIGLIT_BUILD_GLES2_TESTS AND NOT EGL_FOUND)
 452         message(FATAL_ERROR "Option PIGLIT_BUILD_GLES2_TESTS requires EGL. "
 453                             "Failed to find EGL library.")
 454 endif()
 455
 456 if(PIGLIT_BUILD_GLES3_TESTS AND NOT EGL_FOUND)
 457         message(FATAL_ERROR "Option PIGLIT_BUILD_GLES3_TESTS requires EGL. "
 458                             "Failed to find EGL library.")
 459 endif()
 460
 461 # Put all executables into the bin subdirectory
 462 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${piglit_BINARY_DIR}/bin)
 463 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${piglit_BINARY_DIR}/lib)
 464
 465 # Do the same for MSVC, regardless of the build type. This only works correctly
 466 # for CMake 2.8.1 and above.
 467 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY_DEBUG ${piglit_BINARY_DIR}/bin)
 468 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY_RELEASE ${piglit_BINARY_DIR}/bin)
 469 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY_MINSIZEREL ${piglit_BINARY_DIR}/bin)
 470 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY_RELWITHDEBINFO ${piglit_BINARY_DIR}/bin)
 471
 472 check_function_exists(asprintf  HAVE_ASPRINTF)
 473 check_function_exists(ffs       HAVE_FFS)
 474 check_function_exists(strchrnul HAVE_STRCHRNUL)
 475 check_function_exists(strndup   HAVE_STRNDUP)
 476 if(NOT MINGW)
 477 check_function_exists(fopen_s   HAVE_FOPEN_S)
 478 endif()
 479 check_function_exists(setrlimit HAVE_SETRLIMIT)
 480
 481 check_symbol_exists(htobe32 "endian.h" HAVE_HTOBE32)
 482 check_symbol_exists(htole16 "endian.h" HAVE_HTOLE16)
 483 check_symbol_exists(htole32 "endian.h" HAVE_HTOLE32)
 484 check_symbol_exists(htole64 "endian.h" HAVE_HTOLE64)
 485
 486 check_include_file(sys/time.h  HAVE_SYS_TIME_H)
 487 check_include_file(sys/types.h HAVE_SYS_TYPES_H)
 488 check_include_file(sys/resource.h  HAVE_SYS_RESOURCE_H)
 489 check_include_file(sys/stat.h  HAVE_SYS_STAT_H)
 490 check_include_file(unistd.h    HAVE_UNISTD_H)
 491 check_include_file(fcntl.h     HAVE_FCNTL_H)
 492 check_include_file(linux/sync_file.h HAVE_LINUX_SYNC_FILE_H)
 493 check_include_file(endian.h    HAVE_ENDIAN_H)
 494
 495 if(DEFINED PIGLIT_INSTALL_VERSION)
 496         set(PIGLIT_INSTALL_VERSION_SUFFIX
 497             "-${PIGLIT_INSTALL_VERSION}")
 498 else()
 499         set(PIGLIT_INSTALL_VERSION_SUFFIX "")
 500 endif()
 501 set(PIGLIT_INSTALL_LIBDIR
 502     "${CMAKE_INSTALL_LIBDIR}/piglit${PIGLIT_INSTALL_VERSION_SUFFIX}")
 503 if(NOT IS_ABSOLUTE ${PIGLIT_INSTALL_LIBDIR})
 504         set(PIGLIT_INSTALL_FULL_LIBDIR "${CMAKE_INSTALL_PREFIX}/${PIGLIT_INSTALL_LIBDIR}")
 505 else()
 506         set(PIGLIT_INSTALL_FULL_LIBDIR "${PIGLIT_INSTALL_LIBDIR}")
 507 endif()
 508
 509 if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
 510   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -Wl,--enable-new-dtags")
 511 endif(CMAKE_SYSTEM_NAME STREQUAL "Linux")
 512
 513 SET(CMAKE_INSTALL_RPATH "${PIGLIT_INSTALL_FULL_LIBDIR}/lib")
 514
 515 configure_file(
 516         "${piglit_SOURCE_DIR}/tests/util/config.h.in"
 517         "${piglit_BINARY_DIR}/tests/util/config.h"
 518 )
 519
 520 include(cmake/piglit_util.cmake)
 521 include(cmake/piglit_dispatch.cmake)
 522
 523 include_directories(src)
 524 add_subdirectory(cmake/target_api)
 525 add_subdirectory(generated_tests)
 526 add_subdirectory(replayer)
 527
 528
 529 ##############################################################################
 530 # Packaging
 531
 532 install (
 533         FILES
 534                 COPYING
 535                 README.md
 536                 RELEASE
 537         DESTINATION share/doc/piglit${PIGLIT_INSTALL_VERSION_SUFFIX}
 538 )
 539
 540 install (
 541         DIRECTORY framework
 542         DESTINATION ${PIGLIT_INSTALL_LIBDIR}
 543         FILES_MATCHING PATTERN "*.py"
 544 )
 545
 546 install (
 547         DIRECTORY templates
 548         DESTINATION ${PIGLIT_INSTALL_LIBDIR}
 549 )
 550
 551 install (
 552         DIRECTORY tests
 553         DESTINATION ${PIGLIT_INSTALL_LIBDIR}
 554         FILES_MATCHING REGEX ".*\\.(xml|xml.gz|py|program_test|shader_test|shader_source|frag|vert|geom|tesc|tese|comp|spv|ktx|cl|txt|inc|vk_shader_test)$"
 555         REGEX "CMakeFiles|CMakeLists|serializer.py|opengl.py|cl.py|quick_gl.py|glslparser.py|shader.py|quick_shader.py|no_error.py|llvmpipe_gl.py|sanity.py" EXCLUDE
 556 )
 557
 558 install (
 559         DIRECTORY ${CMAKE_BINARY_DIR}/tests
 560         DESTINATION ${PIGLIT_INSTALL_LIBDIR}
 561         FILES_MATCHING REGEX ".*\\.xml.gz"
 562 )
 563
 564 install (
 565         DIRECTORY ${CMAKE_BINARY_DIR}/generated_tests
 566         DESTINATION ${PIGLIT_INSTALL_LIBDIR}
 567         FILES_MATCHING REGEX ".*\\.(shader_test|program_test|frag|vert|geom|tesc|tese|comp|cl|txt|vk_shader_test)$"
 568         REGEX "CMakeFiles|CMakeLists" EXCLUDE
 569 )
 570
 571 install (
 572         DIRECTORY generated_tests
 573         DESTINATION ${PIGLIT_INSTALL_LIBDIR}
 574         FILES_MATCHING REGEX ".*\\.inc$"
 575         REGEX "CMakeFiles|CMakeLists" EXCLUDE
 576 )
 577
 578 if (BASH_COMPLETION_FOUND)
 579         install(
 580                 FILES completions/bash/piglit
 581                 DESTINATION ${CMAKE_INSTALL_PREFIX}/${BASH_COMPLETION_COMPLETIONSDIR}/
 582         )
 583 endif (BASH_COMPLETION_FOUND)
 584
 585 if (WIN32)
 586         set (PYTHON_SUFFIX ".py")
 587 else ()
 588         set (PYTHON_SUFFIX "")
 589 endif ()
 590 install (
 591         PROGRAMS piglit RENAME piglit${PIGLIT_INSTALL_VERSION_SUFFIX}${PYTHON_SUFFIX}
 592         DESTINATION ${CMAKE_INSTALL_BINDIR}
 593 )
 594
 595 # Install MinGW runtime DLLs
 596 if (MINGW)
 597         if (CMAKE_SIZEOF_VOID_P EQUAL 8)
 598                 set (LIBGCC_DLL_NAME libgcc_s_seh-1.dll)
 599         else ()
 600                 set (LIBGCC_DLL_NAME libgcc_s_sjlj-1.dll)
 601         endif ()
 602         execute_process (
 603                 COMMAND ${CMAKE_C_COMPILER} -print-file-name=${LIBGCC_DLL_NAME}
 604                 OUTPUT_STRIP_TRAILING_WHITESPACE
 605                 OUTPUT_VARIABLE LIBGCC_DLL
 606         )
 607         execute_process (
 608                 COMMAND ${CMAKE_CXX_COMPILER} -print-file-name=libstdc++-6.dll
 609                 OUTPUT_STRIP_TRAILING_WHITESPACE
 610                 OUTPUT_VARIABLE LIBSTDCXX_DLL
 611         )
 612         if (EXISTS ${LIBGCC_DLL})
 613                 message (STATUS "Found libgcc DLL: ${LIBGCC_DLL}")
 614                 install (FILES ${LIBGCC_DLL} DESTINATION ${PIGLIT_INSTALL_LIBDIR}/bin)
 615         endif ()
 616         if (EXISTS ${LIBSTDCXX_DLL})
 617                 message (STATUS "Found libstdc++ DLL: ${LIBSTDCXX_DLL}")
 618                 install (FILES ${LIBSTDCXX_DLL} DESTINATION ${PIGLIT_INSTALL_LIBDIR}/bin)
 619         endif ()
 620 endif ()
 621
 622 # Install Waffle DLL if specified
 623 if (WIN32 AND Waffle_DLL)
 624         install (FILES ${Waffle_DLL} DESTINATION ${PIGLIT_INSTALL_LIBDIR}/bin)
 625 endif ()
 626
 627
 628 set (CPACK_PACKAGE_VERSION_MAJOR "1")
 629 set (CPACK_PACKAGE_VERSION_MINOR "0")
 630
 631 # Use current date in YYYYMMDD format as patch number
 632 execute_process (
 633         COMMAND ${PYTHON_EXECUTABLE} -c "import time, sys; sys.stdout.write(time.strftime('%Y%m%d'))"
 634         OUTPUT_VARIABLE CPACK_PACKAGE_VERSION_PATCH
 635 )
 636
 637 # cpack mistakenly detects Mingw-w64 as win32
 638 if (MINGW)
 639         if (CMAKE_SIZEOF_VOID_P EQUAL 8)
 640                 set (CPACK_SYSTEM_NAME win64)
 641         endif ()
 642 endif ()
 643
 644 # See http://www.vtk.org/Wiki/CMake:CPackPackageGenerators
 645 if (WIN32)
 646         set (CPACK_GENERATOR "7Z")
 647         set (CPACK_STRIP_FILES ON)
 648 else ()
 649         set (CPACK_GENERATOR "TBZ2")
 650 endif ()
 651
 652 include(CPack)