CMakeLists.txt

   1 cmake_minimum_required(VERSION 3.2)
   2
   3 list(APPEND CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/cmake/Modules")
   4
   5 INCLUDE (GNUInstallDirs)
   6 INCLUDE (CheckCCompilerFlag)
   7 INCLUDE (CheckCSourceCompiles)
   8 INCLUDE (CheckCXXCompilerFlag)
   9 INCLUDE (CheckFunctionExists)
  10 INCLUDE (CheckSymbolExists)
  11 INCLUDE (CheckIncludeFile)
  12 INCLUDE (FindPkgConfig)
  13
  14 # http://www.cmake.org/cmake/help/v3.0/policy/CMP0042.html
  15 if (POLICY CMP0042)
  16         cmake_policy (SET CMP0042 NEW)
  17 endif()
  18
  19 if (POLICY CMP0072)
  20         cmake_policy (SET CMP0072 OLD)
  21 endif()
  22
  23 project (piglit)
  24
  25 set(CMAKE_EXPORT_COMPILE_COMMANDS ON)
  26
  27 find_package(Threads)
  28 find_package(PNG)
  29 if(PNG_FOUND)
  30         add_definitions(-DPIGLIT_HAS_PNG)
  31 endif(PNG_FOUND)
  32 find_package(X11)
  33 if(X11_FOUND)
  34         set(PIGLIT_HAS_X11 True)
  35         add_definitions(-DPIGLIT_HAS_X11)
  36 endif()
  37
  38 if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
  39         set(PIGLIT_BUILD_GLES_TESTS_DEFAULT ON)
  40 else()
  41         set(PIGLIT_BUILD_GLES_TESTS_DEFAULT OFF)
  42 endif()
  43
  44 option(PIGLIT_BUILD_GL_TESTS "Build tests for OpenGL" ON)
  45 option(PIGLIT_BUILD_GLES1_TESTS "Build tests for OpenGL ES1" ${PIGLIT_BUILD_GLES_TESTS_DEFAULT})
  46 option(PIGLIT_BUILD_GLES2_TESTS "Build tests for OpenGL ES2" ${PIGLIT_BUILD_GLES_TESTS_DEFAULT})
  47 option(PIGLIT_BUILD_GLES3_TESTS "Build tests for OpenGL ES3" ${PIGLIT_BUILD_GLES_TESTS_DEFAULT})
  48 option(PIGLIT_BUILD_CL_TESTS "Build tests for OpenCL" OFF)
  49
  50 if(PIGLIT_BUILD_GL_TESTS)
  51         find_package(OpenGL REQUIRED)
  52 endif()
  53
  54 if(${CMAKE_SYSTEM_NAME} MATCHES "Linux")
  55         option(PIGLIT_USE_WAFFLE "Use Waffle in place of GLUT" ON)
  56 else()
  57         option(PIGLIT_USE_WAFFLE "Use Waffle in place of GLUT" OFF)
  58 endif()
  59
  60 if(PIGLIT_USE_WAFFLE)
  61         if (NOT WIN32)
  62                 pkg_check_modules(Waffle REQUIRED waffle-1)
  63
  64                 if(NOT Waffle_FOUND)
  65                         message(FATAL_ERROR "Failed to find Waffle. If Waffle "
  66                         "is not packaged for your distribution, you can get "
  67                         "it at http://www.waffle-gl.org."
  68                 )
  69                 endif()
  70
  71                 # Check the installed waffle version.
  72                 #
  73                 # We cannot reliably check the version with pkg_check_modules(), but
  74                 # instead must check the version manually as below. The problem is that,
  75                 # if one passes a required version to pkg_check_modules(), CMake
  76                 # validates the required version at most once for the lifetime of the
  77                 # source tree.  If someone changes the required version by editing the
  78                 # CMakeLists, CMake fails to detect the new requirement.
  79                 set(Waffle_REQUIRED_VERSION "1.5.0")
  80                 if(Waffle_VERSION VERSION_LESS Waffle_REQUIRED_VERSION)
  81                         message(FATAL_ERROR "Found waffle-${Waffle_VERSION}, but "
  82                         "piglit requires waffle-${Waffle_REQUIRED_VERSION}")
  83                 endif()
  84         else ()
  85                 find_path(Waffle_INCLUDE_DIRS waffle.h)
  86                 find_library(Waffle_LDFLAGS waffle-1)
  87                 if(Waffle_INCLUDE_DIRS AND Waffle_LDFLAGS)
  88                         set(Waffle_FOUND TRUE)
  89                 else()
  90                         message(FATAL_ERROR "Failed to find Waffle. Get and build Waffle from "
  91                                 "http://www.waffle-gl.org and set Waffle_INCLUDE_DIRS and "
  92                                 "Waffle_LDFLAGS variables accordingly."
  93                         )
  94                 endif()
  95         endif ()
  96
  97         add_definitions(-DPIGLIT_USE_WAFFLE)
  98         add_definitions(-DWAFFLE_API_VERSION=0x0103)
  99 else()
 100         find_package(GLUT REQUIRED)
 101
 102         # The 'REQUIRED' above correctly produces an error for
 103         # OpenGL, but there's a bug involving FindGLUT.cmake
 104         # that fails to produce the error as of CMake 2.8.5.
 105         #
 106         # Instead, CMake keeps going and eventually spams
 107         # the console with a message for every target that used
 108         # e.g. the ${GLUT_INCLUDE_DIR} variable. So it
 109         # prints a line for basically every single test in piglit.
 110         #
 111         # Work around the bug and error out quickly here instead.
 112         if (NOT GLUT_FOUND)
 113                 message(FATAL_ERROR "GLUT library not found")
 114         endif()
 115 endif(PIGLIT_USE_WAFFLE)
 116
 117 if(PIGLIT_BUILD_GLES1_TESTS AND NOT PIGLIT_USE_WAFFLE)
 118         message(FATAL_ERROR "Option PIGLIT_BUILD_GLES1_TESTS requires PIGLIT_USE_WAFFLE")
 119 endif(PIGLIT_BUILD_GLES1_TESTS AND NOT PIGLIT_USE_WAFFLE)
 120
 121 if(PIGLIT_BUILD_GLES2_TESTS AND NOT PIGLIT_USE_WAFFLE)
 122         message(FATAL_ERROR "Option PIGLIT_BUILD_GLES2_TESTS requires PIGLIT_USE_WAFFLE")
 123 endif(PIGLIT_BUILD_GLES2_TESTS AND NOT PIGLIT_USE_WAFFLE)
 124
 125 if(PIGLIT_BUILD_GLES3_TESTS AND NOT PIGLIT_USE_WAFFLE)
 126         message(FATAL_ERROR "Option PIGLIT_BUILD_GLES3_TESTS requires PIGLIT_USE_WAFFLE")
 127 endif(PIGLIT_BUILD_GLES3_TESTS AND NOT PIGLIT_USE_WAFFLE)
 128
 129 if(PIGLIT_BUILD_CL_TESTS)
 130         find_package(OpenCL 1.2 REQUIRED)
 131 endif(PIGLIT_BUILD_CL_TESTS)
 132
 133 IF(${CMAKE_SYSTEM_NAME} MATCHES "Linux")
 134         if(X11_FOUND AND OPENGL_gl_LIBRARY)
 135                 # Assume the system has GLX. In the future, systems may exist
 136                 # with libGL and libX11 but no GLX, but that world hasn't
 137                 # arrived yet.
 138                 set(PIGLIT_HAS_GLX True)
 139                 add_definitions(-DPIGLIT_HAS_GLX)
 140         endif()
 141
 142         pkg_check_modules(GBM QUIET gbm>=17.1)
 143         if(GBM_FOUND)
 144                 set(PIGLIT_HAS_GBM True)
 145                 add_definitions(-DPIGLIT_HAS_GBM)
 146                 set(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} ${GBM_LIBRARIES})
 147                 CHECK_FUNCTION_EXISTS(gbm_bo_map PIGLIT_HAS_GBM_BO_MAP)
 148                 if (PIGLIT_HAS_GBM_BO_MAP)
 149                         add_definitions(-DPIGLIT_HAS_GBM_BO_MAP)
 150                 endif()
 151         endif(GBM_FOUND)
 152
 153         pkg_check_modules(WAYLAND QUIET wayland-client)
 154         if (WAYLAND_FOUND)
 155                 set(PIGLIT_HAS_WAYLAND True)
 156                 add_definitions(-DPIGLIT_HAS_WAYLAND)
 157
 158                 FIND_LIBRARY(HAVE_XKBCOMMON NAMES xkbcommon)
 159                 if(NOT HAVE_XKBCOMMON)
 160                         message(FATAL_ERROR "Wayland support requires xkbcommon. "
 161                                 "Failed to find xkbcommon library.")
 162                 endif()
 163                 pkg_check_modules(XKBCOMMON QUIET xkbcommon)
 164         endif()
 165
 166         pkg_check_modules(LIBDRM QUIET libdrm)
 167         pkg_check_modules(LIBDRM_INTEL QUIET libdrm_intel)
 168         pkg_check_modules(XCB QUIET xcb)
 169         pkg_check_modules(XCB_DRI2 QUIET xcb-dri2)
 170         pkg_check_modules(GLPROTO QUIET glproto)
 171         pkg_check_modules(LIBVULKAN QUIET vulkan)
 172 ELSEIF(${CMAKE_SYSTEM_NAME} MATCHES "Windows")
 173         if (PIGLIT_USE_WAFFLE)
 174                 set(PIGLIT_HAS_WGL True)
 175                 add_definitions(-DPIGLIT_HAS_WGL)
 176         endif()
 177 ENDIF()
 178
 179 IF(PIGLIT_HAS_GLX)
 180         option(PIGLIT_BUILD_GLX_TESTS "Build tests that require GLX" ON)
 181 ELSE()
 182         option(PIGLIT_BUILD_GLX_TESTS "Build tests that require GLX" OFF)
 183 ENDIF()
 184
 185 IF(PIGLIT_HAS_WGL)
 186         option(PIGLIT_BUILD_WGL_TESTS "Build tests that require WGL" ON)
 187 ELSE()
 188         option(PIGLIT_BUILD_WGL_TESTS "Build tests that require WGL" OFF)
 189 ENDIF()
 190
 191
 192 # Choose to build tests that use dma_buf.
 193 #
 194 # Piglit's dma_buf utilities require xcb-dri2 to gain DRM authentication.
 195 #
 196 # The presence of libdrm is not sufficient. At least one libdrm_${hardware}
 197 # library is also needed.
 198 #
 199 # When building for Intel, libdrm_intel>=2.4.38 is required because support for
 200 # drm-prime arrived in that version.
 201 #
 202 if(LIBDRM_FOUND AND XCB_DRI2_FOUND AND
 203    ((LIBDRM_INTEL_VERSION VERSION_GREATER "2.4.37") OR
 204      PIGLIT_HAS_GBM_BO_MAP))
 205         set(PIGLIT_BUILD_DMA_BUF_TESTS_IS_VALID true)
 206 else()
 207         set(PIGLIT_BUILD_DMA_BUF_TESTS_IS_VALID false)
 208 endif()
 209
 210 if(PIGLIT_BUILD_DMA_BUF_TESTS_IS_VALID)
 211         option(PIGLIT_BUILD_DMA_BUF_TESTS "Build tests that use dma_buf" ON)
 212 else()
 213         option(PIGLIT_BUILD_DMA_BUF_TESTS "Build tests that use dma_buf" OFF)
 214 endif()
 215
 216 # If the users has updated PIGLIT_BUILD_DMA_BUF_TESTS in the CMakeCache, then
 217 # we need to validate it.
 218 if(PIGLIT_BUILD_DMA_BUF_TESTS AND NOT PIGLIT_BUILD_DMA_BUF_TESTS_IS_VALID)
 219         message(FATAL_ERROR
 220                 "PIGLIT_BUILD_DMA_BUF_TESTS require libdrm, "
 221                 "libdrm_intel>=2.4.38, and xcb-dri2")
 222 endif()
 223
 224 IF(PIGLIT_BUILD_GLX_TESTS)
 225         pkg_check_modules(GLPROTO REQUIRED glproto)
 226 ENDIF()
 227
 228 if (NOT Python_ADDITIONAL_VERSIONS)
 229         set(Python_ADDITIONAL_VERSIONS 3.8 3.7 3.6)
 230 endif()
 231 find_package(PythonInterp REQUIRED)
 232 find_package(PythonNumpy 1.7.0 REQUIRED)
 233 find_package(PythonMako 1.0.2 REQUIRED)
 234
 235 find_package(bash-completion NO_MODULE)
 236
 237 # Default to compiling with debug information (`gcc -g`):
 238 if(NOT CMAKE_BUILD_TYPE)
 239         SET(CMAKE_BUILD_TYPE Debug CACHE STRING
 240         "May be one of: None Debug RelWithDebInfo Release MinSizeRel" FORCE)
 241 endif(NOT CMAKE_BUILD_TYPE)
 242
 243 if (NOT MSVC)
 244         CHECK_C_COMPILER_FLAG("-Wall" C_COMPILER_FLAG_WALL)
 245         IF (C_COMPILER_FLAG_WALL)
 246                 SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wall")
 247         ENDIF (C_COMPILER_FLAG_WALL)
 248         CHECK_CXX_COMPILER_FLAG("-Wall" CXX_COMPILER_FLAG_WALL)
 249         IF (CXX_COMPILER_FLAG_WALL)
 250                 SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wall")
 251         ENDIF (CXX_COMPILER_FLAG_WALL)
 252
 253         # Target C99.  GCC's default is gnu11 for 5.0 and newer, gnu89 for
 254         # older versions.
 255         check_c_compiler_flag ("-std=gnu99" C_COMPILER_FLAG_STD_GNU99)
 256         if (C_COMPILER_FLAG_STD_GNU99)
 257                 set (CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -std=gnu99")
 258         endif ()
 259         # MSVC does not support C99 variable length arrays
 260         CHECK_C_COMPILER_FLAG("-Werror=vla" C_COMPILER_FLAG_WEVLA)
 261         IF (C_COMPILER_FLAG_WEVLA)
 262                 SET (CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Werror=vla")
 263         ENDIF ()
 264         # GCC allows void pointer arithmetic, but it is not part of ISO C and
 265         # in particular MSVC will throw `C2036: 'void *' : unknown size`
 266         check_c_compiler_flag ("-Werror=pointer-arith" C_COMPILER_FLAG_WEPOINTER_ARITH)
 267         if (C_COMPILER_FLAG_WEPOINTER_ARITH)
 268                 set (CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Werror=pointer-arith")
 269         endif ()
 270         # MSVC only supports C99 variadic macros.  It doesn't support the
 271         # non-standard GNU named variadic macro syntax that's documented in
 272         # https://gcc.gnu.org/onlinedocs/cpp/Variadic-Macros.html
 273         #
 274         # XXX: on older GCC version this option has no effect unless -Wpedantic
 275         # is set, but this should be fixed on future GCC versions, per
 276         # https://gcc.gnu.org/ml/gcc-patches/2014-04/msg01459.html
 277         check_c_compiler_flag ("-Werror=variadic-macros" C_COMPILER_FLAG_WVARIADIC_MACROS)
 278         if (C_COMPILER_FLAG_WVARIADIC_MACROS)
 279                 set (CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Werror=variadic-macros")
 280         endif ()
 281
 282         CHECK_CXX_COMPILER_FLAG("-Wno-narrowing" CXX_COMPILER_FLAG_WNO_NARROWING)
 283         IF (CXX_COMPILER_FLAG_WNO_NARROWING)
 284                 SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wno-narrowing")
 285         ENDIF (CXX_COMPILER_FLAG_WNO_NARROWING)
 286 else ()
 287         # Adjust warnings
 288         add_definitions (-W3)
 289         add_definitions (-wd4018) # signed/unsigned mismatch
 290         add_definitions (-wd4244) # conversion from 'type1' to 'type2', possible loss of data
 291         add_definitions (-wd4305) # truncation from 'type1' to 'type2'
 292         add_definitions (-wd4800) # forcing value to bool 'true' or 'false' (performance warning)
 293
 294         add_definitions (-D_CRT_SECURE_NO_DEPRECATE -D_CRT_SECURE_NO_WARNINGS -D_CRT_NONSTDC_NO_WARNINGS)
 295         add_definitions (-D_SCL_SECURE_NO_DEPRECATE -D_SCL_SECURE_NO_WARNINGS)
 296 endif ()
 297
 298 if (MINGW)
 299         # Match MSVC default stack size
 300         set (CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -Wl,--stack,1048576")
 301
 302         # Avoid depending on MinGW runtime DLLs
 303         check_cxx_compiler_flag (-static-libgcc HAVE_STATIC_LIBGCC_FLAG)
 304         if (HAVE_STATIC_LIBGCC_FLAG)
 305                 set (CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -static-libgcc")
 306                 set (CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -static-libgcc")
 307                 set (CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -static-libgcc")
 308         endif ()
 309         check_cxx_compiler_flag (-static-libstdc++ HAVE_STATIC_LIBSTDCXX_FLAG)
 310         if (HAVE_STATIC_LIBSTDCXX_FLAG)
 311                 set (CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -static-libstdc++")
 312                 set (CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -static-libstdc++")
 313                 set (CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -static-libstdc++")
 314         endif ()
 315 endif ()
 316
 317 if (${CMAKE_C_COMPILER_ID} STREQUAL "SunPro")
 318         # Use C++ to link C files.
 319         # http://developers.sun.com/solaris/articles/mixing.html#linking
 320         # Modified rule from Modules/CMakeCInformation.cmake.
 321         set (CMAKE_C_LINK_EXECUTABLE
 322                 "<CMAKE_CXX_COMPILER> <FLAGS> <CMAKE_C_LINK_FLAGS> <LINK_FLAGS> <OBJECTS> -o <TARGET> <LINK_LIBRARIES>")
 323 endif()
 324
 325 # Always enable GNU C extensions.  Non-GNU platforms will need to
 326 # define wrappers for them.
 327 add_definitions(-D_GNU_SOURCE)
 328
 329 if (WIN32)
 330         # MSVC & MinGW only define & use APIENTRY
 331         add_definitions (-DGLAPIENTRY=__stdcall)
 332
 333         # Avoid namespace pollution when including windows.h
 334         # http://support.microsoft.com/kb/166474
 335         add_definitions (-DWIN32_LEAN_AND_MEAN=1)
 336
 337         # Don't define min/max macros
 338         add_definitions (-DNOMINMAX)
 339
 340         # Even more no min/max macros
 341         add_definitions (-D_CRT_DECLARE_NONSTDC_NAMES=0)
 342
 343         # Define M_PI and others
 344         add_definitions (-D_USE_MATH_DEFINES)
 345 endif (WIN32)
 346
 347 if (APPLE)
 348         # Don't warn about using deprecated OpenGL/GLUT functions.
 349         # TODO: It would be nice to silence just the deprecation macros from
 350         # OpenGLAvailability.h as opposed to all deprecated functions.
 351         set (CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wno-deprecated-declarations")
 352         set (CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wno-deprecated-declarations")
 353 endif ()
 354
 355 if (OPENGL_FOUND)
 356         if (APPLE)
 357                 find_path(GLEXT_INCLUDE_DIR
 358                         NAMES OpenGL/glext.h
 359                         PATHS ${OPENGL_INCLUDE_DIR}
 360                         DOC "Include for OpenGL/glext.h on OSX"
 361                 )
 362         else (APPLE)
 363                 find_path(GLEXT_INCLUDE_DIR
 364                         NAMES GL/glext.h
 365                         PATHS ${OPENGL_INCLUDE_DIR}
 366                         DOC "Include for GL/glext.h"
 367                 )
 368         endif (APPLE)
 369 endif()
 370
 371 if(CMAKE_USE_PTHREADS_INIT)
 372         set(PIGLIT_HAS_PTHREADS true)
 373         add_definitions(-DPIGLIT_HAS_PTHREADS)
 374 endif()
 375
 376 FIND_LIBRARY(HAVE_LIBRT NAMES rt)
 377 if(HAVE_LIBRT)
 378         set(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} rt)
 379 endif()
 380
 381 check_c_source_compiles(
 382         "
 383         #define _POSIX_C_SOURCE 199309L
 384         #include <time.h>
 385         int main() { return clock_gettime(CLOCK_MONOTONIC, NULL); }
 386         "
 387         PIGLIT_HAS_POSIX_CLOCK_MONOTONIC
 388 )
 389
 390 if(PIGLIT_HAS_PTHREADS AND PIGLIT_HAS_POSIX_CLOCK_MONOTONIC)
 391         check_c_source_compiles(
 392                 "
 393                 #include <signal.h>
 394                 #include <time.h>
 395                 static void timeout(union sigval val) { }
 396                 int main() {
 397                         struct sigevent sev = {
 398                                 .sigev_notify = SIGEV_THREAD,
 399                                 .sigev_notify_function = timeout,
 400                         };
 401                         timer_t timerid;
 402                         return timer_create(CLOCK_MONOTONIC, &sev, &timerid);
 403                 }
 404                 "
 405                 PIGLIT_HAS_POSIX_TIMER_NOTIFY_THREAD
 406         )
 407 endif()
 408
 409 set(CMAKE_REQUIRED_LIBRARIES)
 410
 411 if(PIGLIT_HAS_POSIX_CLOCK_MONOTONIC)
 412         add_definitions(-DPIGLIT_HAS_POSIX_CLOCK_MONOTONIC)
 413 endif()
 414
 415 if(PIGLIT_HAS_POSIX_TIMER_NOTIFY_THREAD)
 416         add_definitions(-DPIGLIT_HAS_POSIX_TIMER_NOTIFY_THREAD)
 417 endif()
 418
 419 if(GBM_FOUND)
 420 FIND_LIBRARY(HAVE_LIBCACA NAMES caca)
 421 if(HAVE_LIBCACA)
 422         set(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} caca)
 423         add_definitions(-DPIGLIT_HAS_LIBCACA)
 424 endif(HAVE_LIBCACA)
 425 endif(GBM_FOUND)
 426
 427 if(PIGLIT_USE_WAFFLE AND ${CMAKE_SYSTEM_NAME} STREQUAL "Linux")
 428         pkg_check_modules(EGL egl)
 429 endif()
 430
 431 if(EGL_FOUND)
 432         add_definitions(-DPIGLIT_HAS_EGL)
 433         include_directories(${EGL_INCLUDE_DIRS})
 434         add_definitions (${EGL_CFLAGS_OTHER})
 435 endif()
 436
 437 if(PIGLIT_BUILD_GLES1_TESTS AND NOT EGL_FOUND)
 438         message(FATAL_ERROR "Option PIGLIT_BUILD_GLES1_TESTS requires EGL. "
 439                             "Failed to find EGL library.")
 440 endif()
 441
 442 if(PIGLIT_BUILD_GLES2_TESTS AND NOT EGL_FOUND)
 443         message(FATAL_ERROR "Option PIGLIT_BUILD_GLES2_TESTS requires EGL. "
 444                             "Failed to find EGL library.")
 445 endif()
 446
 447 if(PIGLIT_BUILD_GLES3_TESTS AND NOT EGL_FOUND)
 448         message(FATAL_ERROR "Option PIGLIT_BUILD_GLES3_TESTS requires EGL. "
 449                             "Failed to find EGL library.")
 450 endif()
 451
 452 # Put all executables into the bin subdirectory
 453 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${piglit_BINARY_DIR}/bin)
 454 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${piglit_BINARY_DIR}/lib)
 455
 456 # Do the same for MSVC, regardless of the build type. This only works correctly
 457 # for CMake 2.8.1 and above.
 458 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY_DEBUG ${piglit_BINARY_DIR}/bin)
 459 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY_RELEASE ${piglit_BINARY_DIR}/bin)
 460 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY_MINSIZEREL ${piglit_BINARY_DIR}/bin)
 461 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY_RELWITHDEBINFO ${piglit_BINARY_DIR}/bin)
 462
 463 check_function_exists(asprintf  HAVE_ASPRINTF)
 464 check_function_exists(ffs       HAVE_FFS)
 465 check_function_exists(strchrnul HAVE_STRCHRNUL)
 466 check_function_exists(strndup   HAVE_STRNDUP)
 467 if(NOT MINGW)
 468 check_function_exists(fopen_s   HAVE_FOPEN_S)
 469 endif()
 470 check_function_exists(setrlimit HAVE_SETRLIMIT)
 471
 472 check_symbol_exists(htobe32 "endian.h" HAVE_HTOBE32)
 473
 474 check_include_file(sys/time.h  HAVE_SYS_TIME_H)
 475 check_include_file(sys/types.h HAVE_SYS_TYPES_H)
 476 check_include_file(sys/resource.h  HAVE_SYS_RESOURCE_H)
 477 check_include_file(sys/stat.h  HAVE_SYS_STAT_H)
 478 check_include_file(unistd.h    HAVE_UNISTD_H)
 479 check_include_file(fcntl.h     HAVE_FCNTL_H)
 480 check_include_file(linux/sync_file.h HAVE_LINUX_SYNC_FILE_H)
 481
 482 if(DEFINED PIGLIT_INSTALL_VERSION)
 483         set(PIGLIT_INSTALL_VERSION_SUFFIX
 484             "-${PIGLIT_INSTALL_VERSION}")
 485 else()
 486         set(PIGLIT_INSTALL_VERSION_SUFFIX "")
 487 endif()
 488 set(PIGLIT_INSTALL_LIBDIR
 489     "${CMAKE_INSTALL_LIBDIR}/piglit${PIGLIT_INSTALL_VERSION_SUFFIX}")
 490 if(NOT IS_ABSOLUTE ${PIGLIT_INSTALL_LIBDIR})
 491         set(PIGLIT_INSTALL_FULL_LIBDIR "${CMAKE_INSTALL_PREFIX}/${PIGLIT_INSTALL_LIBDIR}")
 492 else()
 493         set(PIGLIT_INSTALL_FULL_LIBDIR "${PIGLIT_INSTALL_LIBDIR}")
 494 endif()
 495
 496 if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
 497   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -Wl,--enable-new-dtags")
 498 endif(CMAKE_SYSTEM_NAME STREQUAL "Linux")
 499
 500 SET(CMAKE_INSTALL_RPATH "${PIGLIT_INSTALL_FULL_LIBDIR}/lib")
 501
 502 configure_file(
 503         "${piglit_SOURCE_DIR}/tests/util/config.h.in"
 504         "${piglit_BINARY_DIR}/tests/util/config.h"
 505 )
 506
 507 include(cmake/piglit_util.cmake)
 508 include(cmake/piglit_dispatch.cmake)
 509
 510 include_directories(src)
 511 add_subdirectory(cmake/target_api)
 512 add_subdirectory(generated_tests)
 513
 514
 515 ##############################################################################
 516 # Packaging
 517
 518 install (
 519         FILES
 520                 COPYING
 521                 README.md
 522                 RELEASE
 523         DESTINATION share/doc/piglit${PIGLIT_INSTALL_VERSION_SUFFIX}
 524 )
 525
 526 install (
 527         DIRECTORY framework
 528         DESTINATION ${PIGLIT_INSTALL_LIBDIR}
 529         FILES_MATCHING PATTERN "*.py"
 530 )
 531
 532 install (
 533         DIRECTORY templates
 534         DESTINATION ${PIGLIT_INSTALL_LIBDIR}
 535 )
 536
 537 install (
 538         DIRECTORY tests
 539         DESTINATION ${PIGLIT_INSTALL_LIBDIR}
 540         FILES_MATCHING REGEX ".*\\.(xml|xml.gz|py|program_test|shader_test|shader_source|frag|vert|geom|tesc|tese|comp|spv|ktx|cl|txt|inc|vk_shader_test)$"
 541         REGEX "CMakeFiles|CMakeLists|serializer.py|opengl.py|cl.py|quick_gl.py|glslparser.py|shader.py|quick_shader.py|no_error.py|llvmpipe_gl.py|sanity.py" EXCLUDE
 542 )
 543
 544 install (
 545         DIRECTORY ${CMAKE_BINARY_DIR}/tests
 546         DESTINATION ${PIGLIT_INSTALL_LIBDIR}
 547         FILES_MATCHING REGEX ".*\\.xml.gz"
 548 )
 549
 550 install (
 551         DIRECTORY ${CMAKE_BINARY_DIR}/generated_tests
 552         DESTINATION ${PIGLIT_INSTALL_LIBDIR}
 553         FILES_MATCHING REGEX ".*\\.(shader_test|program_test|frag|vert|geom|tesc|tese|comp|cl|txt|vk_shader_test)$"
 554         REGEX "CMakeFiles|CMakeLists" EXCLUDE
 555 )
 556
 557 install (
 558         DIRECTORY generated_tests
 559         DESTINATION ${PIGLIT_INSTALL_LIBDIR}
 560         FILES_MATCHING REGEX ".*\\.inc$"
 561         REGEX "CMakeFiles|CMakeLists" EXCLUDE
 562 )
 563
 564 if (BASH_COMPLETION_FOUND)
 565         install(
 566                 FILES completions/bash/piglit
 567                 DESTINATION ${CMAKE_INSTALL_PREFIX}/${BASH_COMPLETION_COMPLETIONSDIR}/
 568         )
 569 endif (BASH_COMPLETION_FOUND)
 570
 571 if (WIN32)
 572         set (PYTHON_SUFFIX ".py")
 573 else ()
 574         set (PYTHON_SUFFIX "")
 575 endif ()
 576 install (
 577         PROGRAMS piglit RENAME piglit${PIGLIT_INSTALL_VERSION_SUFFIX}${PYTHON_SUFFIX}
 578         DESTINATION ${CMAKE_INSTALL_BINDIR}
 579 )
 580
 581
 582 set (CPACK_PACKAGE_VERSION_MAJOR "1")
 583 set (CPACK_PACKAGE_VERSION_MINOR "0")
 584
 585 # Use current date in YYYYMMDD format as patch number
 586 execute_process (
 587         COMMAND ${PYTHON_EXECUTABLE} -c "import time, sys; sys.stdout.write(time.strftime('%Y%m%d'))"
 588         OUTPUT_VARIABLE CPACK_PACKAGE_VERSION_PATCH
 589 )
 590
 591 # cpack mistakenly detects Mingw-w64 as win32
 592 if (MINGW)
 593         if (CMAKE_SIZEOF_VOID_P EQUAL 8)
 594                 set (CPACK_SYSTEM_NAME win64)
 595         endif ()
 596 endif ()
 597
 598 # See http://www.vtk.org/Wiki/CMake:CPackPackageGenerators
 599 if (WIN32)
 600         set (CPACK_GENERATOR "ZIP")
 601 else ()
 602         set (CPACK_GENERATOR "TBZ2")
 603 endif ()
 604
 605 include(CPack)