CMakeLists.txt

   1 cmake_minimum_required(VERSION 3.2)
   2
   3 # http://www.cmake.org/cmake/help/v3.0/policy/CMP0042.html
   4 if (POLICY CMP0042)
   5         cmake_policy (SET CMP0042 NEW)
   6 endif()
   7
   8 if (POLICY CMP0072)
   9         cmake_policy (SET CMP0072 OLD)
  10 endif()
  11
  12 project (piglit)
  13
  14 list(APPEND CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/cmake/Modules")
  15
  16 INCLUDE (GNUInstallDirs)
  17 INCLUDE (CheckCCompilerFlag)
  18 INCLUDE (CheckCSourceCompiles)
  19 INCLUDE (CheckCXXCompilerFlag)
  20 INCLUDE (CheckFunctionExists)
  21 INCLUDE (CheckSymbolExists)
  22 INCLUDE (CheckIncludeFile)
  23 INCLUDE (FindPkgConfig)
  24
  25 set(CMAKE_EXPORT_COMPILE_COMMANDS ON)
  26
  27 find_package(Threads)
  28 find_package(PNG)
  29 if(PNG_FOUND)
  30         add_definitions(-DPIGLIT_HAS_PNG)
  31 endif(PNG_FOUND)
  32 find_package(X11)
  33 if(X11_FOUND)
  34         set(PIGLIT_HAS_X11 True)
  35         add_definitions(-DPIGLIT_HAS_X11)
  36 endif()
  37
  38 if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
  39         set(PIGLIT_BUILD_GLES_TESTS_DEFAULT ON)
  40         set(PIGLIT_BUILD_VK_TESTS_DEFAULT ON)
  41 else()
  42         set(PIGLIT_BUILD_GLES_TESTS_DEFAULT OFF)
  43         set(PIGLIT_BUILD_VK_TESTS_DEFAULT OFF)
  44 endif()
  45
  46 option(PIGLIT_BUILD_GL_TESTS "Build tests for OpenGL" ON)
  47 option(PIGLIT_BUILD_GLES1_TESTS "Build tests for OpenGL ES1" ${PIGLIT_BUILD_GLES_TESTS_DEFAULT})
  48 option(PIGLIT_BUILD_GLES2_TESTS "Build tests for OpenGL ES2" ${PIGLIT_BUILD_GLES_TESTS_DEFAULT})
  49 option(PIGLIT_BUILD_GLES3_TESTS "Build tests for OpenGL ES3" ${PIGLIT_BUILD_GLES_TESTS_DEFAULT})
  50 option(PIGLIT_BUILD_CL_TESTS "Build tests for OpenCL" OFF)
  51 option(PIGLIT_BUILD_VK_TESTS "Build tests for Vulkan" ${PIGLIT_BUILD_VK_TESTS_DEFAULT})
  52
  53 if(PIGLIT_BUILD_GL_TESTS)
  54         find_package(OpenGL REQUIRED)
  55 endif()
  56
  57 if(${CMAKE_SYSTEM_NAME} MATCHES "Linux")
  58         option(PIGLIT_USE_WAFFLE "Use Waffle in place of GLUT" ON)
  59 else()
  60         option(PIGLIT_USE_WAFFLE "Use Waffle in place of GLUT" OFF)
  61 endif()
  62
  63 if(PIGLIT_USE_WAFFLE)
  64         if (NOT WIN32)
  65                 pkg_check_modules(Waffle REQUIRED waffle-1)
  66
  67                 if(NOT Waffle_FOUND)
  68                         message(FATAL_ERROR "Failed to find Waffle. If Waffle "
  69                         "is not packaged for your distribution, you can get "
  70                         "it at http://www.waffle-gl.org."
  71                 )
  72                 endif()
  73
  74                 # Check the installed waffle version.
  75                 #
  76                 # We cannot reliably check the version with pkg_check_modules(), but
  77                 # instead must check the version manually as below. The problem is that,
  78                 # if one passes a required version to pkg_check_modules(), CMake
  79                 # validates the required version at most once for the lifetime of the
  80                 # source tree.  If someone changes the required version by editing the
  81                 # CMakeLists, CMake fails to detect the new requirement.
  82                 set(Waffle_REQUIRED_VERSION "1.5.0")
  83                 if(Waffle_VERSION VERSION_LESS Waffle_REQUIRED_VERSION)
  84                         message(FATAL_ERROR "Found waffle-${Waffle_VERSION}, but "
  85                         "piglit requires waffle-${Waffle_REQUIRED_VERSION}")
  86                 endif()
  87         else ()
  88                 find_path(Waffle_INCLUDE_DIRS waffle.h)
  89                 find_library(Waffle_LDFLAGS waffle-1)
  90                 if(Waffle_INCLUDE_DIRS AND Waffle_LDFLAGS)
  91                         set(Waffle_FOUND TRUE)
  92                 else()
  93                         message(FATAL_ERROR "Failed to find Waffle. Get and build Waffle from "
  94                                 "http://www.waffle-gl.org and set Waffle_INCLUDE_DIRS and "
  95                                 "Waffle_LDFLAGS variables accordingly."
  96                         )
  97                 endif()
  98         endif ()
  99
 100         add_definitions(-DPIGLIT_USE_WAFFLE)
 101         add_definitions(-DWAFFLE_API_VERSION=0x0103)
 102 else()
 103         find_package(GLUT REQUIRED)
 104
 105         # The 'REQUIRED' above correctly produces an error for
 106         # OpenGL, but there's a bug involving FindGLUT.cmake
 107         # that fails to produce the error as of CMake 2.8.5.
 108         #
 109         # Instead, CMake keeps going and eventually spams
 110         # the console with a message for every target that used
 111         # e.g. the ${GLUT_INCLUDE_DIR} variable. So it
 112         # prints a line for basically every single test in piglit.
 113         #
 114         # Work around the bug and error out quickly here instead.
 115         if (NOT GLUT_FOUND)
 116                 message(FATAL_ERROR "GLUT library not found")
 117         endif()
 118 endif(PIGLIT_USE_WAFFLE)
 119
 120 if(PIGLIT_BUILD_GLES1_TESTS AND NOT PIGLIT_USE_WAFFLE)
 121         message(FATAL_ERROR "Option PIGLIT_BUILD_GLES1_TESTS requires PIGLIT_USE_WAFFLE")
 122 endif(PIGLIT_BUILD_GLES1_TESTS AND NOT PIGLIT_USE_WAFFLE)
 123
 124 if(PIGLIT_BUILD_GLES2_TESTS AND NOT PIGLIT_USE_WAFFLE)
 125         message(FATAL_ERROR "Option PIGLIT_BUILD_GLES2_TESTS requires PIGLIT_USE_WAFFLE")
 126 endif(PIGLIT_BUILD_GLES2_TESTS AND NOT PIGLIT_USE_WAFFLE)
 127
 128 if(PIGLIT_BUILD_GLES3_TESTS AND NOT PIGLIT_USE_WAFFLE)
 129         message(FATAL_ERROR "Option PIGLIT_BUILD_GLES3_TESTS requires PIGLIT_USE_WAFFLE")
 130 endif(PIGLIT_BUILD_GLES3_TESTS AND NOT PIGLIT_USE_WAFFLE)
 131
 132 if(PIGLIT_BUILD_CL_TESTS)
 133         find_package(OpenCL 1.2 REQUIRED)
 134 endif(PIGLIT_BUILD_CL_TESTS)
 135
 136 IF(${CMAKE_SYSTEM_NAME} MATCHES "Linux")
 137         if(X11_FOUND AND OPENGL_gl_LIBRARY)
 138                 # Assume the system has GLX. In the future, systems may exist
 139                 # with libGL and libX11 but no GLX, but that world hasn't
 140                 # arrived yet.
 141                 set(PIGLIT_HAS_GLX True)
 142                 add_definitions(-DPIGLIT_HAS_GLX)
 143         endif()
 144
 145         pkg_check_modules(GBM QUIET gbm>=17.1)
 146         if(GBM_FOUND)
 147                 set(PIGLIT_HAS_GBM True)
 148                 add_definitions(-DPIGLIT_HAS_GBM)
 149                 set(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} ${GBM_LIBRARIES})
 150                 CHECK_FUNCTION_EXISTS(gbm_bo_map PIGLIT_HAS_GBM_BO_MAP)
 151                 if (PIGLIT_HAS_GBM_BO_MAP)
 152                         add_definitions(-DPIGLIT_HAS_GBM_BO_MAP)
 153                 endif()
 154                 CHECK_FUNCTION_EXISTS(gbm_bo_get_fd_for_plane PIGLIT_HAS_GBM_BO_GET_FD_FOR_PLANE)
 155                 if (PIGLIT_HAS_GBM_BO_GET_FD_FOR_PLANE)
 156                         add_definitions(-DPIGLIT_HAS_GBM_BO_GET_FD_FOR_PLANE)
 157                 endif()
 158         endif(GBM_FOUND)
 159
 160         pkg_check_modules(WAYLAND QUIET wayland-client)
 161         if (WAYLAND_FOUND)
 162                 set(PIGLIT_HAS_WAYLAND True)
 163                 add_definitions(-DPIGLIT_HAS_WAYLAND)
 164
 165                 FIND_LIBRARY(HAVE_XKBCOMMON NAMES xkbcommon)
 166                 if(NOT HAVE_XKBCOMMON)
 167                         message(FATAL_ERROR "Wayland support requires xkbcommon. "
 168                                 "Failed to find xkbcommon library.")
 169                 endif()
 170                 pkg_check_modules(XKBCOMMON QUIET xkbcommon)
 171         endif()
 172
 173         pkg_check_modules(LIBDRM QUIET libdrm)
 174         pkg_check_modules(XCB QUIET xcb)
 175         pkg_check_modules(XCB_DRI2 QUIET xcb-dri2)
 176         pkg_check_modules(GLPROTO QUIET glproto)
 177         pkg_check_modules(LIBVULKAN QUIET vulkan)
 178 ELSEIF(${CMAKE_SYSTEM_NAME} MATCHES "Windows")
 179         if (PIGLIT_USE_WAFFLE)
 180                 set(PIGLIT_HAS_WGL True)
 181                 add_definitions(-DPIGLIT_HAS_WGL)
 182         endif()
 183 ENDIF()
 184
 185 if(PIGLIT_BUILD_VK_TESTS)
 186
 187 if (NOT LIBVULKAN_FOUND)
 188         message(FATAL_ERROR "libvulkan required by vulkan tests not found")
 189 endif()
 190
 191 find_program(GLSLANG_VALIDATOR NAMES glslangValidator)
 192
 193 if (NOT GLSLANG_VALIDATOR)
 194         message(FATAL_ERROR "glslangValidator required by vulkan tests not found")
 195 endif()
 196
 197 endif(PIGLIT_BUILD_VK_TESTS)
 198
 199 IF(PIGLIT_HAS_GLX)
 200         option(PIGLIT_BUILD_GLX_TESTS "Build tests that require GLX" ON)
 201 ELSE()
 202         option(PIGLIT_BUILD_GLX_TESTS "Build tests that require GLX" OFF)
 203 ENDIF()
 204
 205 IF(PIGLIT_HAS_WGL)
 206         option(PIGLIT_BUILD_WGL_TESTS "Build tests that require WGL" ON)
 207 ELSE()
 208         option(PIGLIT_BUILD_WGL_TESTS "Build tests that require WGL" OFF)
 209 ENDIF()
 210
 211
 212 # Choose to build tests that use dma_buf.
 213 #
 214 # Piglit's dma_buf utilities require xcb-dri2 to gain DRM authentication, and
 215 # gbm_bo_map() to be available for generating dma_bufs, and libdrm for fourcc
 216 # definitions.
 217 #
 218 if(LIBDRM_FOUND AND LIBDRM_VERSION VERSION_GREATER "2.4.97" AND XCB_DRI2_FOUND AND PIGLIT_HAS_GBM_BO_MAP)
 219         set(PIGLIT_BUILD_DMA_BUF_TESTS_IS_VALID true)
 220 else()
 221         set(PIGLIT_BUILD_DMA_BUF_TESTS_IS_VALID false)
 222 endif()
 223
 224 if(PIGLIT_BUILD_DMA_BUF_TESTS_IS_VALID)
 225         option(PIGLIT_BUILD_DMA_BUF_TESTS "Build tests that use dma_buf" ON)
 226 else()
 227         option(PIGLIT_BUILD_DMA_BUF_TESTS "Build tests that use dma_buf" OFF)
 228 endif()
 229
 230 # If the users has updated PIGLIT_BUILD_DMA_BUF_TESTS in the CMakeCache, then
 231 # we need to validate it.
 232 if(PIGLIT_BUILD_DMA_BUF_TESTS AND NOT PIGLIT_BUILD_DMA_BUF_TESTS_IS_VALID)
 233         message(FATAL_ERROR
 234                 "PIGLIT_BUILD_DMA_BUF_TESTS require libdrm, "
 235                 "gbm_bo_map(), libdrm>=2.4.98 and xcb-dri2")
 236 endif()
 237
 238 IF(PIGLIT_BUILD_GLX_TESTS)
 239         pkg_check_modules(GLPROTO REQUIRED glproto)
 240 ENDIF()
 241
 242 if (NOT Python_ADDITIONAL_VERSIONS)
 243         set(Python_ADDITIONAL_VERSIONS 3.9 3.8 3.7 3.6)
 244 endif()
 245 find_package(PythonInterp REQUIRED)
 246 find_package(PythonNumpy 1.7.0 REQUIRED)
 247 find_package(PythonMako 1.0.2 REQUIRED)
 248
 249 find_package(bash-completion NO_MODULE)
 250
 251 # Default to compiling with debug information (`gcc -g`):
 252 if(NOT CMAKE_BUILD_TYPE)
 253         SET(CMAKE_BUILD_TYPE Debug CACHE STRING
 254         "May be one of: None Debug RelWithDebInfo Release MinSizeRel" FORCE)
 255 endif(NOT CMAKE_BUILD_TYPE)
 256
 257 if (NOT MSVC)
 258         CHECK_C_COMPILER_FLAG("-Wall" C_COMPILER_FLAG_WALL)
 259         IF (C_COMPILER_FLAG_WALL)
 260                 SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wall")
 261         ENDIF (C_COMPILER_FLAG_WALL)
 262         CHECK_CXX_COMPILER_FLAG("-Wall" CXX_COMPILER_FLAG_WALL)
 263         IF (CXX_COMPILER_FLAG_WALL)
 264                 SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wall")
 265         ENDIF (CXX_COMPILER_FLAG_WALL)
 266
 267         # Target C99.  GCC's default is gnu11 for 5.0 and newer, gnu89 for
 268         # older versions.
 269         check_c_compiler_flag ("-std=gnu99" C_COMPILER_FLAG_STD_GNU99)
 270         if (C_COMPILER_FLAG_STD_GNU99)
 271                 set (CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -std=gnu99")
 272         endif ()
 273         # MSVC does not support C99 variable length arrays
 274         CHECK_C_COMPILER_FLAG("-Werror=vla" C_COMPILER_FLAG_WEVLA)
 275         IF (C_COMPILER_FLAG_WEVLA)
 276                 SET (CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Werror=vla")
 277         ENDIF ()
 278         # GCC allows void pointer arithmetic, but it is not part of ISO C and
 279         # in particular MSVC will throw `C2036: 'void *' : unknown size`
 280         check_c_compiler_flag ("-Werror=pointer-arith" C_COMPILER_FLAG_WEPOINTER_ARITH)
 281         if (C_COMPILER_FLAG_WEPOINTER_ARITH)
 282                 set (CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Werror=pointer-arith")
 283         endif ()
 284         # MSVC only supports C99 variadic macros.  It doesn't support the
 285         # non-standard GNU named variadic macro syntax that's documented in
 286         # https://gcc.gnu.org/onlinedocs/cpp/Variadic-Macros.html
 287         #
 288         # XXX: on older GCC version this option has no effect unless -Wpedantic
 289         # is set, but this should be fixed on future GCC versions, per
 290         # https://gcc.gnu.org/ml/gcc-patches/2014-04/msg01459.html
 291         check_c_compiler_flag ("-Werror=variadic-macros" C_COMPILER_FLAG_WVARIADIC_MACROS)
 292         if (C_COMPILER_FLAG_WVARIADIC_MACROS)
 293                 set (CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Werror=variadic-macros")
 294         endif ()
 295
 296         CHECK_CXX_COMPILER_FLAG("-Wno-narrowing" CXX_COMPILER_FLAG_WNO_NARROWING)
 297         IF (CXX_COMPILER_FLAG_WNO_NARROWING)
 298                 SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wno-narrowing")
 299         ENDIF (CXX_COMPILER_FLAG_WNO_NARROWING)
 300 else ()
 301         # Adjust warnings
 302         add_definitions (-W3)
 303         add_definitions (-wd4018) # signed/unsigned mismatch
 304         add_definitions (-wd4244) # conversion from 'type1' to 'type2', possible loss of data
 305         add_definitions (-wd4305) # truncation from 'type1' to 'type2'
 306         add_definitions (-wd4800) # forcing value to bool 'true' or 'false' (performance warning)
 307
 308         add_definitions (-D_CRT_SECURE_NO_DEPRECATE -D_CRT_SECURE_NO_WARNINGS -D_CRT_NONSTDC_NO_WARNINGS)
 309         add_definitions (-D_SCL_SECURE_NO_DEPRECATE -D_SCL_SECURE_NO_WARNINGS)
 310 endif ()
 311
 312 if (MINGW)
 313         # Match MSVC default stack size
 314         set (CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -Wl,--stack,1048576")
 315 endif ()
 316
 317 if (${CMAKE_C_COMPILER_ID} STREQUAL "SunPro")
 318         # Use C++ to link C files.
 319         # http://developers.sun.com/solaris/articles/mixing.html#linking
 320         # Modified rule from Modules/CMakeCInformation.cmake.
 321         set (CMAKE_C_LINK_EXECUTABLE
 322                 "<CMAKE_CXX_COMPILER> <FLAGS> <CMAKE_C_LINK_FLAGS> <LINK_FLAGS> <OBJECTS> -o <TARGET> <LINK_LIBRARIES>")
 323 endif()
 324
 325 # Always enable GNU C extensions.  Non-GNU platforms will need to
 326 # define wrappers for them.
 327 add_definitions(-D_GNU_SOURCE)
 328
 329 if (WIN32)
 330         # MSVC & MinGW only define & use APIENTRY
 331         add_definitions (-DGLAPIENTRY=__stdcall)
 332
 333         # Avoid namespace pollution when including windows.h
 334         # http://support.microsoft.com/kb/166474
 335         add_definitions (-DWIN32_LEAN_AND_MEAN=1)
 336
 337         # Don't define min/max macros
 338         add_definitions (-DNOMINMAX)
 339
 340         # Even more no min/max macros
 341         add_definitions (-D_CRT_DECLARE_NONSTDC_NAMES=0)
 342
 343         # Define M_PI and others
 344         add_definitions (-D_USE_MATH_DEFINES)
 345 endif (WIN32)
 346
 347 if (APPLE)
 348         # Don't warn about using deprecated OpenGL/GLUT functions.
 349         # TODO: It would be nice to silence just the deprecation macros from
 350         # OpenGLAvailability.h as opposed to all deprecated functions.
 351         set (CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wno-deprecated-declarations")
 352         set (CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wno-deprecated-declarations")
 353 endif ()
 354
 355 if (OPENGL_FOUND)
 356         if (APPLE)
 357                 find_path(GLEXT_INCLUDE_DIR
 358                         NAMES OpenGL/glext.h
 359                         PATHS ${OPENGL_INCLUDE_DIR}
 360                         DOC "Include for OpenGL/glext.h on OSX"
 361                 )
 362         else (APPLE)
 363                 find_path(GLEXT_INCLUDE_DIR
 364                         NAMES GL/glext.h
 365                         PATHS ${OPENGL_INCLUDE_DIR}
 366                         DOC "Include for GL/glext.h"
 367                 )
 368         endif (APPLE)
 369 endif()
 370
 371 if(CMAKE_USE_PTHREADS_INIT)
 372         set(PIGLIT_HAS_PTHREADS true)
 373         add_definitions(-DPIGLIT_HAS_PTHREADS)
 374 endif()
 375
 376 FIND_LIBRARY(HAVE_LIBRT NAMES rt)
 377 if(HAVE_LIBRT)
 378         set(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} rt)
 379 endif()
 380
 381 check_c_source_compiles(
 382         "
 383         #define _POSIX_C_SOURCE 199309L
 384         #include <time.h>
 385         int main() { return clock_gettime(CLOCK_MONOTONIC, NULL); }
 386         "
 387         PIGLIT_HAS_POSIX_CLOCK_MONOTONIC
 388 )
 389
 390 if(PIGLIT_HAS_PTHREADS AND PIGLIT_HAS_POSIX_CLOCK_MONOTONIC)
 391         check_c_source_compiles(
 392                 "
 393                 #include <signal.h>
 394                 #include <time.h>
 395                 static void timeout(union sigval val) { }
 396                 int main() {
 397                         struct sigevent sev = {
 398                                 .sigev_notify = SIGEV_THREAD,
 399                                 .sigev_notify_function = timeout,
 400                         };
 401                         timer_t timerid;
 402                         return timer_create(CLOCK_MONOTONIC, &sev, &timerid);
 403                 }
 404                 "
 405                 PIGLIT_HAS_POSIX_TIMER_NOTIFY_THREAD
 406         )
 407 endif()
 408
 409 set(CMAKE_REQUIRED_LIBRARIES)
 410
 411 if(PIGLIT_HAS_POSIX_CLOCK_MONOTONIC)
 412         add_definitions(-DPIGLIT_HAS_POSIX_CLOCK_MONOTONIC)
 413 endif()
 414
 415 if(PIGLIT_HAS_POSIX_TIMER_NOTIFY_THREAD)
 416         add_definitions(-DPIGLIT_HAS_POSIX_TIMER_NOTIFY_THREAD)
 417 endif()
 418
 419 if(GBM_FOUND)
 420 FIND_LIBRARY(HAVE_LIBCACA NAMES caca)
 421 if(HAVE_LIBCACA)
 422         set(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} caca)
 423         add_definitions(-DPIGLIT_HAS_LIBCACA)
 424 endif(HAVE_LIBCACA)
 425 endif(GBM_FOUND)
 426
 427 if(PIGLIT_USE_WAFFLE AND ${CMAKE_SYSTEM_NAME} STREQUAL "Linux")
 428         pkg_check_modules(EGL egl)
 429 endif()
 430
 431 if(EGL_FOUND)
 432         add_definitions(-DPIGLIT_HAS_EGL)
 433         include_directories(${EGL_INCLUDE_DIRS})
 434         add_definitions (${EGL_CFLAGS_OTHER})
 435 endif()
 436
 437 if(PIGLIT_BUILD_GLES1_TESTS AND NOT EGL_FOUND)
 438         message(FATAL_ERROR "Option PIGLIT_BUILD_GLES1_TESTS requires EGL. "
 439                             "Failed to find EGL library.")
 440 endif()
 441
 442 if(PIGLIT_BUILD_GLES2_TESTS AND NOT EGL_FOUND)
 443         message(FATAL_ERROR "Option PIGLIT_BUILD_GLES2_TESTS requires EGL. "
 444                             "Failed to find EGL library.")
 445 endif()
 446
 447 if(PIGLIT_BUILD_GLES3_TESTS AND NOT EGL_FOUND)
 448         message(FATAL_ERROR "Option PIGLIT_BUILD_GLES3_TESTS requires EGL. "
 449                             "Failed to find EGL library.")
 450 endif()
 451
 452 # Put all executables into the bin subdirectory
 453 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${piglit_BINARY_DIR}/bin)
 454 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${piglit_BINARY_DIR}/lib)
 455
 456 # Do the same for MSVC, regardless of the build type. This only works correctly
 457 # for CMake 2.8.1 and above.
 458 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY_DEBUG ${piglit_BINARY_DIR}/bin)
 459 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY_RELEASE ${piglit_BINARY_DIR}/bin)
 460 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY_MINSIZEREL ${piglit_BINARY_DIR}/bin)
 461 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY_RELWITHDEBINFO ${piglit_BINARY_DIR}/bin)
 462
 463 check_function_exists(asprintf  HAVE_ASPRINTF)
 464 check_function_exists(ffs       HAVE_FFS)
 465 check_function_exists(strchrnul HAVE_STRCHRNUL)
 466 check_function_exists(strndup   HAVE_STRNDUP)
 467 if(NOT MINGW)
 468 check_function_exists(fopen_s   HAVE_FOPEN_S)
 469 endif()
 470 check_function_exists(setrlimit HAVE_SETRLIMIT)
 471
 472 check_symbol_exists(htobe32 "endian.h" HAVE_HTOBE32)
 473 check_symbol_exists(htole16 "endian.h" HAVE_HTOLE16)
 474 check_symbol_exists(htole32 "endian.h" HAVE_HTOLE32)
 475 check_symbol_exists(htole64 "endian.h" HAVE_HTOLE64)
 476
 477 check_include_file(sys/time.h  HAVE_SYS_TIME_H)
 478 check_include_file(sys/types.h HAVE_SYS_TYPES_H)
 479 check_include_file(sys/resource.h  HAVE_SYS_RESOURCE_H)
 480 check_include_file(sys/stat.h  HAVE_SYS_STAT_H)
 481 check_include_file(unistd.h    HAVE_UNISTD_H)
 482 check_include_file(fcntl.h     HAVE_FCNTL_H)
 483 check_include_file(linux/sync_file.h HAVE_LINUX_SYNC_FILE_H)
 484
 485 if(DEFINED PIGLIT_INSTALL_VERSION)
 486         set(PIGLIT_INSTALL_VERSION_SUFFIX
 487             "-${PIGLIT_INSTALL_VERSION}")
 488 else()
 489         set(PIGLIT_INSTALL_VERSION_SUFFIX "")
 490 endif()
 491 set(PIGLIT_INSTALL_LIBDIR
 492     "${CMAKE_INSTALL_LIBDIR}/piglit${PIGLIT_INSTALL_VERSION_SUFFIX}")
 493 if(NOT IS_ABSOLUTE ${PIGLIT_INSTALL_LIBDIR})
 494         set(PIGLIT_INSTALL_FULL_LIBDIR "${CMAKE_INSTALL_PREFIX}/${PIGLIT_INSTALL_LIBDIR}")
 495 else()
 496         set(PIGLIT_INSTALL_FULL_LIBDIR "${PIGLIT_INSTALL_LIBDIR}")
 497 endif()
 498
 499 if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
 500   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -Wl,--enable-new-dtags")
 501 endif(CMAKE_SYSTEM_NAME STREQUAL "Linux")
 502
 503 SET(CMAKE_INSTALL_RPATH "${PIGLIT_INSTALL_FULL_LIBDIR}/lib")
 504
 505 configure_file(
 506         "${piglit_SOURCE_DIR}/tests/util/config.h.in"
 507         "${piglit_BINARY_DIR}/tests/util/config.h"
 508 )
 509
 510 include(cmake/piglit_util.cmake)
 511 include(cmake/piglit_dispatch.cmake)
 512
 513 include_directories(src)
 514 add_subdirectory(cmake/target_api)
 515 add_subdirectory(generated_tests)
 516 add_subdirectory(replayer)
 517
 518
 519 ##############################################################################
 520 # Packaging
 521
 522 install (
 523         FILES
 524                 COPYING
 525                 README.md
 526                 RELEASE
 527         DESTINATION share/doc/piglit${PIGLIT_INSTALL_VERSION_SUFFIX}
 528 )
 529
 530 install (
 531         DIRECTORY framework
 532         DESTINATION ${PIGLIT_INSTALL_LIBDIR}
 533         FILES_MATCHING PATTERN "*.py"
 534 )
 535
 536 install (
 537         DIRECTORY templates
 538         DESTINATION ${PIGLIT_INSTALL_LIBDIR}
 539 )
 540
 541 install (
 542         DIRECTORY tests
 543         DESTINATION ${PIGLIT_INSTALL_LIBDIR}
 544         FILES_MATCHING REGEX ".*\\.(xml|xml.gz|py|program_test|shader_test|shader_source|frag|vert|geom|tesc|tese|comp|spv|ktx|cl|txt|inc|vk_shader_test)$"
 545         REGEX "CMakeFiles|CMakeLists|serializer.py|opengl.py|cl.py|quick_gl.py|glslparser.py|shader.py|quick_shader.py|no_error.py|llvmpipe_gl.py|sanity.py" EXCLUDE
 546 )
 547
 548 install (
 549         DIRECTORY ${CMAKE_BINARY_DIR}/tests
 550         DESTINATION ${PIGLIT_INSTALL_LIBDIR}
 551         FILES_MATCHING REGEX ".*\\.xml.gz"
 552 )
 553
 554 install (
 555         DIRECTORY ${CMAKE_BINARY_DIR}/generated_tests
 556         DESTINATION ${PIGLIT_INSTALL_LIBDIR}
 557         FILES_MATCHING REGEX ".*\\.(shader_test|program_test|frag|vert|geom|tesc|tese|comp|cl|txt|vk_shader_test)$"
 558         REGEX "CMakeFiles|CMakeLists" EXCLUDE
 559 )
 560
 561 install (
 562         DIRECTORY generated_tests
 563         DESTINATION ${PIGLIT_INSTALL_LIBDIR}
 564         FILES_MATCHING REGEX ".*\\.inc$"
 565         REGEX "CMakeFiles|CMakeLists" EXCLUDE
 566 )
 567
 568 if (BASH_COMPLETION_FOUND)
 569         install(
 570                 FILES completions/bash/piglit
 571                 DESTINATION ${CMAKE_INSTALL_PREFIX}/${BASH_COMPLETION_COMPLETIONSDIR}/
 572         )
 573 endif (BASH_COMPLETION_FOUND)
 574
 575 if (WIN32)
 576         set (PYTHON_SUFFIX ".py")
 577 else ()
 578         set (PYTHON_SUFFIX "")
 579 endif ()
 580 install (
 581         PROGRAMS piglit RENAME piglit${PIGLIT_INSTALL_VERSION_SUFFIX}${PYTHON_SUFFIX}
 582         DESTINATION ${CMAKE_INSTALL_BINDIR}
 583 )
 584
 585 # Install MinGW runtime DLLs
 586 if (MINGW)
 587         if (CMAKE_SIZEOF_VOID_P EQUAL 8)
 588                 set (LIBGCC_DLL_NAME libgcc_s_seh-1.dll)
 589         else ()
 590                 set (LIBGCC_DLL_NAME libgcc_s_sjlj-1.dll)
 591         endif ()
 592         execute_process (
 593                 COMMAND ${CMAKE_C_COMPILER} -print-file-name=${LIBGCC_DLL_NAME}
 594                 OUTPUT_STRIP_TRAILING_WHITESPACE
 595                 OUTPUT_VARIABLE LIBGCC_DLL
 596         )
 597         execute_process (
 598                 COMMAND ${CMAKE_CXX_COMPILER} -print-file-name=libstdc++-6.dll
 599                 OUTPUT_STRIP_TRAILING_WHITESPACE
 600                 OUTPUT_VARIABLE LIBSTDCXX_DLL
 601         )
 602         if (EXISTS ${LIBGCC_DLL})
 603                 message (STATUS "Found libgcc DLL: ${LIBGCC_DLL}")
 604                 install (FILES ${LIBGCC_DLL} DESTINATION ${PIGLIT_INSTALL_LIBDIR}/bin)
 605         endif ()
 606         if (EXISTS ${LIBSTDCXX_DLL})
 607                 message (STATUS "Found libstdc++ DLL: ${LIBSTDCXX_DLL}")
 608                 install (FILES ${LIBSTDCXX_DLL} DESTINATION ${PIGLIT_INSTALL_LIBDIR}/bin)
 609         endif ()
 610 endif ()
 611
 612 # Install Waffle DLL if specified
 613 if (WIN32 AND Waffle_DLL)
 614         install (FILES ${Waffle_DLL} DESTINATION ${PIGLIT_INSTALL_LIBDIR}/bin)
 615 endif ()
 616
 617
 618 set (CPACK_PACKAGE_VERSION_MAJOR "1")
 619 set (CPACK_PACKAGE_VERSION_MINOR "0")
 620
 621 # Use current date in YYYYMMDD format as patch number
 622 execute_process (
 623         COMMAND ${PYTHON_EXECUTABLE} -c "import time, sys; sys.stdout.write(time.strftime('%Y%m%d'))"
 624         OUTPUT_VARIABLE CPACK_PACKAGE_VERSION_PATCH
 625 )
 626
 627 # cpack mistakenly detects Mingw-w64 as win32
 628 if (MINGW)
 629         if (CMAKE_SIZEOF_VOID_P EQUAL 8)
 630                 set (CPACK_SYSTEM_NAME win64)
 631         endif ()
 632 endif ()
 633
 634 # See http://www.vtk.org/Wiki/CMake:CPackPackageGenerators
 635 if (WIN32)
 636         set (CPACK_GENERATOR "7Z")
 637         set (CPACK_STRIP_FILES ON)
 638 else ()
 639         set (CPACK_GENERATOR "TBZ2")
 640 endif ()
 641
 642 include(CPack)