tests/util/CMakeLists.txt

   1 add_definitions(-DSOURCE_DIR="${piglit_SOURCE_DIR}/")
   2
   3 if(PIGLIT_HAS_POSIX_CLOCK_MONOTONIC AND HAVE_LIBRT)
   4     link_libraries(rt)
   5 endif()
   6
   7 # CMake requires that source file properties be set in the same directory where
   8 # the property is used.
   9 set_source_files_properties(
  10         ${piglit_dispatch_gen_outputs}
  11         PROPERTIES GENERATED 1
  12         )
  13
  14 link_libraries(${CMAKE_DL_LIBS})
  15
  16 if(HAVE_LIBCACA)
  17     link_libraries(caca)
  18 endif()
  19
  20 if(HAVE_XKBCOMMON)
  21         link_libraries(${XKBCOMMON_LIBRARIES})
  22         include_directories(${XKBCOMMON_INCLUDE_DIRS})
  23 endif()
  24
  25 if(PNG_FOUND)
  26         link_libraries(${PNG_LIBRARIES})
  27         include_directories(${PNG_INCLUDE_DIRS})
  28 endif(PNG_FOUND)
  29
  30 set(UTIL_INCLUDES
  31         ${CMAKE_CURRENT_BINARY_DIR}
  32         ${CMAKE_CURRENT_SOURCE_DIR}
  33         )
  34
  35 set(UTIL_SOURCES
  36         piglit-log.c
  37         piglit-util.c
  38         piglit-subprocess.c
  39         )
  40
  41 set(UTIL_GL_INCLUDES
  42         ${UTIL_INCLUDES}
  43         ${GLEXT_INCLUDE_DIR}
  44         ${OPENGL_INCLUDE_PATH}
  45         ${Waffle_INCLUDE_DIRS}
  46         )
  47
  48 set(UTIL_GL_SOURCES
  49         fdo-bitmap.c
  50         minmax-test.c
  51         piglit-dispatch.c
  52         piglit-dispatch-init.c
  53         piglit-fbo.cpp
  54         piglit-matrix.c
  55         piglit-test-pattern.cpp
  56         piglit-util-gl.c
  57         piglit-util-png.c
  58         piglit-vbo.cpp
  59         piglit-framework-gl.c
  60         piglit-framework-gl/piglit_gl_framework.c
  61         piglit-shader.c
  62         piglit-shader-test.c
  63         piglit_ktx.c
  64         rgb9e5.c
  65         r11g11b10f.c
  66         sized-internalformats.c
  67         ${CMAKE_BINARY_DIR}/tests/util/piglit-util-gl-enum-gen.c
  68         )
  69
  70 set(UTIL_GL_LIBS
  71         piglitutil
  72         )
  73
  74 if(PIGLIT_USE_WAFFLE)
  75         list(APPEND UTIL_GL_SOURCES
  76                 piglit-framework-gl/piglit_fbo_framework.c
  77                 piglit-framework-gl/piglit_wfl_framework.c
  78                 piglit-framework-gl/piglit_winsys_framework.c
  79                 piglit-util-waffle.c
  80         )
  81
  82         if(PIGLIT_HAS_WGL)
  83                 list(APPEND UTIL_GL_SOURCES
  84                         piglit-framework-gl/piglit_wgl_framework.c
  85                 )
  86         endif()
  87         if(PIGLIT_HAS_GBM)
  88                 list(APPEND UTIL_GL_SOURCES
  89                         piglit-framework-gl/piglit_gbm_framework.c
  90                 )
  91                 list(APPEND UTIL_GL_LIBS
  92                         ${GBM_LDFLAGS}
  93                 )
  94         endif()
  95         if(PIGLIT_HAS_WAYLAND)
  96                 list(APPEND UTIL_GL_SOURCES
  97                         piglit-framework-gl/piglit_wl_framework.c
  98                 )
  99                 list(APPEND UTIL_GL_INCLUDES
 100                         ${WAYLAND_wayland-client_INCLUDEDIR}
 101                 )
 102         endif()
 103         if(PIGLIT_HAS_X11)
 104                 list(APPEND UTIL_GL_SOURCES
 105                         piglit-framework-gl/piglit_x11_framework.c
 106                 )
 107         endif()
 108         if(PIGLIT_HAS_EGL)
 109                 list(APPEND UTIL_GL_SOURCES
 110                         piglit-framework-gl/piglit_sl_framework.c
 111                 )
 112         endif()
 113
 114         list(APPEND UTIL_GL_LIBS
 115                 ${Waffle_LDFLAGS}
 116         )
 117         IF(PIGLIT_BUILD_GLX_TESTS)
 118                 list(APPEND UTIL_GL_LIBS
 119                         ${OPENGL_gl_LIBRARY}
 120                 )
 121         ENDIF(PIGLIT_BUILD_GLX_TESTS)
 122 else()
 123         list(APPEND UTIL_GL_SOURCES
 124                 piglit-framework-gl/piglit_glut_framework.c
 125         )
 126
 127         list(APPEND UTIL_GL_LIBS
 128                 ${OPENGL_gl_LIBRARY}
 129         )
 130 endif()
 131
 132 if(${CMAKE_SYSTEM_NAME} MATCHES "Linux")
 133         # One needs to have at least one hardware driver present, otherwise
 134         # there is no point compiling just the dispatcher.
 135         if(PIGLIT_BUILD_DMA_BUF_TESTS)
 136                 add_definitions(-DHAVE_LIBDRM)
 137
 138                 list(APPEND UTIL_GL_SOURCES
 139                         piglit-framework-gl/piglit_drm_dma_buf.c
 140                 )
 141
 142                 list(APPEND UTIL_GL_LIBS
 143                         ${LIBDRM_LDFLAGS}
 144                         ${XCB_LDFLAGS}
 145                         ${XCB_DRI2_LDFLAGS}
 146                 )
 147
 148                 list(APPEND UTIL_GL_INCLUDES
 149                         ${LIBDRM_INCLUDE_DIRS}
 150                         ${XCB_INCLUDE_DIRS}
 151                         ${XCB_DRI2_INCLUDE_DIRS}
 152                 )
 153         endif()
 154
 155         if(PIGLIT_HAS_X11)
 156                 list(APPEND UTIL_GL_LIBS ${X11_X11_LIB})
 157         endif()
 158
 159         if(PIGLIT_HAS_WAYLAND)
 160                 list(APPEND UTIL_GL_LIBS ${WAYLAND_LDFLAGS})
 161         endif()
 162
 163 endif(${CMAKE_SYSTEM_NAME} MATCHES "Linux")
 164
 165 if(MSVC)
 166         list(APPEND UTIL_SOURCES msvc/getopt.c)
 167 endif()
 168
 169 piglit_include_target_api()