configure.ac

   1 AC_PREREQ([2.60])
   2 AC_INIT([OpenAFS],
   3     m4_esyscmd([build-tools/git-version .]),
   4     [openafs-bugs@openafs.org], [],
   5     [http://www.openafs.org/])
   6 AC_CONFIG_AUX_DIR([build-tools])
   7 AC_CONFIG_MACRO_DIR([src/cf])
   8 AC_CONFIG_SRCDIR([src/config/stds.h])
   9 AM_INIT_AUTOMAKE([foreign])
  10
  11 AC_CONFIG_HEADER([src/config/afsconfig.h])
  12 MACOS_VERSION=1.8.0fc2
  13 LINUX_PKGREL=1.8.0pre2
  14
  15 AC_SUBST([MACOS_VERSION])
  16
  17 dnl If the user hasn't specified CFLAGS don't let configure pick -g -O2
  18 AS_IF([test -z "$CFLAGS"], [CFLAGS=" "])
  19
  20 AC_USE_SYSTEM_EXTENSIONS
  21
  22 LT_INIT
  23
  24 AC_PROG_CC
  25 AC_PROG_LIBTOOL
  26
  27 AC_PATH_PROGS([PATH_CPP], [cpp], [${CC-cc} -E], [$PATH:/lib:/usr/ccs/lib])
  28 AC_SUBST([PATH_CPP])
  29 OPENAFS_CONFIGURE_COMMON
  30
  31 dnl Probe for Kerberos.  We have a few platform-specific overrides due to
  32 dnl weird Kerberos implementations and installation locations.
  33 AS_CASE([$AFS_SYSNAME],
  34     [*_obsd*],
  35     [KRB5_CPPFLAGS="-I/usr/include/kerberosV"],
  36
  37     [ppc_darwin_70],
  38     [KRB5_CPPFLAGS="-I/usr/include"
  39      KRB5_LDFLAGS="-L/usr/lib -Wl,-search_paths_first"])
  40 RRA_LIB_KRB5_OPTIONAL
  41 AS_CASE([$AFS_SYSNAME],
  42     [hp_ux*|*_hpux*],
  43     [KRB5_LIBS="-l:libkrb5.sl -l:libcom_err.sl"])
  44
  45 dnl Check for the characteristics of whatever Kerberos we found, if we found
  46 dnl one.
  47 BUILD_KRB5=no
  48 MAKE_KRB5="#"
  49 AS_IF([test x"$KRB5_LIBS" != x],
  50     [BUILD_KRB5=yes
  51      MAKE_KRB5=
  52      RRA_LIB_KRB5_SWITCH
  53      AC_CHECK_FUNCS([add_error_table \
  54         add_to_error_table \
  55         encode_krb5_enc_tkt_part \
  56         encode_krb5_ticket \
  57         krb5_524_conv_principal \
  58         krb5_allow_weak_crypto \
  59         krb5_c_encrypt \
  60         krb5_decode_ticket \
  61         krb5_enctype_enable \
  62         krb5_free_keytab_entry_contents \
  63         krb5_free_unparsed_name \
  64         krb5_get_init_creds_opt_alloc \
  65         krb5_get_prompt_types \
  66         krb5_princ_size \
  67         krb5_principal_get_comp_string])
  68      AC_CHECK_FUNCS([krb5_524_convert_creds], [],
  69         [AC_CHECK_FUNCS([krb524_convert_creds_kdc], [],
  70             [AC_CHECK_LIB([krb524], [krb524_convert_creds_kdc],
  71                 [LIBS="-lkrb524 $LIBS"
  72                  KRB5_LIBS="-lkrb524 $KRB5_LIBS"
  73                  AC_CHECK_LIB([krb524], [krb5_524_conv_principal],
  74                      [AC_DEFINE([HAVE_KRB5_524_CONV_PRINCIPAL], [1],
  75                          [Define to 1 if you have the `krb5_524_conv_principal' function.])
  76                  ])
  77                  AC_DEFINE([HAVE_KRB524_CONVERT_CREDS_KDC], [1],
  78                      [Define to 1 if you have the `krb524_convert_creds_kdc' function.])
  79             ])
  80         ])
  81      ])
  82      AC_CHECK_HEADERS([kerberosIV/krb.h])
  83      AC_CHECK_HEADERS([kerberosV/heim_err.h])
  84      AC_CHECK_HEADERS([com_err.h et/com_err.h krb5/com_err.h])
  85      AS_IF([test x"$ac_cv_header_com_err_h" != xyes \
  86              && test x"$ac_cv_header_et_com_err_h" != xyes \
  87              && test x"$ac_cv_header_krb5_com_err_h" != xyes],
  88        [AC_MSG_ERROR([Cannot find a usable com_err.h])])
  89      AC_CHECK_MEMBERS([krb5_creds.keyblock, krb5_creds.keyblock.enctype, krb5_creds.session,
  90                        krb5_prompt.type], [], [], [#include <krb5.h>])
  91      AC_CHECK_MEMBERS([krb5_keytab_entry.key, krb5_keytab_entry.keyblock],
  92                       [], [], [#include <krb5.h>])
  93 dnl If we have krb5_creds.session, we are using heimdal
  94 dnl If we're using heimdal, aklog needs libasn1 for encode_EncTicketPart and a
  95 dnl few other functions. But just aklog; not any of the other stuff that uses
  96 dnl krb5.
  97      AS_IF([test x"$ac_cv_member_krb5_creds_session" = xyes],
  98            [AC_CHECK_LIB([asn1], [encode_EncTicketPart],
  99                [AKLOG_KRB5_LIBS="-lasn1"])
 100      ])
 101      RRA_LIB_KRB5_RESTORE
 102 ])
 103 AC_SUBST([BUILD_KRB5])
 104 AC_SUBST([MAKE_KRB5])
 105 AC_SUBST([AKLOG_KRB5_LIBS])
 106
 107 dnl Probe for GSSAPI
 108 RRA_LIB_GSSAPI
 109 dnl Check for the characteristics of whatever GSSAPI we found, if we found one
 110 BUILD_GSSAPI=no
 111 AS_IF([test x"$GSSAPI_LIBS" != x],
 112     [BUILD_GSSAPI=yes
 113 ])
 114 AC_SUBST([BUILD_GSSAPI])
 115
 116 dnl Checks for summary
 117 OPENAFS_SUMMARY_CHECK_NAMEI
 118
 119 AS_IF([test -d 'doc/man-pages'],
 120     [MAN_MAKEFILE="doc/man-pages/Makefile doc/man-pages/install-man"],
 121     [MAN_MAKEFILE=])
 122 AS_IF([test -f 'doc/xml/AdminGuide/Makefile.in'],
 123     [ADMINGUIDE_MAKEFILE="doc/xml/AdminGuide/Makefile"],
 124     [ADMINGUIDE_MAKEFILE=])
 125 AS_IF([test -f 'doc/xml/QuickStartUnix/Makefile.in'],
 126     [QSUNIX_MAKEFILE="doc/xml/QuickStartUnix/Makefile"],
 127     [QSUNIX_MAKEFILE=])
 128 AS_IF([test -f 'doc/xml/UserGuide/Makefile.in'],
 129     [USERGUIDE_MAKEFILE="doc/xml/UserGuide/Makefile"],
 130     [USERGUIDE_MAKEFILE=])
 131 AS_IF([test -f 'doc/xml/AdminRef/Makefile.in'],
 132     [ADMINREF_MAKEFILE="doc/xml/AdminRef/Makefile"],
 133     [ADMINREF_MAKEFILE=])
 134 AS_IF([test -f 'doc/xml/mobi-fixup.xsl.in'],
 135     [MOBI_FIXUP_XSL="doc/xml/mobi-fixup.xsl"],
 136     [MOBI_FIXUP_XSL=])
 137 AS_IF([test -f 'doc/doxygen/Doxyfile.in'],
 138     [DOXYFILE="doc/doxygen/Doxyfile"],
 139     [DOXYFILE=])
 140
 141 AC_OUTPUT([
 142     Makefile
 143     ${MAN_MAKEFILE}
 144     ${ADMINGUIDE_MAKEFILE}
 145     ${QSUNIX_MAKEFILE}
 146     ${USERGUIDE_MAKEFILE}
 147     ${ADMINREF_MAKEFILE}
 148     ${MOBI_FIXUP_XSL}
 149     ${DOXYFILE}
 150     src/afs/Makefile
 151     src/afsd/Makefile
 152     src/afsmonitor/Makefile
 153     src/afsweb/Makefile
 154     src/aklog/Makefile
 155     src/audit/Makefile
 156     src/auth/Makefile
 157     src/auth/test/Makefile
 158     src/bozo/Makefile
 159     src/bozo/test/Makefile
 160     src/bu_utils/Makefile
 161     src/bubasics/Makefile
 162     src/bucoord/Makefile
 163     src/budb/Makefile
 164     src/tbudb/Makefile
 165     src/butc/Makefile
 166     src/butm/Makefile
 167     src/cmd/Makefile
 168     src/cmd/test/Makefile
 169     src/comerr/Makefile
 170     src/comerr/test/Makefile
 171     src/config/Makefile
 172     src/config/Makefile.config
 173     src/config/Makefile.libtool
 174     src/config/Makefile.lwp
 175     src/config/Makefile.lwptool
 176     src/config/Makefile.pthread
 177     src/config/Makefile.version-CML
 178     src/config/Makefile.version-NOCML
 179     src/config/shlib-build
 180     src/config/shlib-install
 181     src/crypto/hcrypto/Makefile
 182     src/crypto/rfc3961/Makefile
 183     src/dir/Makefile
 184     src/dir/test/Makefile
 185     src/dviced/Makefile
 186     src/dvolser/Makefile
 187     src/export/Makefile
 188     src/finale/Makefile
 189     src/fsint/Makefile
 190     src/fsprobe/Makefile
 191     src/gtx/Makefile
 192     src/JAVA/libjafs/Makefile
 193     src/kauth/Makefile
 194     src/kauth/test/Makefile
 195     src/kopenafs/Makefile
 196     src/libacl/Makefile
 197     src/libacl/test/Makefile
 198     src/libadmin/Makefile
 199     src/libadmin/adminutil/Makefile
 200     src/libadmin/bos/Makefile
 201     src/libadmin/cfg/Makefile
 202     src/libadmin/cfg/test/Makefile
 203     src/libadmin/client/Makefile
 204     src/libadmin/kas/Makefile
 205     src/libadmin/pts/Makefile
 206     src/libadmin/samples/Makefile
 207     src/libadmin/test/Makefile
 208     src/libadmin/vos/Makefile
 209     src/libafs/Makefile.common
 210     src/libafs/MakefileProto.${MKAFS_OSTYPE}
 211     ${DARWIN_PLIST}
 212     src/libafsauthent/Makefile
 213     src/libafsrpc/Makefile
 214     src/libuafs/Makefile.common
 215     src/libuafs/MakefileProto.${MKAFS_OSTYPE}
 216     src/log/Makefile
 217     src/log/test/Makefile
 218     src/lwp/Makefile
 219     src/lwp/test/Makefile
 220     src/opr/Makefile
 221     src/packaging/MacOS/OpenAFS-debug.Description.plist
 222     src/packaging/MacOS/OpenAFS-debug.Info.plist
 223     src/packaging/MacOS/OpenAFS.Description.plist
 224     src/packaging/MacOS/OpenAFS.Info.plist
 225     src/packaging/MacOS/OpenAFS.info
 226     src/packaging/MacOS/buildpkg.sh
 227     src/packaging/MacOS/pkgbuild.sh
 228     src/pam/Makefile
 229     src/platform/Makefile
 230     src/platform/${MKAFS_OSTYPE}/Makefile
 231     src/platform/DARWIN/growlagent/Makefile
 232     src/procmgmt/Makefile
 233     src/procmgmt/test/Makefile
 234     src/ptserver/Makefile
 235     src/tptserver/Makefile
 236     src/roken/Makefile
 237     src/rx/Makefile
 238     src/rx/bulk.example/Makefile
 239     src/rx/bulktest/Makefile
 240     src/rx/multi.example/Makefile
 241     src/rx/simple.example/Makefile
 242     src/rx/test/Makefile
 243     src/rxdebug/Makefile
 244     src/rxgen/Makefile
 245     src/rxkad/Makefile
 246     src/rxkad/test/Makefile
 247     src/rxosd/Makefile
 248     src/rxstat/Makefile
 249     src/scout/Makefile
 250     src/sys/Makefile
 251     src/tbutc/Makefile
 252     src/tests/Makefile
 253     src/tests/run-tests
 254     src/tools/Makefile
 255     src/tools/dumpscan/Makefile
 256     src/tools/rxperf/Makefile
 257     src/tsalvaged/Makefile
 258     src/tsm41/Makefile
 259     src/tvolser/Makefile
 260     src/ubik/Makefile
 261     src/tubik/Makefile
 262     src/update/Makefile
 263     src/usd/Makefile
 264     src/usd/test/Makefile
 265     src/uss/Makefile
 266     src/util/Makefile
 267     src/util/test/Makefile
 268     src/libafscp/Makefile
 269     src/venus/Makefile
 270     src/venus/test/Makefile
 271     src/vfsck/Makefile
 272     src/viced/Makefile
 273     src/vlserver/Makefile
 274     src/tvlserver/Makefile
 275     src/vol/Makefile
 276     src/vol/test/Makefile
 277     src/volser/Makefile
 278     src/xstat/Makefile
 279     src/helper-splint.sh
 280     tests/Makefile
 281     tests/auth/Makefile
 282     tests/cmd/Makefile
 283     tests/common/Makefile
 284     tests/opr/Makefile
 285     tests/rpctestlib/Makefile
 286     tests/rx/Makefile
 287     tests/tap/Makefile
 288     tests/util/Makefile
 289     tests/volser/Makefile],
 290 [chmod a+x src/config/shlib-build
 291  chmod a+x src/config/shlib-install])
 292
 293 # print a final summary
 294 OPENAFS_SUMMARY