configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl Initialize.
   4 AC_PREREQ(2.63)
   5 AC_INIT([GNU PSPP], [0.10.5pre1], [bug-gnu-pspp@gnu.org], [pspp])
   6 AC_CONFIG_AUX_DIR([build-aux])
   7 AC_CONFIG_HEADERS([config.h])
   8 AC_CONFIG_TESTDIR([tests])
   9 AM_INIT_AUTOMAKE
  10
  11 dnl Checks for programs.
  12 AC_GNU_SOURCE
  13 AC_PROG_CC
  14 gl_EARLY
  15 AM_PROG_CC_C_O
  16 AC_LIBTOOL_WIN32_DLL
  17 AC_LIBTOOL_DLOPEN
  18 AC_PROG_LIBTOOL
  19 AC_HEADER_TIOCGWINSZ
  20 PKG_PROG_PKG_CONFIG
  21 m4_pattern_forbid([PKG_CHECK_MODULES])
  22 PSPP_CHECK_CLICKSEQUENCE
  23 PSPP_CHECK_DOT
  24
  25 PSPP_ENABLE_WERROR
  26
  27 AM_CONDITIONAL(cc_is_gcc, test x"$GCC" = x"yes" )
  28
  29 PSPP_CC_FOR_BUILD
  30 PSPP_PERL
  31
  32 dnl Disable automatic po/ support, because PSPP provides its own po/ support.
  33 AC_PROVIDE([AM_PO_SUBDIRS])
  34 AM_GNU_GETTEXT([external], [need-ngettext])
  35 LIBS="$LIBINTL $LIBS"
  36 AC_CHECK_PROGS([MSGFMT], [msgfmt])
  37 if test "x$MSGFMT" = x; then
  38   PSPP_REQUIRED_PREREQ([msgfmt (is usually provided with gettext)])
  39 fi
  40
  41
  42 dnl Checks for libraries.
  43 AC_SYS_LARGEFILE
  44 AC_SEARCH_LIBS([sin], [m])
  45 PSPP_LC_PAPER
  46
  47
  48 AC_ARG_VAR([PSPP_LDFLAGS], [linker flags to be used for linking the pspp binary only])
  49 AC_ARG_VAR([PSPPIRE_LDFLAGS], [linker flags to be used for linking the psppire binary only])
  50
  51 # Support for Cairo and Pango.
  52 AC_ARG_WITH([cairo],
  53   [AS_HELP_STRING(
  54     [--without-cairo],
  55     [Don't build support for charts (using Cairo and Pango);
  56      implies --without-gui])],
  57   [], [with_cairo=yes])
  58 AM_CONDITIONAL([HAVE_CAIRO], [test "$with_cairo" != no])
  59 if test "$with_cairo" != no; then
  60   PKG_CHECK_MODULES([CAIRO], [cairo >= 1.5 pango >= 1.22 pangocairo],
  61     [CPPFLAGS="$CPPFLAGS $CAIRO_CFLAGS"
  62      AC_DEFINE([HAVE_CAIRO], 1,
  63        [Define to 1 if Cairo and Pango are available.])],
  64     [PSPP_REQUIRED_PREREQ([cairo 1.5 or later and pango 1.22 or later (or use --without-cairo)])])
  65 fi
  66
  67 dnl Xmllint is used in the rules to build the documentation.  It is not actually necessary,
  68 dnl but is used for post-build consistency checks.  Thus, non-developers can live without it.
  69 dnl However for it to be useful, it needs to be a certain version and have certain features.
  70 dnl The macros below check that it the xmllint available is up to scratch.  If it isn't
  71 dnl then a dummy /bin/echo is subsituted instead.
  72
  73 AC_CACHE_CHECK([for an xmllint program which fits our needs],[ac_cv_path_XMLLINT],
  74 [AC_PATH_PROGS_FEATURE_CHECK([XMLLINT], [xmllint],
  75   [[$ac_path_XMLLINT --version 2>&1 | $GREP XPath > /dev/null &&
  76     test `$ac_path_XMLLINT --version 2>&1 | $SED 's/^.* \([0-9]*\).*/\1/'` -gt 20900 &&
  77     ac_cv_path_XMLLINT=$ac_path_XMLLINT]],
  78    [AC_MSG_WARN([no appropriate xmllint program found. Using a dummy (echo)]); ac_cv_path_XMLLINT=$ECHO])])
  79
  80 AC_SUBST([XMLLINT],[$ac_cv_path_XMLLINT])
  81
  82 # Support for GUI.
  83 AC_ARG_WITH([gui],
  84   [AS_HELP_STRING([--without-gui],
  85                   [Don't build the PSPPIRE GUI (using GTK+)])],
  86   [], [with_gui=yes])
  87 AM_CONDITIONAL([HAVE_GUI],
  88                [test "$with_cairo" != no && test "$with_gui" != "no"])
  89 if test "$with_cairo" != no && test "$with_gui" != "no"; then
  90   PKG_CHECK_MODULES([GTHREAD], [gthread-2.0], [],
  91     [PSPP_REQUIRED_PREREQ([gthread 2.0 (or use --without-gui)])])
  92
  93   PKG_CHECK_MODULES([GTK], [gtk+-3.0 >= 3.14.5], [],
  94     [PSPP_REQUIRED_PREREQ([gtk+ 3.0 version 3.14.5 or later (or use --without-gui)])])
  95
  96   PKG_CHECK_MODULES([GTKSOURCEVIEW], [gtksourceview-3.0 >= 3.4.2], [],
  97     [PSPP_REQUIRED_PREREQ([gtksourceview 3.0 version 3.4.2 or later (or use --without-gui)])])
  98
  99   PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.32], [],
 100     [PSPP_REQUIRED_PREREQ([glib 2.0 version 2.32 or later (or use --without-gui)])])
 101
 102   AC_ARG_VAR([GLIB_GENMARSHAL])
 103   AC_CHECK_PROGS([GLIB_GENMARSHAL], [glib-genmarshal])
 104   if test "x$GLIB_GENMARSHAL" = x; then
 105     PSPP_REQUIRED_PREREQ([glib-genmarshal (or use --without-gui)])
 106   fi
 107
 108   AC_CHECK_PROGS([GLIB_COMPILE_RESOURCES], [glib-compile-resources])
 109   if test "x$GLIB_COMPILE_RESOURCES" = x; then
 110     PSPP_REQUIRED_PREREQ([glib-compile-resources (or use --without-gui)])
 111   fi
 112
 113 fi
 114
 115 gl_NEXT_HEADERS([gtk/gtk.h])
 116
 117 dnl Checks needed for psql reader
 118
 119 dnl The 8.x series postgres tarballs installs with a default prefix of
 120 dnl /usr/local/pgsql whereas, OSes (such as debian)  install into /usr .
 121
 122 dnl If the libpq.so file is in a non standard path, (one which the linker
 123 dnl doesn't search) then we must set the PG_LDFLAGS to -R/usr/wherever/
 124 dnl However, if the system happens to have more than one version of other
 125 dnl dependent libraries (eg. libgtk) in different standard paths. (eg:
 126 dnl /usr and /usr/local) then the wrong one may get linked.
 127
 128 dnl To overcome this, we first check for libpq in the standard places, and
 129 dnl only set PG_LDFLAGS if it's not found.
 130
 131
 132 AC_ARG_WITH(
 133   libpq,
 134   [AS_HELP_STRING([--without-libpq], [don't compile in Postgres capability])])
 135 AC_ARG_VAR([PG_CONFIG],
 136            [Full pathname of the pg_config program shipped with Postgresql])
 137 AC_PATH_PROG([PG_CONFIG], [pg_config], [],
 138              [$PATH:/usr/local/pgsql/bin:/usr/pgsql/bin])
 139
 140 if test x"$with_libpq" != x"no" && test -n "$PG_CONFIG" ; then
 141   AC_SUBST(PG_CONFIG)
 142   PG_CFLAGS=-I`$PG_CONFIG --includedir`
 143   AC_SUBST(PG_CFLAGS)
 144
 145   AC_CHECK_LIB([pq], [PQexec],
 146      [:],
 147      [PG_LDFLAGS="-L`$PG_CONFIG --libdir` -R`$PG_CONFIG --libdir`"])
 148   AC_SUBST(PG_LDFLAGS)
 149
 150   PG_LIBS=-lpq
 151   AC_SUBST(PG_LIBS)
 152
 153   PKG_CHECK_EXISTS(libssl,
 154         AC_DEFINE([USE_SSL],1,
 155                    [Define to 1 if the openssl library is present.])
 156            ,)
 157
 158   # Now verify that we can actually link against libpq.  If we are
 159   # cross-compiling and picked up a host libpq, or if libpq is just
 160   # badly installed, this will fail.
 161   AC_CACHE_CHECK(
 162     [whether -lpq links successfully],
 163     [pspp_cv_have_libpq],
 164     [save_CPPFLAGS=$CPPFLAGS
 165      save_LIBS=$LIBS
 166      save_LDFLAGS=$LDFLAGS
 167      CPPFLAGS="$PG_CFLAGS $CPPFLAGS"
 168      LIBS="$PG_LIBS $LIBS"
 169      LDFLAGS="$PG_LDFLAGS $LDFLAGS"
 170      AC_LINK_IFELSE(
 171        [AC_LANG_PROGRAM(
 172          [#include <libpq-fe.h>
 173          ], [PQfinish (0);])],
 174        [pspp_cv_have_libpq=yes],
 175        [pspp_cv_have_libpq=no])
 176      CPPFLAGS=$save_CPPFLAGS
 177      LIBS=$save_LIBS
 178      LDFLAGS=$save_LDFLAGS])
 179
 180   if test $pspp_cv_have_libpq = yes; then
 181     PSQL_SUPPORT=yes
 182     AC_DEFINE([PSQL_SUPPORT], [1],
 183       [Define to 1 if building in support for reading from postgres
 184        databases.])
 185   else
 186     PSQL_SUPPORT=no
 187     PG_CONFIG=
 188     PG_CFLAGS=
 189     PG_LDFLAGS=
 190     PG_LIBS=
 191   fi
 192 else
 193   PSQL_SUPPORT=no
 194   pspp_cv_have_libpq=no
 195 fi
 196 AC_SUBST([PSQL_SUPPORT])
 197
 198 dnl Check for libxml2
 199 PKG_CHECK_MODULES(
 200   [LIBXML2], [libxml-2.0],
 201   [HAVE_LIBXML2=yes],
 202   [HAVE_LIBXML2=no
 203    PSPP_OPTIONAL_PREREQ([libxml2])])
 204
 205 dnl Check for zlib.
 206 AC_SEARCH_LIBS([gzopen], [z], [], [PSPP_REQUIRED_PREREQ([zlib])])
 207 AC_CHECK_HEADERS([zlib.h], [], [PSPP_REQUIRED_PREREQ([zlib])])
 208
 209 dnl Avoid interference between zlib's crc32() function and gnulib's
 210 dnl crc32() function, which have different signatures.  PSPP calls
 211 dnl only gnulib's crc32() directly, but it calls zlib's crc32()
 212 dnl indirectly through other zlib calls.  If we don't rename gnulib's
 213 dnl crc32(), then zlib will call gnulib's version instead of its own,
 214 dnl causing failures.  (This can happen even if zlib isn't detected
 215 dnl directly, because other libraries that PSPP uses, e.g. libpng,
 216 dnl sometimes use zlib themselves.)
 217 AC_DEFINE(
 218   [crc32], [gl_crc32],
 219   [Avoid making zlib call gnulib's crc32() instead of its own.])
 220
 221 dnl Gnumeric and OpenDocument (read) support requires libxml2 and zlib.
 222 if test $HAVE_LIBXML2 = yes; then
 223   GNM_READ_SUPPORT=yes
 224   ODF_READ_SUPPORT=yes
 225   AC_DEFINE(
 226     [GNM_READ_SUPPORT], [1],
 227     [Define to 1 if building in support for reading Gnumeric files.])
 228   AC_DEFINE(
 229     [ODF_READ_SUPPORT], [1],
 230     [Define to 1 if building in support for reading OpenDocument files.])
 231 else
 232   GNM_READ_SUPPORT=no
 233   ODF_READ_SUPPORT=no
 234 fi
 235 AC_SUBST([GNM_READ_SUPPORT])
 236 AC_SUBST([ODF_READ_SUPPORT])
 237
 238 dnl ODF support requires libxml2 (zlib is optional).
 239 if test $HAVE_LIBXML2 = yes; then
 240   AC_DEFINE(
 241     [ODF_WRITE_SUPPORT], [1],
 242     [Define to 1 if building in support for writing OpenDocument files.])
 243 fi
 244 AM_CONDITIONAL([ODF_WRITE_SUPPORT], [test $HAVE_LIBXML2 = yes])
 245
 246 AC_ARG_WITH(
 247   gui_tools,
 248   [AS_HELP_STRING([--with-gui-tools], [build the gui developer tools.  For DEVELOPERS only! There is no reason why users will need this flag.])])
 249 if test x"$with_gui_tools" = x"yes" ; then
 250         PKG_CHECK_MODULES(GLADE_UI, gladeui-2.0)
 251 fi
 252 AM_CONDITIONAL(WITH_GUI_TOOLS, test x"$with_gui_tools" = x"yes")
 253
 254 AC_ARG_WITH(
 255   [perl-module],
 256   [AS_HELP_STRING([--without-perl-module], [do not build the Perl module])],
 257   [case $with_perl_module in # (
 258      yes|no) ;; # (
 259      *) AC_MSG_FAILURE([--with-perl-module argument must be 'yes' or 'no']) ;;
 260    esac
 261    WITH_PERL_MODULE=$with_perl_module],
 262   [if test x"$cross_compiling" != x"yes"; then
 263      WITH_PERL_MODULE=yes
 264    else
 265      WITH_PERL_MODULE=no
 266    fi])
 267 AC_SUBST([WITH_PERL_MODULE])
 268 AM_CONDITIONAL(WITH_PERL_MODULE, test $WITH_PERL_MODULE = yes)
 269
 270 AC_SEARCH_LIBS([cblas_dsdot], [gslcblas],,[PSPP_REQUIRED_PREREQ([libgslcblas])])
 271 PKG_CHECK_MODULES([GSL], [gsl >= 1.13], [],
 272                          AC_SEARCH_LIBS([gsl_poly_eval_derivs], [gsl],,[PSPP_REQUIRED_PREREQ([gsl version 1.13 or later])]))
 273
 274
 275 PSPP_GSL_NEEDS_FGNU89_INLINE
 276
 277 PSPP_READLINE
 278
 279 dnl Checks for header files.
 280 AC_CHECK_HEADERS([sys/wait.h fpu_control.h ieeefp.h fenv.h pwd.h])
 281
 282 dnl Some systems don't have SIGWINCH
 283 AC_CHECK_DECLS([SIGWINCH], [], [],
 284           [#include <signal.h>
 285           /* NetBSD declares sys_siglist in unistd.h.  */
 286           #ifdef HAVE_UNISTD_H
 287           # include <unistd.h>
 288           #endif
 289           ])
 290
 291
 292 # For gnulib.
 293 gl_INIT
 294
 295 AC_C_INLINE
 296
 297 AC_C_BIGENDIAN
 298
 299 AC_CHECK_FUNCS([__setfpucw fork execl isinf isnan finite getpid feholdexcept fpsetmask popen round])
 300
 301 AC_PROG_LN_S
 302
 303 AC_ARG_ENABLE(
 304   debug,
 305   [AS_HELP_STRING([--enable-debug],
 306                   [Turn on diagnostic features in the program])])
 307 if test x"$enable_debug" = x"yes"  ; then
 308   AC_DEFINE(DEBUGGING, 1, [Define to 1 if debugging is enabled.])
 309 fi
 310
 311 # iconv is required
 312 AM_ICONV
 313 if test "$am_cv_func_iconv" != "yes"; then
 314    PSPP_REQUIRED_PREREQ([iconv (see http://www.gnu.org/software/libiconv/)])
 315 fi
 316 LIBS="$LIBICONV $LIBS"
 317
 318 dnl Required by the gnulib 'relocatable-prog' module.
 319 dnl See doc/relocatable-maint.texi in the gnulib tree for details.
 320 RELOCATABLE_LIBRARY_PATH='$(pkglibdir)'
 321 RELOCATABLE_STRIP=:
 322
 323 PSPP_CHECK_PREREQS
 324
 325 AC_CONFIG_FILES(
 326   [Makefile gl/Makefile po/Makefile tests/atlocal perl-module/lib/PSPP.pm])
 327
 328 AC_CONFIG_COMMANDS([doc/dummy], [:])
 329
 330 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES])
 331
 332 AC_OUTPUT
 333 echo "PSPP configured successfully."
 334
 335 dnl configure.ac ends here