configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl Initialize.
   4 AC_PREREQ(2.63)
   5 AC_INIT([GNU PSPP], [0.8.4], [bug-gnu-pspp@gnu.org], [pspp])
   6 AC_CONFIG_AUX_DIR([build-aux])
   7 AC_CONFIG_HEADERS([config.h])
   8 AC_CONFIG_TESTDIR([tests])
   9 AM_INIT_AUTOMAKE
  10
  11 dnl Checks for programs.
  12 AC_GNU_SOURCE
  13 AC_PROG_CC
  14 gl_EARLY
  15 AM_PROG_CC_C_O
  16 AC_LIBTOOL_WIN32_DLL
  17 AC_LIBTOOL_DLOPEN
  18 AC_PROG_LIBTOOL
  19 PKG_PROG_PKG_CONFIG
  20 m4_pattern_forbid([PKG_CHECK_MODULES])
  21 PSPP_CHECK_CLICKSEQUENCE
  22
  23 PSPP_ENABLE_WERROR
  24
  25 AM_CONDITIONAL(cc_is_gcc, test x"$GCC" = x"yes" )
  26
  27 PSPP_CC_FOR_BUILD
  28 PSPP_PERL
  29
  30 dnl Disable automatic po/ support, because PSPP provides its own po/ support.
  31 AC_PROVIDE([AM_PO_SUBDIRS])
  32 AM_GNU_GETTEXT([external], [need-ngettext])
  33 LIBS="$LIBINTL $LIBS"
  34
  35 dnl Checks for libraries.
  36 AC_SYS_LARGEFILE
  37 AC_SEARCH_LIBS([sin], [m])
  38 PSPP_LC_PAPER
  39
  40
  41 AC_ARG_VAR([PSPP_LDFLAGS], [linker flags to be used for linking the pspp binary only])
  42 AC_ARG_VAR([PSPPIRE_LDFLAGS], [linker flags to be used for linking the psppire binary only])
  43
  44 # Support for Cairo and Pango.
  45 AC_ARG_WITH([cairo],
  46   [AS_HELP_STRING(
  47     [--without-cairo],
  48     [Don't build support for charts (using Cairo and Pango);
  49      implies --without-gui])],
  50   [], [with_cairo=yes])
  51 AM_CONDITIONAL([HAVE_CAIRO], [test "$with_cairo" != no])
  52 if test "$with_cairo" != no; then
  53   PKG_CHECK_MODULES([CAIRO], [cairo >= 1.5 pango >= 1.22 pangocairo],
  54     [CPPFLAGS="$CPPFLAGS $CAIRO_CFLAGS"
  55      AC_DEFINE([HAVE_CAIRO], 1,
  56        [Define to 1 if Cairo and Pango are available.])],
  57     [PSPP_REQUIRED_PREREQ([cairo 1.5 or later and pango 1.22 or later (or use --without-cairo)])])
  58   AC_PATH_PROG([XMLLINT], [xmllint], [echo], [$PATH])
  59   AC_SUBST(XMLLINT)
  60 fi
  61
  62 # Support for GUI.
  63 AC_ARG_WITH([gui],
  64   [AS_HELP_STRING([--without-gui],
  65                   [Don't build the PSPPIRE GUI (using GTK+)])],
  66   [], [with_gui=yes])
  67 AM_CONDITIONAL([HAVE_GUI],
  68                [test "$with_cairo" != no && test "$with_gui" != "no"])
  69 if test "$with_cairo" != no && test "$with_gui" != "no"; then
  70   PKG_CHECK_MODULES([GTHREAD], [gthread-2.0], [],
  71     [PSPP_REQUIRED_PREREQ([gthread 2.0 (or use --without-gui)])])
  72
  73   PKG_CHECK_MODULES([GTK], [gtk+-2.0 >= 2.24], [],
  74     [PSPP_REQUIRED_PREREQ([gtk+ 2.0 version 2.24 or later (or use --without-gui)])])
  75
  76   PKG_CHECK_MODULES([GTKSOURCEVIEW], [gtksourceview-2.0 >= 2.2], [],
  77     [PSPP_REQUIRED_PREREQ([gtksourceview 2.0 version 2.2 or later (or use --without-gui)])])
  78
  79   AC_ARG_VAR([GLIB_GENMARSHAL])
  80   AC_CHECK_PROGS([GLIB_GENMARSHAL], [glib-genmarshal])
  81   if test "x$GLIB_GENMARSHAL" = x; then
  82     PSPP_REQUIRED_PREREQ([glib-genmarshal (or use --without-gui)])
  83   fi
  84
  85 fi
  86
  87 gl_NEXT_HEADERS([gtk/gtk.h])
  88
  89 dnl Checks needed for psql reader
  90
  91 dnl The 8.x series postgres tarballs installs with a default prefix of
  92 dnl /usr/local/pgsql whereas, OSes (such as debian)  install into /usr .
  93
  94 dnl If the libpq.so file is in a non standard path, (one which the linker
  95 dnl doesn't search) then we must set the PG_LDFLAGS to -R/usr/wherever/
  96 dnl However, if the system happens to have more than one version of other
  97 dnl dependent libraries (eg. libgtk) in different standard paths. (eg:
  98 dnl /usr and /usr/local) then the wrong one may get linked.
  99
 100 dnl To overcome this, we first check for libpq in the standard places, and
 101 dnl only set PG_LDFLAGS if it's not found.
 102
 103
 104 AC_ARG_WITH(
 105   libpq,
 106   [AS_HELP_STRING([--without-libpq], [don't compile in Postgres capability])])
 107 AC_ARG_VAR([PG_CONFIG],
 108            [Full pathname of the pg_config program shipped with Postgresql])
 109 AC_PATH_PROG([PG_CONFIG], [pg_config], [],
 110              [$PATH:/usr/local/pgsql/bin:/usr/pgsql/bin])
 111
 112 if test x"$with_libpq" != x"no" && test -n "$PG_CONFIG" ; then
 113   AC_SUBST(PG_CONFIG)
 114   PG_CFLAGS=-I`$PG_CONFIG --includedir`
 115   AC_SUBST(PG_CFLAGS)
 116
 117   AC_CHECK_LIB([pq], [PQexec],
 118      [:],
 119      [PG_LDFLAGS="-L`$PG_CONFIG --libdir` -R`$PG_CONFIG --libdir`"])
 120   AC_SUBST(PG_LDFLAGS)
 121
 122   PG_LIBS=-lpq
 123   AC_SUBST(PG_LIBS)
 124
 125   PKG_CHECK_EXISTS(libssl,
 126         AC_DEFINE([USE_SSL],1,
 127                    [Define to 1 if the openssl library is present.])
 128            ,)
 129
 130   # Now verify that we can actually link against libpq.  If we are
 131   # cross-compiling and picked up a host libpq, or if libpq is just
 132   # badly installed, this will fail.
 133   AC_CACHE_CHECK(
 134     [whether -lpq links successfully],
 135     [pspp_cv_have_libpq],
 136     [save_CPPFLAGS=$CPPFLAGS
 137      save_LIBS=$LIBS
 138      save_LDFLAGS=$LDFLAGS
 139      CPPFLAGS="$PG_CFLAGS $CPPFLAGS"
 140      LIBS="$PG_LIBS $LIBS"
 141      LDFLAGS="$PG_LDFLAGS $LDFLAGS"
 142      AC_LINK_IFELSE(
 143        [AC_LANG_PROGRAM(
 144          [#include <libpq-fe.h>
 145          ], [PQfinish (0);])],
 146        [pspp_cv_have_libpq=yes],
 147        [pspp_cv_have_libpq=no])
 148      CPPFLAGS=$save_CPPFLAGS
 149      LIBS=$save_LIBS
 150      LDFLAGS=$save_LDFLAGS])
 151
 152   if test $pspp_cv_have_libpq = yes; then
 153     PSQL_SUPPORT=yes
 154     AC_DEFINE([PSQL_SUPPORT], [1],
 155       [Define to 1 if building in support for reading from postgres
 156        databases.])
 157   else
 158     PSQL_SUPPORT=no
 159     PG_CONFIG=
 160     PG_CFLAGS=
 161     PG_LDFLAGS=
 162     PG_LIBS=
 163   fi
 164 else
 165   PSQL_SUPPORT=no
 166   pspp_cv_have_libpq=no
 167 fi
 168 AC_SUBST([PSQL_SUPPORT])
 169
 170 dnl Check for libxml2
 171 PKG_CHECK_MODULES(
 172   [LIBXML2], [libxml-2.0],
 173   [HAVE_LIBXML2=yes],
 174   [HAVE_LIBXML2=no
 175    PSPP_OPTIONAL_PREREQ([libxml2])])
 176
 177 dnl Check for zlib.
 178 AC_SEARCH_LIBS([gzopen], [z], [], [PSPP_REQUIRED_PREREQ([zlib])])
 179 AC_CHECK_HEADERS([zlib.h], [], [PSPP_REQUIRED_PREREQ([zlib])])
 180
 181 dnl Avoid interference between zlib's crc32() function and gnulib's
 182 dnl crc32() function, which have different signatures.  PSPP calls
 183 dnl only gnulib's crc32() directly, but it calls zlib's crc32()
 184 dnl indirectly through other zlib calls.  If we don't rename gnulib's
 185 dnl crc32(), then zlib will call gnulib's version instead of its own,
 186 dnl causing failures.  (This can happen even if zlib isn't detected
 187 dnl directly, because other libraries that PSPP uses, e.g. libpng,
 188 dnl sometimes use zlib themselves.)
 189 AC_DEFINE(
 190   [crc32], [gl_crc32],
 191   [Avoid making zlib call gnulib's crc32() instead of its own.])
 192
 193 dnl Gnumeric and OpenDocument (read) support requires libxml2 and zlib.
 194 if test $HAVE_LIBXML2 = yes; then
 195   GNM_READ_SUPPORT=yes
 196   ODF_READ_SUPPORT=yes
 197   AC_DEFINE(
 198     [GNM_READ_SUPPORT], [1],
 199     [Define to 1 if building in support for reading Gnumeric files.])
 200   AC_DEFINE(
 201     [ODF_READ_SUPPORT], [1],
 202     [Define to 1 if building in support for reading OpenDocument files.])
 203 else
 204   GNM_READ_SUPPORT=no
 205   ODF_READ_SUPPORT=no
 206 fi
 207 AC_SUBST([GNM_READ_SUPPORT])
 208 AC_SUBST([ODF_READ_SUPPORT])
 209
 210 dnl ODF support requires libxml2 (zlib is optional).
 211 if test $HAVE_LIBXML2 = yes; then
 212   AC_DEFINE(
 213     [ODF_WRITE_SUPPORT], [1],
 214     [Define to 1 if building in support for writing OpenDocument files.])
 215 fi
 216 AM_CONDITIONAL([ODF_WRITE_SUPPORT], [test $HAVE_LIBXML2 = yes])
 217
 218 AC_ARG_WITH(
 219   gui_tools,
 220   [AS_HELP_STRING([--with-gui-tools], [build the gui developer tools.  For DEVELOPERS only! There is no reason why users will need this flag.])])
 221 if test x"$with_gui_tools" = x"yes" ; then
 222         PKG_CHECK_MODULES(GLADE_UI, gladeui-1.0)
 223 fi
 224 AM_CONDITIONAL(WITH_GUI_TOOLS, test x"$with_gui_tools" = x"yes")
 225
 226 AC_ARG_WITH(
 227   [perl-module],
 228   [AS_HELP_STRING([--without-perl-module], [do not build the Perl module])],
 229   [case $with_perl_module in # (
 230      yes|no) ;; # (
 231      *) AC_MSG_FAILURE([--with-perl-module argument must be 'yes' or 'no']) ;;
 232    esac
 233    WITH_PERL_MODULE=$with_perl_module],
 234   [if test x"$cross_compiling" != x"yes"; then
 235      WITH_PERL_MODULE=yes
 236    else
 237      WITH_PERL_MODULE=no
 238    fi])
 239 AC_SUBST([WITH_PERL_MODULE])
 240 AM_CONDITIONAL(WITH_PERL_MODULE, test $WITH_PERL_MODULE = yes)
 241
 242 AC_SEARCH_LIBS([cblas_dsdot], [gslcblas],,[PSPP_REQUIRED_PREREQ([libgslcblas])])
 243 PKG_CHECK_MODULES([GSL], [gsl >= 1.13], [],
 244                          AC_SEARCH_LIBS([gsl_poly_eval_derivs], [gsl],,[PSPP_REQUIRED_PREREQ([gsl version 1.13 or later])]))
 245
 246
 247 PSPP_GSL_NEEDS_FGNU89_INLINE
 248
 249 dnl Recent versions of GNU ncurses install the curses header files into
 250 dnl /usr/include/ncurses, and provide a 'ncurses5-config' program which
 251 dnl enables us to discover where they are. Earlier versions don't have
 252 dnl this, so we can't rely on it.  So if ncurses5-config is present,
 253 dnl we'll trust it to find the right information.  Otherwise, we'll
 254 dnl try to discover it ourselves.
 255 dnl To confound things further, Cygwin has decided to rename ncurses5-config
 256 dnl to ncurses8-config !!!
 257 AC_ARG_WITH(
 258   libncurses,
 259   [AS_HELP_STRING([--without-libncurses], [don't compile in ncurses functions])])
 260
 261 if test x"$with_libncurses" != x"no" ; then
 262   if test x"$cross_compiling" != x"yes" ; then
 263           AC_CHECK_PROGS([NCURSES_CONFIG], [ncurses5-config ncurses8-config])
 264   fi
 265   if test x"$NCURSES_CONFIG" = x ; then
 266           AC_SEARCH_LIBS([tgetent], [ncurses],
 267               [curses_available=yes; AC_CHECK_HEADERS([term.h curses.h],,[curses_available=no])])
 268   else
 269           old_cflags=$CFLAGS
 270           CFLAGS="$CFLAGS `$NCURSES_CONFIG --cflags`"
 271           AC_CHECK_HEADERS([term.h curses.h],[curses_available=yes])
 272           CFLAGS=$old_cflags
 273           if test x"$curses_available" = x"yes" ; then
 274            NCURSES_LIBS=`$NCURSES_CONFIG --libs`
 275            NCURSES_CFLAGS=`$NCURSES_CONFIG --cflags`
 276            AC_SUBST(NCURSES_CFLAGS)
 277            AC_SUBST(NCURSES_LIBS)
 278           fi
 279   fi
 280   if test x"$curses_available" = x"yes" ; then
 281           AC_DEFINE([LIBNCURSES_USABLE], 1,
 282               [Define to 1 if the libncurses is both present and usable.])
 283   fi
 284   AC_CHECK_HEADERS([termcap.h])
 285 fi
 286
 287 PSPP_READLINE
 288
 289 dnl Checks for header files.
 290 AC_CHECK_HEADERS([sys/wait.h fpu_control.h ieeefp.h fenv.h pwd.h])
 291
 292 dnl Some systems dont have SIGWINCH
 293 AC_CHECK_DECLS([SIGWINCH], [], [],
 294           [#include <signal.h>
 295           /* NetBSD declares sys_siglist in unistd.h.  */
 296           #ifdef HAVE_UNISTD_H
 297           # include <unistd.h>
 298           #endif
 299           ])
 300
 301
 302 # For gnulib.
 303 gl_INIT
 304
 305 AC_C_INLINE
 306
 307 AC_C_BIGENDIAN
 308
 309 AC_CHECK_FUNCS([__setfpucw fork execl isinf isnan finite getpid feholdexcept fpsetmask popen round])
 310
 311 AC_PROG_LN_S
 312
 313 AC_ARG_ENABLE(
 314   debug,
 315   [AS_HELP_STRING([--enable-debug],
 316                   [Turn on diagnostic features in the program])])
 317 if test x"$enable_debug" = x"yes"  ; then
 318   AC_DEFINE(DEBUGGING, 1, [Define to 1 if debugging is enabled.])
 319 fi
 320
 321 # iconv is required
 322 AM_ICONV
 323 if test "$am_cv_func_iconv" != "yes"; then
 324    PSPP_REQUIRED_PREREQ([iconv (see http://www.gnu.org/software/libiconv/)])
 325 fi
 326 LIBS="$LIBICONV $LIBS"
 327
 328 dnl Required by the gnulib 'relocatable-prog' module.
 329 dnl See doc/relocatable-maint.texi in the gnulib tree for details.
 330 RELOCATABLE_LIBRARY_PATH='$(pkglibdir)'
 331 RELOCATABLE_STRIP=:
 332
 333 PSPP_CHECK_PREREQS
 334
 335 AC_CONFIG_FILES(
 336   [Makefile gl/Makefile po/Makefile tests/atlocal perl-module/lib/PSPP.pm])
 337
 338 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES])
 339
 340 AC_OUTPUT
 341 echo "PSPP configured successfully."
 342
 343 dnl configure.ac ends here