configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl Initialize.
   4 AC_PREREQ(2.63)
   5 AC_INIT([GNU PSPP], [0.9.0], [bug-gnu-pspp@gnu.org], [pspp])
   6 AC_CONFIG_AUX_DIR([build-aux])
   7 AC_CONFIG_HEADERS([config.h])
   8 AC_CONFIG_TESTDIR([tests])
   9 AM_INIT_AUTOMAKE
  10
  11 dnl Checks for programs.
  12 AC_GNU_SOURCE
  13 AC_PROG_CC
  14 gl_EARLY
  15 AM_PROG_CC_C_O
  16 AC_LIBTOOL_WIN32_DLL
  17 AC_LIBTOOL_DLOPEN
  18 AC_PROG_LIBTOOL
  19 PKG_PROG_PKG_CONFIG
  20 m4_pattern_forbid([PKG_CHECK_MODULES])
  21 PSPP_CHECK_CLICKSEQUENCE
  22
  23 PSPP_ENABLE_WERROR
  24
  25 AM_CONDITIONAL(cc_is_gcc, test x"$GCC" = x"yes" )
  26
  27 PSPP_CC_FOR_BUILD
  28 PSPP_PERL
  29
  30 dnl Disable automatic po/ support, because PSPP provides its own po/ support.
  31 AC_PROVIDE([AM_PO_SUBDIRS])
  32 AM_GNU_GETTEXT([external], [need-ngettext])
  33 LIBS="$LIBINTL $LIBS"
  34
  35 dnl Checks for libraries.
  36 AC_SYS_LARGEFILE
  37 AC_SEARCH_LIBS([sin], [m])
  38 PSPP_LC_PAPER
  39
  40
  41 AC_ARG_VAR([PSPP_LDFLAGS], [linker flags to be used for linking the pspp binary only])
  42 AC_ARG_VAR([PSPPIRE_LDFLAGS], [linker flags to be used for linking the psppire binary only])
  43
  44 # Support for Cairo and Pango.
  45 AC_ARG_WITH([cairo],
  46   [AS_HELP_STRING(
  47     [--without-cairo],
  48     [Don't build support for charts (using Cairo and Pango);
  49      implies --without-gui])],
  50   [], [with_cairo=yes])
  51 AM_CONDITIONAL([HAVE_CAIRO], [test "$with_cairo" != no])
  52 if test "$with_cairo" != no; then
  53   PKG_CHECK_MODULES([CAIRO], [cairo >= 1.5 pango >= 1.22 pangocairo],
  54     [CPPFLAGS="$CPPFLAGS $CAIRO_CFLAGS"
  55      AC_DEFINE([HAVE_CAIRO], 1,
  56        [Define to 1 if Cairo and Pango are available.])],
  57     [PSPP_REQUIRED_PREREQ([cairo 1.5 or later and pango 1.22 or later (or use --without-cairo)])])
  58 fi
  59
  60 dnl Xmllint is used in the rules to build the documentation.  It is not actually necessary,
  61 dnl but is used for post-build consistency checks.  Thus, non-developers can live without it.
  62 dnl However for it to be usefull, it needs to be a certain version and have certain features.
  63 dnl The macros below check that it the xmllint available is up to scratch.  If it isn't
  64 dnl then a dummy /bin/echo is subsituted instead.
  65
  66 AC_CACHE_CHECK([for an xmllint program which fits our needs],[ac_cv_path_XMLLINT],
  67 [AC_PATH_PROGS_FEATURE_CHECK([XMLLINT], [xmllint],
  68   [[$ac_path_XMLLINT --version 2>&1 | $GREP XPath > /dev/null &&
  69     test `$ac_path_XMLLINT --version 2>&1 | $SED 's/^.* \([0-9]*\).*/\1/'` -gt 20900 &&
  70     ac_cv_path_XMLLINT=$ac_path_XMLLINT]],
  71    [AC_MSG_WARN([no appropriate xmllint program found. Using a dummy (echo)]); ac_cv_path_XMLLINT=$ECHO])])
  72
  73 AC_SUBST([XMLLINT],[$ac_cv_path_XMLLINT])
  74
  75 # Support for GUI.
  76 AC_ARG_WITH([gui],
  77   [AS_HELP_STRING([--without-gui],
  78                   [Don't build the PSPPIRE GUI (using GTK+)])],
  79   [], [with_gui=yes])
  80 AM_CONDITIONAL([HAVE_GUI],
  81                [test "$with_cairo" != no && test "$with_gui" != "no"])
  82 if test "$with_cairo" != no && test "$with_gui" != "no"; then
  83   PKG_CHECK_MODULES([GTHREAD], [gthread-2.0], [],
  84     [PSPP_REQUIRED_PREREQ([gthread 2.0 (or use --without-gui)])])
  85
  86   PKG_CHECK_MODULES([GTK], [gtk+-3.0 >= 3.4.2], [],
  87     [PSPP_REQUIRED_PREREQ([gtk+ 3.0 version 3.4.2 or later (or use --without-gui)])])
  88
  89   PKG_CHECK_MODULES([GTKSOURCEVIEW], [gtksourceview-3.0 >= 3.4.2], [],
  90     [PSPP_REQUIRED_PREREQ([gtksourceview 3.0 version 3.4.2 or later (or use --without-gui)])])
  91
  92   PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.32], [],
  93     [PSPP_REQUIRED_PREREQ([glib 2.0 version 2.32 or later (or use --without-gui)])])
  94
  95   AC_ARG_VAR([GLIB_GENMARSHAL])
  96   AC_CHECK_PROGS([GLIB_GENMARSHAL], [glib-genmarshal])
  97   if test "x$GLIB_GENMARSHAL" = x; then
  98     PSPP_REQUIRED_PREREQ([glib-genmarshal (or use --without-gui)])
  99   fi
 100
 101 fi
 102
 103 gl_NEXT_HEADERS([gtk/gtk.h])
 104
 105 dnl Checks needed for psql reader
 106
 107 dnl The 8.x series postgres tarballs installs with a default prefix of
 108 dnl /usr/local/pgsql whereas, OSes (such as debian)  install into /usr .
 109
 110 dnl If the libpq.so file is in a non standard path, (one which the linker
 111 dnl doesn't search) then we must set the PG_LDFLAGS to -R/usr/wherever/
 112 dnl However, if the system happens to have more than one version of other
 113 dnl dependent libraries (eg. libgtk) in different standard paths. (eg:
 114 dnl /usr and /usr/local) then the wrong one may get linked.
 115
 116 dnl To overcome this, we first check for libpq in the standard places, and
 117 dnl only set PG_LDFLAGS if it's not found.
 118
 119
 120 AC_ARG_WITH(
 121   libpq,
 122   [AS_HELP_STRING([--without-libpq], [don't compile in Postgres capability])])
 123 AC_ARG_VAR([PG_CONFIG],
 124            [Full pathname of the pg_config program shipped with Postgresql])
 125 AC_PATH_PROG([PG_CONFIG], [pg_config], [],
 126              [$PATH:/usr/local/pgsql/bin:/usr/pgsql/bin])
 127
 128 if test x"$with_libpq" != x"no" && test -n "$PG_CONFIG" ; then
 129   AC_SUBST(PG_CONFIG)
 130   PG_CFLAGS=-I`$PG_CONFIG --includedir`
 131   AC_SUBST(PG_CFLAGS)
 132
 133   AC_CHECK_LIB([pq], [PQexec],
 134      [:],
 135      [PG_LDFLAGS="-L`$PG_CONFIG --libdir` -R`$PG_CONFIG --libdir`"])
 136   AC_SUBST(PG_LDFLAGS)
 137
 138   PG_LIBS=-lpq
 139   AC_SUBST(PG_LIBS)
 140
 141   PKG_CHECK_EXISTS(libssl,
 142         AC_DEFINE([USE_SSL],1,
 143                    [Define to 1 if the openssl library is present.])
 144            ,)
 145
 146   # Now verify that we can actually link against libpq.  If we are
 147   # cross-compiling and picked up a host libpq, or if libpq is just
 148   # badly installed, this will fail.
 149   AC_CACHE_CHECK(
 150     [whether -lpq links successfully],
 151     [pspp_cv_have_libpq],
 152     [save_CPPFLAGS=$CPPFLAGS
 153      save_LIBS=$LIBS
 154      save_LDFLAGS=$LDFLAGS
 155      CPPFLAGS="$PG_CFLAGS $CPPFLAGS"
 156      LIBS="$PG_LIBS $LIBS"
 157      LDFLAGS="$PG_LDFLAGS $LDFLAGS"
 158      AC_LINK_IFELSE(
 159        [AC_LANG_PROGRAM(
 160          [#include <libpq-fe.h>
 161          ], [PQfinish (0);])],
 162        [pspp_cv_have_libpq=yes],
 163        [pspp_cv_have_libpq=no])
 164      CPPFLAGS=$save_CPPFLAGS
 165      LIBS=$save_LIBS
 166      LDFLAGS=$save_LDFLAGS])
 167
 168   if test $pspp_cv_have_libpq = yes; then
 169     PSQL_SUPPORT=yes
 170     AC_DEFINE([PSQL_SUPPORT], [1],
 171       [Define to 1 if building in support for reading from postgres
 172        databases.])
 173   else
 174     PSQL_SUPPORT=no
 175     PG_CONFIG=
 176     PG_CFLAGS=
 177     PG_LDFLAGS=
 178     PG_LIBS=
 179   fi
 180 else
 181   PSQL_SUPPORT=no
 182   pspp_cv_have_libpq=no
 183 fi
 184 AC_SUBST([PSQL_SUPPORT])
 185
 186 dnl Check for libxml2
 187 PKG_CHECK_MODULES(
 188   [LIBXML2], [libxml-2.0],
 189   [HAVE_LIBXML2=yes],
 190   [HAVE_LIBXML2=no
 191    PSPP_OPTIONAL_PREREQ([libxml2])])
 192
 193 dnl Check for zlib.
 194 AC_SEARCH_LIBS([gzopen], [z], [], [PSPP_REQUIRED_PREREQ([zlib])])
 195 AC_CHECK_HEADERS([zlib.h], [], [PSPP_REQUIRED_PREREQ([zlib])])
 196
 197 dnl Avoid interference between zlib's crc32() function and gnulib's
 198 dnl crc32() function, which have different signatures.  PSPP calls
 199 dnl only gnulib's crc32() directly, but it calls zlib's crc32()
 200 dnl indirectly through other zlib calls.  If we don't rename gnulib's
 201 dnl crc32(), then zlib will call gnulib's version instead of its own,
 202 dnl causing failures.  (This can happen even if zlib isn't detected
 203 dnl directly, because other libraries that PSPP uses, e.g. libpng,
 204 dnl sometimes use zlib themselves.)
 205 AC_DEFINE(
 206   [crc32], [gl_crc32],
 207   [Avoid making zlib call gnulib's crc32() instead of its own.])
 208
 209 dnl Gnumeric and OpenDocument (read) support requires libxml2 and zlib.
 210 if test $HAVE_LIBXML2 = yes; then
 211   GNM_READ_SUPPORT=yes
 212   ODF_READ_SUPPORT=yes
 213   AC_DEFINE(
 214     [GNM_READ_SUPPORT], [1],
 215     [Define to 1 if building in support for reading Gnumeric files.])
 216   AC_DEFINE(
 217     [ODF_READ_SUPPORT], [1],
 218     [Define to 1 if building in support for reading OpenDocument files.])
 219 else
 220   GNM_READ_SUPPORT=no
 221   ODF_READ_SUPPORT=no
 222 fi
 223 AC_SUBST([GNM_READ_SUPPORT])
 224 AC_SUBST([ODF_READ_SUPPORT])
 225
 226 dnl ODF support requires libxml2 (zlib is optional).
 227 if test $HAVE_LIBXML2 = yes; then
 228   AC_DEFINE(
 229     [ODF_WRITE_SUPPORT], [1],
 230     [Define to 1 if building in support for writing OpenDocument files.])
 231 fi
 232 AM_CONDITIONAL([ODF_WRITE_SUPPORT], [test $HAVE_LIBXML2 = yes])
 233
 234 AC_ARG_WITH(
 235   gui_tools,
 236   [AS_HELP_STRING([--with-gui-tools], [build the gui developer tools.  For DEVELOPERS only! There is no reason why users will need this flag.])])
 237 if test x"$with_gui_tools" = x"yes" ; then
 238         PKG_CHECK_MODULES(GLADE_UI, gladeui-2.0)
 239 fi
 240 AM_CONDITIONAL(WITH_GUI_TOOLS, test x"$with_gui_tools" = x"yes")
 241
 242 AC_ARG_WITH(
 243   [perl-module],
 244   [AS_HELP_STRING([--without-perl-module], [do not build the Perl module])],
 245   [case $with_perl_module in # (
 246      yes|no) ;; # (
 247      *) AC_MSG_FAILURE([--with-perl-module argument must be 'yes' or 'no']) ;;
 248    esac
 249    WITH_PERL_MODULE=$with_perl_module],
 250   [if test x"$cross_compiling" != x"yes"; then
 251      WITH_PERL_MODULE=yes
 252    else
 253      WITH_PERL_MODULE=no
 254    fi])
 255 AC_SUBST([WITH_PERL_MODULE])
 256 AM_CONDITIONAL(WITH_PERL_MODULE, test $WITH_PERL_MODULE = yes)
 257
 258 AC_SEARCH_LIBS([cblas_dsdot], [gslcblas],,[PSPP_REQUIRED_PREREQ([libgslcblas])])
 259 PKG_CHECK_MODULES([GSL], [gsl >= 1.13], [],
 260                          AC_SEARCH_LIBS([gsl_poly_eval_derivs], [gsl],,[PSPP_REQUIRED_PREREQ([gsl version 1.13 or later])]))
 261
 262
 263 PSPP_GSL_NEEDS_FGNU89_INLINE
 264
 265 dnl Recent versions of GNU ncurses install the curses header files into
 266 dnl /usr/include/ncurses, and provide a 'ncurses5-config' program which
 267 dnl enables us to discover where they are. Earlier versions don't have
 268 dnl this, so we can't rely on it.  So if ncurses5-config is present,
 269 dnl we'll trust it to find the right information.  Otherwise, we'll
 270 dnl try to discover it ourselves.
 271 dnl To confound things further, Cygwin has decided to rename ncurses5-config
 272 dnl to ncurses8-config !!!
 273 AC_ARG_WITH(
 274   libncurses,
 275   [AS_HELP_STRING([--without-libncurses], [don't compile in ncurses functions])])
 276
 277 if test x"$with_libncurses" != x"no" ; then
 278   if test x"$cross_compiling" != x"yes" ; then
 279           AC_CHECK_PROGS([NCURSES_CONFIG], [ncurses5-config ncurses8-config])
 280   fi
 281   if test x"$NCURSES_CONFIG" = x ; then
 282           AC_SEARCH_LIBS([tgetent], [ncurses],
 283               [curses_available=yes; AC_CHECK_HEADERS([term.h curses.h],,[curses_available=no])])
 284   else
 285           old_cflags=$CFLAGS
 286           CFLAGS="$CFLAGS `$NCURSES_CONFIG --cflags`"
 287           AC_CHECK_HEADERS([term.h curses.h],[curses_available=yes])
 288           CFLAGS=$old_cflags
 289           if test x"$curses_available" = x"yes" ; then
 290            NCURSES_LIBS=`$NCURSES_CONFIG --libs`
 291            NCURSES_CFLAGS=`$NCURSES_CONFIG --cflags`
 292            AC_SUBST(NCURSES_CFLAGS)
 293            AC_SUBST(NCURSES_LIBS)
 294           fi
 295   fi
 296   if test x"$curses_available" = x"yes" ; then
 297           AC_DEFINE([LIBNCURSES_USABLE], 1,
 298               [Define to 1 if the libncurses is both present and usable.])
 299   fi
 300   AC_CHECK_HEADERS([termcap.h])
 301 fi
 302
 303 PSPP_READLINE
 304
 305 dnl Checks for header files.
 306 AC_CHECK_HEADERS([sys/wait.h fpu_control.h ieeefp.h fenv.h pwd.h])
 307
 308 dnl Some systems dont have SIGWINCH
 309 AC_CHECK_DECLS([SIGWINCH], [], [],
 310           [#include <signal.h>
 311           /* NetBSD declares sys_siglist in unistd.h.  */
 312           #ifdef HAVE_UNISTD_H
 313           # include <unistd.h>
 314           #endif
 315           ])
 316
 317
 318 # For gnulib.
 319 gl_INIT
 320
 321 AC_C_INLINE
 322
 323 AC_C_BIGENDIAN
 324
 325 AC_CHECK_FUNCS([__setfpucw fork execl isinf isnan finite getpid feholdexcept fpsetmask popen round])
 326
 327 AC_PROG_LN_S
 328
 329 AC_ARG_ENABLE(
 330   debug,
 331   [AS_HELP_STRING([--enable-debug],
 332                   [Turn on diagnostic features in the program])])
 333 if test x"$enable_debug" = x"yes"  ; then
 334   AC_DEFINE(DEBUGGING, 1, [Define to 1 if debugging is enabled.])
 335 fi
 336
 337 # iconv is required
 338 AM_ICONV
 339 if test "$am_cv_func_iconv" != "yes"; then
 340    PSPP_REQUIRED_PREREQ([iconv (see http://www.gnu.org/software/libiconv/)])
 341 fi
 342 LIBS="$LIBICONV $LIBS"
 343
 344 dnl Required by the gnulib 'relocatable-prog' module.
 345 dnl See doc/relocatable-maint.texi in the gnulib tree for details.
 346 RELOCATABLE_LIBRARY_PATH='$(pkglibdir)'
 347 RELOCATABLE_STRIP=:
 348
 349 PSPP_CHECK_PREREQS
 350
 351 AC_CONFIG_FILES(
 352   [Makefile gl/Makefile po/Makefile tests/atlocal perl-module/lib/PSPP.pm])
 353
 354 AC_CONFIG_COMMANDS([doc/dummy], [:])
 355
 356 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES])
 357
 358 AC_OUTPUT
 359 echo "PSPP configured successfully."
 360
 361 dnl configure.ac ends here