contrib/pulseview_cross.nsi.in

   1 ##
   2 ## This file is part of the PulseView project.
   3 ##
   4 ## Copyright (C) 2013-2014 Uwe Hermann <uwe@hermann-uwe.de>
   5 ##
   6 ## This program is free software; you can redistribute it and/or modify
   7 ## it under the terms of the GNU General Public License as published by
   8 ## the Free Software Foundation; either version 2 of the License, or
   9 ## (at your option) any later version.
  10 ##
  11 ## This program is distributed in the hope that it will be useful,
  12 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 ## GNU General Public License for more details.
  15 ##
  16 ## You should have received a copy of the GNU General Public License
  17 ## along with this program; if not, see <http://www.gnu.org/licenses/>.
  18 ##
  19
  20 #
  21 # This file is used to create the PulseView Windows installer via NSIS.
  22 # It is meant for use in a cross-compile setup (not for native builds).
  23 # See the 'sigrok-cross-mingw' script in the sigrok-util repo for details.
  24 #
  25 # NSIS documentation:
  26 # http://nsis.sourceforge.net/Docs/
  27 # http://nsis.sourceforge.net/Docs/Modern%20UI%202/Readme.html
  28 #
  29
  30 # Include the "Modern UI" header, which gives us the usual Windows look-n-feel.
  31 !include "MUI2.nsh"
  32
  33
  34 # --- Global stuff ------------------------------------------------------------
  35
  36 # Installer/product name.
  37 Name "PulseView"
  38
  39 # Filename of the installer executable.
  40 OutFile "pulseview-@PV_VERSION_STRING@-installer.exe"
  41
  42 # Where to install the application.
  43 InstallDir "$PROGRAMFILES\sigrok\PulseView"
  44
  45 # Request admin privileges for Windows Vista and Windows 7.
  46 # http://nsis.sourceforge.net/Docs/Chapter4.html
  47 RequestExecutionLevel admin
  48
  49 # Local helper definitions.
  50 !define REGSTR "Software\Microsoft\Windows\CurrentVersion\Uninstall\PulseView"
  51
  52
  53 # --- MUI interface configuration ---------------------------------------------
  54
  55 # Use the following icon for the installer EXE file.
  56 !define MUI_ICON "@PROJECT_SOURCE_DIR@/icons/sigrok-logo-notext.ico"
  57
  58 # Show a nice image at the top of each installer page.
  59 !define MUI_HEADERIMAGE
  60
  61 # Don't automatically go to the Finish page so the user can check the log.
  62 !define MUI_FINISHPAGE_NOAUTOCLOSE
  63
  64 # Upon "cancel", ask the user if he really wants to abort the installer.
  65 !define MUI_ABORTWARNING
  66
  67 # Don't force the user to accept the license, just show it.
  68 # Details: http://trac.videolan.org/vlc/ticket/3124
  69 !define MUI_LICENSEPAGE_BUTTON $(^NextBtn)
  70 !define MUI_LICENSEPAGE_TEXT_BOTTOM "Click Next to continue."
  71
  72 # Path where the cross-compiled sigrok tools and libraries are located.
  73 # Change this to where-ever you installed libsigrok.a and so on.
  74 !define CROSS "@CMAKE_INSTALL_PREFIX@"
  75
  76
  77 # --- MUI pages ---------------------------------------------------------------
  78
  79 # Show a nice "Welcome to the ... Setup Wizard" page.
  80 !insertmacro MUI_PAGE_WELCOME
  81
  82 # Show the license of the project.
  83 !insertmacro MUI_PAGE_LICENSE "@PROJECT_SOURCE_DIR@/COPYING"
  84
  85 # Show a screen which allows the user to select which components to install.
  86 !insertmacro MUI_PAGE_COMPONENTS
  87
  88 # Allow the user to select a different install directory.
  89 !insertmacro MUI_PAGE_DIRECTORY
  90
  91 # Perform the actual installation, i.e. install the files.
  92 !insertmacro MUI_PAGE_INSTFILES
  93
  94 # Show a final "We're done, click Finish to close this wizard" message.
  95 !insertmacro MUI_PAGE_FINISH
  96
  97 # Pages used for the uninstaller.
  98 !insertmacro MUI_UNPAGE_WELCOME
  99 !insertmacro MUI_UNPAGE_CONFIRM
 100 !insertmacro MUI_UNPAGE_INSTFILES
 101 !insertmacro MUI_UNPAGE_FINISH
 102
 103
 104 # --- MUI language files ------------------------------------------------------
 105
 106 # Select an installer language (required!).
 107 !insertmacro MUI_LANGUAGE "English"
 108
 109
 110 # --- Default section ---------------------------------------------------------
 111
 112 Section "PulseView (required)" Section1
 113
 114         # This section is gray (can't be disabled) in the component list.
 115         SectionIn RO
 116
 117         # Install the file(s) specified below into the specified directory.
 118         SetOutPath "$INSTDIR"
 119
 120         # License file.
 121         File "@PROJECT_SOURCE_DIR@/COPYING"
 122
 123         # PulseView (statically linked, includes all libs).
 124         File "${CROSS}/bin/pulseview.exe"
 125
 126         # Zadig (used for installing WinUSB drivers).
 127         File "${CROSS}/zadig.exe"
 128         File "${CROSS}/zadig_xp.exe"
 129
 130         # Python
 131         File "${CROSS}/python36.dll"
 132         File "${CROSS}/python36.zip"
 133
 134         SetOutPath "$INSTDIR\share"
 135
 136         # Protocol decoders.
 137         File /r /x "__pycache__" /x "*.pyc" "${CROSS}/share/libsigrokdecode"
 138
 139         # Firmware files.
 140         File /r "${CROSS}/share/sigrok-firmware"
 141
 142         # Example *.sr files.
 143         SetOutPath "$INSTDIR\examples"
 144         File /r "${CROSS}/share/sigrok-dumps/*"
 145
 146         # Generate the uninstaller executable.
 147         WriteUninstaller "$INSTDIR\Uninstall.exe"
 148
 149         # Create a sub-directory in the start menu.
 150         CreateDirectory "$SMPROGRAMS\sigrok"
 151         CreateDirectory "$SMPROGRAMS\sigrok\PulseView"
 152
 153         # Create a shortcut for the PulseView application.
 154         SetOutPath "$INSTDIR"
 155         CreateShortCut "$SMPROGRAMS\sigrok\PulseView\PulseView.lnk" \
 156                 "$INSTDIR\pulseview.exe" "" "$INSTDIR\pulseview.exe" \
 157                 0 SW_SHOWNORMAL \
 158                 "" "Open-source, portable sigrok GUI"
 159
 160         # Create a shortcut for the uninstaller.
 161         CreateShortCut "$SMPROGRAMS\sigrok\PulseView\Uninstall.lnk" \
 162                 "$INSTDIR\Uninstall.exe" "" "$INSTDIR\Uninstall.exe" 0 \
 163                 SW_SHOWNORMAL "" "Uninstall PulseView"
 164
 165         # Create a shortcut for the Zadig executable.
 166         CreateShortCut "$SMPROGRAMS\sigrok\PulseView\Zadig.lnk" \
 167                 "$INSTDIR\zadig.exe" "" "$INSTDIR\zadig.exe" 0 \
 168                 SW_SHOWNORMAL "" "Zadig"
 169
 170         # Create a shortcut for the Zadig executable (for Win XP).
 171         CreateShortCut "$SMPROGRAMS\sigrok\PulseView\Zadig (Win XP).lnk" \
 172                 "$INSTDIR\zadig_xp.exe" "" "$INSTDIR\zadig_xp.exe" 0 \
 173                 SW_SHOWNORMAL "" "Zadig (Win XP)"
 174
 175         # Create registry keys for "Add/remove programs" in the control panel.
 176         WriteRegStr HKLM "${REGSTR}" "DisplayName" "PulseView"
 177         WriteRegStr HKLM "${REGSTR}" "UninstallString" \
 178                 "$\"$INSTDIR\Uninstall.exe$\""
 179         WriteRegStr HKLM "${REGSTR}" "InstallLocation" "$\"$INSTDIR$\""
 180         WriteRegStr HKLM "${REGSTR}" "DisplayIcon" \
 181                 "$\"$INSTDIR\sigrok-logo-notext.ico$\""
 182         WriteRegStr HKLM "${REGSTR}" "Publisher" "sigrok"
 183         WriteRegStr HKLM "${REGSTR}" "HelpLink" \
 184                 "http://sigrok.org/wiki/PulseView"
 185         WriteRegStr HKLM "${REGSTR}" "URLUpdateInfo" \
 186                 "http://sigrok.org/wiki/Downloads"
 187         WriteRegStr HKLM "${REGSTR}" "URLInfoAbout" "http://sigrok.org"
 188         WriteRegStr HKLM "${REGSTR}" "DisplayVersion" "@PV_VERSION_STRING@"
 189         WriteRegStr HKLM "${REGSTR}" "Contact" \
 190                 "sigrok-devel@lists.sourceforge.org"
 191         WriteRegStr HKLM "${REGSTR}" "Comments" \
 192                 "This is a Qt based sigrok GUI."
 193
 194         # Display "Remove" instead of "Modify/Remove" in the control panel.
 195         WriteRegDWORD HKLM "${REGSTR}" "NoModify" 1
 196         WriteRegDWORD HKLM "${REGSTR}" "NoRepair" 1
 197
 198 SectionEnd
 199
 200
 201 # --- Uninstaller section -----------------------------------------------------
 202
 203 Section "Uninstall"
 204
 205         # Always delete the uninstaller first (yes, this really works).
 206         Delete "$INSTDIR\Uninstall.exe"
 207
 208         # Delete the application, the application data, and related libs.
 209         Delete "$INSTDIR\COPYING"
 210         Delete "$INSTDIR\pulseview.exe"
 211         Delete "$INSTDIR\zadig.exe"
 212         Delete "$INSTDIR\zadig_xp.exe"
 213         Delete "$INSTDIR\python36.dll"
 214         Delete "$INSTDIR\python36.zip"
 215
 216         # Delete all decoders and everything else in libsigrokdecode/.
 217         # There could be *.pyc files or __pycache__ subdirs and so on.
 218         RMDir /r "$INSTDIR\share\libsigrokdecode"
 219
 220         # Delete the firmware files.
 221         RMDir /r "$INSTDIR\share\sigrok-firmware"
 222
 223         # Delete the example *.sr files.
 224         RMDir /r "$INSTDIR\examples\*"
 225
 226         # Delete the install directory and its sub-directories.
 227         RMDir "$INSTDIR\share"
 228         RMDir "$INSTDIR\examples"
 229         RMDir "$INSTDIR"
 230
 231         # Delete the links from the start menu.
 232         Delete "$SMPROGRAMS\sigrok\PulseView\PulseView.lnk"
 233         Delete "$SMPROGRAMS\sigrok\PulseView\Uninstall.lnk"
 234         Delete "$SMPROGRAMS\sigrok\PulseView\Zadig.lnk"
 235         Delete "$SMPROGRAMS\sigrok\PulseView\Zadig (Win XP).lnk"
 236
 237         # Delete the sub-directory in the start menu.
 238         RMDir "$SMPROGRAMS\sigrok\PulseView"
 239         RMDir "$SMPROGRAMS\sigrok"
 240
 241         # Delete the registry key(s).
 242         DeleteRegKey HKLM "${REGSTR}"
 243
 244 SectionEnd
 245
 246
 247 # --- Component selection section descriptions --------------------------------
 248
 249 LangString DESC_Section1 ${LANG_ENGLISH} "This installs the PulseView sigrok GUI, some firmware files, the protocol decoders, some example files, and all required libraries."
 250
 251 !insertmacro MUI_FUNCTION_DESCRIPTION_BEGIN
 252 !insertmacro MUI_DESCRIPTION_TEXT ${Section1} $(DESC_Section1)
 253 !insertmacro MUI_FUNCTION_DESCRIPTION_END
 254