windows/putty.iss

   1 ; -*- no -*-
   2 ; $Id: putty.iss 7488 2007-04-29 11:28:54Z simon $
   3 ;
   4 ; -- Inno Setup installer script for PuTTY and its related tools.
   5 ;    Last tested with Inno Setup 5.0.8.
   6 ;
   7 ; TODO for future releases:
   8 ;
   9 ;  - It might be nice to have an option to add PSCP, Plink and PSFTP to
  10 ;    the PATH. See wish `installer-addpath'.
  11 ;
  12 ;  - Maybe a "custom" installation might be useful? Hassle with
  13 ;    UninstallDisplayIcon, though.
  14
  15 [Setup]
  16 AppName=PuTTY
  17 AppVerName=PuTTY version 0.60
  18 VersionInfoTextVersion=Release 0.60
  19 AppVersion=0.60
  20 VersionInfoVersion=0.60.0.0
  21 AppPublisher=Simon Tatham
  22 AppPublisherURL=http://www.chiark.greenend.org.uk/~sgtatham/putty/
  23 AppReadmeFile={app}\README.txt
  24 DefaultDirName={pf}\PuTTY
  25 DefaultGroupName=PuTTY
  26 SetupIconFile=puttyins.ico
  27 UninstallDisplayIcon={app}\putty.exe
  28 ChangesAssociations=yes
  29 ;ChangesEnvironment=yes -- when PATH munging is sorted (probably)
  30 Compression=zip/9
  31 AllowNoIcons=yes
  32
  33 [Files]
  34 ; We flag all files with "restartreplace" et al primarily for the benefit
  35 ; of unattended un/installations/upgrades, when the user is running one
  36 ; of the apps at a time. Without it, the operation will fail noisily in
  37 ; this situation.
  38 ; This does mean that the user will be prompted to restart their machine
  39 ; if any of the files _were_ open during installation (or, if /VERYSILENT
  40 ; is used, the machine will be restarted automatically!). The /NORESTART
  41 ; flag avoids this.
  42 ; It might be nicer to have a "no worries, replace the file next time you
  43 ; reboot" option, but the developers have no interest in adding one.
  44 ; NB: apparently, using long (non-8.3) filenames with restartreplace is a
  45 ; bad idea. (Not that we do.)
  46 Source: "putty.exe"; DestDir: "{app}"; Flags: promptifolder replacesameversion restartreplace uninsrestartdelete
  47 Source: "pageant.exe"; DestDir: "{app}"; Flags: promptifolder replacesameversion restartreplace uninsrestartdelete
  48 Source: "puttygen.exe"; DestDir: "{app}"; Flags: promptifolder replacesameversion restartreplace uninsrestartdelete
  49 Source: "pscp.exe"; DestDir: "{app}"; Flags: promptifolder replacesameversion restartreplace uninsrestartdelete
  50 Source: "psftp.exe"; DestDir: "{app}"; Flags: promptifolder replacesameversion restartreplace uninsrestartdelete
  51 Source: "plink.exe"; DestDir: "{app}"; Flags: promptifolder replacesameversion restartreplace uninsrestartdelete
  52 Source: "website.url"; DestDir: "{app}"; Flags: restartreplace uninsrestartdelete
  53 Source: "..\doc\putty.chm"; DestDir: "{app}"; Flags: restartreplace uninsrestartdelete
  54 Source: "..\doc\putty.hlp"; DestDir: "{app}"; Flags: restartreplace uninsrestartdelete
  55 Source: "..\doc\putty.cnt"; DestDir: "{app}"; Flags: restartreplace uninsrestartdelete
  56 Source: "..\LICENCE"; DestDir: "{app}"; Flags: restartreplace uninsrestartdelete
  57 Source: "README.txt"; DestDir: "{app}"; Flags: isreadme restartreplace uninsrestartdelete
  58
  59 [Icons]
  60 Name: "{group}\PuTTY"; Filename: "{app}\putty.exe"
  61 ; We have to fall back from the .chm to the older .hlp file on some Windows
  62 ; versions.
  63 Name: "{group}\PuTTY Manual"; Filename: "{app}\putty.chm"; MinVersion: 4.1,5.0
  64 Name: "{group}\PuTTY Manual"; Filename: "{app}\putty.hlp"; OnlyBelowVersion: 4.1,5.0
  65 Name: "{group}\PuTTY Web Site"; Filename: "{app}\website.url"
  66 Name: "{group}\PSFTP"; Filename: "{app}\psftp.exe"
  67 Name: "{group}\PuTTYgen"; Filename: "{app}\puttygen.exe"
  68 Name: "{group}\Pageant"; Filename: "{app}\pageant.exe"
  69 Name: "{commondesktop}\PuTTY"; Filename: "{app}\putty.exe"; Tasks: desktopicon\common
  70 Name: "{userdesktop}\PuTTY"; Filename: "{app}\putty.exe"; Tasks: desktopicon\user
  71 ; Putting this in {commonappdata} doesn't seem to work, on 98SE at least.
  72 Name: "{userappdata}\Microsoft\Internet Explorer\Quick Launch\PuTTY"; Filename: "{app}\putty.exe"; Tasks: quicklaunchicon
  73
  74 [Tasks]
  75 Name: desktopicon; Description: "Create a &desktop icon for PuTTY"; GroupDescription: "Additional icons:"; Flags: unchecked
  76 Name: desktopicon\common; Description: "For all users"; GroupDescription: "Additional icons:"; Flags: exclusive unchecked
  77 Name: desktopicon\user; Description: "For the current user only"; GroupDescription: "Additional icons:"; Flags: exclusive unchecked
  78 Name: quicklaunchicon; Description: "Create a &Quick Launch icon for PuTTY (current user only)"; GroupDescription: "Additional icons:"; Flags: unchecked
  79 Name: associate; Description: "&Associate .PPK files (PuTTY Private Key) with Pageant and PuTTYgen"; GroupDescription: "Other tasks:"
  80
  81 [Registry]
  82 Root: HKCR; Subkey: ".ppk"; ValueType: string; ValueName: ""; ValueData: "PuTTYPrivateKey"; Flags: uninsdeletevalue; Tasks: associate
  83 Root: HKCR; Subkey: "PuTTYPrivateKey"; ValueType: string; ValueName: ""; ValueData: "PuTTY Private Key File"; Flags: uninsdeletekey; Tasks: associate
  84 Root: HKCR; Subkey: "PuTTYPrivateKey\DefaultIcon"; ValueType: string; ValueName: ""; ValueData: "{app}\pageant.exe,0"; Tasks: associate
  85 Root: HKCR; Subkey: "PuTTYPrivateKey\shell\open\command"; ValueType: string; ValueName: ""; ValueData: """{app}\pageant.exe"" ""%1"""; Tasks: associate
  86 Root: HKCR; Subkey: "PuTTYPrivateKey\shell\edit"; ValueType: string; ValueName: ""; ValueData: "&Edit"; Tasks: associate
  87 Root: HKCR; Subkey: "PuTTYPrivateKey\shell\edit\command"; ValueType: string; ValueName: ""; ValueData: """{app}\puttygen.exe"" ""%1"""; Tasks: associate
  88 ; Add to PATH on NT-class OS?
  89
  90 [UninstallRun]
  91 ; -cleanup-during-uninstall is an undocumented option that tailors the
  92 ; message displayed.
  93 ; XXX: it would be nice if this task weren't run if a silent uninstall is
  94 ;      requested, but "skipifsilent" is disallowed.
  95 Filename: "{app}\putty.exe"; Parameters: "-cleanup-during-uninstall"; RunOnceId: "PuTTYCleanup"; StatusMsg: "Cleaning up saved sessions etc (optional)..."
  96
  97 [Messages]
  98 ; Since it's possible for the user to be asked to restart their computer,
  99 ; we should override the default messages to explain exactly why, so they
 100 ; can make an informed decision. (Especially as 95% of users won't need or
 101 ; want to restart; see rant above.)
 102 FinishedRestartLabel=One or more [name] programs are still running. Setup will not replace these program files until you restart your computer. Would you like to restart now?
 103 ; This message is popped up in a message box on a /SILENT install.
 104 FinishedRestartMessage=One or more [name] programs are still running.%nSetup will not replace these program files until you restart your computer.%n%nWould you like to restart now?
 105 ; ...and this comes up if you try to uninstall.
 106 UninstalledAndNeedsRestart=One or more %1 programs are still running.%nThe program files will not be removed until your computer is restarted.%n%nWould you like to restart now?