arch/x86/kernel/vmlinux_32.lds.S

   1 /* ld script to make i386 Linux kernel
   2  * Written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>;
   3  *
   4  * Don't define absolute symbols until and unless you know that symbol
   5  * value is should remain constant even if kernel image is relocated
   6  * at run time. Absolute symbols are not relocated. If symbol value should
   7  * change if kernel is relocated, make the symbol section relative and
   8  * put it inside the section definition.
   9  */
  10
  11 #define LOAD_OFFSET __PAGE_OFFSET
  12
  13 #include <asm-generic/vmlinux.lds.h>
  14 #include <asm/thread_info.h>
  15 #include <asm/page.h>
  16 #include <asm/cache.h>
  17 #include <asm/boot.h>
  18
  19 OUTPUT_FORMAT("elf32-i386", "elf32-i386", "elf32-i386")
  20 OUTPUT_ARCH(i386)
  21 ENTRY(phys_startup_32)
  22 jiffies = jiffies_64;
  23
  24 PHDRS {
  25         text PT_LOAD FLAGS(5);  /* R_E */
  26         data PT_LOAD FLAGS(7);  /* RWE */
  27         note PT_NOTE FLAGS(0);  /* ___ */
  28 }
  29 SECTIONS
  30 {
  31   . = LOAD_OFFSET + LOAD_PHYSICAL_ADDR;
  32   phys_startup_32 = startup_32 - LOAD_OFFSET;
  33
  34   .text.head : AT(ADDR(.text.head) - LOAD_OFFSET) {
  35         _text = .;                      /* Text and read-only data */
  36         *(.text.head)
  37   } :text = 0x9090
  38
  39   /* read-only */
  40   .text : AT(ADDR(.text) - LOAD_OFFSET) {
  41         . = ALIGN(PAGE_SIZE); /* not really needed, already page aligned */
  42         *(.text.page_aligned)
  43         TEXT_TEXT
  44         SCHED_TEXT
  45         LOCK_TEXT
  46         KPROBES_TEXT
  47         *(.fixup)
  48         *(.gnu.warning)
  49         _etext = .;                     /* End of text section */
  50   } :text = 0x9090
  51
  52   . = ALIGN(16);                /* Exception table */
  53   __ex_table : AT(ADDR(__ex_table) - LOAD_OFFSET) {
  54         __start___ex_table = .;
  55          *(__ex_table)
  56         __stop___ex_table = .;
  57   }
  58
  59   NOTES :text :note
  60
  61   BUG_TABLE :text
  62
  63   . = ALIGN(4);
  64   .tracedata : AT(ADDR(.tracedata) - LOAD_OFFSET) {
  65         __tracedata_start = .;
  66         *(.tracedata)
  67         __tracedata_end = .;
  68   }
  69
  70   RODATA
  71
  72   /* writeable */
  73   . = ALIGN(PAGE_SIZE);
  74   .data : AT(ADDR(.data) - LOAD_OFFSET) {       /* Data */
  75         DATA_DATA
  76         CONSTRUCTORS
  77         } :data
  78
  79   . = ALIGN(PAGE_SIZE);
  80   .data_nosave : AT(ADDR(.data_nosave) - LOAD_OFFSET) {
  81         __nosave_begin = .;
  82         *(.data.nosave)
  83         . = ALIGN(PAGE_SIZE);
  84         __nosave_end = .;
  85   }
  86
  87   . = ALIGN(PAGE_SIZE);
  88   .data.page_aligned : AT(ADDR(.data.page_aligned) - LOAD_OFFSET) {
  89         *(.data.page_aligned)
  90         *(.data.idt)
  91   }
  92
  93   . = ALIGN(32);
  94   .data.cacheline_aligned : AT(ADDR(.data.cacheline_aligned) - LOAD_OFFSET) {
  95         *(.data.cacheline_aligned)
  96   }
  97
  98   /* rarely changed data like cpu maps */
  99   . = ALIGN(32);
 100   .data.read_mostly : AT(ADDR(.data.read_mostly) - LOAD_OFFSET) {
 101         *(.data.read_mostly)
 102         _edata = .;             /* End of data section */
 103   }
 104
 105   . = ALIGN(THREAD_SIZE);       /* init_task */
 106   .data.init_task : AT(ADDR(.data.init_task) - LOAD_OFFSET) {
 107         *(.data.init_task)
 108   }
 109
 110   /* might get freed after init */
 111   . = ALIGN(PAGE_SIZE);
 112   .smp_locks : AT(ADDR(.smp_locks) - LOAD_OFFSET) {
 113         __smp_locks = .;
 114         *(.smp_locks)
 115         __smp_locks_end = .;
 116   }
 117   /* will be freed after init
 118    * Following ALIGN() is required to make sure no other data falls on the
 119    * same page where __smp_alt_end is pointing as that page might be freed
 120    * after boot. Always make sure that ALIGN() directive is present after
 121    * the section which contains __smp_alt_end.
 122    */
 123   . = ALIGN(PAGE_SIZE);
 124
 125   /* will be freed after init */
 126   . = ALIGN(PAGE_SIZE);         /* Init code and data */
 127   .init.text : AT(ADDR(.init.text) - LOAD_OFFSET) {
 128         __init_begin = .;
 129         _sinittext = .;
 130         INIT_TEXT
 131         _einittext = .;
 132   }
 133   .init.data : AT(ADDR(.init.data) - LOAD_OFFSET) {
 134         INIT_DATA
 135   }
 136   . = ALIGN(16);
 137   .init.setup : AT(ADDR(.init.setup) - LOAD_OFFSET) {
 138         __setup_start = .;
 139         *(.init.setup)
 140         __setup_end = .;
 141    }
 142   .initcall.init : AT(ADDR(.initcall.init) - LOAD_OFFSET) {
 143         __initcall_start = .;
 144         INITCALLS
 145         __initcall_end = .;
 146   }
 147   .con_initcall.init : AT(ADDR(.con_initcall.init) - LOAD_OFFSET) {
 148         __con_initcall_start = .;
 149         *(.con_initcall.init)
 150         __con_initcall_end = .;
 151   }
 152   SECURITY_INIT
 153   . = ALIGN(4);
 154   .altinstructions : AT(ADDR(.altinstructions) - LOAD_OFFSET) {
 155         __alt_instructions = .;
 156         *(.altinstructions)
 157         __alt_instructions_end = .;
 158   }
 159   .altinstr_replacement : AT(ADDR(.altinstr_replacement) - LOAD_OFFSET) {
 160         *(.altinstr_replacement)
 161   }
 162   . = ALIGN(4);
 163   .parainstructions : AT(ADDR(.parainstructions) - LOAD_OFFSET) {
 164         __parainstructions = .;
 165         *(.parainstructions)
 166         __parainstructions_end = .;
 167   }
 168   /* .exit.text is discard at runtime, not link time, to deal with references
 169      from .altinstructions and .eh_frame */
 170   .exit.text : AT(ADDR(.exit.text) - LOAD_OFFSET) {
 171         EXIT_TEXT
 172   }
 173   .exit.data : AT(ADDR(.exit.data) - LOAD_OFFSET) {
 174         EXIT_DATA
 175   }
 176 #if defined(CONFIG_BLK_DEV_INITRD)
 177   . = ALIGN(PAGE_SIZE);
 178   .init.ramfs : AT(ADDR(.init.ramfs) - LOAD_OFFSET) {
 179         __initramfs_start = .;
 180         *(.init.ramfs)
 181         __initramfs_end = .;
 182   }
 183 #endif
 184   . = ALIGN(PAGE_SIZE);
 185   .data.percpu  : AT(ADDR(.data.percpu) - LOAD_OFFSET) {
 186         __per_cpu_start = .;
 187         *(.data.percpu)
 188         *(.data.percpu.shared_aligned)
 189         __per_cpu_end = .;
 190   }
 191   . = ALIGN(PAGE_SIZE);
 192   /* freed after init ends here */
 193
 194   .bss : AT(ADDR(.bss) - LOAD_OFFSET) {
 195         __init_end = .;
 196         __bss_start = .;                /* BSS */
 197         *(.bss.page_aligned)
 198         *(.bss)
 199         . = ALIGN(4);
 200         __bss_stop = .;
 201         _end = . ;
 202         /* This is where the kernel creates the early boot page tables */
 203         . = ALIGN(PAGE_SIZE);
 204         pg0 = . ;
 205   }
 206
 207   /* Sections to be discarded */
 208   /DISCARD/ : {
 209         *(.exitcall.exit)
 210         }
 211
 212   STABS_DEBUG
 213
 214   DWARF_DEBUG
 215 }