arch/parisc/hpux/gate.S

   1 /*
   2  *
   3  * Linux/PARISC Project (http://www.parisc-linux.org/)
   4  *
   5  * System call entry code Copyright (c) Matthew Wilcox 1999 <willy@bofh.ai>
   6  * Licensed under the GNU GPL.
   7  * thanks to Philipp Rumpf, Mike Shaver and various others
   8  * sorry about the wall, puffin..
   9  */
  10
  11 #include <asm/assembly.h>
  12 #include <asm/asm-offsets.h>
  13 #include <asm/unistd.h>
  14 #include <asm/errno.h>
  15 #include <linux/linkage.h>
  16 #include <linux/init.h>
  17
  18         .level  LEVEL
  19         __HEAD
  20
  21         .import hpux_call_table
  22         .import hpux_syscall_exit,code
  23
  24         .align  PAGE_SIZE
  25 ENTRY(hpux_gateway_page)
  26         nop
  27 #ifdef CONFIG_64BIT
  28 #warning NEEDS WORK for 64-bit
  29 #endif
  30         ldw     -64(%r30), %r29                 ;! 8th argument
  31         ldw     -60(%r30), %r19                 ;! 7th argument
  32         ldw     -56(%r30), %r20                 ;! 6th argument
  33         ldw     -52(%r30), %r21                 ;! 5th argument
  34         gate    .+8, %r0                        /* become privileged */
  35         mtsp    %r0,%sr4                        /* get kernel space into sr4 */
  36         mtsp    %r0,%sr5                        /* get kernel space into sr5 */
  37         mtsp    %r0,%sr6                        /* get kernel space into sr6 */
  38         mfsp    %sr7,%r1                        /* save user sr7 */
  39         mtsp    %r1,%sr3                        /* and store it in sr3 */
  40
  41         mtctl   %r30,%cr28
  42         mfctl   %cr30,%r1
  43         xor     %r1,%r30,%r30                   /* ye olde xor trick */
  44         xor     %r1,%r30,%r1
  45         xor     %r1,%r30,%r30
  46         ldo     TASK_SZ_ALGN+FRAME_SIZE(%r30),%r30  /* set up kernel stack */
  47
  48         /* N.B.: It is critical that we don't set sr7 to 0 until r30
  49          *       contains a valid kernel stack pointer. It is also
  50          *       critical that we don't start using the kernel stack
  51          *       until after sr7 has been set to 0.
  52          */
  53
  54         mtsp    %r0,%sr7                        /* get kernel space into sr7 */
  55         STREG   %r1,TASK_PT_GR30-TASK_SZ_ALGN-FRAME_SIZE(%r30) /* save usp */
  56         ldo     -TASK_SZ_ALGN-FRAME_SIZE(%r30),%r1   /* get task ptr in %r1 */
  57
  58         /* Save some registers for sigcontext and potential task
  59            switch (see entry.S for the details of which ones are
  60            saved/restored).  TASK_PT_PSW is zeroed so we can see whether
  61            a process is on a syscall or not.  For an interrupt the real
  62            PSW value is stored.  This is needed for gdb and sys_ptrace. */
  63         STREG   %r0,  TASK_PT_PSW(%r1)
  64         STREG   %r2,  TASK_PT_GR2(%r1)          /* preserve rp */
  65         STREG   %r19, TASK_PT_GR19(%r1)         /* 7th argument */
  66         STREG   %r20, TASK_PT_GR20(%r1)         /* 6th argument */
  67         STREG   %r21, TASK_PT_GR21(%r1)         /* 5th argument */
  68         STREG   %r22, TASK_PT_GR22(%r1)         /* syscall # */
  69         STREG   %r23, TASK_PT_GR23(%r1)         /* 4th argument */
  70         STREG   %r24, TASK_PT_GR24(%r1)         /* 3rd argument */
  71         STREG   %r25, TASK_PT_GR25(%r1)         /* 2nd argument */
  72         STREG   %r26, TASK_PT_GR26(%r1)         /* 1st argument */
  73         STREG   %r27, TASK_PT_GR27(%r1)         /* user dp */
  74         STREG   %r28, TASK_PT_GR28(%r1)         /* return value 0 */
  75         STREG   %r28, TASK_PT_ORIG_R28(%r1)     /* return value 0 (saved for signals) */
  76         STREG   %r29, TASK_PT_GR29(%r1)         /* 8th argument */
  77         STREG   %r31, TASK_PT_GR31(%r1)         /* preserve syscall return ptr */
  78
  79         ldo     TASK_PT_FR0(%r1), %r27          /* save fpregs from the kernel */
  80         save_fp %r27                            /* or potential task switch  */
  81
  82         mfctl   %cr11, %r27                     /* i.e. SAR */
  83         STREG   %r27, TASK_PT_SAR(%r1)
  84
  85         loadgp
  86
  87         stw     %r21, -52(%r30)                 ;! 5th argument
  88         stw     %r20, -56(%r30)                 ;! 6th argument
  89         stw     %r19, -60(%r30)                 ;! 7th argument
  90         stw     %r29, -64(%r30)                 ;! 8th argument
  91
  92         ldil    L%hpux_call_table, %r21
  93         ldo     R%hpux_call_table(%r21), %r21
  94         comiclr,>>=     __NR_HPUX_syscalls, %r22, %r0
  95         b,n     syscall_nosys
  96         LDREGX  %r22(%r21), %r21
  97         ldil    L%hpux_syscall_exit,%r2
  98         be      0(%sr7,%r21)
  99         ldo     R%hpux_syscall_exit(%r2),%r2
 100
 101 syscall_nosys:
 102         ldil    L%hpux_syscall_exit,%r1
 103         be      R%hpux_syscall_exit(%sr7,%r1)
 104         ldo     -ENOSYS(%r0),%r28
 105 ENDPROC(hpux_gateway_page)
 106
 107         .align  PAGE_SIZE
 108 ENTRY(end_hpux_gateway_page)