macxconf.pri

   1 # The first path is used when the source is being build by packagers (pbuilder/sbuild/etc)
   2 # The second path is used when you manually run the configure script in the root folder (eg when using qt creator)
   3 exists($$OUT_PWD/../conf.pri) {
   4     include($$OUT_PWD/../conf.pri)
   5 }
   6 else {
   7     include(conf.pri)
   8 }
   9
  10 QMAKE_MACOSX_DEPLOYMENT_TARGET = 10.14
  11
  12 LIBS += -framework Carbon -framework IOKit -framework AppKit
  13
  14 QT_LANG_PATH = ../dist/qt-translations
  15 DIST_PATH = ../dist/mac
  16
  17 document_icon.path = Contents/Resources
  18 document_icon.files = $$DIST_PATH/qBitTorrentDocument.icns
  19 QMAKE_BUNDLE_DATA += document_icon
  20
  21 qt_conf.path = Contents/Resources
  22 qt_conf.files = $$DIST_PATH/qt.conf
  23 QMAKE_BUNDLE_DATA += qt_conf
  24
  25 qt_translations.path = Contents/translations
  26 qt_translations.files = $$files($$QT_LANG_PATH/qtbase_*.qm)
  27 qt_translations.files += \
  28     $$QT_LANG_PATH/qt_fa.qm \
  29     $$QT_LANG_PATH/qt_gl.qm \
  30     $$QT_LANG_PATH/qt_lt.qm \
  31     $$QT_LANG_PATH/qt_pt.qm \
  32     $$QT_LANG_PATH/qt_sl.qm \
  33     $$QT_LANG_PATH/qt_sv.qm \
  34     $$QT_LANG_PATH/qt_zh_CN.qm
  35 QMAKE_BUNDLE_DATA += qt_translations
  36
  37 ICON = $$DIST_PATH/qbittorrent_mac.icns
  38 QMAKE_INFO_PLIST = $$DIST_PATH/Info.plist