src/src.pro

   1 # Global
   2 TEMPLATE = app
   3 CONFIG += qt thread silent
   4
   5 # Platform specific configuration
   6 win32: include(../winconf.pri)
   7 macx: include(../macxconf.pri)
   8 unix:!macx: include(../unixconf.pri)
   9
  10 QT += network sql xml
  11
  12 macx|*-clang*: QMAKE_CXXFLAGS_WARN_ON += -Wno-range-loop-analysis
  13
  14 nogui {
  15     TARGET = qbittorrent-nox
  16     QT -= gui
  17     DEFINES += DISABLE_GUI
  18 } else {
  19     TARGET = qbittorrent
  20     QT += xml svg widgets
  21
  22     CONFIG(static) {
  23         DEFINES += QBT_STATIC_QT
  24         QTPLUGIN += qico
  25     }
  26     win32 {
  27         QT += winextras
  28     }
  29     macx {
  30         LIBS += -lobjc
  31     }
  32 }
  33
  34 nowebui {
  35     DEFINES += DISABLE_WEBUI
  36 }
  37
  38 stacktrace {
  39     DEFINES += STACKTRACE
  40     win32 {
  41         DEFINES += STACKTRACE_WIN_PROJECT_PATH=$$PWD
  42         DEFINES += STACKTRACE_WIN_MAKEFILE_PATH=$$OUT_PWD
  43     }
  44 }
  45
  46 CONFIG(debug, debug|release): message(Project is built in DEBUG mode.)
  47 CONFIG(release, debug|release): message(Project is built in RELEASE mode.)
  48
  49 # Disable debug output in release mode
  50 CONFIG(release, debug|release) {
  51     message(Disabling debug output.)
  52     DEFINES += QT_NO_DEBUG_OUTPUT
  53 }
  54
  55 # VERSION DEFINES
  56 include(../version.pri)
  57
  58 # Qt defines
  59 DEFINES += QT_DISABLE_DEPRECATED_BEFORE=0x050e00
  60 DEFINES += QT_NO_CAST_TO_ASCII
  61 DEFINES += QT_NO_CAST_FROM_BYTEARRAY
  62 DEFINES += QT_USE_QSTRINGBUILDER
  63 DEFINES += QT_STRICT_ITERATORS
  64
  65 INCLUDEPATH += $$PWD
  66
  67 include(app/app.pri)
  68 include(base/base.pri)
  69 !nogui: include(gui/gui.pri)
  70 !nowebui: include(webui/webui.pri)
  71
  72 isEmpty(QMAKE_LRELEASE) {
  73     win32: QMAKE_LRELEASE = $$[QT_HOST_BINS]/lrelease.exe
  74     else: QMAKE_LRELEASE = $$[QT_HOST_BINS]/lrelease
  75     unix {
  76         equals(QT_MAJOR_VERSION, 5) {
  77             !exists($$QMAKE_LRELEASE): QMAKE_LRELEASE = lrelease-qt5
  78         }
  79     }
  80     else {
  81         !exists($$QMAKE_LRELEASE): QMAKE_LRELEASE = lrelease
  82     }
  83 }
  84 lrelease.input = TS_SOURCES
  85 lrelease.output = ${QMAKE_FILE_PATH}/${QMAKE_FILE_BASE}.qm
  86 lrelease.commands = @echo "lrelease ${QMAKE_FILE_NAME}" && $$QMAKE_LRELEASE -silent ${QMAKE_FILE_NAME} -qm ${QMAKE_FILE_OUT}
  87 lrelease.CONFIG += no_link target_predeps
  88 QMAKE_EXTRA_COMPILERS += lrelease
  89
  90 TRANSLATIONS = $$files($$PWD/lang/qbittorrent_*.ts)
  91 TS_SOURCES += $$TRANSLATIONS
  92
  93 # Resource files
  94 QMAKE_RESOURCE_FLAGS += -compress 9 -threshold 5
  95 RESOURCES += \
  96     icons/icons.qrc \
  97     lang/lang.qrc \
  98     searchengine/searchengine.qrc
  99
 100 DESTDIR = .