macxconf.pri

   1 # The first path is used when the source is being build by packagers (pbuilder/sbuild/etc)
   2 # The second path is used when you manually run the configure script in the root folder (eg when using qt creator)
   3 exists($$OUT_PWD/../conf.pri) {
   4     include($$OUT_PWD/../conf.pri)
   5 }
   6 else {
   7     include(conf.pri)
   8 }
   9
  10 LIBS += -framework Carbon -framework IOKit -framework AppKit
  11
  12 QT_LANG_PATH = ../dist/qt-translations
  13 DIST_PATH = ../dist/mac
  14
  15 document_icon.path = Contents/Resources
  16 document_icon.files = $$DIST_PATH/qBitTorrentDocument.icns
  17 QMAKE_BUNDLE_DATA += document_icon
  18
  19 qt_conf.path = Contents/Resources
  20 qt_conf.files = $$DIST_PATH/qt.conf
  21 QMAKE_BUNDLE_DATA += qt_conf
  22
  23 qt_translations.path = Contents/translations
  24 qt_translations.files = $$files($$QT_LANG_PATH/qtbase_*.qm)
  25 qt_translations.files += \
  26     $$QT_LANG_PATH/qt_fa.qm \
  27     $$QT_LANG_PATH/qt_gl.qm \
  28     $$QT_LANG_PATH/qt_lt.qm \
  29     $$QT_LANG_PATH/qt_pt.qm \
  30     $$QT_LANG_PATH/qt_sl.qm \
  31     $$QT_LANG_PATH/qt_sv.qm \
  32     $$QT_LANG_PATH/qt_zh_CN.qm
  33 QMAKE_BUNDLE_DATA += qt_translations
  34
  35 ICON = $$DIST_PATH/qbittorrent_mac.icns
  36 QMAKE_INFO_PLIST = $$DIST_PATH/Info.plist