dist/windows/installer.nsi

   1 Var uninstallerPath
   2
   3 Section "-hidden"
   4
   5     ;Search if qBittorrent is already installed.
   6     FindFirst $0 $1 "$uninstallerPath\uninst.exe"
   7     FindClose $0
   8     StrCmp $1 "" done
   9
  10     ;Run the uninstaller of the previous install.
  11     DetailPrint $(inst_unist)
  12     ExecWait '"$uninstallerPath\uninst.exe" /S _?=$uninstallerPath'
  13     Delete "$uninstallerPath\uninst.exe"
  14     RMDir "$uninstallerPath"
  15
  16     done:
  17
  18 SectionEnd
  19
  20
  21 Section $(inst_qbt_req) ;"qBittorrent (required)"
  22
  23   SectionIn RO
  24
  25   ; Set output path to the installation directory.
  26   SetOutPath $INSTDIR
  27   ; Put files there
  28   File "qbittorrent.exe"
  29   File "qbittorrent.pdb"
  30   File "qt.conf"
  31
  32   ;Create 'translations' directory
  33   CreateDirectory $INSTDIR\translations
  34   ; Set output path to the installation\translations directory.
  35   SetOutPath "$INSTDIR\translations"
  36   ; Put files there
  37   File /r "translations\qt*.qm"
  38
  39   ; Write the installation path into the registry
  40   WriteRegStr HKLM "Software\qBittorrent" "InstallLocation" "$INSTDIR"
  41
  42   ; Write the uninstall keys for Windows
  43   WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\qBittorrent" "DisplayName" "qBittorrent ${PROG_VERSION}"
  44   WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\qBittorrent" "UninstallString" '"$INSTDIR\uninst.exe"'
  45   WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\qBittorrent" "DisplayIcon" '"$INSTDIR\qbittorrent.exe",0'
  46   WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\qBittorrent" "Publisher" "The qBittorrent project"
  47   WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\qBittorrent" "URLInfoAbout" "https://www.qbittorrent.org"
  48   WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\qBittorrent" "DisplayVersion" "${PROG_VERSION}"
  49   WriteRegDWORD HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\qBittorrent" "NoModify" 1
  50   WriteRegDWORD HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\qBittorrent" "NoRepair" 1
  51   WriteUninstaller "uninst.exe"
  52   ${GetSize} "$INSTDIR" "/S=0K" $0 $1 $2
  53   IntFmt $0 "0x%08X" $0
  54   WriteRegDWORD HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\qBittorrent" "EstimatedSize" "$0"
  55
  56   ; qBittorrent ProgID
  57   WriteRegStr HKLM "Software\Classes\qBittorrent" "" "qBittorrent Torrent File"
  58   WriteRegStr HKLM "Software\Classes\qBittorrent" "FriendlyTypeName" "qBittorrent Torrent File"
  59   WriteRegStr HKLM "Software\Classes\qBittorrent\shell" "" "open"
  60   WriteRegStr HKLM "Software\Classes\qBittorrent\shell\open\command" "" '"$INSTDIR\qbittorrent.exe" "%1"'
  61   WriteRegStr HKLM "Software\Classes\qBittorrent\DefaultIcon" "" '"$INSTDIR\qbittorrent.exe",1'
  62
  63 SectionEnd
  64
  65 ; Optional section (can be disabled by the user)
  66 Section /o $(inst_dekstop) ;"Create Desktop Shortcut"
  67
  68   CreateShortCut "$DESKTOP\qBittorrent.lnk" "$INSTDIR\qbittorrent.exe"
  69
  70 SectionEnd
  71
  72 Section $(inst_startmenu) ;"Create Start Menu Shortcut"
  73
  74   CreateDirectory "$SMPROGRAMS\qBittorrent"
  75   CreateShortCut "$SMPROGRAMS\qBittorrent\qBittorrent.lnk" "$INSTDIR\qbittorrent.exe"
  76   CreateShortCut "$SMPROGRAMS\qBittorrent\$(inst_uninstall_link_description).lnk" "$INSTDIR\uninst.exe"
  77
  78 SectionEnd
  79
  80 Section /o $(inst_startup) ;"Start qBittorrent on Windows start up"
  81
  82   !insertmacro UAC_AsUser_Call Function inst_startup_user ${UAC_SYNCREGISTERS}|${UAC_SYNCOUTDIR}|${UAC_SYNCINSTDIR}
  83
  84 SectionEnd
  85
  86 Function inst_startup_user
  87
  88   WriteRegStr HKCU "Software\Microsoft\Windows\CurrentVersion\Run" "qBittorrent" "$INSTDIR\qbittorrent.exe"
  89
  90 FunctionEnd
  91
  92 Section $(inst_torrent) ;"Open .torrent files with qBittorrent"
  93
  94   ReadRegStr $0 HKLM "Software\Classes\.torrent" ""
  95
  96   StrCmp $0 "qBittorrent" clear_errors 0
  97   ;Check if empty string
  98   StrCmp $0 "" clear_errors 0
  99   ;Write old value to OpenWithProgIds
 100   WriteRegStr HKLM "Software\Classes\.torrent\OpenWithProgIds" $0 ""
 101
 102   clear_errors:
 103   ClearErrors
 104
 105   WriteRegStr HKLM "Software\Classes\.torrent" "" "qBittorrent"
 106   WriteRegStr HKLM "Software\Classes\.torrent" "Content Type" "application/x-bittorrent"
 107
 108   !insertmacro UAC_AsUser_Call Function inst_torrent_user ${UAC_SYNCREGISTERS}|${UAC_SYNCOUTDIR}|${UAC_SYNCINSTDIR}
 109
 110   System::Call 'Shell32::SHChangeNotify(i ${SHCNE_ASSOCCHANGED}, i ${SHCNF_IDLIST}, i 0, i 0)'
 111
 112 SectionEnd
 113
 114 Function inst_torrent_user
 115
 116   ReadRegStr $0 HKCU "Software\Classes\.torrent" ""
 117
 118   StrCmp $0 "qBittorrent" clear_errors 0
 119   ;Check if empty string
 120   StrCmp $0 "" clear_errors 0
 121   ;Write old value to OpenWithProgIds
 122   WriteRegStr HKCU "Software\Classes\.torrent\OpenWithProgIds" $0 ""
 123
 124   clear_errors:
 125   ClearErrors
 126
 127   WriteRegStr HKCU "Software\Classes\.torrent" "" "qBittorrent"
 128   WriteRegStr HKCU "Software\Classes\.torrent" "Content Type" "application/x-bittorrent"
 129
 130 FunctionEnd
 131
 132 Section $(inst_magnet) ;"Open magnet links with qBittorrent"
 133
 134   WriteRegStr HKLM "Software\Classes\magnet" "" "URL:Magnet link"
 135   WriteRegStr HKLM "Software\Classes\magnet" "Content Type" "application/x-magnet"
 136   WriteRegStr HKLM "Software\Classes\magnet" "URL Protocol" ""
 137   WriteRegStr HKLM "Software\Classes\magnet\DefaultIcon" "" '"$INSTDIR\qbittorrent.exe",1'
 138   WriteRegStr HKLM "Software\Classes\magnet\shell" "" "open"
 139   WriteRegStr HKLM "Software\Classes\magnet\shell\open\command" "" '"$INSTDIR\qbittorrent.exe" "%1"'
 140
 141   !insertmacro UAC_AsUser_Call Function inst_magnet_user ${UAC_SYNCREGISTERS}|${UAC_SYNCOUTDIR}|${UAC_SYNCINSTDIR}
 142
 143   System::Call 'Shell32::SHChangeNotify(i ${SHCNE_ASSOCCHANGED}, i ${SHCNF_IDLIST}, i 0, i 0)'
 144
 145 SectionEnd
 146
 147 Function inst_magnet_user
 148
 149   WriteRegStr HKCU "Software\Classes\magnet" "" "URL:Magnet link"
 150   WriteRegStr HKCU "Software\Classes\magnet" "Content Type" "application/x-magnet"
 151   WriteRegStr HKCU "Software\Classes\magnet" "URL Protocol" ""
 152   WriteRegStr HKCU "Software\Classes\magnet\DefaultIcon" "" '"$INSTDIR\qbittorrent.exe",1'
 153   WriteRegStr HKCU "Software\Classes\magnet\shell" "" "open"
 154   WriteRegStr HKCU "Software\Classes\magnet\shell\open\command" "" '"$INSTDIR\qbittorrent.exe" "%1"'
 155
 156 FunctionEnd
 157
 158 Section $(inst_firewall)
 159
 160   DetailPrint $(inst_firewallinfo)
 161   nsisFirewallW::AddAuthorizedApplication "$INSTDIR\qbittorrent.exe" "qBittorrent"
 162
 163 SectionEnd
 164
 165 Section $(inst_pathlimit) ;"Disable Windows path length limit (260 character MAX_PATH limitation, requires Windows 10 1607 or later)"
 166
 167   WriteRegDWORD HKLM "SYSTEM\CurrentControlSet\Control\FileSystem" "LongPathsEnabled" 1
 168
 169 SectionEnd
 170
 171 ;--------------------------------
 172
 173 Function .onInit
 174
 175   !insertmacro Init "installer"
 176   !insertmacro MUI_LANGDLL_DISPLAY
 177
 178   ${IfNot} ${AtLeastWin7}
 179     MessageBox MB_OK|MB_ICONEXCLAMATION $(inst_requires_win7)
 180     Abort
 181   ${EndIf}
 182
 183   !ifdef APP64BIT
 184     ${IfNot} ${RunningX64}
 185       MessageBox MB_OK|MB_ICONEXCLAMATION $(inst_requires_64bit)
 186       Abort
 187     ${EndIf}
 188   !endif
 189
 190   ;Search if qBittorrent is already installed.
 191   FindFirst $0 $1 "$INSTDIR\uninst.exe"
 192   FindClose $0
 193   StrCmp $1 "" done
 194
 195   ;Copy old value to var so we can call the correct uninstaller
 196   StrCpy $uninstallerPath $INSTDIR
 197
 198   ;Inform the user
 199   MessageBox MB_OKCANCEL|MB_ICONINFORMATION $(inst_uninstall_question) /SD IDOK IDOK done
 200   Quit
 201
 202   done:
 203
 204 FunctionEnd
 205
 206 Function check_instance
 207
 208   check:
 209   FindProcDLL::FindProc "qbittorrent.exe"
 210   StrCmp $R0 "1" 0 notfound
 211   MessageBox MB_RETRYCANCEL|MB_ICONEXCLAMATION $(inst_warning) IDRETRY check IDCANCEL done
 212
 213   done:
 214   Abort
 215
 216   notfound:
 217
 218 FunctionEnd
 219
 220 Function PageFinishRun
 221
 222   !insertmacro UAC_AsUser_ExecShell "" "$INSTDIR\qbittorrent.exe" "" "" ""
 223
 224 FunctionEnd
 225
 226 Function .onInstSuccess
 227   SetErrorLevel 0
 228 FunctionEnd