winconf.pri

   1 DEFINES += BOOST_ASIO_HASH_MAP_BUCKETS=1021
   2 # After 1.55 some Windows users reported regular UI freezes.
   3 # This makes ASIO use the pre-1.56 way of doing things. See issue #2003
   4 DEFINES += BOOST_ASIO_DISABLE_CONNECTEX
   5 DEFINES += BOOST_EXCEPTION_DISABLE
   6
   7 DEFINES += TORRENT_USE_OPENSSL
   8 DEFINES += TORRENT_DISABLE_GEO_IP
   9 DEFINES += TORRENT_DISABLE_RESOLVE_COUNTRIES
  10
  11 DEFINES += UNICODE
  12 DEFINES += _UNICODE
  13 DEFINES += WIN32
  14 DEFINES += _WIN32
  15 DEFINES += WIN32_LEAN_AND_MEAN
  16 DEFINES += _CRT_SECURE_NO_DEPRECATE
  17 DEFINES += _SCL_SECURE_NO_DEPRECATE
  18 DEFINES += __USE_W32_SOCKETS
  19 DEFINES += _FILE_OFFSET_BITS=64
  20 DEFINES += NOMINMAX
  21
  22 CONFIG(debug, debug|release) {
  23     DEFINES += TORRENT_DEBUG
  24 }
  25 else {
  26     DEFINES += NDEBUG
  27 }
  28
  29 win32-g++* {
  30     CONFIG(debug, debug|release) {
  31         # Make sure binary is not relocatable, otherwise debugging will fail
  32         QMAKE_LFLAGS -= -Wl,--dynamicbase
  33     }
  34
  35     RC_FILE = qbittorrent_mingw.rc
  36
  37     LIBS += libadvapi32 libshell32 libuser32 libole32 libwsock32 libws2_32
  38 }
  39 else:win32-msvc* {
  40     CONFIG -= embed_manifest_exe
  41     QMAKE_LFLAGS += "/MANIFEST:EMBED /MANIFESTINPUT:$$quote($${PWD}/src/qbittorrent.exe.manifest) /STACK:0x800000"
  42
  43     RC_FILE = qbittorrent.rc
  44
  45     LIBS += advapi32.lib shell32.lib crypt32.lib User32.lib ole32.lib
  46 }
  47
  48 # See an example build configuration in "conf.pri.windows"
  49 exists(conf.pri) {
  50     include(conf.pri)
  51 }
  52 else {
  53     error("'conf.pri' does not exist. See an example configuration in 'conf.pri.windows'.")
  54 }
  55
  56 # Stack trace support can be enabled in 'conf.pri'
  57 stacktrace {
  58     win32-g++* {
  59         contains(QMAKE_HOST.arch, x86) {
  60             # i686 arch requires frame pointer preservation
  61             QMAKE_CXXFLAGS += -fno-omit-frame-pointer
  62         }
  63
  64         QMAKE_LFLAGS += -Wl,--export-all-symbols
  65
  66         LIBS += libdbghelp
  67     }
  68     else:win32-msvc* {
  69         contains(QMAKE_HOST.arch, x86) {
  70             # i686 arch requires frame pointer preservation
  71             QMAKE_CXXFLAGS += -Oy-
  72         }
  73
  74         QMAKE_CXXFLAGS *= -Zi
  75         QMAKE_LFLAGS *= "/DEBUG"
  76
  77         LIBS += dbghelp.lib
  78     }
  79 }