winconf.pri

   1 # After 1.55 some Windows users reported regular UI freezes.
   2 # This makes ASIO use the pre-1.56 way of doing things. See issue #2003
   3 DEFINES += BOOST_ASIO_DISABLE_CONNECTEX
   4 DEFINES += BOOST_EXCEPTION_DISABLE
   5
   6 DEFINES += TORRENT_USE_LIBCRYPTO
   7 DEFINES += TORRENT_USE_OPENSSL
   8
   9 DEFINES += NTDDI_VERSION=0x06010000
  10 DEFINES += _WIN32_WINNT=0x0601
  11 DEFINES += _WIN32_IE=0x0601
  12 DEFINES += UNICODE
  13 DEFINES += _UNICODE
  14 DEFINES += WIN32
  15 DEFINES += _WIN32
  16 DEFINES += WIN32_LEAN_AND_MEAN
  17 DEFINES += NOMINMAX
  18
  19 CONFIG(debug, debug|release) {
  20     DEFINES += TORRENT_DEBUG
  21 }
  22 else {
  23     DEFINES += NDEBUG
  24 }
  25
  26 win32-g++*|win32-clang-g++* {
  27     CONFIG(debug, debug|release) {
  28         # Make sure binary is not relocatable, otherwise debugging will fail
  29         QMAKE_LFLAGS -= -Wl,--dynamicbase
  30     }
  31
  32     DEFINES += _FILE_OFFSET_BITS=64
  33     DEFINES += __USE_W32_SOCKETS
  34
  35     QMAKE_CXXFLAGS += -std=c++17
  36
  37     RC_FILE = qbittorrent_mingw.rc
  38
  39     LIBS += libadvapi32 libiphlpapi libole32 libpowrprof libshell32 libuser32 libwsock32 libws2_32
  40 }
  41 else:win32-msvc* {
  42     CONFIG -= embed_manifest_exe
  43     QMAKE_CXXFLAGS += /std:c++17 /utf-8
  44     QMAKE_LFLAGS += "/MANIFEST:EMBED /MANIFESTINPUT:$$quote($${PWD}/src/qbittorrent.exe.manifest) /STACK:0x800000"
  45
  46     RC_FILE = qbittorrent.rc
  47
  48     LIBS += advapi32.lib crypt32.lib Iphlpapi.lib ole32.lib PowrProf.lib shell32.lib User32.lib
  49 }
  50
  51 # See an example build configuration in "conf.pri.windows"
  52 exists(conf.pri) {
  53     include(conf.pri)
  54 }
  55 else {
  56     error("'conf.pri' does not exist. See an example configuration in 'conf.pri.windows'.")
  57 }
  58
  59 # Stack trace support can be enabled in 'conf.pri'
  60 stacktrace {
  61     win32-g++*|win32-clang-g++* {
  62         contains(QMAKE_HOST.arch, x86) {
  63             # i686 arch requires frame pointer preservation
  64             QMAKE_CXXFLAGS += -fno-omit-frame-pointer
  65         }
  66
  67         QMAKE_LFLAGS += -Wl,--export-all-symbols
  68
  69         LIBS += libdbghelp
  70     }
  71     else:win32-msvc* {
  72         contains(QMAKE_HOST.arch, x86) {
  73             # i686 arch requires frame pointer preservation
  74             QMAKE_CXXFLAGS += -Oy-
  75         }
  76
  77         QMAKE_CXXFLAGS *= -Zi
  78         QMAKE_LFLAGS *= "/DEBUG"
  79
  80         LIBS += dbghelp.lib
  81     }
  82 }