unixconf.pri

   1 # The first path is used when the source is being build by packagers (pbuilder/sbuild/etc)
   2 # The second path is used when you manually run the configure script in the root folder (eg when using qt creator)
   3 exists($$OUT_PWD/../conf.pri) {
   4     include($$OUT_PWD/../conf.pri)
   5 }
   6 else {
   7     include(conf.pri)
   8 }
   9
  10 # COMPILATION SPECIFIC
  11 !nogui:dbus: QT += dbus
  12
  13 QMAKE_CXXFLAGS += -Wall -Wextra -Wpedantic -Wformat-security
  14 !haiku: QMAKE_LFLAGS_APP += -rdynamic
  15
  16 # Man page
  17 nogui {
  18     man.files = ../doc/qbittorrent-nox.1
  19 }
  20 else {
  21     man.files = ../doc/qbittorrent.1
  22 }
  23
  24 man.path = $$MANPREFIX/man1
  25 INSTALLS += man
  26
  27 DIST_PATH = ../dist/unix
  28
  29 # Systemd Service file
  30 nogui:systemd {
  31     systemdService.files = $$DIST_PATH/systemd/qbittorrent-nox@.service
  32     systemdService.path = $$PREFIX/lib/systemd/system
  33     INSTALLS += systemdService
  34 }
  35
  36 # Menu Icon
  37 !nogui {
  38     desktopEntry.files = $$DIST_PATH/org.qbittorrent.qBittorrent.desktop
  39     desktopEntry.path = $$DATADIR/applications
  40     INSTALLS += desktopEntry
  41
  42     appdata.files = $$DIST_PATH/org.qbittorrent.qBittorrent.appdata.xml
  43     appdata.path = $$DATADIR/metainfo
  44     INSTALLS += appdata
  45
  46     menuicons.files = $$DIST_PATH/menuicons/*
  47     menuicons.path = $$DATADIR/icons/hicolor
  48     statusIconScalable.files = $$PWD/src/icons/qbittorrent-tray.svg \
  49                                $$PWD/src/icons/qbittorrent-tray-dark.svg \
  50                                $$PWD/src/icons/qbittorrent-tray-light.svg
  51     statusIconScalable.path = $$DATADIR/icons/hicolor/scalable/status
  52     INSTALLS += \
  53         menuicons \
  54         statusIconScalable
  55
  56     pixmap.files = $$DIST_PATH/menuicons/128x128/apps/qbittorrent.png
  57     pixmap.path = $$DATADIR/pixmaps
  58     INSTALLS += pixmap
  59 }
  60
  61 # INSTALL
  62 target.path = $$PREFIX/bin
  63 INSTALLS += target