macxconf.pri

   1 # The first path is used when the source is being build by packagers (pbuilder/sbuild/etc)
   2 # The second path is used when you manually run the configure script in the root folder (eg when using qt creator)
   3 exists($$OUT_PWD/../conf.pri) {
   4     include($$OUT_PWD/../conf.pri)
   5 }
   6 else {
   7     include(conf.pri)
   8 }
   9
  10 QMAKE_MACOSX_DEPLOYMENT_TARGET = 10.14
  11
  12 DEFINES += _DARWIN_FEATURE_64_BIT_INODE
  13
  14 LIBS += -framework Carbon -framework IOKit -framework AppKit
  15
  16 QT_LANG_PATH = ../dist/qt-translations
  17 DIST_PATH = ../dist/mac
  18
  19 document_icon.path = Contents/Resources
  20 document_icon.files = $$DIST_PATH/qBitTorrentDocument.icns
  21 QMAKE_BUNDLE_DATA += document_icon
  22
  23 qt_conf.path = Contents/Resources
  24 qt_conf.files = $$DIST_PATH/qt.conf
  25 QMAKE_BUNDLE_DATA += qt_conf
  26
  27 qt_translations.path = Contents/translations
  28 qt_translations.files = $$files($$QT_LANG_PATH/qtbase_*.qm)
  29 qt_translations.files += \
  30     $$QT_LANG_PATH/qt_fa.qm \
  31     $$QT_LANG_PATH/qt_gl.qm \
  32     $$QT_LANG_PATH/qt_lt.qm \
  33     $$QT_LANG_PATH/qt_pt.qm \
  34     $$QT_LANG_PATH/qt_sl.qm \
  35     $$QT_LANG_PATH/qt_sv.qm \
  36     $$QT_LANG_PATH/qt_zh_CN.qm
  37 QMAKE_BUNDLE_DATA += qt_translations
  38
  39 ICON = $$DIST_PATH/qbittorrent_mac.icns
  40 QMAKE_INFO_PLIST = $$DIST_PATH/Info.plist