CMakeLists.txt

   1 cmake_minimum_required(VERSION 3.16 FATAL_ERROR) # Policies <= CMP0097 default to NEW
   2
   3 project(qBittorrent
   4     DESCRIPTION "The qBittorrent BitTorrent client"
   5     HOMEPAGE_URL "https://www.qbittorrent.org/"
   6     LANGUAGES CXX
   7 )
   8
   9 # version requirements - older versions may work, but you are on your own
  10 set(minBoostVersion 1.71)
  11 set(minQt6Version 6.2)
  12 set(minOpenSSLVersion 1.1.1)
  13 set(minLibtorrent1Version 1.2.19)
  14 set(minLibtorrentVersion 2.0.9)
  15 set(minZlibVersion 1.2.11)
  16
  17 include(CheckCXXSourceCompiles) # TODO: migrate to CheckSourceCompiles in CMake >= 3.19
  18 include(GNUInstallDirs)
  19
  20 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Modules)
  21 include(FeatureSummary)
  22 include(FeatureOptionsSetup)
  23
  24 # features, list is loosely sorted by user's interests
  25 feature_option(GUI "Build GUI application" ON)
  26 feature_option(WEBUI "Enable built-in HTTP server for remote control" ON)
  27 feature_option(STACKTRACE "Enable stacktrace support" ON)
  28 feature_option(TESTING "Build internal testing suite" OFF)
  29 feature_option(VERBOSE_CONFIGURE "Show information about PACKAGES_FOUND and PACKAGES_NOT_FOUND in the configure output (only useful for debugging the CMake build scripts)" OFF)
  30
  31 if (CMAKE_SYSTEM_NAME STREQUAL "Linux")
  32     feature_option_dependent(DBUS
  33         "Enable support for notifications and power-management features via D-Bus on Linux"
  34         ON "GUI" OFF
  35     )
  36     feature_option_dependent(SYSTEMD
  37         "Install systemd service file. Target directory is overridable with `SYSTEMD_SERVICES_INSTALL_DIR` variable"
  38         OFF "NOT GUI" OFF
  39     )
  40 elseif (MSVC)
  41     feature_option(MSVC_RUNTIME_DYNAMIC "Use MSVC dynamic runtime library (-MD) instead of static (-MT)" ON)
  42 endif()
  43
  44 if (VERBOSE_CONFIGURE)
  45     feature_summary(WHAT ALL)
  46 else()
  47     feature_summary(WHAT ENABLED_FEATURES DISABLED_FEATURES)
  48 endif()
  49
  50 # go check the packages
  51 include(CheckPackages)
  52 # configure for specific platform
  53 include(CommonConfig)
  54
  55 # Generate version header
  56 configure_file("src/base/version.h.in" "${CMAKE_CURRENT_SOURCE_DIR}/src/base/version.h" @ONLY)
  57
  58 add_subdirectory(src)
  59 add_subdirectory(dist)
  60
  61 if (TESTING)
  62     add_subdirectory(test)
  63 endif()