src/src.pro

   1 # Global
   2 TEMPLATE = app
   3 CONFIG += qt thread silent
   4
   5 # C++11 support
   6 CONFIG += c++11
   7
   8 # Platform specific configuration
   9 win32: include(../winconf.pri)
  10 macx: include(../macxconf.pri)
  11 unix:!macx: include(../unixconf.pri)
  12
  13 QT += network xml
  14
  15 nogui {
  16     TARGET = qbittorrent-nox
  17     QT -= gui
  18     DEFINES += DISABLE_GUI
  19 } else {
  20     TARGET = qbittorrent
  21     QT += xml svg widgets
  22
  23     CONFIG(static) {
  24         DEFINES += QBT_STATIC_QT
  25         QTPLUGIN += qico
  26     }
  27     win32 {
  28         QT += winextras
  29     }
  30     macx {
  31         QT += macextras
  32         LIBS += -lobjc
  33     }
  34 }
  35
  36 nowebui {
  37     DEFINES += DISABLE_WEBUI
  38 }
  39
  40 stacktrace {
  41     DEFINES += STACKTRACE
  42     win32 {
  43         DEFINES += STACKTRACE_WIN_PROJECT_PATH=$$PWD
  44         DEFINES += STACKTRACE_WIN_MAKEFILE_PATH=$$OUT_PWD
  45     }
  46 }
  47
  48 CONFIG(debug, debug|release): message(Project is built in DEBUG mode.)
  49 CONFIG(release, debug|release): message(Project is built in RELEASE mode.)
  50
  51 # Disable debug output in release mode
  52 CONFIG(release, debug|release) {
  53     message(Disabling debug output.)
  54     DEFINES += QT_NO_DEBUG_OUTPUT
  55 }
  56
  57 # VERSION DEFINES
  58 include(../version.pri)
  59
  60 DEFINES += QT_NO_CAST_TO_ASCII
  61 # Efficient construction for QString & QByteArray (Qt >= 4.8)
  62 DEFINES += QT_USE_QSTRINGBUILDER
  63 DEFINES += QT_STRICT_ITERATORS
  64
  65 INCLUDEPATH += $$PWD
  66
  67 include(app/app.pri)
  68 include(base/base.pri)
  69 !nogui: include(gui/gui.pri)
  70 !nowebui: include(webui/webui.pri)
  71
  72 # Resource files
  73 QMAKE_RESOURCE_FLAGS += -compress 9 -threshold 5
  74 RESOURCES += \
  75     icons/icons.qrc \
  76     lang/lang.qrc \
  77     searchengine/searchengine.qrc
  78
  79 DESTDIR = .