winconf.pri

   1 # After 1.55 some Windows users reported regular UI freezes.
   2 # This makes ASIO use the pre-1.56 way of doing things. See issue #2003
   3 DEFINES += BOOST_ASIO_DISABLE_CONNECTEX
   4 DEFINES += BOOST_EXCEPTION_DISABLE
   5
   6 DEFINES += TORRENT_USE_OPENSSL
   7 DEFINES += TORRENT_DISABLE_RESOLVE_COUNTRIES
   8
   9 DEFINES += UNICODE
  10 DEFINES += _UNICODE
  11 DEFINES += WIN32
  12 DEFINES += _WIN32
  13 DEFINES += WIN32_LEAN_AND_MEAN
  14 DEFINES += NOMINMAX
  15
  16 CONFIG(debug, debug|release) {
  17     DEFINES += TORRENT_DEBUG
  18 }
  19 else {
  20     DEFINES += NDEBUG
  21 }
  22
  23 win32-g++* {
  24     CONFIG(debug, debug|release) {
  25         # Make sure binary is not relocatable, otherwise debugging will fail
  26         QMAKE_LFLAGS -= -Wl,--dynamicbase
  27     }
  28
  29     DEFINES += _FILE_OFFSET_BITS=64
  30     DEFINES += __USE_W32_SOCKETS
  31
  32     RC_FILE = qbittorrent_mingw.rc
  33
  34     LIBS += libadvapi32 libshell32 libuser32 libole32 libwsock32 libws2_32
  35 }
  36 else:win32-msvc* {
  37     CONFIG -= embed_manifest_exe
  38     QMAKE_LFLAGS += "/MANIFEST:EMBED /MANIFESTINPUT:$$quote($${PWD}/src/qbittorrent.exe.manifest) /STACK:0x800000"
  39
  40     RC_FILE = qbittorrent.rc
  41
  42     LIBS += advapi32.lib shell32.lib crypt32.lib User32.lib ole32.lib
  43 }
  44
  45 # See an example build configuration in "conf.pri.windows"
  46 exists(conf.pri) {
  47     include(conf.pri)
  48 }
  49 else {
  50     error("'conf.pri' does not exist. See an example configuration in 'conf.pri.windows'.")
  51 }
  52
  53 # Stack trace support can be enabled in 'conf.pri'
  54 stacktrace {
  55     win32-g++* {
  56         contains(QMAKE_HOST.arch, x86) {
  57             # i686 arch requires frame pointer preservation
  58             QMAKE_CXXFLAGS += -fno-omit-frame-pointer
  59         }
  60
  61         QMAKE_LFLAGS += -Wl,--export-all-symbols
  62
  63         LIBS += libdbghelp
  64     }
  65     else:win32-msvc* {
  66         contains(QMAKE_HOST.arch, x86) {
  67             # i686 arch requires frame pointer preservation
  68             QMAKE_CXXFLAGS += -Oy-
  69         }
  70
  71         QMAKE_CXXFLAGS *= -Zi
  72         QMAKE_LFLAGS *= "/DEBUG"
  73
  74         LIBS += dbghelp.lib
  75     }
  76 }