src/gui/macutilities.mm

   1 /*
   2  * Bittorrent Client using Qt and libtorrent.
   3  * Copyright (C) 2017  Brian Kendall <brian@briankendall.net>
   4  *
   5  * This program is free software; you can redistribute it and/or
   6  * modify it under the terms of the GNU General Public License
   7  * as published by the Free Software Foundation; either version 2
   8  * of the License, or (at your option) any later version.
   9  *
  10  * This program is distributed in the hope that it will be useful,
  11  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  12  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13  * GNU General Public License for more details.
  14  *
  15  * You should have received a copy of the GNU General Public License
  16  * along with this program; if not, write to the Free Software
  17  * Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301, USA.
  18  *
  19  * In addition, as a special exception, the copyright holders give permission to
  20  * link this program with the OpenSSL project's "OpenSSL" library (or with
  21  * modified versions of it that use the same license as the "OpenSSL" library),
  22  * and distribute the linked executables. You must obey the GNU General Public
  23  * License in all respects for all of the code used other than "OpenSSL".  If you
  24  * modify file(s), you may extend this exception to your version of the file(s),
  25  * but you are not obligated to do so. If you do not wish to do so, delete this
  26  * exception statement from your version.
  27  */
  28
  29 #include "macutilities.h"
  30
  31 #import <Cocoa/Cocoa.h>
  32 #include <objc/message.h>
  33
  34 #include <QPixmap>
  35 #include <QSize>
  36 #include <QString>
  37 #include <QVector>
  38
  39 #include "base/path.h"
  40
  41 QImage qt_mac_toQImage(CGImageRef image);
  42
  43 namespace MacUtils
  44 {
  45     QPixmap pixmapForExtension(const QString &ext, const QSize &size)
  46     {
  47         @autoreleasepool
  48         {
  49             NSImage *image = [[NSWorkspace sharedWorkspace] iconForFileType:ext.toNSString()];
  50             if (image)
  51             {
  52                 NSRect rect = NSMakeRect(0, 0, size.width(), size.height());
  53                 CGImageRef cgImage = [image CGImageForProposedRect:&rect context:nil hints:nil];
  54                 return QPixmap::fromImage(qt_mac_toQImage(cgImage));
  55             }
  56
  57             return QPixmap();
  58         }
  59     }
  60
  61     void overrideDockClickHandler(bool (*dockClickHandler)(id, SEL, ...))
  62     {
  63         NSApplication *appInst = [NSApplication sharedApplication];
  64
  65         if (!appInst)
  66             return;
  67
  68         Class delClass = [[appInst delegate] class];
  69         SEL shouldHandle = sel_registerName("applicationShouldHandleReopen:hasVisibleWindows:");
  70
  71         if (class_getInstanceMethod(delClass, shouldHandle))
  72         {
  73             if (class_replaceMethod(delClass, shouldHandle, reinterpret_cast<IMP>(dockClickHandler), "B@:"))
  74                 qDebug("Registered dock click handler (replaced original method)");
  75             else
  76                 qWarning("Failed to replace method for dock click handler");
  77         }
  78         else
  79         {
  80             if (class_addMethod(delClass, shouldHandle, reinterpret_cast<IMP>(dockClickHandler), "B@:"))
  81                 qDebug("Registered dock click handler");
  82             else
  83                 qWarning("Failed to register dock click handler");
  84         }
  85     }
  86
  87     void displayNotification(const QString &title, const QString &message)
  88     {
  89         @autoreleasepool
  90         {
  91             NSUserNotification *notification = [[NSUserNotification alloc] init];
  92             notification.title = title.toNSString();
  93             notification.informativeText = message.toNSString();
  94             notification.soundName = NSUserNotificationDefaultSoundName;
  95
  96             [[NSUserNotificationCenter defaultUserNotificationCenter] deliverNotification:notification];
  97         }
  98     }
  99
 100     void openFiles(const PathList &pathList)
 101     {
 102         @autoreleasepool
 103         {
 104             NSMutableArray *pathURLs = [NSMutableArray arrayWithCapacity:pathList.size()];
 105
 106             for (const auto &path : pathList)
 107                 [pathURLs addObject:[NSURL fileURLWithPath:path.toString().toNSString()]];
 108
 109             // In some unknown way, the next line affects Qt's main loop causing the crash
 110             // in QApplication::exec() on processing next event after this call.
 111             // Even crash doesn't happen exactly after this call, it will happen on
 112             // application exit. Call stack and disassembly are the same in all cases.
 113             // But running it in another thread (aka in background) solves the issue.
 114             dispatch_async(dispatch_get_global_queue(DISPATCH_QUEUE_PRIORITY_DEFAULT, 0), ^
 115             {
 116                 [[NSWorkspace sharedWorkspace] activateFileViewerSelectingURLs:pathURLs];
 117             });
 118         }
 119     }
 120
 121     QString badgeLabelText()
 122     {
 123         return QString::fromNSString(NSApp.dockTile.badgeLabel);
 124     }
 125
 126     void setBadgeLabelText(const QString &text)
 127     {
 128         NSApp.dockTile.badgeLabel = text.toNSString();
 129     }
 130 }