dist/windows/installer.nsi

   1 Var uninstallerPath
   2
   3 Section "-hidden"
   4
   5     ;Search if qBittorrent is already installed.
   6     FindFirst $0 $1 "$uninstallerPath\uninst.exe"
   7     FindClose $0
   8     StrCmp $1 "" done
   9
  10     ;Run the uninstaller of the previous install.
  11     DetailPrint $(inst_unist)
  12     ExecWait '"$uninstallerPath\uninst.exe" /S _?=$uninstallerPath'
  13     Delete "$uninstallerPath\uninst.exe"
  14     RMDir "$uninstallerPath"
  15
  16     done:
  17
  18 SectionEnd
  19
  20
  21 Section $(inst_qbt_req) ;"qBittorrent (required)"
  22
  23   SectionIn RO
  24
  25   ; Set output path to the installation directory.
  26   SetOutPath $INSTDIR
  27   ; Put files there
  28   File "qbittorrent.exe"
  29   File "qbittorrent.pdb"
  30   File "qt.conf"
  31
  32   ;Create 'translations' directory
  33   CreateDirectory $INSTDIR\translations
  34   ; Set output path to the installation\translations directory.
  35   SetOutPath "$INSTDIR\translations"
  36   ; Put files there
  37   File /r "translations\qt*.qm"
  38   ; Restore output path because it affects `CreateShortCut`. It affects the "Start in" field.
  39   SetOutPath $INSTDIR
  40
  41   ; Write the installation path into the registry
  42   WriteRegStr HKLM "Software\qBittorrent" "InstallLocation" "$INSTDIR"
  43
  44   ; Write the uninstall keys for Windows
  45   WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\qBittorrent" "DisplayName" "qBittorrent"
  46   WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\qBittorrent" "UninstallString" '"$INSTDIR\uninst.exe"'
  47   WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\qBittorrent" "DisplayIcon" '"$INSTDIR\qbittorrent.exe",0'
  48   WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\qBittorrent" "Publisher" "The qBittorrent project"
  49   WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\qBittorrent" "URLInfoAbout" "https://www.qbittorrent.org"
  50   WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\qBittorrent" "DisplayVersion" "${QBT_VERSION}"
  51   WriteRegDWORD HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\qBittorrent" "NoModify" 1
  52   WriteRegDWORD HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\qBittorrent" "NoRepair" 1
  53   WriteUninstaller "uninst.exe"
  54   ${GetSize} "$INSTDIR" "/S=0K" $0 $1 $2
  55   IntFmt $0 "0x%08X" $0
  56   WriteRegDWORD HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\qBittorrent" "EstimatedSize" "$0"
  57
  58   ; qBittorrent ProgID
  59   WriteRegStr HKLM "Software\Classes\qBittorrent" "" "qBittorrent Torrent File"
  60   WriteRegStr HKLM "Software\Classes\qBittorrent" "FriendlyTypeName" "qBittorrent Torrent File"
  61   WriteRegStr HKLM "Software\Classes\qBittorrent\shell" "" "open"
  62   WriteRegStr HKLM "Software\Classes\qBittorrent\shell\open\command" "" '"$INSTDIR\qbittorrent.exe" "%1"'
  63   WriteRegStr HKLM "Software\Classes\qBittorrent\DefaultIcon" "" '"$INSTDIR\qbittorrent.exe",1'
  64
  65 SectionEnd
  66
  67 ; Optional section (can be disabled by the user)
  68 Section /o $(inst_desktop) ;"Create Desktop Shortcut"
  69
  70   CreateShortCut "$DESKTOP\qBittorrent.lnk" "$INSTDIR\qbittorrent.exe"
  71
  72 SectionEnd
  73
  74 Section $(inst_startmenu) ;"Create Start Menu Shortcut"
  75
  76   CreateDirectory "$SMPROGRAMS\qBittorrent"
  77   CreateShortCut "$SMPROGRAMS\qBittorrent\qBittorrent.lnk" "$INSTDIR\qbittorrent.exe"
  78   CreateShortCut "$SMPROGRAMS\qBittorrent\$(inst_uninstall_link_description).lnk" "$INSTDIR\uninst.exe"
  79
  80 SectionEnd
  81
  82 Section /o $(inst_startup) ;"Start qBittorrent on Windows start up"
  83
  84   !insertmacro UAC_AsUser_Call Function inst_startup_user ${UAC_SYNCREGISTERS}|${UAC_SYNCOUTDIR}|${UAC_SYNCINSTDIR}
  85
  86 SectionEnd
  87
  88 Function inst_startup_user
  89
  90   WriteRegStr HKCU "Software\Microsoft\Windows\CurrentVersion\Run" "qBittorrent" "$INSTDIR\qbittorrent.exe"
  91
  92 FunctionEnd
  93
  94 Section $(inst_torrent) ;"Open .torrent files with qBittorrent"
  95
  96   ReadRegStr $0 HKLM "Software\Classes\.torrent" ""
  97
  98   StrCmp $0 "qBittorrent" clear_errors 0
  99   ;Check if empty string
 100   StrCmp $0 "" clear_errors 0
 101   ;Write old value to OpenWithProgIds
 102   WriteRegStr HKLM "Software\Classes\.torrent\OpenWithProgIds" $0 ""
 103
 104   clear_errors:
 105   ClearErrors
 106
 107   WriteRegStr HKLM "Software\Classes\.torrent" "" "qBittorrent"
 108   WriteRegStr HKLM "Software\Classes\.torrent" "Content Type" "application/x-bittorrent"
 109
 110   !insertmacro UAC_AsUser_Call Function inst_torrent_user ${UAC_SYNCREGISTERS}|${UAC_SYNCOUTDIR}|${UAC_SYNCINSTDIR}
 111
 112   System::Call 'Shell32::SHChangeNotify(i ${SHCNE_ASSOCCHANGED}, i ${SHCNF_IDLIST}, p 0, p 0)'
 113
 114 SectionEnd
 115
 116 Function inst_torrent_user
 117
 118   ReadRegStr $0 HKCU "Software\Classes\.torrent" ""
 119
 120   StrCmp $0 "qBittorrent" clear_errors 0
 121   ;Check if empty string
 122   StrCmp $0 "" clear_errors 0
 123   ;Write old value to OpenWithProgIds
 124   WriteRegStr HKCU "Software\Classes\.torrent\OpenWithProgIds" $0 ""
 125
 126   clear_errors:
 127   ClearErrors
 128
 129   WriteRegStr HKCU "Software\Classes\.torrent" "" "qBittorrent"
 130   WriteRegStr HKCU "Software\Classes\.torrent" "Content Type" "application/x-bittorrent"
 131
 132 FunctionEnd
 133
 134 Section $(inst_magnet) ;"Open magnet links with qBittorrent"
 135
 136   WriteRegStr HKLM "Software\Classes\magnet" "" "URL:Magnet link"
 137   WriteRegStr HKLM "Software\Classes\magnet" "Content Type" "application/x-magnet"
 138   WriteRegStr HKLM "Software\Classes\magnet" "URL Protocol" ""
 139   WriteRegStr HKLM "Software\Classes\magnet\DefaultIcon" "" '"$INSTDIR\qbittorrent.exe",1'
 140   WriteRegStr HKLM "Software\Classes\magnet\shell" "" "open"
 141   WriteRegStr HKLM "Software\Classes\magnet\shell\open\command" "" '"$INSTDIR\qbittorrent.exe" "%1"'
 142
 143   !insertmacro UAC_AsUser_Call Function inst_magnet_user ${UAC_SYNCREGISTERS}|${UAC_SYNCOUTDIR}|${UAC_SYNCINSTDIR}
 144
 145   System::Call 'Shell32::SHChangeNotify(i ${SHCNE_ASSOCCHANGED}, i ${SHCNF_IDLIST}, p 0, p 0)'
 146
 147 SectionEnd
 148
 149 Function inst_magnet_user
 150
 151   WriteRegStr HKCU "Software\Classes\magnet" "" "URL:Magnet link"
 152   WriteRegStr HKCU "Software\Classes\magnet" "Content Type" "application/x-magnet"
 153   WriteRegStr HKCU "Software\Classes\magnet" "URL Protocol" ""
 154   WriteRegStr HKCU "Software\Classes\magnet\DefaultIcon" "" '"$INSTDIR\qbittorrent.exe",1'
 155   WriteRegStr HKCU "Software\Classes\magnet\shell" "" "open"
 156   WriteRegStr HKCU "Software\Classes\magnet\shell\open\command" "" '"$INSTDIR\qbittorrent.exe" "%1"'
 157
 158 FunctionEnd
 159
 160 Section $(inst_firewall)
 161
 162   DetailPrint $(inst_firewallinfo)
 163   nsisFirewallW::AddAuthorizedApplication "$INSTDIR\qbittorrent.exe" "qBittorrent"
 164
 165 SectionEnd
 166
 167 Section $(inst_pathlimit) ;"Disable Windows path length limit (260 character MAX_PATH limitation, requires Windows 10 1607 or later)"
 168
 169   WriteRegDWORD HKLM "SYSTEM\CurrentControlSet\Control\FileSystem" "LongPathsEnabled" 1
 170
 171 SectionEnd
 172
 173 ;--------------------------------
 174
 175 Function .onInit
 176
 177   !insertmacro Init "installer"
 178   !insertmacro MUI_LANGDLL_DISPLAY
 179
 180   !ifndef QBT_USES_QT6
 181     ${IfNot} ${AtLeastWin7}
 182       MessageBox MB_OK|MB_ICONEXCLAMATION $(inst_requires_win7)
 183       Abort
 184     ${EndIf}
 185   !else
 186     ${IfNot} ${AtLeastWaaS} 1809 ; Windows 10 1809. Min supported version by Qt6
 187       MessageBox MB_OK|MB_ICONEXCLAMATION $(inst_requires_win10)
 188       Abort
 189     ${EndIf}
 190   !endif
 191
 192   !ifdef QBT_IS_X64
 193     ${IfNot} ${RunningX64}
 194       MessageBox MB_OK|MB_ICONEXCLAMATION $(inst_requires_64bit)
 195       Abort
 196     ${EndIf}
 197   !endif
 198
 199   ;Search if qBittorrent is already installed.
 200   FindFirst $0 $1 "$INSTDIR\uninst.exe"
 201   FindClose $0
 202   StrCmp $1 "" done
 203
 204   ;Copy old value to var so we can call the correct uninstaller
 205   StrCpy $uninstallerPath $INSTDIR
 206
 207   ;Inform the user
 208   MessageBox MB_OKCANCEL|MB_ICONINFORMATION $(inst_uninstall_question) /SD IDOK IDOK done
 209   Quit
 210
 211   done:
 212
 213 FunctionEnd
 214
 215 Function check_instance
 216
 217   check:
 218   FindProcDLL::FindProc "qbittorrent.exe"
 219   StrCmp $R0 "1" 0 notfound
 220   MessageBox MB_RETRYCANCEL|MB_ICONEXCLAMATION $(inst_warning) IDRETRY check IDCANCEL done
 221
 222   done:
 223   Abort
 224
 225   notfound:
 226
 227 FunctionEnd
 228
 229 Function PageFinishRun
 230
 231   !insertmacro UAC_AsUser_ExecShell "" "$INSTDIR\qbittorrent.exe" "" "" ""
 232
 233 FunctionEnd
 234
 235 Function .onInstSuccess
 236   SetErrorLevel 0
 237 FunctionEnd