configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ([2.67])
   5
   6 AC_INIT([quvi], m4_esyscmd([./gen-ver.sh -c | tr -d '\n']),
   7         [http://quvi.sf.net/bugs/],[],[http://quvi.sf.net/])
   8
   9 AC_CONFIG_SRCDIR([src/main.c])
  10 AC_CONFIG_HEADERS([config.h])
  11 AC_CONFIG_AUX_DIR([config.aux])
  12 AC_CONFIG_MACRO_DIR([m4])
  13
  14 AC_CANONICAL_TARGET
  15 AC_USE_SYSTEM_EXTENSIONS
  16
  17 AC_DEFINE_UNQUOTED([CANONICAL_TARGET], "$target", [...])
  18 AC_DEFINE_UNQUOTED([CANONICAL_HOST], "$host", [...])
  19
  20 # GNU Automake 1.13 spews a warning about AM_GNU_GETTEXT (0.18.1,
  21 # 0.18.2) using the deprecated AM_PROG_MKDIR_P macro. Do not specify
  22 # '-Werror` in the options to work around this.
  23 AM_INIT_AUTOMAKE([1.11.1 -Wall dist-xz no-dist-gzip tar-ustar])
  24 AM_SILENT_RULES([yes])
  25
  26 # GNU Automake 1.12 requires this macro. Earlier versions do not
  27 # recognize this macro. Work around this.
  28 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  29
  30 LT_INIT([disable-static])
  31 LT_PREREQ([2.2.6])
  32
  33 AM_GNU_GETTEXT_VERSION([0.18.1])
  34 AM_GNU_GETTEXT([external])
  35 # GETTEXT_PACKAGE is used by glib.
  36 AC_DEFINE([GETTEXT_PACKAGE], [PACKAGE], [Define to the gettext package name])
  37 AC_SUBST([GETTEXT_PACKAGE], [PACKAGE])
  38
  39 # Checks for programs.
  40 AC_PROG_CC
  41 AM_PROG_CC_C_O
  42
  43 AC_PATH_PROG([DATE], [date], [no])
  44 AS_IF([test "$DATE" != x"$xno"], [build_time=`$DATE +"%F %T %z"`])
  45 AC_DEFINE_UNQUOTED([BUILD_TIME], ["$build_time"], [We have build time])
  46
  47 AC_PATH_PROG([A2X], [a2x], [no])
  48 AM_CONDITIONAL([HAVE_A2X], [test x"$A2X" != "xno"])
  49 AC_SUBST([A2X])
  50
  51 # Checks for libraries.
  52 PKG_CHECK_MODULES([libquvi], [libquvi-0.9 >= 0.9])
  53 PKG_CHECK_MODULES([libcurl], [libcurl >= 7.18.2])
  54 PKG_CHECK_MODULES([gobject], [gobject-2.0 >= 2.24])
  55 PKG_CHECK_MODULES([glib], [glib-2.0 >= 2.24])
  56
  57 PKG_CHECK_MODULES([json_glib], [json-glib-1.0 >= 0.12],
  58   [have_json_glib=yes
  59    AC_DEFINE([HAVE_JSON_GLIB], [1], [Define to json-glib package])
  60   ],
  61   [have_json_glib=no
  62    AC_MSG_NOTICE([json-glib 0.12+ not found, building without json output])
  63   ])
  64 AM_CONDITIONAL([HAVE_JSON_GLIB], [test x"$have_json_glib" = "xyes"])
  65
  66 PKG_CHECK_MODULES([libxml], [libxml-2.0 >= 2.7.8],
  67   [have_libxml=yes
  68    AC_DEFINE([HAVE_LIBXML], [1], [Define to libxml package])
  69   ],
  70   [have_libxml=no
  71    AC_MSG_NOTICE([libxml 2.7.8+ not found, building without xml output])
  72   ])
  73 AM_CONDITIONAL([HAVE_LIBXML], [test x"$have_libxml" = "xyes"])
  74
  75 # Checks for header files.
  76 AC_CHECK_HEADERS([locale.h])
  77
  78 # Checks for typedefs, structures, and compiler characteristics.
  79
  80 # Checks for library functions.
  81 AC_CHECK_FUNCS([setlocale memset strerror])
  82 AC_FUNC_STRERROR_R
  83
  84 # Version.
  85 VN=`$srcdir/gen-ver.sh`
  86 AC_DEFINE_UNQUOTED([VN],["$VN"], [We have version number from gen-ver.sh])
  87
  88 # --with-manual
  89 AC_ARG_WITH([manual],
  90   [AS_HELP_STRING([--with-manual],
  91     [install manual page(s) @<:@default=yes@:>@])],
  92   [],
  93   [with_manual=yes])
  94 AM_CONDITIONAL([WITH_MANUAL], [test x"$with_manual" != "xno"])
  95
  96 AC_CONFIG_FILES([
  97   Makefile
  98   doc/Makefile
  99   doc/man1/Makefile
 100   doc/man5/Makefile
 101   src/get/Makefile
 102   src/input/Makefile
 103   src/opts/Makefile
 104   src/pbar/Makefile
 105   src/print/Makefile
 106   src/util/Makefile
 107   src/Makefile
 108   po/Makefile.in
 109 ])
 110 AC_OUTPUT
 111
 112 AC_MSG_NOTICE([
 113   version:        ${VERSION}
 114   prefix:         ${prefix}
 115   compiler:       ${CC}
 116   cflags:         ${CFLAGS}
 117 System types
 118   target          ${target}
 119   build           ${build}
 120   host            ${host}
 121 Build options
 122   json-glib 0.12+ ${have_json_glib}
 123   libxml 2.7.8+   ${have_libxml}
 124 Install options
 125   with
 126   - manual  ${with_manual}])