configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ([2.68])
   5
   6 m4_include([m4/version.m4])
   7
   8 AC_INIT([quvi], [_QUVI_VERSION],
   9   [http://sourceforge.net/apps/trac/quvi/], [],
  10   [http://quvi.sourceforge.net/])
  11
  12 AC_CONFIG_SRCDIR([src/quvi/quvi.c])
  13 AC_CONFIG_HEADERS([config.h])
  14 AC_CONFIG_AUX_DIR([config.aux])
  15 AC_CONFIG_MACRO_DIR([m4])
  16
  17 AC_CANONICAL_SYSTEM
  18 AC_GNU_SOURCE
  19
  20 AC_DEFINE_UNQUOTED([CANONICAL_TARGET], "$target", [...])
  21 AC_DEFINE_UNQUOTED([CANONICAL_HOST], "$host", [...])
  22
  23 AM_INIT_AUTOMAKE([-Wall -Werror foreign dist-bzip2 dist-xz])
  24 AM_SILENT_RULES([yes])
  25
  26 # Checks for programs.
  27 AC_PROG_CC
  28
  29 # Checks for libraries.
  30 PKG_CHECK_MODULES([libquvi], [libquvi >= 0.4.0])
  31 PKG_CHECK_MODULES([libcurl], [libcurl >= 7.18.2])
  32
  33 # Checks for header files.
  34 AC_CHECK_HEADERS([stdarg.h stdlib.h string.h stddef.h])
  35
  36 # Checks for typedefs, structures, and compiler characteristics.
  37 AC_CHECK_TYPES([ptrdiff_t])
  38 AC_TYPE_SIZE_T
  39
  40 # Checks for library functions.
  41 AC_CHECK_FUNCS([memset strchr strcspn strdup strerror strspn strstr strtol])
  42 AC_FUNC_REALLOC
  43 AC_FUNC_MALLOC
  44
  45 have_asprintf=no
  46 AC_CHECK_FUNCS([vasprintf], [
  47   AC_CHECK_FUNCS([asprintf], [have_asprintf=yes])
  48 ])
  49 AM_CONDITIONAL([NO_ASPRINTF], [test x"$have_asprintf" != "xyes"])
  50
  51 # Version.
  52 VN=`$srcdir/gen-ver.sh $srcdir`
  53 AC_DEFINE_UNQUOTED([VN],["$VN"], [We have version number from gen-ver.sh])
  54
  55 # --with-manual
  56 AC_ARG_WITH([manual],
  57   [AS_HELP_STRING([--with-manual],
  58     [install manual page(s) @<:@default=yes@:>@])],
  59   [],
  60   [with_manual=yes])
  61 AM_CONDITIONAL([WITH_MANUAL], [test x"$with_manual" != "xno"])
  62
  63 AC_CONFIG_FILES([
  64   Makefile
  65   doc/Makefile
  66   doc/man1/Makefile
  67   src/Makefile
  68   src/quvi/Makefile])
  69 AC_OUTPUT
  70
  71 AC_MSG_NOTICE([
  72   version:        ${VERSION} (${VN})
  73   host setup:     ${host}
  74   compiler:       ${CC}
  75   cflags:         ${CFLAGS}
  76   prefix:         ${prefix}
  77   install manual: ${with_manual}])