lisp/org-src.el

   1 ;;; org-src.el --- Source code examples in Org
   2 ;;
   3 ;; Copyright (C) 2004, 2005, 2006, 2007, 2008, 2009
   4 ;;   Free Software Foundation, Inc.
   5 ;;
   6 ;; Author: Carsten Dominik <carsten at orgmode dot org>
   7 ;;         Bastien Guerry <bzg AT altern DOT org>
   8 ;; Keywords: outlines, hypermedia, calendar, wp
   9 ;; Homepage: http://orgmode.org
  10 ;; Version: 6.31trans
  11 ;;
  12 ;; This file is part of GNU Emacs.
  13 ;;
  14 ;; GNU Emacs is free software: you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation, either version 3 of the License, or
  17 ;; (at your option) any later version.
  18
  19 ;; GNU Emacs is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  26 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  27 ;;
  28 ;;; Commentary:
  29
  30 ;; This file contains the code dealing with source code examples in Org-mode.
  31
  32 ;;; Code:
  33
  34 (require 'org-macs)
  35 (require 'org-compat)
  36
  37 (declare-function org-do-remove-indentation "org" (&optional n))
  38 (declare-function org-get-indentation "org" (&optional line))
  39
  40 (defcustom org-edit-src-region-extra nil
  41   "Additional regexps to identify regions for editing with `org-edit-src-code'.
  42 For examples see the function `org-edit-src-find-region-and-lang'.
  43 The regular expression identifying the begin marker should end with a newline,
  44 and the regexp marking the end line should start with a newline, to make sure
  45 there are kept outside the narrowed region."
  46   :group 'org-edit-structure
  47   :type '(repeat
  48           (list
  49            (regexp :tag "begin regexp")
  50            (regexp :tag "end regexp")
  51            (choice :tag "language"
  52                    (string :tag "specify")
  53                    (integer :tag "from match group")
  54                    (const :tag "from `lang' element")
  55                    (const :tag "from `style' element")))))
  56
  57 (defcustom org-coderef-label-format "(ref:%s)"
  58   "The default coderef format.
  59 This format string will be used to search for coderef labels in literal
  60 examples (EXAMPLE and SRC blocks).  The format can be overwritten in
  61 an individual literal example with the -f option, like
  62
  63 #+BEGIN_SRC pascal +n -r -l \"((%s))\"
  64 ...
  65 #+END_SRC
  66
  67 If you want to use this for HTML export, make sure that the format does
  68 not introduce special font-locking, and avoid the HTML special
  69 characters `<', `>', and `&'.  The reason for this restriction is that
  70 the labels are searched for only after htmlize has done its job."
  71   :group 'org-edit-structure ; FIXME this is not in the right group
  72   :type 'string)
  73
  74 (defcustom org-edit-fixed-width-region-mode 'artist-mode
  75   "The mode that should be used to edit fixed-width regions.
  76 These are the regions where each line starts with a colon."
  77   :group 'org-edit-structure
  78   :type '(choice
  79           (const artist-mode)
  80           (const picture-mode)
  81           (const fundamental-mode)
  82           (function :tag "Other (specify)")))
  83
  84 (defcustom org-src-preserve-indentation nil
  85   "If non-nil, leading whitespace characters in source code
  86   blocks are preserved. Otherwise, after editing with
  87   \\[org-edit-src-code], the minimum (across-lines) number of
  88   leading whitespace characters are removed from all lines, and
  89   the code block is then uniformly indented according to the
  90   value of `org-edit-src-content-indentation'."
  91   :group 'org-edit-structure
  92   :type 'boolean)
  93
  94 (defcustom org-edit-src-content-indentation 2
  95   "Indentation for the content of a source code block.
  96 This should be the number of spaces added to the indentation of the #+begin
  97 line in order to compute the indentation of the block content after
  98 editing it with \\[org-edit-src-code]. Has no effect if
  99 `org-src-preserve-indentation' is non-nil."
 100   :group 'org-edit-structure
 101   :type 'integer)
 102
 103 (defcustom org-edit-src-persistent-message t
 104   "Non-nil means show persistent exit help message while editing src examples.
 105 The message is shown in the header-line, which will be created in the
 106 first line of the window showing the editing buffer.
 107 When nil, the message will only be shown intermittently in the echo area."
 108   :group 'org-edit-structure
 109   :type 'boolean)
 110
 111
 112 (defvar org-src-mode-hook nil
 113   "Hook  run after Org switched a source code snippet to its Emacs mode.
 114 This hook will run
 115
 116 - when editing a source code snippet with \"C-c '\".
 117 - When formatting a source code snippet for export with htmlize.
 118
 119 You may want to use this hook for example to turn off `outline-minor-mode'
 120 or similar things which you want to have when editing a source code file,
 121 but which mess up the display of a snippet in Org exported files.")
 122
 123 (defcustom org-src-lang-modes
 124   '(("ocaml" . tuareg) ("elisp" . emacs-lisp) ("ditaa" . artist)
 125     ("asymptote" . asy))
 126   "Alist mapping languages to their major mode.
 127 The key is the language name, the value is the string that should
 128 be inserted as the name of the major mode.  For many languages this is
 129 simple, but for language where this is not the case, this variable
 130 provides a way to simplify things on the user side.
 131 For example, there is no ocaml-mode in Emacs, but the mode to use is
 132 `tuareg-mode'."
 133   :group 'org-edit-structure
 134   :type '(repeat
 135           (cons
 136            (string "Language name")
 137            (symbol "Major mode"))))
 138
 139 ;;; Editing source examples
 140
 141 (defvar org-src-mode-map (make-sparse-keymap))
 142 (define-key org-src-mode-map "\C-c'" 'org-edit-src-exit)
 143 (defvar org-edit-src-force-single-line nil)
 144 (defvar org-edit-src-from-org-mode nil)
 145 (defvar org-edit-src-picture nil)
 146 (defvar org-edit-src-beg-marker nil)
 147 (defvar org-edit-src-end-marker nil)
 148 (defvar org-edit-src-overlay nil)
 149 (defvar org-edit-src-block-indentation nil)
 150
 151 (define-minor-mode org-src-mode
 152   "Minor mode for language major mode buffers generated by org.
 153 This minor mode is turned on in two situations:
 154 - when editing a source code snippet with \"C-c '\".
 155 - When formatting a source code snippet for export with htmlize.
 156 There is a mode hook, and keybindings for `org-edit-src-exit' and
 157 `org-edit-src-save'")
 158
 159 (defun org-edit-src-code ()
 160   "Edit the source code example at point.
 161 The example is copied to a separate buffer, and that buffer is switched
 162 to the correct language mode.  When done, exit with \\[org-edit-src-exit].
 163 This will remove the original code in the Org buffer, and replace it with
 164 the edited version."
 165   (interactive)
 166   (let ((line (org-current-line))
 167         (col (current-column))
 168         (case-fold-search t)
 169         (msg (substitute-command-keys
 170               "Edit, then exit with C-c ' (C-c and single quote)"))
 171         (info (org-edit-src-find-region-and-lang))
 172         (org-mode-p (eq major-mode 'org-mode))
 173         (beg (make-marker))
 174         (end (make-marker))
 175         (preserve-indentation org-src-preserve-indentation)
 176         block-nindent total-nindent ovl lang lang-f single lfmt code begline buffer)
 177     (if (not info)
 178         nil
 179       (setq beg (move-marker beg (nth 0 info))
 180             end (move-marker end (nth 1 info))
 181             code (buffer-substring-no-properties beg end)
 182             lang (or (cdr (assoc (nth 2 info) org-src-lang-modes))
 183                      (nth 2 info))
 184             lang (if (symbolp lang) (symbol-name lang) lang)
 185             single (nth 3 info)
 186             lfmt (nth 4 info)
 187             block-nindent (nth 5 info)
 188             lang-f (intern (concat lang "-mode"))
 189             begline (save-excursion (goto-char beg) (org-current-line)))
 190       (unless (functionp lang-f)
 191         (error "No such language mode: %s" lang-f))
 192       (org-goto-line line)
 193       (if (and (setq buffer (org-edit-src-find-buffer beg end))
 194                (y-or-n-p "Return to existing edit buffer? [n] will revert changes: "))
 195           (switch-to-buffer buffer)
 196         (when buffer
 197           (with-current-buffer buffer
 198             (if (boundp 'org-edit-src-overlay)
 199                 (org-delete-overlay org-edit-src-overlay)))
 200           (kill-buffer buffer))
 201         (setq buffer (generate-new-buffer
 202                       (org-src-construct-edit-buffer-name (buffer-name) lang)))
 203         (setq ovl (org-make-overlay beg end))
 204         (org-overlay-put ovl 'face 'secondary-selection)
 205         (org-overlay-put ovl 'edit-buffer buffer)
 206         (org-overlay-put ovl 'help-echo "Click with mouse-1 to switch to buffer editing this segment")
 207         (org-overlay-put ovl 'face 'secondary-selection)
 208         (org-overlay-put ovl
 209                          'keymap
 210                          (let ((map (make-sparse-keymap)))
 211                            (define-key map [mouse-1] 'org-edit-src-continue)
 212                            map))
 213         (org-overlay-put ovl :read-only "Leave me alone")
 214         (switch-to-buffer buffer)
 215         (if (eq single 'macro-definition)
 216             (setq code (replace-regexp-in-string "\\\\n" "\n" code t t)))
 217         (insert code)
 218         (remove-text-properties (point-min) (point-max)
 219                                 '(display nil invisible nil intangible nil))
 220         (unless preserve-indentation
 221           (setq total-nindent (or (org-do-remove-indentation) 0)))
 222         (let ((org-inhibit-startup t))
 223           (funcall lang-f))
 224         (set (make-local-variable 'org-edit-src-force-single-line) single)
 225         (set (make-local-variable 'org-edit-src-from-org-mode) org-mode-p)
 226         (set (make-local-variable 'org-src-preserve-indentation) preserve-indentation)
 227         (when lfmt
 228           (set (make-local-variable 'org-coderef-label-format) lfmt))
 229         (when org-mode-p
 230           (goto-char (point-min))
 231           (while (re-search-forward "^," nil t)
 232             (if (eq (org-current-line) line) (setq total-nindent (1+ total-nindent)))
 233             (replace-match "")))
 234         (org-goto-line (1+ (- line begline)))
 235         (org-move-to-column
 236          (if preserve-indentation col (max 0 (- col total-nindent))))
 237         (org-set-local 'org-edit-src-beg-marker beg)
 238         (org-set-local 'org-edit-src-end-marker end)
 239         (org-set-local 'org-edit-src-overlay ovl)
 240         (org-set-local 'org-edit-src-block-indentation block-nindent)
 241         (org-src-mode)
 242         (set-buffer-modified-p nil)
 243         (and org-edit-src-persistent-message
 244              (org-set-local 'header-line-format msg)))
 245       (message "%s" msg)
 246       t)))
 247
 248 (defun org-edit-src-continue (e)
 249   (interactive "e")
 250   (mouse-set-point e)
 251   (let ((buf (get-char-property (point) 'edit-buffer)))
 252     (if buf (switch-to-buffer buf)
 253       (error "Something is wrong here"))))
 254
 255 (defun org-src-construct-edit-buffer-name (org-buffer-name lang)
 256   "Construct the buffer name for a source editing buffer"
 257   (concat "*Org Src " org-buffer-name "[ " lang " ]*"))
 258
 259 (defun org-edit-src-find-buffer (beg end)
 260   "Find a source editing buffer that is already editing the region BEG to END."
 261   (catch 'exit
 262     (mapc
 263      (lambda (b)
 264        (with-current-buffer b
 265          (if (and (string-match "\\`*Org Src " (buffer-name))
 266                   (local-variable-p 'org-edit-src-beg-marker (current-buffer))
 267                   (local-variable-p 'org-edit-src-end-marker (current-buffer))
 268                   (equal beg org-edit-src-beg-marker)
 269                   (equal end org-edit-src-end-marker))
 270              (throw 'exit (current-buffer)))))
 271      (buffer-list))
 272     nil))
 273
 274 (defun org-edit-fixed-width-region ()
 275   "Edit the fixed-width ascii drawing at point.
 276 This must be a region where each line starts with a colon followed by
 277 a space character.
 278 An new buffer is created and the fixed-width region is copied into it,
 279 and the buffer is switched into `artist-mode' for editing.  When done,
 280 exit with \\[org-edit-src-exit].  The edited text will then replace
 281 the fragment in the Org-mode buffer."
 282   (interactive)
 283   (let ((line (org-current-line))
 284         (col (current-column))
 285         (case-fold-search t)
 286         (msg (substitute-command-keys
 287               "Edit, then exit with C-c ' (C-c and single quote)"))
 288         (org-mode-p (eq major-mode 'org-mode))
 289         (beg (make-marker))
 290         (end (make-marker))
 291         (preserve-indentation org-src-preserve-indentation)
 292         block-nindent ovl beg1 end1 code begline buffer)
 293     (beginning-of-line 1)
 294     (if (looking-at "[ \t]*[^:\n \t]")
 295         nil
 296       (if (looking-at "[ \t]*\\(\n\\|\\'\\)")
 297           (setq beg1 (point) end1 beg1)
 298         (save-excursion
 299           (if (re-search-backward "^[ \t]*[^: \t]" nil 'move)
 300               (setq beg1 (point-at-bol 2))
 301             (setq beg1 (point))))
 302         (save-excursion
 303           (if (re-search-forward "^[ \t]*[^: \t]" nil 'move)
 304               (setq end1 (1- (match-beginning 0)))
 305             (setq end1 (point))))
 306         (org-goto-line line))
 307       (setq beg (move-marker beg beg1)
 308             end (move-marker end end1)
 309             code (buffer-substring-no-properties beg end)
 310             begline (save-excursion (goto-char beg) (org-current-line)))
 311       (if (and (setq buffer (org-edit-src-find-buffer beg end))
 312                (y-or-n-p "Return to existing edit buffer? [n] will revert changes: "))
 313           (switch-to-buffer buffer)
 314         (when buffer
 315           (with-current-buffer buffer
 316             (if (boundp 'org-edit-src-overlay)
 317                 (org-delete-overlay org-edit-src-overlay)))
 318           (kill-buffer buffer))
 319         (setq buffer (generate-new-buffer
 320                       (org-src-construct-edit-buffer-name
 321                        (buffer-name) "Fixed Width")))
 322         (setq ovl (org-make-overlay beg end))
 323         (org-overlay-put ovl 'face 'secondary-selection)
 324         (org-overlay-put ovl 'edit-buffer buffer)
 325         (org-overlay-put ovl 'help-echo "Click with mouse-1 to switch to buffer editing this segment")
 326         (org-overlay-put ovl 'face 'secondary-selection)
 327         (org-overlay-put ovl
 328                          'keymap
 329                          (let ((map (make-sparse-keymap)))
 330                            (define-key map [mouse-1] 'org-edit-src-continue)
 331                            map))
 332         (org-overlay-put ovl :read-only "Leave me alone")
 333         (switch-to-buffer buffer)
 334         (insert code)
 335         (remove-text-properties (point-min) (point-max)
 336                                 '(display nil invisible nil intangible nil))
 337         (setq block-nindent (or (org-do-remove-indentation) 0))
 338         (cond
 339          ((eq org-edit-fixed-width-region-mode 'artist-mode)
 340           (fundamental-mode)
 341           (artist-mode 1))
 342        (t (funcall org-edit-fixed-width-region-mode)))
 343         (set (make-local-variable 'org-edit-src-force-single-line) nil)
 344         (set (make-local-variable 'org-edit-src-from-org-mode) org-mode-p)
 345         (set (make-local-variable 'org-edit-src-picture) t)
 346         (goto-char (point-min))
 347         (while (re-search-forward "^[ \t]*: ?" nil t)
 348           (replace-match ""))
 349         (org-goto-line (1+ (- line begline)))
 350         (org-move-to-column (max 0 (- col block-nindent 2)))
 351         (org-set-local 'org-edit-src-beg-marker beg)
 352         (org-set-local 'org-edit-src-end-marker end)
 353         (org-set-local 'org-edit-src-overlay ovl)
 354         (org-set-local 'org-edit-src-block-indentation block-nindent)
 355         (org-set-local 'org-edit-src-content-indentation 0)
 356         (org-set-local 'org-src-preserve-indentation nil)
 357         (org-src-mode)
 358         (set-buffer-modified-p nil)
 359         (and org-edit-src-persistent-message
 360              (org-set-local 'header-line-format msg)))
 361       (message "%s" msg)
 362       t)))
 363
 364 (defun org-edit-src-find-region-and-lang ()
 365   "Find the region and language for a local edit.
 366 Return a list with beginning and end of the region, a string representing
 367 the language, a switch telling if the content should be in a single line."
 368   (let ((re-list
 369          (append
 370           org-edit-src-region-extra
 371           '(
 372             ("<src\\>[^<]*>[ \t]*\n?" "\n?[ \t]*</src>" lang)
 373             ("<literal\\>[^<]*>[ \t]*\n?" "\n?[ \t]*</literal>" style)
 374             ("<example>[ \t]*\n?" "\n?[ \t]*</example>" "fundamental")
 375             ("<lisp>[ \t]*\n?" "\n?[ \t]*</lisp>" "emacs-lisp")
 376             ("<perl>[ \t]*\n?" "\n?[ \t]*</perl>" "perl")
 377             ("<python>[ \t]*\n?" "\n?[ \t]*</python>" "python")
 378             ("<ruby>[ \t]*\n?" "\n?[ \t]*</ruby>" "ruby")
 379             ("^[ \t]*#\\+begin_src\\( \\([^ \t\n]+\\)\\)?.*\n" "\n[ \t]*#\\+end_src" 2)
 380             ("^[ \t]*#\\+begin_example.*\n" "\n[ \t]*#\\+end_example" "fundamental")
 381             ("^[ \t]*#\\+html:" "\n" "html" single-line)
 382             ("^[ \t]*#\\+begin_html.*\n" "\n[ \t]*#\\+end_html" "html")
 383             ("^[ \t]*#\\+latex:" "\n" "latex" single-line)
 384             ("^[ \t]*#\\+begin_latex.*\n" "\n[ \t]*#\\+end_latex" "latex")
 385             ("^[ \t]*#\\+ascii:" "\n" "fundamental" single-line)
 386             ("^[ \t]*#\\+begin_ascii.*\n" "\n[ \t]*#\\+end_ascii" "fundamental")
 387             ("^[ \t]*#\\+docbook:" "\n" "xml" single-line)
 388             ("^[ \t]*#\\+macro:[ \t]+\\S-+\\( \\|$\\)"
 389              "\n" "fundamental" macro-definition)
 390             ("^[ \t]*#\\+begin_docbook.*\n" "\n[ \t]*#\\+end_docbook" "xml")
 391             )))
 392         (pos (point))
 393         re1 re2 single beg end lang lfmt match-re1 ind entry)
 394     (catch 'exit
 395       (while (setq entry (pop re-list))
 396         (setq re1 (car entry) re2 (nth 1 entry) lang (nth 2 entry)
 397               single (nth 3 entry))
 398         (save-excursion
 399           (if (or (looking-at re1)
 400                   (re-search-backward re1 nil t))
 401               (progn
 402                 (setq match-re1 (match-string 0))
 403                 (setq beg (match-end 0)
 404                       lang (org-edit-src-get-lang lang)
 405                       lfmt (org-edit-src-get-label-format match-re1)
 406                       ind (org-edit-src-get-indentation (match-beginning 0)))
 407                 (if (and (re-search-forward re2 nil t)
 408                          (>= (match-end 0) pos))
 409                     (throw 'exit (list beg (match-beginning 0)
 410                                        lang single lfmt ind))))
 411             (if (or (looking-at re2)
 412                     (re-search-forward re2 nil t))
 413                 (progn
 414                   (setq end (match-beginning 0))
 415                   (if (and (re-search-backward re1 nil t)
 416                            (<= (match-beginning 0) pos))
 417                       (progn
 418                         (setq lfmt (org-edit-src-get-label-format
 419                                     (match-string 0))
 420                               ind (org-edit-src-get-indentation
 421                                    (match-beginning 0)))
 422                         (throw 'exit
 423                                (list (match-end 0) end
 424                                      (org-edit-src-get-lang lang)
 425                                      single lfmt ind))))))))))))
 426
 427 (defun org-edit-src-get-lang (lang)
 428   "Extract the src language."
 429   (let ((m (match-string 0)))
 430     (cond
 431      ((stringp lang) lang)
 432      ((integerp lang) (match-string lang))
 433      ((and (eq lang 'lang)
 434            (string-match "\\<lang=\"\\([^ \t\n\"]+\\)\"" m))
 435       (match-string 1 m))
 436      ((and (eq lang 'style)
 437            (string-match "\\<style=\"\\([^ \t\n\"]+\\)\"" m))
 438       (match-string 1 m))
 439      (t "fundamental"))))
 440
 441 (defun org-edit-src-get-label-format (s)
 442   "Extract the label format."
 443   (save-match-data
 444     (if (string-match "-l[ \t]+\\\\?\"\\([^\t\r\n\"]+\\)\\\\?\"" s)
 445         (match-string 1 s))))
 446
 447 (defun org-edit-src-get-indentation (pos)
 448   "Count leading whitespace characters on line"
 449   (save-match-data
 450     (goto-char pos)
 451     (org-get-indentation)))
 452
 453 (defun org-edit-src-exit ()
 454   "Exit special edit and protect problematic lines."
 455   (interactive)
 456   (unless org-edit-src-from-org-mode
 457     (error "This is not a sub-editing buffer, something is wrong..."))
 458   (let* ((beg org-edit-src-beg-marker)
 459          (end org-edit-src-end-marker)
 460          (ovl org-edit-src-overlay)
 461          (buffer (current-buffer))
 462          (single (org-bound-and-true-p org-edit-src-force-single-line))
 463          (macro (eq single 'macro-definition))
 464          (total-nindent (+ (or org-edit-src-block-indentation 0)
 465                            org-edit-src-content-indentation))
 466          (preserve-indentation org-src-preserve-indentation)
 467          (delta 0) code line col indent)
 468     (untabify (point-min) (point-max))
 469     (save-excursion
 470       (goto-char (point-min))
 471       (if (looking-at "[ \t\n]*\n") (replace-match ""))
 472       (unless macro
 473         (if (re-search-forward "\n[ \t\n]*\\'" nil t) (replace-match ""))))
 474     (setq line (if (org-bound-and-true-p org-edit-src-force-single-line)
 475                    1
 476                  (org-current-line))
 477           col (current-column))
 478     (when single
 479       (goto-char (point-min))
 480       (if (re-search-forward "\\s-+\\'" nil t) (replace-match ""))
 481       (goto-char (point-min))
 482       (let ((cnt 0))
 483         (while (re-search-forward "\n" nil t)
 484           (setq cnt (1+ cnt))
 485           (replace-match (if macro "\\n" " ") t t))
 486         (when (and macro (> cnt 0))
 487           (goto-char (point-max)) (insert "\\n")))
 488       (goto-char (point-min))
 489       (if (looking-at "\\s-*") (replace-match " ")))
 490     (when (org-bound-and-true-p org-edit-src-from-org-mode)
 491       (goto-char (point-min))
 492       (while (re-search-forward
 493               (if (org-mode-p) "^\\(.\\)" "^\\([*]\\|[ \t]*#\\+\\)") nil t)
 494         (if (eq (org-current-line) line) (setq delta (1+ delta)))
 495         (replace-match ",\\1")))
 496     (when (org-bound-and-true-p org-edit-src-picture)
 497       (setq preserve-indentation nil)
 498       (untabify (point-min) (point-max))
 499       (goto-char (point-min))
 500       (while (re-search-forward "^" nil t)
 501         (replace-match ": ")))
 502     (unless (or single preserve-indentation (= total-nindent 0))
 503       (setq indent (make-string total-nindent ?\ ))
 504       (goto-char (point-min))
 505       (while (re-search-forward "^" nil t)
 506         (replace-match indent)))
 507     (if (org-bound-and-true-p org-edit-src-picture)
 508         (setq total-nindent (+ total-nindent 2)))
 509     (setq code (buffer-string))
 510     (set-buffer-modified-p nil)
 511     (switch-to-buffer (marker-buffer beg))
 512     (kill-buffer buffer)
 513     (goto-char beg)
 514     (delete-region beg end)
 515     (insert code)
 516     (goto-char beg)
 517     (if single (just-one-space))
 518     (org-goto-line (1- (+ (org-current-line) line)))
 519     (org-move-to-column (if preserve-indentation col (+ col total-nindent delta)))
 520     (move-marker beg nil)
 521     (move-marker end nil)))
 522
 523 (defun org-edit-src-save ()
 524   "Save parent buffer with current state source-code buffer."
 525   (interactive)
 526   (save-window-excursion
 527     (let ((p (point)) (m (mark)) msg)
 528       (org-edit-src-exit)
 529       (save-buffer)
 530       (setq msg (current-message))
 531       (org-edit-src-code)
 532       (push-mark m 'nomessage)
 533       (goto-char (min p (point-max)))
 534       (message (or msg "")))))
 535
 536 (defun org-src-mode-configure-edit-buffer ()
 537   (when org-edit-src-from-org-mode
 538     (setq buffer-offer-save t)
 539     (setq buffer-file-name
 540           (concat (buffer-file-name (marker-buffer org-edit-src-beg-marker))
 541                   "[" (buffer-name) "]"))
 542     (set (if (featurep 'xemacs) 'write-contents-hooks 'write-contents-functions)
 543          '(org-edit-src-save))
 544     (org-add-hook 'kill-buffer-hook
 545                   '(lambda () (org-delete-overlay org-edit-src-overlay)) nil 'local)))
 546
 547 (org-add-hook 'org-src-mode-hook 'org-src-mode-configure-edit-buffer)
 548
 549 (provide 'org-src)
 550
 551 ;; arch-tag: 6a1fc84f-dec7-47be-a416-64be56bea5d8
 552 ;;; org-src.el ends here