lisp/org-id.el

   1 ;;; org-id.el --- Global identifiers for Org-mode entries
   2 ;;
   3 ;; Copyright (C) 2008, 2009 Free Software Foundation, Inc.
   4 ;;
   5 ;; Author: Carsten Dominik <carsten at orgmode dot org>
   6 ;; Keywords: outlines, hypermedia, calendar, wp
   7 ;; Homepage: http://orgmode.org
   8 ;; Version: 6.32trans
   9 ;;
  10 ;; This file is part of GNU Emacs.
  11 ;;
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  25 ;;
  26 ;;; Commentary:
  27
  28 ;; This file implements globally unique identifiers for Org-mode entries.
  29 ;; Identifiers are stored in the entry as an :ID: property.  Functions
  30 ;; are provided that create and retrieve such identifiers, and that find
  31 ;; entries based on the identifier.
  32
  33 ;; Identifiers consist of a prefix (default "Org" given by the variable
  34 ;; `org-id-prefix') and a unique part that can be created by a number
  35 ;; of different methods, see the variable `org-id-method'.
  36 ;; Org has a builtin method that uses a compact encoding of the creation
  37 ;; time of the ID, with microsecond accuracy.  This virtually
  38 ;; guarantees globally unique identifiers, even if several people are
  39 ;; creating IDs at the same time in files that will eventually be used
  40 ;; together.  As an external method `uuidgen' is supported, if installed
  41 ;; on the system.
  42 ;;
  43 ;; This file defines the following API:
  44 ;;
  45 ;; org-id-get-create
  46 ;;        Create an ID for the entry at point if it does not yet have one.
  47 ;;        Returns the ID (old or new).  This function can be used
  48 ;;        interactively, with prefix argument the creation of a new ID is
  49 ;;        forced, even if there was an old one.
  50 ;;
  51 ;; org-id-get
  52 ;;        Get the ID property of an entry.  Using appropriate arguments
  53 ;;        to the function, it can also create the ID for this entry.
  54 ;;
  55 ;; org-id-goto
  56 ;;        Command to go to a specific ID, this command can be used
  57 ;;        interactively.
  58 ;;
  59 ;; org-id-get-with-outline-path-completion
  60 ;;        Retrieve the ID of an entry, using outline path completion.
  61 ;;        This function can work for multiple files.
  62 ;;
  63 ;; org-id-get-with-outline-drilling
  64 ;;        Retrieve the ID of an entry, using outline path completion.
  65 ;;        This function only works for the current file.
  66 ;;
  67 ;; org-id-find
  68 ;;        Find the location of an entry with specific id.
  69 ;;
  70
  71 (require 'org)
  72
  73 (declare-function message-make-fqdn "message" ())
  74
  75 ;;; Customization
  76
  77 (defgroup org-id nil
  78   "Options concerning global entry identifiers in Org-mode."
  79   :tag "Org ID"
  80   :group 'org)
  81
  82 (defcustom org-id-uuid-program "uuidgen"
  83   "The uuidgen program."
  84   :group 'org-id
  85   :type 'string)
  86
  87 (defcustom org-id-method
  88   (condition-case nil
  89       (if (string-match "\\`[-0-9a-fA-F]\\{36\\}\\'"
  90                         (org-trim (shell-command-to-string
  91                                    org-id-uuid-program)))
  92           'uuidgen
  93         'org)
  94     (error 'org))
  95   "The method that should be used to create new IDs.
  96
  97 If `uuidgen' is available on the system, it will be used as the default method.
  98 if not, the method `org' is used.
  99 An ID will consist of the optional prefix specified in `org-id-prefix',
 100 and a unique part created by the method this variable specifies.
 101
 102 Allowed values are:
 103
 104 org        Org's own internal method, using an encoding of the current time to
 105            microsecond accuracy, and optionally the current domain of the
 106            computer.  See the variable `org-id-include-domain'.
 107
 108 uuidgen    Call the external command uuidgen."
 109   :group 'org-id
 110   :type '(choice
 111           (const :tag "Org's internal method" org)
 112           (const :tag "external: uuidgen" uuidgen)))
 113
 114 (defcustom org-id-prefix nil
 115   "The prefix for IDs.
 116
 117 This may be a string, or it can be nil to indicate that no prefix is required.
 118 When a string, the string should have no space characters as IDs are expected
 119 to have no space characters in them."
 120   :group 'org-id
 121   :type '(choice
 122           (const :tag "No prefix")
 123           (string :tag "Prefix")))
 124
 125 (defcustom org-id-include-domain nil
 126   "Non-nil means, add the domain name to new IDs.
 127 This ensures global uniqueness of IDs, and is also suggested by
 128 RFC 2445 in combination with RFC 822.  This is only relevant if
 129 `org-id-method' is `org'.  When uuidgen is used, the domain will never
 130 be added.
 131 The default is to not use this because we have no really good way to get
 132 the true domain, and Org entries will normally not be shared with enough
 133 people to make this necessary."
 134   :group 'org-id
 135   :type 'boolean)
 136
 137 (defcustom org-id-track-globally t
 138   "Non-nil means, track IDs through files, so that links work globally.
 139 This work by maintaining a hash table for IDs and writing this table
 140 to disk when exiting Emacs.  Because of this, it works best if you use
 141 a single Emacs process, not many.
 142
 143 When nil, IDs are not tracked.  Links to IDs will still work within
 144 a buffer, but not if the entry is located in another file.
 145 IDs can still be used if the entry with the id is in the same file as
 146 the link."
 147   :group 'org-id
 148   :type 'boolean)
 149
 150 (defcustom org-id-locations-file (convert-standard-filename
 151                                   "~/.emacs.d/.org-id-locations")
 152   "The file for remembering in which file an ID was defined.
 153 This variable is only relevant when `org-id-track-globally' is set."
 154   :group 'org-id
 155   :type 'file)
 156
 157 (defvar org-id-locations nil
 158   "List of files with IDs in those files.
 159 Depending on `org-id-use-hash' this can also be a hash table mapping IDs
 160 to files.")
 161
 162 (defvar org-id-files nil
 163   "List of files that contain IDs.")
 164
 165 (defcustom org-id-extra-files 'org-agenda-text-search-extra-files
 166   "Files to be searched for IDs, besides the agenda files.
 167 When Org reparses files to remake the list of files and IDs it is tracking,
 168 it will normally scan the agenda files, the archives related to agenda files,
 169 any files that are listed as ID containing in the current register, and
 170 any Org-mode files currently visited by Emacs.
 171 You can list additional files here.
 172 This variable is only relevant when `org-id-track-globally' is set."
 173   :group 'org-id
 174   :type
 175   '(choice
 176     (symbol :tag "Variable")
 177     (repeat :tag "List of files"
 178             (file))))
 179
 180 (defcustom org-id-search-archives t
 181   "Non-nil means, search also the archive files of agenda files for entries.
 182 This is a possibility to reduce overhead, but it means that entries moved
 183 to the archives can no longer be found by ID.
 184 This variable is only relevant when `org-id-track-globally' is set."
 185   :group 'org-id
 186   :type 'boolean)
 187
 188 ;;; The API functions
 189
 190 ;;;###autoload
 191 (defun org-id-get-create (&optional force)
 192   "Create an ID for the current entry and return it.
 193 If the entry already has an ID, just return it.
 194 With optional argument FORCE, force the creation of a new ID."
 195   (interactive "P")
 196   (when force
 197     (org-entry-put (point) "ID" nil))
 198   (org-id-get (point) 'create))
 199
 200 ;;;###autoload
 201 (defun org-id-copy ()
 202   "Copy the ID of the entry at point to the kill ring.
 203 Create an ID if necessary."
 204   (interactive)
 205   (org-kill-new (org-id-get nil 'create)))
 206
 207 ;;;###autoload
 208 (defun org-id-get (&optional pom create prefix)
 209   "Get the ID property of the entry at point-or-marker POM.
 210 If POM is nil, refer to the entry at point.
 211 If the entry does not have an ID, the function returns nil.
 212 However, when CREATE is non nil, create an ID if none is present already.
 213 PREFIX will be passed through to `org-id-new'.
 214 In any case, the ID of the entry is returned."
 215   (org-with-point-at pom
 216     (let ((id (org-entry-get nil "ID")))
 217       (cond
 218        ((and id (stringp id) (string-match "\\S-" id))
 219         id)
 220        (create
 221         (setq id (org-id-new prefix))
 222         (org-entry-put pom "ID" id)
 223         (org-id-add-location id (buffer-file-name (buffer-base-buffer)))
 224         id)
 225        (t nil)))))
 226
 227 ;;;###autoload
 228 (defun org-id-get-with-outline-path-completion (&optional targets)
 229   "Use outline-path-completion to retrieve the ID of an entry.
 230 TARGETS may be a setting for `org-refile-targets' to define the eligible
 231 headlines.  When omitted, all headlines in all agenda files are
 232 eligible.
 233 It returns the ID of the entry.  If necessary, the ID is created."
 234   (let* ((org-refile-targets (or targets '((nil . (:maxlevel . 10)))))
 235          (org-refile-use-outline-path
 236           (if (caar org-refile-targets) 'file t))
 237          (org-refile-target-verify-function nil)
 238          (spos (org-refile-get-location "Entry: "))
 239          (pom (and spos (move-marker (make-marker) (nth 3 spos)
 240                                      (get-file-buffer (nth 1 spos))))))
 241     (prog1 (org-id-get pom 'create)
 242       (move-marker pom nil))))
 243
 244 ;;;###autoload
 245 (defun org-id-get-with-outline-drilling (&optional targets)
 246   "Use an outline-cycling interface to retrieve the ID of an entry.
 247 This only finds entries in the current buffer, using `org-get-location'.
 248 It returns the ID of the entry.  If necessary, the ID is created."
 249   (let* ((spos (org-get-location (current-buffer) org-goto-help))
 250          (pom (and spos (move-marker (make-marker) (car spos)))))
 251     (prog1 (org-id-get pom 'create)
 252       (move-marker pom nil))))
 253
 254 ;;;###autoload
 255 (defun org-id-goto (id)
 256   "Switch to the buffer containing the entry with id ID.
 257 Move the cursor to that entry in that buffer."
 258   (interactive "sID: ")
 259   (let ((m (org-id-find id 'marker)))
 260     (unless m
 261       (error "Cannot find entry with ID \"%s\"" id))
 262     (switch-to-buffer (marker-buffer m))
 263     (goto-char m)
 264     (move-marker m nil)
 265     (org-show-context)))
 266
 267 ;;;###autoload
 268 (defun org-id-find (id &optional markerp)
 269   "Return the location of the entry with the id ID.
 270 The return value is a cons cell (file-name . position), or nil
 271 if there is no entry with that ID.
 272 With optional argument MARKERP, return the position as a new marker."
 273   (cond
 274    ((symbolp id) (setq id (symbol-name id)))
 275    ((numberp id) (setq id (number-to-string id))))
 276   (let ((file (org-id-find-id-file id))
 277         org-agenda-new-buffers where)
 278     (when file
 279       (setq where (org-id-find-id-in-file id file markerp)))
 280     (unless where
 281       (org-id-update-id-locations)
 282       (setq file (org-id-find-id-file id))
 283       (when file
 284         (setq where (org-id-find-id-in-file id file markerp))))
 285     where))
 286
 287 ;;; Internal functions
 288
 289 ;; Creating new IDs
 290
 291 (defun org-id-new (&optional prefix)
 292   "Create a new globally unique ID.
 293
 294 An ID consists of two parts separated by a colon:
 295 - a prefix
 296 - a unique part that will be created according to `org-id-method'.
 297
 298 PREFIX can specify the prefix, the default is given by the variable
 299 `org-id-prefix'.  However, if PREFIX is the symbol `none', don't use any
 300 prefix even if `org-id-prefix' specifies one.
 301
 302 So a typical ID could look like \"Org:4nd91V40HI\"."
 303   (let* ((prefix (if (eq prefix 'none)
 304                      ""
 305                    (concat (or prefix org-id-prefix) ":")))
 306          unique)
 307     (if (equal prefix ":") (setq prefix ""))
 308     (cond
 309      ((eq org-id-method 'uuidgen)
 310       (setq unique (org-trim (shell-command-to-string org-id-uuid-program))))
 311      ((eq org-id-method 'org)
 312       (let* ((etime (org-id-reverse-string (org-id-time-to-b36)))
 313              (postfix (if org-id-include-domain
 314                           (progn
 315                             (require 'message)
 316                             (concat "@" (message-make-fqdn))))))
 317         (setq unique (concat etime postfix))))
 318      (t (error "Invalid `org-id-method'")))
 319     (concat prefix unique)))
 320
 321 (defun org-id-reverse-string (s)
 322   (mapconcat 'char-to-string (nreverse (string-to-list s)) ""))
 323
 324 (defun org-id-int-to-b36-one-digit (i)
 325   "Turn an integer between 0 and 61 into a single character 0..9, A..Z, a..z."
 326   (cond
 327    ((< i 10) (+ ?0 i))
 328    ((< i 36) (+ ?a i -10))
 329    (t (error "Larger that 35"))))
 330
 331 (defun org-id-b36-to-int-one-digit (i)
 332   "Turn a character 0..9, A..Z, a..z into a number 0..61.
 333 The input I may be a character, or a single-letter string."
 334   (and (stringp i) (setq i (string-to-char i)))
 335   (cond
 336    ((and (>= i ?0) (<= i ?9)) (- i ?0))
 337    ((and (>= i ?a) (<= i ?z)) (+ (- i ?a) 10))
 338    (t (error "Invalid b36 letter"))))
 339
 340 (defun org-id-int-to-b36 (i &optional length)
 341   "Convert an integer to a base-36 number represented as a string."
 342   (let ((s ""))
 343     (while (> i 0)
 344       (setq s (concat (char-to-string
 345                        (org-id-int-to-b36-one-digit (mod i 36))) s)
 346             i (/ i 36)))
 347     (setq length (max 1 (or length 1)))
 348     (if (< (length s) length)
 349         (setq s (concat (make-string (- length (length s)) ?0) s)))
 350     s))
 351
 352 (defun org-id-b36-to-int (s)
 353   "Convert a base-36 string into the corresponding integer."
 354   (let ((r 0))
 355     (mapc (lambda (i) (setq r (+ (* r 36) (org-id-b36-to-int-one-digit i))))
 356           s)
 357     r))
 358
 359 (defun org-id-time-to-b36 (&optional time)
 360   "Encode TIME as a 10-digit string.
 361 This string holds the time to micro-second accuracy, and can be decoded
 362 using `org-id-decode'."
 363   (setq time (or time (current-time)))
 364   (concat (org-id-int-to-b36 (nth 0 time) 4)
 365           (org-id-int-to-b36 (nth 1 time) 4)
 366           (org-id-int-to-b36 (or (nth 2 time) 0) 4)))
 367
 368 (defun org-id-decode (id)
 369   "Split ID into the prefix and the time value that was used to create it.
 370 The return value is (prefix . time) where PREFIX is nil or a string,
 371 and time is the usual three-integer representation of time."
 372   (let (prefix time parts)
 373     (setq parts (org-split-string id ":"))
 374     (if (= 2 (length parts))
 375         (setq prefix (car parts) time (nth 1 parts))
 376       (setq prefix nil time (nth 0 parts)))
 377     (setq time (org-id-reverse-string time))
 378     (setq time (list (org-id-b36-to-int (substring time 0 4))
 379                      (org-id-b36-to-int (substring time 4 8))
 380                      (org-id-b36-to-int (substring time 8 12))))
 381     (cons prefix time)))
 382
 383 ;; Storing ID locations (files)
 384
 385 (defun org-id-update-id-locations (&optional files)
 386   "Scan relevant files for IDs.
 387 Store the relation between files and corresponding IDs.
 388 This will scan all agenda files, all associated archives, and all
 389 files currently mentioned in `org-id-locations'.
 390 When FILES is given, scan these files instead.
 391 When CHECK is given, prepare detailed information about duplicate IDs."
 392   (interactive)
 393   (if (not org-id-track-globally)
 394       (error "Please turn on `org-id-track-globally' if you want to track IDs")
 395     (let* ((org-id-search-archives
 396             (or org-id-search-archives
 397                 (and (symbolp org-id-extra-files)
 398                      (symbol-value org-id-extra-files)
 399                      (member 'agenda-archives org-id-extra-files))))
 400            (files
 401             (or files
 402                 (append
 403                  ;; Agenda files and all associated archives
 404                  (org-agenda-files t org-id-search-archives)
 405                  ;; Explicit extra files
 406                  (if (symbolp org-id-extra-files)
 407                      (symbol-value org-id-extra-files)
 408                    org-id-extra-files)
 409               ;; Files associated with live org-mode buffers
 410                  (delq nil
 411                        (mapcar (lambda (b)
 412                                  (with-current-buffer b
 413                                    (and (org-mode-p) (buffer-file-name))))
 414                                (buffer-list)))
 415                  ;; All files known to have IDs
 416                  org-id-files)))
 417            org-agenda-new-buffers
 418            file nfiles tfile ids reg found id seen (ndup 0))
 419       (when (member 'agenda-archives files)
 420         (setq files (delq 'agenda-archives (copy-sequence files))))
 421       (setq nfiles (length files))
 422       (while (setq file (pop files))
 423         (message "Finding ID locations (%d/%d files): %s"
 424                  (- nfiles (length files)) nfiles file)
 425         (setq tfile (file-truename file))
 426         (when (and (file-exists-p file) (not (member tfile seen)))
 427           (push tfile seen)
 428           (setq ids nil)
 429           (with-current-buffer (org-get-agenda-file-buffer file)
 430             (save-excursion
 431               (save-restriction
 432                 (widen)
 433                 (goto-char (point-min))
 434                 (while (re-search-forward "^[ \t]*:ID:[ \t]+\\(\\S-+\\)[ \t]*$"
 435                                           nil t)
 436                   (setq id (org-match-string-no-properties 1))
 437                   (if (member id found)
 438                       (progn
 439                         (message "Duplicate ID \"%s\", also in file %s"
 440                                  id (car (delq
 441                                           nil
 442                                           (mapcar
 443                                            (lambda (x)
 444                                              (if (member id (cdr x)) (car x)))
 445                                            reg))))
 446                         (when (= ndup 0)
 447                           (ding)
 448                           (sit-for 2))
 449                         (setq ndup (1+ ndup)))
 450                     (push id found)
 451                     (push id ids)))
 452                 (push (cons (abbreviate-file-name file) ids) reg))))))
 453       (org-release-buffers org-agenda-new-buffers)
 454       (setq org-agenda-new-buffers nil)
 455       (setq org-id-locations reg)
 456       (setq org-id-files (mapcar 'car org-id-locations))
 457       (org-id-locations-save) ;; this function can also handle the alist form
 458       ;; now convert to a hash
 459       (setq org-id-locations (org-id-alist-to-hash org-id-locations))
 460       (if (> ndup 0)
 461           (message "WARNING: %d duplicate IDs found, check *Messages* buffer" ndup)
 462         (message "%d unique files scanned for IDs" (length org-id-files)))
 463       org-id-locations)))
 464
 465 (defun org-id-locations-save ()
 466   "Save `org-id-locations' in `org-id-locations-file'."
 467   (when org-id-track-globally
 468     (let ((out (if (hash-table-p org-id-locations)
 469                    (org-id-hash-to-alist org-id-locations)
 470                  org-id-locations)))
 471       (with-temp-file org-id-locations-file
 472         (print out (current-buffer))))))
 473
 474 (defun org-id-locations-load ()
 475   "Read the data from `org-id-locations-file'."
 476   (setq org-id-locations nil)
 477   (when org-id-track-globally
 478     (with-temp-buffer
 479       (condition-case nil
 480           (progn
 481             (insert-file-contents-literally org-id-locations-file)
 482             (goto-char (point-min))
 483             (setq org-id-locations (read (current-buffer))))
 484         (error
 485          (message "Could not read org-id-values from %s. Setting it to nil."
 486                   org-id-locations-file))))
 487     (setq org-id-files (mapcar 'car org-id-locations))
 488     (setq org-id-locations (org-id-alist-to-hash org-id-locations))))
 489
 490 (defun org-id-add-location (id file)
 491   "Add the ID with location FILE to the database of ID locations."
 492   ;; Only if global tracking is on, and when the buffer has a file
 493   (when (and org-id-track-globally id file)
 494     (unless org-id-locations (org-id-locations-load))
 495     (puthash id (abbreviate-file-name file) org-id-locations)
 496     (add-to-list 'org-id-files (abbreviate-file-name file))))
 497
 498 (add-hook 'kill-emacs-hook 'org-id-locations-save)
 499
 500 (defun org-id-hash-to-alist (hash)
 501   "Turn an org-id hash into an alist, so that it can be written to a file."
 502   (let (res x)
 503     (maphash
 504      (lambda (k v)
 505        (if (setq x (member v res))
 506            (setcdr x (cons k (cdr x)))
 507          (push (list v k) res)))
 508      hash)
 509     res))
 510
 511 (defun org-id-alist-to-hash (list)
 512   "Turn an org-id location list into a hash table."
 513   (let ((res (make-hash-table
 514               :test 'equal
 515               :size (apply '+ (mapcar 'length list))))
 516         f)
 517     (mapc
 518      (lambda (x)
 519        (setq f (car x))
 520        (mapc (lambda (i) (puthash i f res)) (cdr x)))
 521      list)
 522     res))
 523
 524 (defun org-id-paste-tracker (txt &optional buffer-or-file)
 525   "Update any IDs in TXT and assign BUFFER-OR-FILE to them."
 526   (when org-id-track-globally
 527     (save-match-data
 528       (setq buffer-or-file (or buffer-or-file (current-buffer)))
 529       (when (bufferp buffer-or-file)
 530         (setq buffer-or-file (or (buffer-base-buffer buffer-or-file)
 531                                  buffer-or-file))
 532         (setq buffer-or-file (buffer-file-name buffer-or-file)))
 533       (when buffer-or-file
 534         (let ((fname (abbreviate-file-name buffer-or-file))
 535               (s 0))
 536           (while (string-match "^[ \t]*:ID:[ \t]+\\([^ \t\n\r]+\\)" txt s)
 537             (setq s (match-end 0))
 538             (org-id-add-location (match-string 1 txt) fname)))))))
 539
 540 ;; Finding entries with specified id
 541
 542 ;;;###autoload
 543 (defun org-id-find-id-file (id)
 544   "Query the id database for the file in which this ID is located."
 545   (unless org-id-locations (org-id-locations-load))
 546   (or (gethash id org-id-locations)
 547       ;; ball back on current buffer
 548       (buffer-file-name (or (buffer-base-buffer (current-buffer))
 549                             (current-buffer)))))
 550
 551 (defun org-id-find-id-in-file (id file &optional markerp)
 552   "Return the position of the entry ID in FILE.
 553 If that files does not exist, or if it does not contain this ID,
 554 return nil.
 555 The position is returned as a cons cell (file-name . position).  With
 556 optional argument MARKERP, return the position as a new marker."
 557   (let (org-agenda-new-buffers buf pos)
 558     (cond
 559      ((not file) nil)
 560      ((not (file-exists-p file)) nil)
 561      (t (with-current-buffer (setq buf (org-get-agenda-file-buffer file))
 562           (setq pos (org-find-entry-with-id id))
 563           (when pos
 564             (if markerp
 565                 (move-marker (make-marker) pos buf)
 566               (cons file pos))))))))
 567
 568 ;; id link type
 569
 570 ;; Calling the following function is hard-coded into `org-store-link',
 571 ;; so we do have to add it to `org-store-link-functions'.
 572
 573 (defun org-id-store-link ()
 574   "Store a link to the current entry, using its ID."
 575   (interactive)
 576   (let* ((link (org-make-link "id:" (org-id-get-create)))
 577          (desc (save-excursion
 578                  (org-back-to-heading t)
 579                  (or (and (looking-at org-complex-heading-regexp)
 580                           (if (match-end 4) (match-string 4) (match-string 0)))
 581                      link))))
 582     (org-store-link-props :link link :description desc :type "id")
 583     link))
 584
 585 (defun org-id-open (id)
 586   "Go to the entry with id ID."
 587   (org-mark-ring-push)
 588   (let ((m (org-id-find id 'marker))
 589         cmd)
 590     (unless m
 591       (error "Cannot find entry with ID \"%s\"" id))
 592     ;; Use a buffer-switching command in analogy to finding files
 593     (setq cmd
 594           (or
 595            (cdr
 596             (assq
 597              (cdr (assq 'file org-link-frame-setup))
 598              '((find-file . switch-to-buffer)
 599                (find-file-other-window . switch-to-buffer-other-window)
 600                (find-file-other-frame . switch-to-buffer-other-frame))))
 601            'switch-to-buffer-other-window))
 602     (if (not (equal (current-buffer) (marker-buffer m)))
 603         (funcall cmd (marker-buffer m)))
 604     (goto-char m)
 605     (move-marker m nil)
 606     (org-show-context)))
 607
 608 (org-add-link-type "id" 'org-id-open)
 609
 610 (provide 'org-id)
 611
 612 ;;; org-id.el ends here
 613
 614 ;; arch-tag: e5abaca4-e16f-4b25-832a-540cfb63a712
 615
 616