lisp/org-clock.el

   1 ;;; org-clock.el --- The time clocking code for Org-mode
   2
   3 ;; Copyright (C) 2004, 2005, 2006, 2007, 2008, 2009
   4 ;;   Free Software Foundation, Inc.
   5
   6 ;; Author: Carsten Dominik <carsten at orgmode dot org>
   7 ;; Keywords: outlines, hypermedia, calendar, wp
   8 ;; Homepage: http://orgmode.org
   9 ;; Version: 6.33trans
  10 ;;
  11 ;; This file is part of GNU Emacs.
  12 ;;
  13 ;; GNU Emacs is free software: you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation, either version 3 of the License, or
  16 ;; (at your option) any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  26 ;;
  27 ;;; Commentary:
  28
  29 ;; This file contains the time clocking code for Org-mode
  30
  31 (require 'org)
  32 (eval-when-compile
  33   (require 'cl)
  34   (require 'calendar))
  35
  36 (declare-function calendar-absolute-from-iso    "cal-iso"    (&optional date))
  37 (defvar org-time-stamp-formats)
  38
  39 (defgroup org-clock nil
  40   "Options concerning clocking working time in Org-mode."
  41   :tag "Org Clock"
  42   :group 'org-progress)
  43
  44 (defcustom org-clock-into-drawer org-log-into-drawer
  45   "Should clocking info be wrapped into a drawer?
  46 When t, clocking info will always be inserted into a :LOGBOOK: drawer.
  47 If necessary, the drawer will be created.
  48 When nil, the drawer will not be created, but used when present.
  49 When an integer and the number of clocking entries in an item
  50 reaches or exceeds this number, a drawer will be created.
  51 When a string, it names the drawer to be used.
  52
  53 The default for this variable is the value of `org-log-into-drawer',
  54 which see."
  55   :group 'org-todo
  56   :group 'org-clock
  57   :type '(choice
  58           (const :tag "Always" t)
  59           (const :tag "Only when drawer exists" nil)
  60           (integer :tag "When at least N clock entries")
  61           (const :tag "Into LOGBOOK drawer" "LOGBOOK")
  62           (string :tag "Into Drawer named...")))
  63
  64 (defcustom org-clock-out-when-done t
  65   "When non-nil, clock will be stopped when the clocked entry is marked DONE.
  66 A nil value means, clock will keep running until stopped explicitly with
  67 `C-c C-x C-o', or until the clock is started in a different item."
  68   :group 'org-clock
  69   :type 'boolean)
  70
  71 (defcustom org-clock-out-remove-zero-time-clocks nil
  72   "Non-nil means, remove the clock line when the resulting time is zero."
  73   :group 'org-clock
  74   :type 'boolean)
  75
  76 (defcustom org-clock-in-switch-to-state nil
  77   "Set task to a special todo state while clocking it.
  78 The value should be the state to which the entry should be
  79 switched. If the value is a function, it must take one
  80 parameter (the current TODO state of the item) and return the
  81 state to switch it to."
  82   :group 'org-clock
  83   :group 'org-todo
  84   :type '(choice
  85           (const :tag "Don't force a state" nil)
  86           (string :tag "State")
  87           (symbol :tag "Function")))
  88
  89 (defcustom org-clock-out-switch-to-state nil
  90   "Set task to a special todo state after clocking out.
  91 The value should be the state to which the entry should be
  92 switched. If the value is a function, it must take one
  93 parameter (the current TODO state of the item) and return the
  94 state to switch it to."
  95   :group 'org-clock
  96   :group 'org-todo
  97   :type '(choice
  98           (const :tag "Don't force a state" nil)
  99           (string :tag "State")
 100           (symbol :tag "Function")))
 101
 102 (defcustom org-clock-history-length 5
 103   "Number of clock tasks to remember in history."
 104   :group 'org-clock
 105   :type 'integer)
 106
 107 (defcustom org-clock-goto-may-find-recent-task t
 108   "Non-nil means, `org-clock-goto' can go to recent task if no active clock."
 109   :group 'org-clock
 110   :type 'boolean)
 111
 112 (defcustom org-clock-heading-function nil
 113   "When non-nil, should be a function to create `org-clock-heading'.
 114 This is the string shown in the mode line when a clock is running.
 115 The function is called with point at the beginning of the headline."
 116   :group 'org-clock
 117   :type 'function)
 118
 119 (defcustom org-clock-string-limit 0
 120   "Maximum length of clock strings in the modeline. 0 means no limit."
 121   :group 'org-clock
 122   :type 'integer)
 123
 124 (defcustom org-clock-in-resume nil
 125   "If non-nil, resume clock when clocking into task with open clock.
 126 When clocking into a task with a clock entry which has not been closed,
 127 the clock can be resumed from that point."
 128   :group 'org-clock
 129   :type 'boolean)
 130
 131 (defcustom org-clock-persist nil
 132   "When non-nil, save the running clock when emacs is closed.
 133 The clock is resumed when emacs restarts.
 134 When this is t, both the running clock, and the entire clock
 135 history are saved.  When this is the symbol `clock', only the
 136 running clock is saved.
 137
 138 When Emacs restarts with saved clock information, the file containing the
 139 running clock as well as all files mentioned in the clock history will
 140 be visited.
 141 All this depends on running `org-clock-persistence-insinuate' in .emacs"
 142   :group 'org-clock
 143   :type '(choice
 144           (const :tag "Just the running clock" clock)
 145           (const :tag "Just the history" history)
 146           (const :tag "Clock and history" t)
 147           (const :tag "No persistence" nil)))
 148
 149 (defcustom org-clock-persist-file (convert-standard-filename
 150                                    "~/.emacs.d/org-clock-save.el")
 151   "File to save clock data to."
 152   :group 'org-clock
 153   :type 'string)
 154
 155 (defcustom org-clock-persist-query-save nil
 156   "When non-nil, ask before saving the current clock on exit."
 157   :group 'org-clock
 158   :type 'boolean)
 159
 160 (defcustom org-clock-persist-query-resume t
 161   "When non-nil, ask before resuming any stored clock during load."
 162   :group 'org-clock
 163   :type 'boolean)
 164
 165 (defcustom org-clock-sound nil
 166   "Sound that will used for notifications.
 167 Possible values:
 168
 169 nil        no sound played.
 170 t          standard Emacs beep
 171 file name  play this sound file.  If not possible, fall back to beep"
 172   :group 'org-clock
 173   :type '(choice
 174           (const :tag "No sound" nil)
 175           (const :tag "Standard beep" t)
 176           (file :tag "Play sound file")))
 177
 178 (defcustom org-clock-modeline-total 'auto
 179   "Default setting for the time included for the modeline clock.
 180 This can be overruled locally using the CLOCK_MODELINE_TOTAL property.
 181 Allowed values are:
 182
 183 current  Only the time in the current instance of the clock
 184 today    All time clocked into this task today
 185 repeat   All time clocked into this task since last repeat
 186 all      All time ever recorded for this task
 187 auto     Automatically, either `all', or `repeat' for repeating tasks"
 188   :group 'org-clock
 189   :type '(choice
 190           (const :tag "Current clock" current)
 191           (const :tag "Today's task time" today)
 192           (const :tag "Since last repeat" repeat)
 193           (const :tag "All task time" all)
 194           (const :tag "Automatically, `all' or since `repeat'" auto)))
 195
 196 (defcustom org-show-notification-handler nil
 197   "Function or program to send notification with.
 198 The function or program will be called with the notification
 199 string as argument."
 200   :group 'org-clock
 201   :type '(choice
 202           (string :tag "Program")
 203           (function :tag "Function")))
 204
 205 (defcustom org-clock-clocktable-default-properties '(:maxlevel 2 :scope file)
 206   "Default properties for new clocktables."
 207   :group 'org-clock
 208   :type 'plist)
 209
 210 (defcustom org-clock-idle-time nil
 211   "When non-nil, resolve open clocks if the user is idle more than X minutes."
 212   :group 'org-clock
 213   :type '(choice
 214           (const :tag "Never" nil)
 215           (integer :tag "After N minutes")))
 216
 217 (defcustom org-clock-auto-clock-resolution 'when-no-clock-is-running
 218   "When to automatically resolve open clocks found in Org buffers."
 219   :group 'org-clock
 220   :type '(choice
 221           (const :tag "Never" nil)
 222           (const :tag "Always" t)
 223           (const :tag "When no clock is running" when-no-clock-is-running)))
 224
 225 (defvar org-clock-in-prepare-hook nil
 226   "Hook run when preparing the clock.
 227 This hook is run before anything happens to the task that
 228 you want to clock in.  For example, you can use this hook
 229 to add an effort property.")
 230 (defvar org-clock-in-hook nil
 231   "Hook run when starting the clock.")
 232 (defvar org-clock-out-hook nil
 233   "Hook run when stopping the current clock.")
 234
 235 (defvar org-clock-cancel-hook nil
 236   "Hook run when cancelling the current clock.")
 237 (defvar org-clock-goto-hook nil
 238   "Hook run when selecting the currently clocked-in entry.")
 239 (defvar org-clock-has-been-used nil
 240   "Has the clock been used during the current Emacs session?")
 241
 242 ;;; The clock for measuring work time.
 243
 244 (defvar org-mode-line-string "")
 245 (put 'org-mode-line-string 'risky-local-variable t)
 246
 247 (defvar org-clock-mode-line-timer nil)
 248 (defvar org-clock-idle-timer nil)
 249 (defvar org-clock-heading) ; defined in org.el
 250 (defvar org-clock-heading-for-remember "")
 251 (defvar org-clock-start-time "")
 252
 253 (defvar org-clock-left-over-time nil
 254   "If non-nil, user cancelled a clock; this is when leftover time started.")
 255
 256 (defvar org-clock-effort ""
 257   "Effort estimate of the currently clocking task")
 258
 259 (defvar org-clock-total-time nil
 260   "Holds total time, spent previously on currently clocked item.
 261 This does not include the time in the currently running clock.")
 262
 263 (defvar org-clock-history nil
 264   "List of marker pointing to recent clocked tasks.")
 265
 266 (defvar org-clock-default-task (make-marker)
 267   "Marker pointing to the default task that should clock time.
 268 The clock can be made to switch to this task after clocking out
 269 of a different task.")
 270
 271 (defvar org-clock-interrupted-task (make-marker)
 272   "Marker pointing to the task that has been interrupted by the current clock.")
 273
 274 (defvar org-clock-mode-line-map (make-sparse-keymap))
 275 (define-key org-clock-mode-line-map [mode-line mouse-2] 'org-clock-goto)
 276 (define-key org-clock-mode-line-map [mode-line mouse-1] 'org-clock-menu)
 277
 278 (defun org-clock-menu ()
 279   (interactive)
 280   (popup-menu
 281    '("Clock"
 282      ["Clock out" org-clock-out t]
 283      ["Change effort estimate" org-clock-modify-effort-estimate t]
 284      ["Go to clock entry" org-clock-goto t]
 285      ["Switch task" (lambda () (interactive) (org-clock-in '(4))) :active t :keys "C-u C-c C-x C-i"])))
 286
 287 (defun org-clock-history-push (&optional pos buffer)
 288   "Push a marker to the clock history."
 289   (setq org-clock-history-length (max 1 (min 35 org-clock-history-length)))
 290   (let ((m (move-marker (make-marker) (or pos (point)) buffer)) n l)
 291     (while (setq n (member m org-clock-history))
 292       (move-marker (car n) nil))
 293     (setq org-clock-history
 294           (delq nil
 295                 (mapcar (lambda (x) (if (marker-buffer x) x nil))
 296                         org-clock-history)))
 297     (when (>= (setq l (length org-clock-history)) org-clock-history-length)
 298       (setq org-clock-history
 299             (nreverse
 300              (nthcdr (- l org-clock-history-length -1)
 301                      (nreverse org-clock-history)))))
 302     (push m org-clock-history)))
 303
 304 (defun org-clock-save-markers-for-cut-and-paste (beg end)
 305   "Save relative positions of markers in region."
 306   (org-check-and-save-marker org-clock-marker beg end)
 307   (org-check-and-save-marker org-clock-hd-marker beg end)
 308   (org-check-and-save-marker org-clock-default-task beg end)
 309   (org-check-and-save-marker org-clock-interrupted-task beg end)
 310   (mapc (lambda (m) (org-check-and-save-marker m beg end))
 311         org-clock-history))
 312
 313 (defun org-clock-select-task (&optional prompt)
 314   "Select a task that recently was associated with clocking."
 315   (interactive)
 316   (let (sel-list rpl (i 0) s)
 317     (save-window-excursion
 318       (org-switch-to-buffer-other-window
 319        (get-buffer-create "*Clock Task Select*"))
 320       (erase-buffer)
 321       (when (marker-buffer org-clock-default-task)
 322         (insert (org-add-props "Default Task\n" nil 'face 'bold))
 323         (setq s (org-clock-insert-selection-line ?d org-clock-default-task))
 324         (push s sel-list))
 325       (when (marker-buffer org-clock-interrupted-task)
 326         (insert (org-add-props "The task interrupted by starting the last one\n" nil 'face 'bold))
 327         (setq s (org-clock-insert-selection-line ?i org-clock-interrupted-task))
 328         (push s sel-list))
 329       (when (marker-buffer org-clock-marker)
 330         (insert (org-add-props "Current Clocking Task\n" nil 'face 'bold))
 331         (setq s (org-clock-insert-selection-line ?c org-clock-marker))
 332         (push s sel-list))
 333       (insert (org-add-props "Recent Tasks\n" nil 'face 'bold))
 334       (mapc
 335        (lambda (m)
 336          (when (marker-buffer m)
 337            (setq i (1+ i)
 338                  s (org-clock-insert-selection-line
 339                     (if (< i 10)
 340                         (+ i ?0)
 341                       (+ i (- ?A 10))) m))
 342            (if (fboundp 'int-to-char) (setf (car s) (int-to-char (car s))))
 343            (push s sel-list)))
 344        org-clock-history)
 345       (org-fit-window-to-buffer)
 346       (message (or prompt "Select task for clocking:"))
 347       (setq rpl (read-char-exclusive))
 348       (cond
 349        ((eq rpl ?q) nil)
 350        ((eq rpl ?x) nil)
 351        ((assoc rpl sel-list) (cdr (assoc rpl sel-list)))
 352        (t (error "Invalid task choice %c" rpl))))))
 353
 354 (defun org-clock-insert-selection-line (i marker)
 355   "Insert a line for the clock selection menu.
 356 And return a cons cell with the selection character integer and the marker
 357 pointing to it."
 358   (when (marker-buffer marker)
 359     (let (file cat task heading prefix)
 360       (with-current-buffer (org-base-buffer (marker-buffer marker))
 361         (save-excursion
 362           (save-restriction
 363             (widen)
 364             (ignore-errors
 365               (goto-char marker)
 366               (setq file (buffer-file-name (marker-buffer marker))
 367                     cat (or (org-get-category)
 368                             (progn (org-refresh-category-properties)
 369                                    (org-get-category)))
 370                     heading (org-get-heading 'notags)
 371                     prefix (save-excursion
 372                              (org-back-to-heading t)
 373                              (looking-at "\\*+ ")
 374                              (match-string 0))
 375                     task (substring
 376                           (org-fontify-like-in-org-mode
 377                            (concat prefix heading)
 378                            org-odd-levels-only)
 379                           (length prefix)))))))
 380       (when (and cat task)
 381         (insert (format "[%c] %-15s %s\n" i cat task))
 382         (cons i marker)))))
 383
 384 (defun org-clock-get-clock-string ()
 385   "Form a clock-string, that will be show in the mode line.
 386 If an effort estimate was defined for current item, use
 387 01:30/01:50 format (clocked/estimated).
 388 If not, show simply the clocked time like 01:50."
 389   (let* ((clocked-time (org-clock-get-clocked-time))
 390          (h (floor clocked-time 60))
 391          (m (- clocked-time (* 60 h))))
 392     (if (and org-clock-effort)
 393         (let* ((effort-in-minutes (org-hh:mm-string-to-minutes org-clock-effort))
 394                (effort-h (floor effort-in-minutes 60))
 395                (effort-m (- effort-in-minutes (* effort-h 60))))
 396           (format (concat "-[" org-time-clocksum-format "/" org-time-clocksum-format " (%s)]")
 397                   h m effort-h effort-m  org-clock-heading))
 398       (format (concat "-[" org-time-clocksum-format " (%s)]")
 399               h m org-clock-heading))))
 400
 401 (defun org-clock-update-mode-line ()
 402   (setq org-mode-line-string
 403         (org-propertize
 404          (let ((clock-string (org-clock-get-clock-string))
 405                (help-text "Org-mode clock is running.\nmouse-1 shows a menu\nmouse-2 will jump to task"))
 406            (if (and (> org-clock-string-limit 0)
 407                     (> (length clock-string) org-clock-string-limit))
 408                (org-propertize (substring clock-string 0 org-clock-string-limit)
 409                                'help-echo (concat help-text ": " org-clock-heading))
 410              (org-propertize clock-string 'help-echo help-text)))
 411          'local-map org-clock-mode-line-map
 412          'mouse-face (if (featurep 'xemacs) 'highlight 'mode-line-highlight)
 413          'face 'org-mode-line-clock))
 414   (if org-clock-effort (org-clock-notify-once-if-expired))
 415   (force-mode-line-update))
 416
 417 (defun org-clock-get-clocked-time ()
 418   "Get the clocked time for the current item in minutes.
 419 The time returned includes the time spent on this task in
 420 previous clocking intervals."
 421   (let ((currently-clocked-time
 422          (floor (- (org-float-time)
 423                    (org-float-time org-clock-start-time)) 60)))
 424     (+ currently-clocked-time (or org-clock-total-time 0))))
 425
 426 (defun org-clock-modify-effort-estimate (&optional value)
 427  "Add to or set the effort estimate of the item currently being clocked.
 428 VALUE can be a number of minutes, or a string with format hh:mm or mm.
 429 When the string starts with a + or a - sign, the current value of the effort
 430 property will be changed by that amount.
 431 This will update the \"Effort\" property of currently clocked item, and
 432 the mode line."
 433  (interactive)
 434  (when (org-clock-is-active)
 435    (let ((current org-clock-effort) sign)
 436      (unless value
 437        ;; Prompt user for a value or a change
 438        (setq value
 439              (read-string
 440               (format "Set effort (hh:mm or mm%s): "
 441                       (if current
 442                           (format ", prefix + to add to %s" org-clock-effort)
 443                         "")))))
 444      (when (stringp value)
 445        ;; A string.  See if it is a delta
 446        (setq sign (string-to-char value))
 447        (if (member sign '(?- ?+))
 448            (setq current (org-hh:mm-string-to-minutes (substring current 1)))
 449          (setq current 0))
 450        (setq value (org-hh:mm-string-to-minutes value))
 451        (if (equal ?- sign)
 452            (setq value (- current value))
 453          (if (equal ?+ sign) (setq value (+ current value)))))
 454      (setq value (max 0 value)
 455            org-clock-effort (org-minutes-to-hh:mm-string value))
 456      (org-entry-put org-clock-marker "Effort" org-clock-effort)
 457      (org-clock-update-mode-line)
 458      (message "Effort is now %s" org-clock-effort))))
 459
 460 (defvar org-clock-notification-was-shown nil
 461   "Shows if we have shown notification already.")
 462
 463 (defun org-clock-notify-once-if-expired ()
 464   "Show notification if we spent more time than we estimated before.
 465 Notification is shown only once."
 466   (when (marker-buffer org-clock-marker)
 467     (let ((effort-in-minutes (org-hh:mm-string-to-minutes org-clock-effort))
 468           (clocked-time (org-clock-get-clocked-time)))
 469       (if (>= clocked-time effort-in-minutes)
 470           (unless org-clock-notification-was-shown
 471             (setq org-clock-notification-was-shown t)
 472             (org-notify
 473              (format "Task '%s' should be finished by now. (%s)"
 474                      org-clock-heading org-clock-effort) t))
 475         (setq org-clock-notification-was-shown nil)))))
 476
 477 (defun org-notify (notification &optional play-sound)
 478   "Send a NOTIFICATION and maybe PLAY-SOUND."
 479   (org-show-notification notification)
 480   (if play-sound (org-clock-play-sound)))
 481
 482 (defun org-show-notification (notification)
 483   "Show notification.
 484 Use `org-show-notification-handler' if defined,
 485 use libnotify if available, or fall back on a message."
 486   (cond ((functionp org-show-notification-handler)
 487          (funcall org-show-notification-handler notification))
 488         ((stringp org-show-notification-handler)
 489          (start-process "emacs-timer-notification" nil
 490                         org-show-notification-handler notification))
 491         ((org-program-exists "notify-send")
 492          (start-process "emacs-timer-notification" nil
 493                         "notify-send" notification))
 494         ;; Maybe the handler will send a message, so only use message as
 495         ;; a fall back option
 496         (t (message "%s" notification))))
 497
 498 (defun org-clock-play-sound ()
 499   "Play sound as configured by `org-clock-sound'.
 500 Use alsa's aplay tool if available."
 501   (cond
 502    ((not org-clock-sound))
 503    ((eq org-clock-sound t) (beep t) (beep t))
 504    ((stringp org-clock-sound)
 505     (let ((file (expand-file-name org-clock-sound)))
 506       (if (file-exists-p file)
 507           (if (org-program-exists "aplay")
 508               (start-process "org-clock-play-notification" nil
 509                              "aplay" file)
 510             (condition-case nil
 511                 (play-sound-file file)
 512               (error (beep t) (beep t)))))))))
 513
 514 (defun org-program-exists (program-name)
 515   "Checks whenever we can locate program and launch it."
 516   (if (eq system-type 'gnu/linux)
 517       (= 0 (call-process "which" nil nil nil program-name))))
 518
 519 (defvar org-clock-mode-line-entry nil
 520   "Information for the modeline about the running clock.")
 521
 522 (defun org-find-open-clocks (file)
 523   "Search through the given file and find all open clocks."
 524   (let ((buf (or (get-file-buffer file)
 525                  (find-file-noselect file)))
 526         clocks)
 527     (with-current-buffer buf
 528       (save-excursion
 529         (goto-char (point-min))
 530         (while (re-search-forward "CLOCK: \\(\\[.*?\\]\\)$" nil t)
 531           (push (cons (copy-marker (1- (match-end 1)) t)
 532                       (org-time-string-to-time (match-string 1))) clocks))))
 533     clocks))
 534
 535 (defsubst org-is-active-clock (clock)
 536   "Return t if CLOCK is the currently active clock."
 537   (and (org-clock-is-active)
 538        (= org-clock-marker (car clock))))
 539
 540 (defmacro org-with-clock-position (clock &rest forms)
 541   "Evaluate FORMS with CLOCK as the current active clock."
 542   `(with-current-buffer (marker-buffer (car ,clock))
 543      (save-excursion
 544        (save-restriction
 545          (widen)
 546          (goto-char (car ,clock))
 547          (beginning-of-line)
 548          ,@forms))))
 549
 550 (put 'org-with-clock-position 'lisp-indent-function 1)
 551
 552 (defmacro org-with-clock (clock &rest forms)
 553   "Evaluate FORMS with CLOCK as the current active clock.
 554 This macro also protects the current active clock from being altered."
 555   `(org-with-clock-position ,clock
 556      (let ((org-clock-start-time (cdr ,clock))
 557            (org-clock-total-time)
 558            (org-clock-history)
 559            (org-clock-effort)
 560            (org-clock-marker (car ,clock))
 561            (org-clock-hd-marker (save-excursion
 562                                   (outline-back-to-heading t)
 563                                   (point-marker))))
 564        ,@forms)))
 565
 566 (put 'org-with-clock 'lisp-indent-function 1)
 567
 568 (defsubst org-clock-clock-in (clock &optional resume)
 569   "Clock in to the clock located by CLOCK.
 570 If necessary, clock-out of the currently active clock."
 571   (org-with-clock-position clock
 572     (let ((org-clock-in-resume (or resume org-clock-in-resume)))
 573       (org-clock-in))))
 574
 575 (defsubst org-clock-clock-out (clock &optional fail-quietly at-time)
 576   "Clock out of the clock located by CLOCK."
 577   (let ((temp (copy-marker (car clock)
 578                            (marker-insertion-type (car clock)))))
 579     (if (org-is-active-clock clock)
 580         (org-clock-out fail-quietly at-time)
 581       (org-with-clock clock
 582         (org-clock-out fail-quietly at-time)))
 583     (setcar clock temp)))
 584
 585 (defsubst org-clock-clock-cancel (clock)
 586   "Cancel the clock located by CLOCK."
 587   (let ((temp (copy-marker (car clock)
 588                            (marker-insertion-type (car clock)))))
 589     (if (org-is-active-clock clock)
 590         (org-clock-cancel)
 591       (org-with-clock clock
 592         (org-clock-cancel)))
 593     (setcar clock temp)))
 594
 595 (defvar org-clock-clocking-in nil)
 596 (defvar org-clock-resolving-clocks nil)
 597 (defvar org-clock-resolving-clocks-due-to-idleness nil)
 598
 599 (defun org-clock-resolve-clock (clock resolve-to &optional close-p
 600                                       restart-p fail-quietly)
 601   "Resolve `CLOCK' given the time `RESOLVE-TO', and the present.
 602 `CLOCK' is a cons cell of the form (MARKER START-TIME).
 603 This routine can do one of many things:
 604
 605   if `RESOLVE-TO' is nil
 606     if `CLOSE-P' is non-nil, give an error
 607     if this clock is the active clock, cancel it
 608     else delete the clock line (as if it never happened)
 609     if `RESTART-P' is non-nil, start a new clock
 610
 611   else if `RESOLVE-TO' is the symbol `now'
 612     if `RESTART-P' is non-nil, give an error
 613     if `CLOSE-P' is non-nil, clock out the entry and
 614        if this clock is the active clock, stop it
 615     else if this clock is the active clock, do nothing
 616     else if there is no active clock, resume this clock
 617     else ask to cancel the active clock, and if so,
 618          resume this clock after cancelling it
 619
 620   else if `RESOLVE-TO' is some date in the future
 621     give an error about `RESOLVE-TO' being invalid
 622
 623   else if `RESOLVE-TO' is some date in the past
 624     if `RESTART-P' is non-nil, give an error
 625     if `CLOSE-P' is non-nil, enter a closing time and
 626        if this clock is the active clock, stop it
 627     else if this clock is the active clock, enter a
 628        closing time, stop the current clock, then
 629        start a new clock for the same item
 630     else just enter a closing time for this clock
 631        and then start a new clock for the same item"
 632   (let ((org-clock-resolving-clocks t))
 633     (cond
 634      ((null resolve-to)
 635       (org-clock-clock-cancel clock)
 636       (if (and restart-p (not org-clock-clocking-in))
 637           (org-clock-clock-in clock)))
 638
 639      ((eq resolve-to 'now)
 640       (if restart-p
 641           (error "RESTART-P is not valid here"))
 642       (if (or close-p org-clock-clocking-in)
 643           (org-clock-clock-out clock fail-quietly)
 644         (unless (org-is-active-clock clock)
 645           (org-clock-clock-in clock t))))
 646
 647      ((not (time-less-p resolve-to (current-time)))
 648       (error "RESOLVE-TO must refer to a time in the past"))
 649
 650      (t
 651       (if restart-p
 652           (error "RESTART-P is not valid here"))
 653       (org-clock-clock-out clock fail-quietly resolve-to)
 654       (unless org-clock-clocking-in
 655         (if close-p
 656             (setq org-clock-left-over-time resolve-to)
 657           (org-clock-clock-in clock)))))))
 658
 659 (defun org-clock-resolve (clock &optional prompt-fn last-valid fail-quietly)
 660   "Resolve an open org-mode clock.
 661 An open clock was found, with `dangling' possibly being non-nil.
 662 If this function was invoked with a prefix argument, non-dangling
 663 open clocks are ignored.  The given clock requires some sort of
 664 user intervention to resolve it, either because a clock was left
 665 dangling or due to an idle timeout.  The clock resolution can
 666 either be:
 667
 668   (a) deleted, the user doesn't care about the clock
 669   (b) restarted from the current time (if no other clock is open)
 670   (c) closed, giving the clock X minutes
 671   (d) closed and then restarted
 672   (e) resumed, as if the user had never left
 673
 674 The format of clock is (CONS MARKER START-TIME), where MARKER
 675 identifies the buffer and position the clock is open at (and
 676 thus, the heading it's under), and START-TIME is when the clock
 677 was started."
 678   (assert clock)
 679   (let* ((ch
 680           (save-window-excursion
 681             (save-excursion
 682               (unless org-clock-resolving-clocks-due-to-idleness
 683                 (org-with-clock clock (org-clock-goto))
 684                 (with-current-buffer (marker-buffer (car clock))
 685                   (goto-char (car clock))
 686                   (if org-clock-into-drawer
 687                       (let ((logbook
 688                              (if (stringp org-clock-into-drawer)
 689                                  (concat ":" org-clock-into-drawer ":")
 690                                ":LOGBOOK:")))
 691                         (ignore-errors
 692                           (outline-flag-region
 693                            (save-excursion
 694                              (outline-back-to-heading t)
 695                              (search-forward logbook)
 696                              (goto-char (match-beginning 0)))
 697                            (save-excursion
 698                              (outline-back-to-heading t)
 699                              (search-forward logbook)
 700                              (search-forward ":END:")
 701                              (goto-char (match-end 0)))
 702                            nil))))))
 703               (let (char-pressed)
 704                 (if (featurep 'xemacs)
 705                     (progn
 706                       (message (concat (funcall prompt-fn clock)
 707                                        " [(kK)eep (sS)ubtract (C)ancel]? "))
 708                       (setq char-pressed (read-char-exclusive)))
 709                 (while (or (null char-pressed)
 710                            (and (not (memq char-pressed '(?k ?K ?s ?S ?C ?i)))
 711                                 (or (ding) t)))
 712                   (setq char-pressed
 713                         (read-char (concat (funcall prompt-fn clock)
 714                                            " [(kK)p (sS)ub (C)ncl (i)gn]? ")
 715                                    nil 45)))
 716                 (and (not (eq char-pressed ?i)) char-pressed))))))
 717          (default (floor (/ (org-float-time
 718                              (time-subtract (current-time) last-valid)) 60)))
 719          (keep (and (memq ch '(?k ?K))
 720                     (read-number "Keep how many minutes? " default)))
 721          (subtractp (memq ch '(?s ?S)))
 722          (barely-started-p (< (- (org-float-time last-valid)
 723                                  (org-float-time (cdr clock))) 45))
 724          (start-over (and subtractp barely-started-p)))
 725     (if (or (null ch)
 726             (not (memq ch '(?k ?K ?s ?S ?C))))
 727         (message "")
 728       (org-clock-resolve-clock
 729        clock (cond
 730               ((or (eq ch ?C)
 731                    ;; If the time on the clock was less than a minute before
 732                    ;; the user went away, and they've ask to subtract all the
 733                    ;; time...
 734                    start-over)
 735                nil)
 736               (subtractp
 737                last-valid)
 738               ((= keep default)
 739                'now)
 740               (t
 741                (time-add last-valid (seconds-to-time (* 60 keep)))))
 742        (memq ch '(?K ?S))
 743        (and start-over
 744             (not (memq ch '(?K ?S ?C))))
 745        fail-quietly))))
 746
 747 (defun org-resolve-clocks (&optional also-non-dangling-p prompt-fn last-valid)
 748   "Resolve all currently open org-mode clocks.
 749 If `also-non-dangling-p' is non-nil, also ask to resolve
 750 non-dangling (i.e., currently open and valid) clocks."
 751   (interactive "P")
 752   (unless org-clock-resolving-clocks
 753     (let ((org-clock-resolving-clocks t))
 754       (dolist (file (org-files-list))
 755         (let ((clocks (org-find-open-clocks file)))
 756           (dolist (clock clocks)
 757             (let ((dangling (or (not (org-clock-is-active))
 758                                 (/= (car clock) org-clock-marker))))
 759               (unless (and (not dangling) (not also-non-dangling-p))
 760                 (org-clock-resolve
 761                  clock
 762                  (or prompt-fn
 763                      (function
 764                       (lambda (clock)
 765                         (format
 766                          "Dangling clock started %d mins ago"
 767                          (floor
 768                           (/ (- (org-float-time (current-time))
 769                                 (org-float-time (cdr clock))) 60))))))
 770                  (or last-valid
 771                      (cdr clock)))))))))))
 772
 773 (defun org-emacs-idle-seconds ()
 774   "Return the current Emacs idle time in seconds, or nil if not idle."
 775   (let ((idle-time (current-idle-time)))
 776     (if idle-time
 777         (org-float-time idle-time)
 778       0)))
 779
 780 (defun org-mac-idle-seconds ()
 781   "Return the current Mac idle time in seconds"
 782   (string-to-number (shell-command-to-string "ioreg -c IOHIDSystem | perl -ane 'if (/Idle/) {$idle=(pop @F)/1000000000; print $idle; last}'")))
 783
 784 (defun org-x11-idle-seconds ()
 785   "Return the current X11 idle time in seconds"
 786   (/ (string-to-number (shell-command-to-string "x11idle")) 1000))
 787
 788 (defun org-user-idle-seconds ()
 789   "Return the number of seconds the user has been idle for.
 790 This routine returns a floating point number."
 791   (cond
 792    ((eq system-type 'darwin)
 793     (org-mac-idle-seconds))
 794    ((eq window-system 'x)
 795     (org-x11-idle-seconds))
 796    (t
 797     (org-emacs-idle-seconds))))
 798
 799 (defvar org-clock-user-idle-seconds)
 800
 801 (defun org-resolve-clocks-if-idle ()
 802   "Resolve all currently open org-mode clocks.
 803 This is performed after `org-clock-idle-time' minutes, to check
 804 if the user really wants to stay clocked in after being idle for
 805 so long."
 806   (when (and org-clock-idle-time (not org-clock-resolving-clocks)
 807              org-clock-marker)
 808     (let* ((org-clock-user-idle-seconds (org-user-idle-seconds))
 809            (org-clock-user-idle-start
 810             (time-subtract (current-time)
 811                            (seconds-to-time org-clock-user-idle-seconds)))
 812            (org-clock-resolving-clocks-due-to-idleness t))
 813       (if (> org-clock-user-idle-seconds (* 60 org-clock-idle-time))
 814           (org-clock-resolve
 815            (cons org-clock-marker
 816                  org-clock-start-time)
 817            (function
 818             (lambda (clock)
 819               (format "Clocked in & idle for %.1f mins"
 820                       (/ (org-float-time
 821                           (time-subtract (current-time)
 822                                          org-clock-user-idle-start))
 823                          60.0))))
 824            org-clock-user-idle-start)))))
 825
 826 (defun org-clock-in (&optional select)
 827   "Start the clock on the current item.
 828 If necessary, clock-out of the currently active clock.
 829 With prefix arg SELECT, offer a list of recently clocked tasks to
 830 clock into.  When SELECT is `C-u C-u', clock into the current task and mark
 831 is as the default task, a special task that will always be offered in
 832 the clocking selection, associated with the letter `d'."
 833   (interactive "P")
 834   (setq org-clock-notification-was-shown nil)
 835   (catch 'abort
 836     (let ((interrupting (and (not org-clock-resolving-clocks-due-to-idleness)
 837                              (marker-buffer org-clock-marker)))
 838           ts selected-task target-pos (msg-extra "")
 839           (left-over (and (not org-clock-resolving-clocks)
 840                           org-clock-left-over-time)))
 841       (when (and org-clock-auto-clock-resolution
 842                  (or (not interrupting)
 843                      (eq t org-clock-auto-clock-resolution))
 844                  (not org-clock-clocking-in)
 845                  (not org-clock-resolving-clocks))
 846         (setq org-clock-left-over-time nil)
 847         (let ((org-clock-clocking-in t))
 848           (org-resolve-clocks)))        ; check if any clocks are dangling
 849       (when (equal select '(4))
 850         (setq selected-task (org-clock-select-task "Clock-in on task: "))
 851         (if selected-task
 852             (setq selected-task (copy-marker selected-task))
 853           (error "Abort")))
 854       (when interrupting
 855         ;; We are interrupting the clocking of a different task.
 856         ;; Save a marker to this task, so that we can go back.
 857         (move-marker org-clock-interrupted-task
 858                      (marker-position org-clock-marker)
 859                      (marker-buffer org-clock-marker))
 860         (org-clock-out t))
 861
 862       (when (equal select '(16))
 863         ;; Mark as default clocking task
 864         (org-clock-mark-default-task))
 865
 866       ;; Clock in at which position?
 867       (setq target-pos
 868             (if (and (eobp) (not (org-on-heading-p)))
 869                 (point-at-bol 0)
 870               (point)))
 871       (run-hooks 'org-clock-in-prepare-hook)
 872       (save-excursion
 873         (when (and selected-task (marker-buffer selected-task))
 874           ;; There is a selected task, move to the correct buffer
 875           ;; and set the new target position.
 876           (set-buffer (org-base-buffer (marker-buffer selected-task)))
 877           (setq target-pos (marker-position selected-task))
 878           (move-marker selected-task nil))
 879         (save-excursion
 880           (save-restriction
 881             (widen)
 882             (goto-char target-pos)
 883             (org-back-to-heading t)
 884             (or interrupting (move-marker org-clock-interrupted-task nil))
 885             (org-clock-history-push)
 886             (cond ((functionp org-clock-in-switch-to-state)
 887                    (looking-at org-complex-heading-regexp)
 888                    (let ((newstate (funcall org-clock-in-switch-to-state
 889                                             (match-string 2))))
 890                      (if newstate (org-todo newstate))))
 891                   ((and org-clock-in-switch-to-state
 892                         (not (looking-at (concat outline-regexp "[ \t]*"
 893                                                  org-clock-in-switch-to-state
 894                                                  "\\>"))))
 895                    (org-todo org-clock-in-switch-to-state)))
 896             (setq org-clock-heading-for-remember
 897                   (and (looking-at org-complex-heading-regexp)
 898                        (match-end 4)
 899                        (org-trim (buffer-substring (match-end 1)
 900                                                    (match-end 4)))))
 901             (setq org-clock-heading
 902                   (cond ((and org-clock-heading-function
 903                               (functionp org-clock-heading-function))
 904                          (funcall org-clock-heading-function))
 905                         ((looking-at org-complex-heading-regexp)
 906                          (match-string 4))
 907                         (t "???")))
 908             (setq org-clock-heading (org-propertize org-clock-heading
 909                                                     'face nil))
 910             (org-clock-find-position org-clock-in-resume)
 911             (cond
 912              ((and org-clock-in-resume
 913                    (looking-at
 914                     (concat "^[ \t]* " org-clock-string
 915                             " \\[\\([0-9]\\{4\\}-[0-9]\\{2\\}-[0-9]\\{2\\}"
 916                             " +\\sw+\.? +[012][0-9]:[0-5][0-9]\\)\\][ \t]*$")))
 917               (message "Matched %s" (match-string 1))
 918               (setq ts (concat "[" (match-string 1) "]"))
 919               (goto-char (match-end 1))
 920               (setq org-clock-start-time
 921                     (apply 'encode-time
 922                            (org-parse-time-string (match-string 1))))
 923               (setq org-clock-effort (org-get-effort))
 924               (setq org-clock-total-time (org-clock-sum-current-item
 925                                           (org-clock-get-sum-start))))
 926              ((eq org-clock-in-resume 'auto-restart)
 927               ;; called from org-clock-load during startup,
 928               ;; do not interrupt, but warn!
 929               (message "Cannot restart clock because task does not contain unfinished clock")
 930               (ding)
 931               (sit-for 2)
 932               (throw 'abort nil))
 933              (t
 934               (insert-before-markers "\n")
 935               (backward-char 1)
 936               (org-indent-line-function)
 937               (when (and (save-excursion
 938                            (end-of-line 0)
 939                            (org-in-item-p)))
 940                 (beginning-of-line 1)
 941                 (org-indent-line-to (- (org-get-indentation) 2)))
 942               (insert org-clock-string " ")
 943               (setq org-clock-effort (org-get-effort))
 944               (setq org-clock-total-time (org-clock-sum-current-item
 945                                           (org-clock-get-sum-start)))
 946               (setq org-clock-start-time
 947                     (or (and left-over
 948                              (y-or-n-p
 949                               (format
 950                                "You stopped another clock %d mins ago; start this one from then? "
 951                                (/ (- (org-float-time (current-time))
 952                                      (org-float-time left-over)) 60)))
 953                              left-over)
 954                         (current-time)))
 955               (setq ts (org-insert-time-stamp org-clock-start-time
 956                                               'with-hm 'inactive))))
 957             (move-marker org-clock-marker (point) (buffer-base-buffer))
 958             (move-marker org-clock-hd-marker
 959                          (save-excursion (org-back-to-heading t) (point))
 960                          (buffer-base-buffer))
 961             (setq org-clock-has-been-used t)
 962             (or global-mode-string (setq global-mode-string '("")))
 963             (or (memq 'org-mode-line-string global-mode-string)
 964                 (setq global-mode-string
 965                       (append global-mode-string '(org-mode-line-string))))
 966             (org-clock-update-mode-line)
 967             (when org-clock-mode-line-timer
 968               (cancel-timer org-clock-mode-line-timer)
 969               (setq org-clock-mode-line-timer nil))
 970             (setq org-clock-mode-line-timer
 971                   (run-with-timer 60 60 'org-clock-update-mode-line))
 972             (when org-clock-idle-timer
 973               (cancel-timer org-clock-idle-timer)
 974               (setq org-clock-idle-timer nil))
 975             (setq org-clock-idle-timer
 976                   (run-with-timer 60 60 'org-resolve-clocks-if-idle))
 977             (message "Clock starts at %s - %s" ts msg-extra)
 978             (run-hooks 'org-clock-in-hook)))))))
 979
 980 (defun org-clock-mark-default-task ()
 981   "Mark current task as default task."
 982   (interactive)
 983   (save-excursion
 984     (org-back-to-heading t)
 985     (move-marker org-clock-default-task (point))))
 986
 987 (defvar msg-extra)
 988 (defun org-clock-get-sum-start ()
 989   "Return the time from which clock times should be counted.
 990 This is for the currently running clock as it is displayed
 991 in the mode line.  This function looks at the properties
 992 LAST_REPEAT and in particular CLOCK_MODELINE_TOTAL and the
 993 corresponding variable `org-clock-modeline-total' and then
 994 decides which time to use."
 995   (let ((cmt (or (org-entry-get nil "CLOCK_MODELINE_TOTAL")
 996                  (symbol-name org-clock-modeline-total)))
 997         (lr (org-entry-get nil "LAST_REPEAT")))
 998     (cond
 999      ((equal cmt "current")
1000       (setq msg-extra "showing time in current clock instance")
1001       (current-time))
1002      ((equal cmt "today")
1003       (setq msg-extra "showing today's task time.")
1004       (let* ((dt (decode-time (current-time))))
1005         (setq dt (append (list 0 0 0) (nthcdr 3 dt)))
1006         (if org-extend-today-until
1007             (setf (nth 2 dt) org-extend-today-until))
1008         (apply 'encode-time dt)))
1009      ((or (equal cmt "all")
1010           (and (or (not cmt) (equal cmt "auto"))
1011                (not lr)))
1012       (setq msg-extra "showing entire task time.")
1013       nil)
1014      ((or (equal cmt "repeat")
1015           (and (or (not cmt) (equal cmt "auto"))
1016                lr))
1017       (setq msg-extra "showing task time since last repeat.")
1018       (if (not lr)
1019           nil
1020         (org-time-string-to-time lr)))
1021      (t nil))))
1022
1023 (defun org-clock-find-position (find-unclosed)
1024   "Find the location where the next clock line should be inserted.
1025 When FIND-UNCLOSED is non-nil, first check if there is an unclosed clock
1026 line and position cursor in that line."
1027   (org-back-to-heading t)
1028   (catch 'exit
1029     (let ((beg (save-excursion
1030                  (beginning-of-line 2)
1031                  (or (bolp) (newline))
1032                  (point)))
1033           (end (progn (outline-next-heading) (point)))
1034           (re (concat "^[ \t]*" org-clock-string))
1035           (cnt 0)
1036           (drawer (if (stringp org-clock-into-drawer)
1037                       org-clock-into-drawer "LOGBOOK"))
1038           first last ind-last)
1039       (goto-char beg)
1040       (when (and find-unclosed
1041                  (re-search-forward
1042                   (concat "^[ \t]* " org-clock-string
1043                           " \\[\\([0-9]\\{4\\}-[0-9]\\{2\\}-[0-9]\\{2\\}"
1044                           " +\\sw+ +[012][0-9]:[0-5][0-9]\\)\\][ \t]*$")
1045                   end t))
1046         (beginning-of-line 1)
1047         (throw 'exit t))
1048       (when (eobp) (newline) (setq end (max (point) end)))
1049       (when (re-search-forward (concat "^[ \t]*:" drawer ":") end t)
1050         ;; we seem to have a CLOCK drawer, so go there.
1051         (beginning-of-line 2)
1052         (or org-log-states-order-reversed
1053             (and (re-search-forward org-property-end-re nil t)
1054                  (goto-char (match-beginning 0))))
1055         (throw 'exit t))
1056       ;; Lets count the CLOCK lines
1057       (goto-char beg)
1058       (while (re-search-forward re end t)
1059         (setq first (or first (match-beginning 0))
1060               last (match-beginning 0)
1061               cnt (1+ cnt)))
1062       (when (and (integerp org-clock-into-drawer)
1063                  last
1064                  (>= (1+ cnt) org-clock-into-drawer))
1065         ;; Wrap current entries into a new drawer
1066         (goto-char last)
1067         (setq ind-last (org-get-indentation))
1068         (beginning-of-line 2)
1069         (if (and (>= (org-get-indentation) ind-last)
1070                  (org-at-item-p))
1071             (org-end-of-item))
1072         (insert ":END:\n")
1073         (beginning-of-line 0)
1074         (org-indent-line-to ind-last)
1075         (goto-char first)
1076         (insert ":" drawer ":\n")
1077         (beginning-of-line 0)
1078         (org-indent-line-function)
1079         (org-flag-drawer t)
1080         (beginning-of-line 2)
1081         (or org-log-states-order-reversed
1082             (and (re-search-forward org-property-end-re nil t)
1083                  (goto-char (match-beginning 0))))
1084         (throw 'exit nil))
1085
1086       (goto-char beg)
1087       (while (and (looking-at (concat "[ \t]*" org-keyword-time-regexp))
1088                   (not (equal (match-string 1) org-clock-string)))
1089         ;; Planning info, skip to after it
1090         (beginning-of-line 2)
1091         (or (bolp) (newline)))
1092       (when (or (eq org-clock-into-drawer t)
1093                 (stringp org-clock-into-drawer)
1094                 (and (integerp org-clock-into-drawer)
1095                      (< org-clock-into-drawer 2)))
1096         (insert ":" drawer ":\n:END:\n")
1097         (beginning-of-line -1)
1098         (org-indent-line-function)
1099         (org-flag-drawer t)
1100         (beginning-of-line 2)
1101         (org-indent-line-function)
1102         (beginning-of-line)
1103         (or org-log-states-order-reversed
1104             (and (re-search-forward org-property-end-re nil t)
1105                  (goto-char (match-beginning 0))))))))
1106
1107 (defun org-clock-out (&optional fail-quietly at-time)
1108   "Stop the currently running clock.
1109 If there is no running clock, throw an error, unless FAIL-QUIETLY is set."
1110   (interactive)
1111   (catch 'exit
1112     (if (not (marker-buffer org-clock-marker))
1113         (if fail-quietly (throw 'exit t) (error "No active clock")))
1114     (let (ts te s h m remove)
1115       (save-excursion
1116         (set-buffer (marker-buffer org-clock-marker))
1117         (save-restriction
1118           (widen)
1119           (goto-char org-clock-marker)
1120           (beginning-of-line 1)
1121           (if (and (looking-at (concat "[ \t]*" org-keyword-time-regexp))
1122                    (equal (match-string 1) org-clock-string))
1123               (setq ts (match-string 2))
1124             (if fail-quietly (throw 'exit nil) (error "Clock start time is gone")))
1125           (goto-char (match-end 0))
1126           (delete-region (point) (point-at-eol))
1127           (insert "--")
1128           (setq te (org-insert-time-stamp (or at-time (current-time))
1129                                           'with-hm 'inactive))
1130           (setq s (- (org-float-time (apply 'encode-time (org-parse-time-string te)))
1131                      (org-float-time (apply 'encode-time (org-parse-time-string ts))))
1132                 h (floor (/ s 3600))
1133                 s (- s (* 3600 h))
1134                 m (floor (/ s 60))
1135                 s (- s (* 60 s)))
1136           (insert " => " (format "%2d:%02d" h m))
1137           (when (setq remove (and org-clock-out-remove-zero-time-clocks
1138                                   (= (+ h m) 0)))
1139             (beginning-of-line 1)
1140             (delete-region (point) (point-at-eol))
1141             (and (looking-at "\n") (> (point-max) (1+ (point)))
1142                  (delete-char 1)))
1143           (move-marker org-clock-marker nil)
1144           (move-marker org-clock-hd-marker nil)
1145           (when org-log-note-clock-out
1146             (org-add-log-setup 'clock-out nil nil nil nil
1147                                (concat "# Task: " (org-get-heading t) "\n\n")))
1148           (when org-clock-mode-line-timer
1149             (cancel-timer org-clock-mode-line-timer)
1150             (setq org-clock-mode-line-timer nil))
1151           (when org-clock-idle-timer
1152             (cancel-timer org-clock-idle-timer)
1153             (setq org-clock-idle-timer nil))
1154           (setq global-mode-string
1155                 (delq 'org-mode-line-string global-mode-string))
1156           (when org-clock-out-switch-to-state
1157             (save-excursion
1158               (org-back-to-heading t)
1159               (let ((org-inhibit-logging t))
1160                 (cond
1161                  ((functionp org-clock-out-switch-to-state)
1162                   (looking-at org-complex-heading-regexp)
1163                   (let ((newstate (funcall org-clock-out-switch-to-state
1164                                            (match-string 2))))
1165                     (if newstate (org-todo newstate))))
1166                  ((and org-clock-out-switch-to-state
1167                        (not (looking-at (concat outline-regexp "[ \t]*"
1168                                                 org-clock-out-switch-to-state
1169                                                 "\\>"))))
1170                   (org-todo org-clock-out-switch-to-state))))))
1171           (force-mode-line-update)
1172           (message (concat "Clock stopped at %s after HH:MM = " org-time-clocksum-format "%s") te h m
1173                    (if remove " => LINE REMOVED" ""))
1174           (run-hooks 'org-clock-out-hook))))))
1175
1176 (defun org-clock-cancel ()
1177   "Cancel the running clock be removing the start timestamp."
1178   (interactive)
1179   (if (not (marker-buffer org-clock-marker))
1180       (error "No active clock"))
1181   (save-excursion
1182     (set-buffer (marker-buffer org-clock-marker))
1183     (goto-char org-clock-marker)
1184     (delete-region (1- (point-at-bol)) (point-at-eol))
1185     ;; Just in case, remove any empty LOGBOOK left over
1186     (org-remove-empty-drawer-at "LOGBOOK" (point)))
1187   (move-marker org-clock-marker nil)
1188   (move-marker org-clock-hd-marker nil)
1189   (setq global-mode-string
1190         (delq 'org-mode-line-string global-mode-string))
1191   (force-mode-line-update)
1192   (message "Clock canceled")
1193   (run-hooks 'org-clock-cancel-hook))
1194
1195 (defun org-clock-goto (&optional select)
1196   "Go to the currently clocked-in entry, or to the most recently clocked one.
1197 With prefix arg SELECT, offer recently clocked tasks for selection."
1198   (interactive "@P")
1199   (let* ((recent nil)
1200          (m (cond
1201              (select
1202               (or (org-clock-select-task "Select task to go to: ")
1203                   (error "No task selected")))
1204              ((marker-buffer org-clock-marker) org-clock-marker)
1205              ((and org-clock-goto-may-find-recent-task
1206                    (car org-clock-history)
1207                    (marker-buffer (car org-clock-history)))
1208               (setq recent t)
1209               (car org-clock-history))
1210              (t (error "No active or recent clock task")))))
1211     (switch-to-buffer (marker-buffer m))
1212     (if (or (< m (point-min)) (> m (point-max))) (widen))
1213     (goto-char m)
1214     (org-show-entry)
1215     (org-back-to-heading t)
1216     (org-cycle-hide-drawers 'children)
1217     (recenter)
1218     (if recent
1219         (message "No running clock, this is the most recently clocked task"))
1220     (run-hooks 'org-clock-goto-hook)))
1221
1222 (defvar org-clock-file-total-minutes nil
1223   "Holds the file total time in minutes, after a call to `org-clock-sum'.")
1224 (make-variable-buffer-local 'org-clock-file-total-minutes)
1225
1226 (defun org-clock-sum (&optional tstart tend)
1227   "Sum the times for each subtree.
1228 Puts the resulting times in minutes as a text property on each headline.
1229 TSTART and TEND can mark a time range to be considered."
1230   (interactive)
1231   (let* ((bmp (buffer-modified-p))
1232          (re (concat "^\\(\\*+\\)[ \t]\\|^[ \t]*"
1233                      org-clock-string
1234                      "[ \t]*\\(?:\\(\\[.*?\\]\\)-+\\(\\[.*?\\]\\)\\|=>[ \t]+\\([0-9]+\\):\\([0-9]+\\)\\)"))
1235          (lmax 30)
1236          (ltimes (make-vector lmax 0))
1237          (t1 0)
1238          (level 0)
1239          ts te dt
1240          time)
1241     (if (stringp tstart) (setq tstart (org-time-string-to-seconds tstart)))
1242     (if (stringp tend) (setq tend (org-time-string-to-seconds tend)))
1243     (if (consp tstart) (setq tstart (org-float-time tstart)))
1244     (if (consp tend) (setq tend (org-float-time tend)))
1245     (remove-text-properties (point-min) (point-max) '(:org-clock-minutes t))
1246     (save-excursion
1247       (goto-char (point-max))
1248       (while (re-search-backward re nil t)
1249         (cond
1250          ((match-end 2)
1251           ;; Two time stamps
1252           (setq ts (match-string 2)
1253                 te (match-string 3)
1254                 ts (org-float-time
1255                     (apply 'encode-time (org-parse-time-string ts)))
1256                 te (org-float-time
1257                     (apply 'encode-time (org-parse-time-string te)))
1258                 ts (if tstart (max ts tstart) ts)
1259                 te (if tend (min te tend) te)
1260                 dt (- te ts)
1261                 t1 (if (> dt 0) (+ t1 (floor (/ dt 60))) t1)))
1262          ((match-end 4)
1263           ;; A naked time
1264           (setq t1 (+ t1 (string-to-number (match-string 5))
1265                       (* 60 (string-to-number (match-string 4))))))
1266          (t ;; A headline
1267           (setq level (- (match-end 1) (match-beginning 1)))
1268           (when (or (> t1 0) (> (aref ltimes level) 0))
1269             (loop for l from 0 to level do
1270                   (aset ltimes l (+ (aref ltimes l) t1)))
1271             (setq t1 0 time (aref ltimes level))
1272             (loop for l from level to (1- lmax) do
1273                   (aset ltimes l 0))
1274             (goto-char (match-beginning 0))
1275             (put-text-property (point) (point-at-eol) :org-clock-minutes time)))))
1276       (setq org-clock-file-total-minutes (aref ltimes 0)))
1277     (set-buffer-modified-p bmp)))
1278
1279 (defun org-clock-sum-current-item (&optional tstart)
1280   "Returns time, clocked on current item in total"
1281   (save-excursion
1282     (save-restriction
1283       (org-narrow-to-subtree)
1284       (org-clock-sum tstart)
1285       org-clock-file-total-minutes)))
1286
1287 (defun org-clock-display (&optional total-only)
1288   "Show subtree times in the entire buffer.
1289 If TOTAL-ONLY is non-nil, only show the total time for the entire file
1290 in the echo area."
1291   (interactive)
1292   (org-clock-remove-overlays)
1293   (let (time h m p)
1294     (org-clock-sum)
1295     (unless total-only
1296       (save-excursion
1297         (goto-char (point-min))
1298         (while (or (and (equal (setq p (point)) (point-min))
1299                         (get-text-property p :org-clock-minutes))
1300                    (setq p (next-single-property-change
1301                             (point) :org-clock-minutes)))
1302           (goto-char p)
1303           (when (setq time (get-text-property p :org-clock-minutes))
1304             (org-clock-put-overlay time (funcall outline-level))))
1305         (setq h (/ org-clock-file-total-minutes 60)
1306               m (- org-clock-file-total-minutes (* 60 h)))
1307         ;; Arrange to remove the overlays upon next change.
1308         (when org-remove-highlights-with-change
1309           (org-add-hook 'before-change-functions 'org-clock-remove-overlays
1310                         nil 'local))))
1311     (if org-time-clocksum-use-fractional
1312         (message (concat "Total file time: " org-time-clocksum-fractional-format
1313                          " (%d hours and %d minutes)")
1314                  (/ (+ (* h 60.0) m) 60.0) h m)
1315       (message (concat "Total file time: " org-time-clocksum-format
1316                        " (%d hours and %d minutes)") h m h m))))
1317
1318 (defvar org-clock-overlays nil)
1319 (make-variable-buffer-local 'org-clock-overlays)
1320
1321 (defun org-clock-put-overlay (time &optional level)
1322   "Put an overlays on the current line, displaying TIME.
1323 If LEVEL is given, prefix time with a corresponding number of stars.
1324 This creates a new overlay and stores it in `org-clock-overlays', so that it
1325 will be easy to remove."
1326   (let* ((c 60) (h (floor (/ time 60))) (m (- time (* 60 h)))
1327          (l (if level (org-get-valid-level level 0) 0))
1328          (fmt (concat "%s " (if org-time-clocksum-use-fractional
1329                                 org-time-clocksum-fractional-format
1330                               org-time-clocksum-format) "%s"))
1331          (off 0)
1332          ov tx)
1333     (org-move-to-column c)
1334     (unless (eolp) (skip-chars-backward "^ \t"))
1335     (skip-chars-backward " \t")
1336     (setq ov (org-make-overlay (1- (point)) (point-at-eol))
1337           tx (concat (buffer-substring (1- (point)) (point))
1338                      (make-string (+ off (max 0 (- c (current-column)))) ?.)
1339                      (org-add-props (if org-time-clocksum-use-fractional
1340                                         (format fmt
1341                                                 (make-string l ?*)
1342                                                 (/ (+ (* h 60.0) m) 60.0)
1343                                                 (make-string (- 16 l) ?\ ))
1344                                       (format fmt
1345                                               (make-string l ?*) h m
1346                                               (make-string (- 16 l) ?\ )))
1347                          (list 'face 'org-clock-overlay))
1348                      ""))
1349     (if (not (featurep 'xemacs))
1350         (org-overlay-put ov 'display tx)
1351       (org-overlay-put ov 'invisible t)
1352       (org-overlay-put ov 'end-glyph (make-glyph tx)))
1353     (push ov org-clock-overlays)))
1354
1355 (defun org-clock-remove-overlays (&optional beg end noremove)
1356   "Remove the occur highlights from the buffer.
1357 BEG and END are ignored.  If NOREMOVE is nil, remove this function
1358 from the `before-change-functions' in the current buffer."
1359   (interactive)
1360   (unless org-inhibit-highlight-removal
1361     (mapc 'org-delete-overlay org-clock-overlays)
1362     (setq org-clock-overlays nil)
1363     (unless noremove
1364       (remove-hook 'before-change-functions
1365                    'org-clock-remove-overlays 'local))))
1366
1367 (defvar state) ;; dynamically scoped into this function
1368 (defun org-clock-out-if-current ()
1369   "Clock out if the current entry contains the running clock.
1370 This is used to stop the clock after a TODO entry is marked DONE,
1371 and is only done if the variable `org-clock-out-when-done' is not nil."
1372   (when (and org-clock-out-when-done
1373              (member state org-done-keywords)
1374              (equal (or (buffer-base-buffer (marker-buffer org-clock-marker))
1375                         (marker-buffer org-clock-marker))
1376                     (or (buffer-base-buffer (current-buffer))
1377                         (current-buffer)))
1378              (< (point) org-clock-marker)
1379              (> (save-excursion (outline-next-heading) (point))
1380                 org-clock-marker))
1381     ;; Clock out, but don't accept a logging message for this.
1382     (let ((org-log-note-clock-out nil))
1383       (org-clock-out))))
1384
1385 (add-hook 'org-after-todo-state-change-hook
1386           'org-clock-out-if-current)
1387
1388 ;;;###autoload
1389 (defun org-get-clocktable (&rest props)
1390   "Get a formatted clocktable with parameters according to PROPS.
1391 The table is created in a temporary buffer, fully formatted and
1392 fontified, and then returned."
1393   ;; Set the defaults
1394   (setq props (plist-put props :name "clocktable"))
1395   (unless (plist-member props :maxlevel)
1396     (setq props (plist-put props :maxlevel 2)))
1397   (unless (plist-member props :scope)
1398     (setq props (plist-put props :scope 'agenda)))
1399   (with-temp-buffer
1400     (org-mode)
1401     (org-create-dblock props)
1402     (org-update-dblock)
1403     (font-lock-fontify-buffer)
1404     (forward-line 2)
1405     (buffer-substring (point) (progn
1406                                 (re-search-forward "^#\\+END" nil t)
1407                                 (point-at-bol)))))
1408
1409 (defun org-clock-report (&optional arg)
1410   "Create a table containing a report about clocked time.
1411 If the cursor is inside an existing clocktable block, then the table
1412 will be updated.  If not, a new clocktable will be inserted.
1413 When called with a prefix argument, move to the first clock table in the
1414 buffer and update it."
1415   (interactive "P")
1416   (org-clock-remove-overlays)
1417   (when arg
1418     (org-find-dblock "clocktable")
1419     (org-show-entry))
1420   (if (org-in-clocktable-p)
1421       (goto-char (org-in-clocktable-p))
1422     (org-create-dblock (append (list :name "clocktable")
1423                                org-clock-clocktable-default-properties)))
1424   (org-update-dblock))
1425
1426 (defun org-in-clocktable-p ()
1427   "Check if the cursor is in a clocktable."
1428   (let ((pos (point)) start)
1429     (save-excursion
1430       (end-of-line 1)
1431       (and (re-search-backward "^#\\+BEGIN:[ \t]+clocktable" nil t)
1432            (setq start (match-beginning 0))
1433            (re-search-forward "^#\\+END:.*" nil t)
1434            (>= (match-end 0) pos)
1435            start))))
1436
1437 (defun org-clock-special-range (key &optional time as-strings)
1438   "Return two times bordering a special time range.
1439 Key is a symbol specifying the range and can be one of `today', `yesterday',
1440 `thisweek', `lastweek', `thismonth', `lastmonth', `thisyear', `lastyear'.
1441 A week starts Monday 0:00 and ends Sunday 24:00.
1442 The range is determined relative to TIME.  TIME defaults to the current time.
1443 The return value is a cons cell with two internal times like the ones
1444 returned by `current time' or `encode-time'. if AS-STRINGS is non-nil,
1445 the returned times will be formatted strings."
1446   (if (integerp key) (setq key (intern (number-to-string key))))
1447   (let* ((tm (decode-time (or time (current-time))))
1448          (s 0) (m (nth 1 tm)) (h (nth 2 tm))
1449          (d (nth 3 tm)) (month (nth 4 tm)) (y (nth 5 tm))
1450          (dow (nth 6 tm))
1451          (skey (symbol-name key))
1452          (shift 0)
1453          s1 m1 h1 d1 month1 y1 diff ts te fm txt w date)
1454     (cond
1455      ((string-match "^[0-9]+$" skey)
1456       (setq y (string-to-number skey) m 1 d 1 key 'year))
1457      ((string-match "^\\([0-9]+\\)-\\([0-9]\\{1,2\\}\\)$" skey)
1458       (setq y (string-to-number (match-string 1 skey))
1459             month (string-to-number (match-string 2 skey))
1460             d 1 key 'month))
1461      ((string-match "^\\([0-9]+\\)-[wW]\\([0-9]\\{1,2\\}\\)$" skey)
1462       (require 'cal-iso)
1463       (setq y (string-to-number (match-string 1 skey))
1464             w (string-to-number (match-string 2 skey)))
1465       (setq date (calendar-gregorian-from-absolute
1466                   (calendar-absolute-from-iso (list w 1 y))))
1467       (setq d (nth 1 date) month (car date) y (nth 2 date)
1468             dow 1
1469             key 'week))
1470      ((string-match "^\\([0-9]+\\)-\\([0-9]\\{1,2\\}\\)-\\([0-9]\\{1,2\\}\\)$" skey)
1471       (setq y (string-to-number (match-string 1 skey))
1472             month (string-to-number (match-string 2 skey))
1473             d (string-to-number (match-string 3 skey))
1474             key 'day))
1475      ((string-match "\\([-+][0-9]+\\)$" skey)
1476       (setq shift (string-to-number (match-string 1 skey))
1477             key (intern (substring skey 0 (match-beginning 1))))))
1478     (when (= shift 0)
1479       (cond ((eq key 'yesterday) (setq key 'today shift -1))
1480             ((eq key 'lastweek)  (setq key 'week  shift -1))
1481             ((eq key 'lastmonth) (setq key 'month shift -1))
1482             ((eq key 'lastyear)  (setq key 'year  shift -1))))
1483     (cond
1484      ((memq key '(day today))
1485       (setq d (+ d shift) h 0 m 0 h1 24 m1 0))
1486      ((memq key '(week thisweek))
1487       (setq diff (+ (* -7 shift) (if (= dow 0) 6 (1- dow)))
1488             m 0 h 0 d (- d diff) d1 (+ 7 d)))
1489      ((memq key '(month thismonth))
1490       (setq d 1 h 0 m 0 d1 1 month (+ month shift) month1 (1+ month) h1 0 m1 0))
1491      ((memq key '(year thisyear))
1492       (setq m 0 h 0 d 1 month 1 y (+ y shift) y1 (1+ y)))
1493      (t (error "No such time block %s" key)))
1494     (setq ts (encode-time s m h d month y)
1495           te (encode-time (or s1 s) (or m1 m) (or h1 h)
1496                           (or d1 d) (or month1 month) (or y1 y)))
1497     (setq fm (cdr org-time-stamp-formats))
1498     (cond
1499      ((memq key '(day today))
1500       (setq txt (format-time-string "%A, %B %d, %Y" ts)))
1501      ((memq key '(week thisweek))
1502       (setq txt (format-time-string "week %G-W%V" ts)))
1503      ((memq key '(month thismonth))
1504       (setq txt (format-time-string "%B %Y" ts)))
1505      ((memq key '(year thisyear))
1506       (setq txt (format-time-string "the year %Y" ts))))
1507     (if as-strings
1508         (list (format-time-string fm ts) (format-time-string fm te) txt)
1509       (list ts te txt))))
1510
1511 (defun org-clocktable-shift (dir n)
1512   "Try to shift the :block date of the clocktable at point.
1513 Point must be in the #+BEGIN: line of a clocktable, or this function
1514 will throw an error.
1515 DIR is a direction, a symbol `left', `right', `up', or `down'.
1516 Both `left' and `down' shift the block toward the past, `up' and `right'
1517 push it toward the future.
1518 N is the number of shift steps to take.  The size of the step depends on
1519 the currently selected interval size."
1520   (setq n (prefix-numeric-value n))
1521   (and (memq dir '(left down)) (setq n (- n)))
1522   (save-excursion
1523     (goto-char (point-at-bol))
1524     (if (not (looking-at "#\\+BEGIN: clocktable\\>.*?:block[ \t]+\\(\\S-+\\)"))
1525         (error "Line needs a :block definition before this command works")
1526       (let* ((b (match-beginning 1)) (e (match-end 1))
1527              (s (match-string 1))
1528              block shift ins y mw d date wp m)
1529         (cond
1530          ((equal s "yesterday") (setq s "today-1"))
1531          ((equal s "lastweek") (setq s "thisweek-1"))
1532          ((equal s "lastmonth") (setq s "thismonth-1"))
1533          ((equal s "lastyear") (setq s "thisyear-1")))
1534         (cond
1535          ((string-match "^\\(today\\|thisweek\\|thismonth\\|thisyear\\)\\([-+][0-9]+\\)?$" s)
1536           (setq block (match-string 1 s)
1537                 shift (if (match-end 2)
1538                           (string-to-number (match-string 2 s))
1539                         0))
1540           (setq shift (+ shift n))
1541           (setq ins (if (= shift 0) block (format "%s%+d" block shift))))
1542          ((string-match "\\([0-9]+\\)\\(-\\([wW]?\\)\\([0-9]\\{1,2\\}\\)\\(-\\([0-9]\\{1,2\\}\\)\\)?\\)?" s)
1543           ;;               1        1  2   3       3  4                4  5   6                6  5   2
1544           (setq y (string-to-number (match-string 1 s))
1545                 wp (and (match-end 3) (match-string 3 s))
1546                 mw (and (match-end 4) (string-to-number (match-string 4 s)))
1547                 d (and (match-end 6) (string-to-number (match-string 6 s))))
1548           (cond
1549            (d (setq ins (format-time-string
1550                          "%Y-%m-%d"
1551                          (encode-time 0 0 0 (+ d n) m y))))
1552            ((and wp mw (> (length wp) 0))
1553             (require 'cal-iso)
1554             (setq date (calendar-gregorian-from-absolute (calendar-absolute-from-iso (list (+ mw n) 1 y))))
1555             (setq ins (format-time-string
1556                        "%G-W%V"
1557                        (encode-time 0 0 0 (nth 1 date) (car date) (nth 2 date)))))
1558            (mw
1559             (setq ins (format-time-string
1560                        "%Y-%m"
1561                        (encode-time 0 0 0 1 (+ mw n) y))))
1562            (y
1563             (setq ins (number-to-string (+ y n))))))
1564          (t (error "Cannot shift clocktable block")))
1565         (when ins
1566           (goto-char b)
1567           (insert ins)
1568           (delete-region (point) (+ (point) (- e b)))
1569           (beginning-of-line 1)
1570           (org-update-dblock)
1571           t)))))
1572
1573 (defun org-dblock-write:clocktable (params)
1574   "Write the standard clocktable."
1575   (catch 'exit
1576     (let* ((hlchars '((1 . "*") (2 . "/")))
1577            (ins (make-marker))
1578            (total-time nil)
1579            (scope (plist-get params :scope))
1580            (tostring (plist-get  params :tostring))
1581            (multifile (plist-get  params :multifile))
1582            (header (plist-get  params :header))
1583            (maxlevel (or (plist-get params :maxlevel) 3))
1584            (step (plist-get params :step))
1585            (emph (plist-get params :emphasize))
1586            (timestamp (plist-get params :timestamp))
1587            (ts (plist-get params :tstart))
1588            (te (plist-get params :tend))
1589            (block (plist-get params :block))
1590            (link (plist-get params :link))
1591            ipos time p level hlc hdl tsp props content recalc formula pcol
1592            cc beg end pos tbl tbl1 range-text rm-file-column scope-is-list st)
1593       (setq org-clock-file-total-minutes nil)
1594       (when step
1595         (unless (or block (and ts te))
1596           (error "Clocktable `:step' can only be used with `:block' or `:tstart,:end'"))
1597         (org-clocktable-steps params)
1598         (throw 'exit nil))
1599       (when block
1600         (setq cc (org-clock-special-range block nil t)
1601               ts (car cc) te (nth 1 cc) range-text (nth 2 cc)))
1602       (when (integerp ts) (setq ts (calendar-gregorian-from-absolute ts)))
1603       (when (integerp te) (setq te (calendar-gregorian-from-absolute te)))
1604       (when (and ts (listp ts))
1605         (setq ts (format "%4d-%02d-%02d" (nth 2 ts) (car ts) (nth 1 ts))))
1606       (when (and te (listp te))
1607         (setq te (format "%4d-%02d-%02d" (nth 2 te) (car te) (nth 1 te))))
1608       ;; Now the times are strings we can parse.
1609       (if ts (setq ts (org-float-time
1610                        (apply 'encode-time (org-parse-time-string ts)))))
1611       (if te (setq te (org-float-time
1612                        (apply 'encode-time (org-parse-time-string te)))))
1613       (move-marker ins (point))
1614       (setq ipos (point))
1615
1616       ;; Get the right scope
1617       (setq pos (point))
1618       (cond
1619        ((and scope (listp scope) (symbolp (car scope)))
1620         (setq scope (eval scope)))
1621        ((eq scope 'agenda)
1622         (setq scope (org-agenda-files t)))
1623        ((eq scope 'agenda-with-archives)
1624         (setq scope (org-agenda-files t))
1625         (setq scope (org-add-archive-files scope)))
1626        ((eq scope 'file-with-archives)
1627         (setq scope (org-add-archive-files (list (buffer-file-name)))
1628               rm-file-column t)))
1629       (setq scope-is-list (and scope (listp scope)))
1630       (save-restriction
1631         (cond
1632          ((not scope))
1633          ((eq scope 'file) (widen))
1634          ((eq scope 'subtree) (org-narrow-to-subtree))
1635          ((eq scope 'tree)
1636           (while (org-up-heading-safe))
1637           (org-narrow-to-subtree))
1638          ((and (symbolp scope) (string-match "^tree\\([0-9]+\\)$"
1639                                              (symbol-name scope)))
1640           (setq level (string-to-number (match-string 1 (symbol-name scope))))
1641           (catch 'exit
1642             (while (org-up-heading-safe)
1643               (looking-at outline-regexp)
1644               (if (<= (org-reduced-level (funcall outline-level)) level)
1645                   (throw 'exit nil))))
1646           (org-narrow-to-subtree))
1647          (scope-is-list
1648           (let* ((files scope)
1649                  (scope 'agenda)
1650                  (p1 (copy-sequence params))
1651                  file)
1652             (setq p1 (plist-put p1 :tostring t))
1653             (setq p1 (plist-put p1 :multifile t))
1654             (setq p1 (plist-put p1 :scope 'file))
1655             (org-prepare-agenda-buffers files)
1656             (while (setq file (pop files))
1657               (with-current-buffer (find-buffer-visiting file)
1658                 (setq tbl1 (org-dblock-write:clocktable p1))
1659                 (when tbl1
1660                   (push (org-clocktable-add-file
1661                          file
1662                          (concat "| |*File time*|*"
1663                                  (org-minutes-to-hh:mm-string
1664                                   org-clock-file-total-minutes)
1665                                  "*|\n"
1666                                  tbl1)) tbl)
1667                   (setq total-time (+ (or total-time 0)
1668                                       org-clock-file-total-minutes))))))))
1669         (goto-char pos)
1670
1671         (unless scope-is-list
1672           (org-clock-sum ts te)
1673           (goto-char (point-min))
1674           (setq st t)
1675           (while (or (and (bobp) (prog1 st (setq st nil))
1676                           (get-text-property (point) :org-clock-minutes)
1677                           (setq p (point-min)))
1678                      (setq p (next-single-property-change (point) :org-clock-minutes)))
1679             (goto-char p)
1680             (when (setq time (get-text-property p :org-clock-minutes))
1681               (save-excursion
1682                 (beginning-of-line 1)
1683                 (when (and (looking-at (org-re "\\(\\*+\\)[ \t]+\\(.*?\\)\\([ \t]+:[[:alnum:]_@:]+:\\)?[ \t]*$"))
1684                            (setq level (org-reduced-level
1685                                         (- (match-end 1) (match-beginning 1))))
1686                            (<= level maxlevel))
1687                   (setq hlc (if emph (or (cdr (assoc level hlchars)) "") "")
1688                         hdl (if (not link)
1689                                 (match-string 2)
1690                               (org-make-link-string
1691                                (format "file:%s::%s"
1692                                        (buffer-file-name)
1693                                        (save-match-data
1694                                          (org-make-org-heading-search-string
1695                                           (match-string 2))))
1696                                (match-string 2)))
1697                         tsp (when timestamp
1698                               (setq props (org-entry-properties (point)))
1699                               (or (cdr (assoc "SCHEDULED" props))
1700                                   (cdr (assoc "TIMESTAMP" props))
1701                                   (cdr (assoc "DEADLINE" props))
1702                                   (cdr (assoc "TIMESTAMP_IA" props)))))
1703                   (if (and (not multifile) (= level 1)) (push "|-" tbl))
1704                   (push (concat
1705                          "| " (int-to-string level) "|"
1706                          (if timestamp (concat tsp "|") "")
1707                          hlc hdl hlc " |"
1708                          (make-string (1- level) ?|)
1709                          hlc (org-minutes-to-hh:mm-string time) hlc
1710                          " |") tbl))))))
1711         (setq tbl (nreverse tbl))
1712         (if tostring
1713             (if tbl (mapconcat 'identity tbl "\n") nil)
1714           (goto-char ins)
1715           (insert-before-markers
1716            (or header
1717                (concat
1718                 "Clock summary at ["
1719                 (substring
1720                  (format-time-string (cdr org-time-stamp-formats))
1721                  1 -1)
1722                 "]"
1723                 (if block (concat ", for " range-text ".") "")
1724                 "\n\n"))
1725            (if scope-is-list "|File" "")
1726            "|L|" (if timestamp "Timestamp|" "") "Headline|Time|\n")
1727           (setq total-time (or total-time org-clock-file-total-minutes))
1728           (insert-before-markers
1729            "|-\n|"
1730            (if scope-is-list "|" "")
1731            (if timestamp "|Timestamp|" "|")
1732            "*Total time*| *"
1733            (org-minutes-to-hh:mm-string (or total-time 0))
1734            "*|\n|-\n")
1735           (setq tbl (delq nil tbl))
1736           (if (and (stringp (car tbl)) (> (length (car tbl)) 1)
1737                    (equal (substring (car tbl) 0 2) "|-"))
1738               (pop tbl))
1739           (insert-before-markers (mapconcat
1740                                   'identity (delq nil tbl)
1741                                   (if scope-is-list "\n|-\n" "\n")))
1742           (backward-delete-char 1)
1743           (if (setq formula (plist-get params :formula))
1744               (cond
1745                ((eq formula '%)
1746                 (setq pcol (+ (if scope-is-list 1 0) maxlevel 3))
1747                 (insert
1748                  (format
1749                   "\n#+TBLFM: $%d='(org-clock-time%% @%d$%d $%d..$%d);%%.1f"
1750                   pcol
1751                   2
1752                   (+ 3 (if scope-is-list 1 0))
1753                   (+ (if scope-is-list 1 0) 3)
1754                   (1- pcol)))
1755                 (setq recalc t))
1756                ((stringp formula)
1757                 (insert "\n#+TBLFM: " formula)
1758                 (setq recalc t))
1759                (t (error "invalid formula in clocktable")))
1760             ;; Should we rescue an old formula?
1761             (when (stringp (setq content (plist-get params :content)))
1762               (when (string-match "^\\([ \t]*#\\+TBLFM:.*\\)" content)
1763                 (setq recalc t)
1764                 (insert "\n" (match-string 1 (plist-get params :content)))
1765                 (beginning-of-line 0))))
1766           (goto-char ipos)
1767           (skip-chars-forward "^|")
1768           (org-table-align)
1769           (when recalc
1770             (if (eq formula '%)
1771                 (save-excursion (org-table-goto-column pcol nil 'force)
1772                                 (insert "%")))
1773             (org-table-recalculate 'all))
1774           (when rm-file-column
1775             (forward-char 1)
1776             (org-table-delete-column)))))))
1777
1778 (defun org-clocktable-steps (params)
1779   (let* ((p1 (copy-sequence params))
1780          (ts (plist-get p1 :tstart))
1781          (te (plist-get p1 :tend))
1782          (step0 (plist-get p1 :step))
1783          (step (cdr (assoc step0 '((day . 86400) (week . 604800)))))
1784          (block (plist-get p1 :block))
1785          cc range-text)
1786     (when block
1787       (setq cc (org-clock-special-range block nil t)
1788             ts (car cc) te (nth 1 cc) range-text (nth 2 cc)))
1789     (if ts (setq ts (org-float-time
1790                      (apply 'encode-time (org-parse-time-string ts)))))
1791     (if te (setq te (org-float-time
1792                      (apply 'encode-time (org-parse-time-string te)))))
1793     (setq p1 (plist-put p1 :header ""))
1794     (setq p1 (plist-put p1 :step nil))
1795     (setq p1 (plist-put p1 :block nil))
1796     (while (< ts te)
1797       (or (bolp) (insert "\n"))
1798       (setq p1 (plist-put p1 :tstart (format-time-string
1799                                       (org-time-stamp-format nil t)
1800                                       (seconds-to-time ts))))
1801       (setq p1 (plist-put p1 :tend (format-time-string
1802                                     (org-time-stamp-format nil t)
1803                                     (seconds-to-time (setq ts (+ ts step))))))
1804       (insert "\n" (if (eq step0 'day) "Daily report: " "Weekly report starting on: ")
1805               (plist-get p1 :tstart) "\n")
1806       (org-dblock-write:clocktable p1)
1807       (re-search-forward "#\\+END:")
1808       (end-of-line 0))))
1809
1810 (defun org-clocktable-add-file (file table)
1811   (if table
1812       (let ((lines (org-split-string table "\n"))
1813             (ff (file-name-nondirectory file)))
1814         (mapconcat 'identity
1815                    (mapcar (lambda (x)
1816                              (if (string-match org-table-dataline-regexp x)
1817                                  (concat "|" ff x)
1818                                x))
1819                            lines)
1820                    "\n"))))
1821
1822 (defun org-clock-time% (total &rest strings)
1823   "Compute a time fraction in percent.
1824 TOTAL s a time string like 10:21 specifying the total times.
1825 STRINGS is a list of strings that should be checked for a time.
1826 The first string that does have a time will be used.
1827 This function is made for clock tables."
1828   (let ((re "\\([0-9]+\\):\\([0-9]+\\)")
1829         tot s)
1830     (save-match-data
1831       (catch 'exit
1832         (if (not (string-match re total))
1833             (throw 'exit 0.)
1834           (setq tot (+ (string-to-number (match-string 2 total))
1835                        (* 60 (string-to-number (match-string 1 total)))))
1836           (if (= tot 0.) (throw 'exit 0.)))
1837         (while (setq s (pop strings))
1838           (if (string-match "\\([0-9]+\\):\\([0-9]+\\)" s)
1839               (throw 'exit
1840                      (/ (* 100.0 (+ (string-to-number (match-string 2 s))
1841                                     (* 60 (string-to-number (match-string 1 s)))))
1842                         tot))))
1843         0))))
1844
1845 (defvar org-clock-loaded nil
1846   "Was the clock file loaded?")
1847
1848 (defun org-clock-save ()
1849   "Persist various clock-related data to disk.
1850 The details of what will be saved are regulated by the variable
1851 `org-clock-persist'."
1852   (when (and org-clock-persist
1853              (or org-clock-loaded
1854                  org-clock-has-been-used
1855                  (not (file-exists-p org-clock-persist-file))))
1856     (let (b)
1857       (with-current-buffer (find-file (expand-file-name org-clock-persist-file))
1858         (progn
1859           (delete-region (point-min) (point-max))
1860           ;;Store clock
1861           (insert (format ";; org-persist.el - %s at %s\n"
1862                           system-name (format-time-string
1863                                        (cdr org-time-stamp-formats))))
1864           (if (and (memq org-clock-persist '(t clock))
1865                    (setq b (marker-buffer org-clock-marker))
1866                    (setq b (or (buffer-base-buffer b) b))
1867                    (buffer-live-p b)
1868                    (buffer-file-name b)
1869                    (or (not org-clock-persist-query-save)
1870                        (y-or-n-p (concat "Save current clock ("
1871                                          (substring-no-properties org-clock-heading)
1872                                          ") "))))
1873               (insert "(setq resume-clock '(\""
1874                       (buffer-file-name (marker-buffer org-clock-marker))
1875                       "\" . " (int-to-string (marker-position org-clock-marker))
1876                       "))\n"))
1877           ;; Store clocked task history. Tasks are stored reversed to make
1878           ;; reading simpler
1879           (when (and (memq org-clock-persist '(t history))
1880                      org-clock-history)
1881             (insert
1882              "(setq stored-clock-history '("
1883              (mapconcat
1884               (lambda (m)
1885                 (when (and (setq b (marker-buffer m))
1886                            (setq b (or (buffer-base-buffer b) b))
1887                            (buffer-live-p b)
1888                            (buffer-file-name b))
1889                   (concat "(\"" (buffer-file-name b)
1890                           "\" . " (int-to-string (marker-position m))
1891                           ")")))
1892               (reverse org-clock-history) " ") "))\n"))
1893           (save-buffer)
1894           (kill-buffer (current-buffer)))))))
1895
1896 (defun org-clock-load ()
1897   "Load clock-related data from disk, maybe resuming a stored clock."
1898   (when (and org-clock-persist (not org-clock-loaded))
1899     (let ((filename (expand-file-name org-clock-persist-file))
1900           (org-clock-in-resume 'auto-restart)
1901           resume-clock stored-clock-history)
1902       (if (not (file-readable-p filename))
1903           (message "Not restoring clock data; %s not found"
1904                    org-clock-persist-file)
1905         (message "%s" "Restoring clock data")
1906         (setq org-clock-loaded t)
1907         (load-file filename)
1908         ;; load history
1909         (when stored-clock-history
1910           (save-window-excursion
1911             (mapc (lambda (task)
1912                     (if (file-exists-p (car task))
1913                         (org-clock-history-push (cdr task)
1914                                                 (find-file (car task)))))
1915                   stored-clock-history)))
1916         ;; resume clock
1917         (when (and resume-clock org-clock-persist
1918                    (file-exists-p (car resume-clock))
1919                    (or (not org-clock-persist-query-resume)
1920                        (y-or-n-p
1921                         (concat
1922                          "Resume clock ("
1923                          (with-current-buffer (find-file (car resume-clock))
1924                            (save-excursion
1925                              (goto-char (cdr resume-clock))
1926                              (org-back-to-heading t)
1927                              (and (looking-at org-complex-heading-regexp)
1928                                   (match-string 4))))
1929                          ") "))))
1930           (when (file-exists-p (car resume-clock))
1931             (with-current-buffer (find-file (car resume-clock))
1932               (goto-char (cdr resume-clock))
1933               (let ((org-clock-auto-clock-resolution nil))
1934                 (org-clock-in)
1935                 (if (org-invisible-p)
1936                     (org-show-context))))))))))
1937
1938 ;;;###autoload
1939 (defun org-clock-persistence-insinuate ()
1940   "Set up hooks for clock persistence"
1941   (add-hook 'org-mode-hook 'org-clock-load)
1942   (add-hook 'kill-emacs-hook 'org-clock-save))
1943
1944 ;; Suggested bindings
1945 (org-defkey org-mode-map "\C-c\C-x\C-e" 'org-clock-modify-effort-estimate)
1946
1947 (provide 'org-clock)
1948
1949 ;; arch-tag: 7b42c5d4-9b36-48be-97c0-66a869daed4c
1950
1951 ;;; org-clock.el ends here