configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_INIT(src/armdis.h)
   4
   5 AC_CANONICAL_HOST
   6 AC_CANONICAL_TARGET
   7
   8 VBA_USE_C_CORE=yes
   9 VBA_USE_MMX=no
  10
  11 AM_INIT_AUTOMAKE(VisualBoyAdvance, 1.8.0)
  12
  13 AC_ARG_ENABLE(c-core,
  14   AC_HELP_STRING([--enable-c-core],[enable C core (default is no on x86 targets)]),
  15   , enable_c_core=$VBA_USE_C_CORE)
  16
  17 AC_ARG_ENABLE(profiling,
  18   AC_HELP_STRING([--enable-profiling],[enable profiling (default is yes)]),
  19   , enable_profiling=no)
  20
  21 AC_ARG_WITH(mmx,
  22   AC_HELP_STRING([--with-mmx],[use MMX (default is yes on x86 targets)]),
  23   , with_mmx=$VBA_USE_MMX)
  24
  25 AC_ARG_ENABLE(sdl,
  26   AC_HELP_STRING([--enable-sdl],[build the SDL interface (default is yes)]),
  27   , enable_sdl=yes)
  28
  29 AC_ARG_ENABLE(gtk,
  30 [  --enable-gtk=[[VERSION]]  build the GTK+ interface (default is no)],[
  31 if test "x$enable_gtk" != xno; then
  32   enable_gtk=yes
  33   if test "x$enableval" = xyes; then
  34     gtk_version=2.0
  35   else
  36     gtk_version=$enableval
  37   fi
  38 fi
  39 ],[
  40 enable_gtk=no
  41 ])
  42
  43 AC_ARG_ENABLE(dev,
  44   AC_HELP_STRING([--enable-dev],[enable development features (default is yes)]),
  45   , enable_dev=yes)
  46
  47 dnl Checks for programs.
  48 AC_PROG_CC
  49 AC_PROG_YACC
  50 AM_PROG_LEX
  51 AC_PROG_CXX
  52 AC_PROG_RANLIB
  53 AC_PATH_PROG(NASM, nasm)
  54
  55 dnl Checks for libraries.
  56 AC_CHECK_LIB(z, gzopen,
  57   , AC_MSG_ERROR([*** Cannot compile without zlib.]))
  58 AC_CHECK_LIB(pthread, pthread_yield)
  59
  60 PKG_CHECK_MODULES(LIBPNG, libpng)
  61 CPPFLAGS="$CPPFLAGS $LIBPNG_CFLAGS"
  62 LIBS="$LIBS $LIBPNG_LIBS"
  63
  64 dnl Checks for header files.
  65 AC_PATH_X
  66 AC_HEADER_STDC
  67 AC_CHECK_HEADERS(malloc.h strings.h unistd.h arpa/inet.h netinet/in.h zutil.h)
  68
  69 dnl Checks for typedefs, structures, and compiler characteristics.
  70 AC_C_CONST
  71 AC_C_INLINE
  72 AC_TYPE_SIZE_T
  73 AC_STRUCT_TM
  74 AC_MSG_CHECKING(for socklen_t)
  75 AC_TRY_COMPILE([
  76 #include <sys/socket.h>
  77 socklen_t x;
  78 ],[
  79 ],[
  80 AC_MSG_RESULT(yes)
  81 ],[
  82 AC_TRY_COMPILE([
  83 #include <sys/socket.h>
  84 int accept (int, struct sockaddr *, size_t *);
  85 ],[
  86 ],[
  87 AC_MSG_RESULT(size_t)
  88 AC_DEFINE(socklen_t,size_t)
  89 ],[
  90 AC_MSG_RESULT(int)
  91 AC_DEFINE(socklen_t,int)
  92 ])
  93 ])
  94
  95 AC_C_BIGENDIAN
  96
  97 VBA_LIBS="../gb/libgb.a"
  98
  99 CXXFLAGS="$CXXFLAGS -DBKPT_SUPPORT"
 100 CFLAGS="$CFLAGS -DBKPT_SUPPORT -std=gnu99"
 101
 102 if test "x$enable_c_core" = xyes; then
 103   CXXFLAGS="$CXXFLAGS -DC_CORE"
 104   CFLAGS="$CFLAGS -DC_CORE"
 105 fi
 106
 107 if test "x$enable_profiling" = xyes; then
 108   CXXFLAGS="$CXXFLAGS -DPROFILING"
 109   VBA_SRC_EXTRA="$VBA_SRC_EXTRA prof"
 110   VBA_LIBS="$VBA_LIBS ../prof/libprof.a"
 111 fi
 112
 113 if test "x$with_mmx" = xyes; then
 114   if test "x$NASM" = x; then
 115     AC_MSG_ERROR([*** Couldn't find nasm program.])
 116   fi
 117   CXXFLAGS="$CXXFLAGS -DMMX"
 118   VBA_SRC_EXTRA="$VBA_SRC_EXTRA i386"
 119   VBA_LIBS="$VBA_LIBS ../i386/lib386.a"
 120 fi
 121
 122 if test "x$enable_sdl" = xyes || test "x$enable_gtk" = xyes; then
 123   SDL_VERSION=1.2.2
 124   AM_PATH_SDL($SDL_VERSION,[
 125   ],[
 126   AC_MSG_ERROR([*** Couldn't find SDL library (version >= $SDL_VERSION).])
 127   ])
 128 fi
 129
 130 if test "x$enable_sdl" = xyes; then
 131   VBA_SRC_EXTRA="$VBA_SRC_EXTRA sdl"
 132 fi
 133
 134 if test "x$enable_gtk" = xyes; then
 135   dnl Internationalisation support.
 136   ALL_LINGUAS="fr"
 137   AM_GNU_GETTEXT(external)
 138   AC_CHECK_HEADERS(libintl.h)
 139   GETTEXT_PACKAGE=vba-1.8.0
 140   AC_SUBST(GETTEXT_PACKAGE)
 141
 142   PKG_CHECK_MODULES(GTKMM, gtkmm-$gtk_version >= 2.0.0 libglademm-$gtk_version >= 2.1.0)
 143   AC_SUBST(GTKMM_CFLAGS)
 144   AC_SUBST(GTKMM_LIBS)
 145   if test "x$gtk_version" = x2.0; then
 146     GTKMM_CPPFLAGS="-DGTKMM20"
 147   fi
 148   AC_SUBST(GTKMM_CPPFLAGS)
 149   VBA_EXTRA="$VBA_EXTRA po"
 150   VBA_SRC_EXTRA="$VBA_SRC_EXTRA gtk"
 151 fi
 152
 153 if test "x$enable_dev" = xyes; then
 154   CXXFLAGS="$CXXFLAGS -DDEV_VERSION"
 155 fi
 156
 157 if test "x$enable_sdl" != xyes && test "x$enable_gtk" != xyes; then
 158   AC_MSG_WARN([*** You have chosen not to build any frontend.])
 159 fi
 160
 161 AC_SUBST(VBA_EXTRA)
 162 AC_SUBST(VBA_SRC_EXTRA)
 163 AC_SUBST(VBA_LIBS)
 164
 165 dnl Generated files.
 166 AC_CONFIG_FILES([
 167 Makefile
 168 m4/Makefile
 169 po/Makefile.in
 170 src/Makefile
 171 src/gb/Makefile
 172 src/gtk/Makefile
 173 src/gtk/images/Makefile
 174 src/i386/Makefile
 175 src/prof/Makefile
 176 src/sdl/Makefile
 177 win32/Makefile
 178 ])
 179 AC_OUTPUT