ROX-Filer/src/Docs/to_html_alt.xsl

   1 <?xml version="1.0"?>
   2
   3 <xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
   4                 version='1.0'>
   5
   6   <xsl:import href="/usr/share/xml/docbook/stylesheet/nwalsh/current/xhtml/docbook.xsl"/>
   7 <!--
   8   <xsl:param name="generate.component.toc">0</xsl:param>
   9 -->
  10   <xsl:template name="head.content">
  11     <link rel="stylesheet" href="../style.css" type="text/css" media="all"/>
  12     <title><xsl:value-of select='/book/bookinfo/title'/></title>
  13   </xsl:template>
  14
  15   <xsl:template match="guimenuitem">
  16     <span class="guimenuitem">
  17       <xsl:call-template name="inline.charseq"/>
  18     </span>
  19   </xsl:template>
  20
  21   <xsl:template match="function">
  22     <span class="function"><xsl:apply-templates/></span>
  23   </xsl:template>
  24
  25   <xsl:template match="parameter">
  26     <span class="parameter"><xsl:apply-templates/></span>
  27   </xsl:template>
  28
  29   <xsl:template match="filename">`<tt class="filename"><xsl:apply-templates/></tt>'</xsl:template>
  30
  31   <xsl:template match="keycap">
  32     <span class="keycap"><xsl:apply-templates/></span>
  33   </xsl:template>
  34
  35   <xsl:template match="book">
  36     <div class='chapter'>
  37       <xsl:call-template name="book.titlepage"/>
  38       <xsl:call-template name="division.toc"/>
  39     </div>
  40     <xsl:apply-templates/>
  41   </xsl:template>
  42
  43   <xsl:template match="othercredit" mode="titlepage.mode">
  44     <h3 class="{name(.)}"><xsl:call-template name="person.name"/></h3>
  45     <xsl:apply-templates mode="titlepage.mode" select="./contrib"/>
  46     <xsl:apply-templates mode="titlepage.mode" select="./affiliation"/>
  47   </xsl:template>
  48
  49   <xsl:template match="emphasis">
  50     <xsl:choose>
  51       <xsl:when test="@role='underline'">
  52         <u><xsl:apply-templates/></u>
  53       </xsl:when>
  54       <xsl:otherwise>
  55         <xsl:apply-imports/>
  56       </xsl:otherwise>
  57     </xsl:choose>
  58   </xsl:template>
  59
  60   <xsl:template match="citation">
  61     <xsl:text>[</xsl:text>
  62     <xsl:variable name="cited"><xsl:value-of select="."/></xsl:variable>
  63     <a href="#{generate-id(/book/bibliography/bibliomixed[string(abbrev/.) = $cited])}">
  64       <xsl:call-template name="inline.charseq"/>
  65     </a>
  66     <xsl:text>]</xsl:text>
  67   </xsl:template>
  68
  69   <xsl:template match="bibliomixed">
  70     <div xmlns="http://www.w3.org/1999/xhtml" class="{name(.)}" id="{generate-id(.)}">
  71       <xsl:call-template name="anchor"/>
  72       <p class="{name(.)}">
  73         <xsl:call-template name="biblioentry.label"/>
  74         <xsl:apply-templates mode="bibliomixed.mode"/>
  75       </p>
  76     </div>
  77   </xsl:template>
  78
  79   <xsl:template match="email">
  80     <xsl:call-template name="inline.monoseq">
  81       <xsl:with-param name="content">
  82         <xsl:text>&lt;</xsl:text>
  83         <xsl:apply-templates/>
  84         <xsl:text>&gt;</xsl:text>
  85       </xsl:with-param>
  86     </xsl:call-template>
  87   </xsl:template>
  88
  89 </xsl:stylesheet>