configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_INIT()
   4 AC_CONFIG_SRCDIR([byteorder.h])
   5 AC_CONFIG_HEADER(config.h)
   6 AC_PREREQ(2.59)
   7
   8 RSYNC_VERSION=2.6.5
   9 AC_SUBST(RSYNC_VERSION)
  10 AC_MSG_NOTICE([Configuring rsync $RSYNC_VERSION])
  11
  12 AC_DEFINE_UNQUOTED(RSYNC_VERSION, ["$RSYNC_VERSION"], [rsync release version])
  13
  14 LDFLAGS=${LDFLAGS-""}
  15
  16 AC_CANONICAL_TARGET([])
  17
  18 dnl Checks for programs.
  19 AC_PROG_CC
  20 AC_PROG_CPP
  21 AC_PROG_EGREP
  22 AC_PROG_INSTALL
  23 AC_PROG_CC_STDC
  24 AC_SUBST(SHELL)
  25
  26 AC_DEFINE([_GNU_SOURCE], 1,
  27           [Define _GNU_SOURCE so that we get all necessary prototypes])
  28
  29 if test "x$ac_cv_prog_cc_stdc" = xno
  30 then
  31         AC_MSG_WARN([rsync requires an ANSI C compiler and you don't seem to have one])
  32 fi
  33
  34 # We must decide this before testing the compiler.
  35
  36 # Please allow this to default to yes, so that your users have more
  37 # chance of getting a useful stack trace if problems occur.
  38
  39 AC_MSG_CHECKING([whether to include debugging symbols])
  40 AC_ARG_ENABLE(debug,
  41         AC_HELP_STRING([--enable-debug],
  42                 [including debugging symbols and features (default yes)]),
  43                 [], [])
  44
  45 if test x"$enable_debug" = x"no"
  46 then
  47     AC_MSG_RESULT(no)
  48     CFLAGS=${CFLAGS-"-O"}
  49 else
  50     AC_MSG_RESULT([yes])
  51     # leave CFLAGS alone; AC_PROG_CC will try to include -g if it can
  52     dnl AC_DEFINE(DEBUG, 1, [Define to turn on debugging code that may slow normal operation])
  53     dnl CFLAGS=${CFLAGS-"-g"}
  54 fi
  55
  56
  57
  58
  59 AC_ARG_ENABLE(profile,
  60         AC_HELP_STRING([--enable-profile],
  61                 [turn on CPU profiling (default no)],
  62                 [], []))
  63 if test x"$enable_profile" = xyes
  64 then
  65         CFLAGS="$CFLAGS -pg"
  66 fi
  67
  68
  69 # Specifically, this turns on panic_action handling.
  70 AC_ARG_ENABLE(maintainer-mode,
  71         AC_HELP_STRING([--enable-maintainer-mode],
  72                 [turn on extra debug features],
  73                 [], []))
  74 if test x"$enable_maintainer_mode" = xyes
  75 then
  76         CFLAGS="$CFLAGS -DMAINTAINER_MODE"
  77 fi
  78
  79
  80 # This is needed for our included version of popt.  Kind of silly, but
  81 # I don't want our version too far out of sync.
  82 CFLAGS="$CFLAGS -DHAVE_CONFIG_H"
  83
  84 # If GCC, turn on warnings.
  85 if test x"$GCC" = x"yes"
  86 then
  87         CFLAGS="$CFLAGS -Wall -W"
  88 fi
  89
  90 AC_ARG_WITH(included-popt,
  91         [  --with-included-popt    use bundled popt library, not from system])
  92
  93 AC_ARG_WITH(rsync-path,
  94         [  --with-rsync-path=PATH  set default --rsync-path to PATH (default: rsync)],
  95         [ RSYNC_PATH="$with_rsync_path" ],
  96         [ RSYNC_PATH="rsync" ])
  97
  98 AC_DEFINE_UNQUOTED(RSYNC_PATH, "$RSYNC_PATH", [location of rsync on remote machine])
  99
 100 AC_ARG_WITH(rsyncd-conf,
 101         AC_HELP_STRING([--with-rsyncd-conf=PATH], [set configuration file for rsync server to PATH (default: /etc/rsyncd.conf)]),
 102         [ if test ! -z "$with_rsyncd_conf" ; then
 103                 case $with_rsyncd_conf in
 104                         yes|no)
 105                                 RSYNCD_SYSCONF="/etc/rsyncd.conf"
 106                                 ;;
 107                         /*)
 108                                 RSYNCD_SYSCONF="$with_rsyncd_conf"
 109                                 ;;
 110                         *)
 111                                 AC_MSG_ERROR(You must specify an absolute path to --with-rsyncd-conf=PATH)
 112                                 ;;
 113                 esac
 114         else
 115                 RSYNCD_SYSCONF="/etc/rsyncd.conf"
 116         fi ],
 117         [ RSYNCD_SYSCONF="/etc/rsyncd.conf" ])
 118
 119 AC_DEFINE_UNQUOTED(RSYNCD_SYSCONF, "$RSYNCD_SYSCONF", [location of configuration file for rsync server])
 120
 121 AC_ARG_WITH(rsh,
 122         AC_HELP_STRING([--with-rsh=CMD], [set remote shell command to CMD (default: ssh)]))
 123
 124 AC_CHECK_PROG(HAVE_REMSH, remsh, 1, 0)
 125 if test x$HAVE_REMSH = x1; then
 126         AC_DEFINE(HAVE_REMSH, 1, [Define to 1 if remote shell is remsh, not rsh])
 127 fi
 128
 129 if test x"$with_rsh" != x
 130 then
 131         RSYNC_RSH="$with_rsh"
 132 else
 133         RSYNC_RSH="ssh"
 134 fi
 135
 136 AC_DEFINE_UNQUOTED(RSYNC_RSH, "$RSYNC_RSH", [default -e command])
 137
 138 # arrgh. libc in the current debian stable screws up the largefile
 139 # stuff, getting byte range locking wrong
 140 AC_CACHE_CHECK([for broken largefile support],rsync_cv_HAVE_BROKEN_LARGEFILE,[
 141 AC_TRY_RUN([
 142 #define _FILE_OFFSET_BITS 64
 143 #include <stdio.h>
 144 #include <fcntl.h>
 145 #include <sys/types.h>
 146 #include <sys/wait.h>
 147
 148 int main(void)
 149 {
 150         struct flock lock;
 151         int status;
 152         char tpl[32] = "/tmp/locktest.XXXXXX";
 153         int fd = mkstemp(tpl);
 154         if (fd < 0) {
 155                 strcpy(tpl, "conftest.dat");
 156                 fd = open(tpl, O_CREAT|O_RDWR, 0600);
 157         }
 158
 159         lock.l_type = F_WRLCK;
 160         lock.l_whence = SEEK_SET;
 161         lock.l_start = 0;
 162         lock.l_len = 1;
 163         lock.l_pid = 0;
 164         fcntl(fd,F_SETLK,&lock);
 165         if (fork() == 0) {
 166                 lock.l_start = 1;
 167                 _exit(fcntl(fd,F_SETLK,&lock) == 0);
 168         }
 169         wait(&status);
 170         unlink(tpl);
 171         exit(WEXITSTATUS(status));
 172 }
 173 ],
 174 rsync_cv_HAVE_BROKEN_LARGEFILE=yes,rsync_cv_HAVE_BROKEN_LARGEFILE=no,rsync_cv_HAVE_BROKEN_LARGEFILE=cross)])
 175 if test x"$rsync_cv_HAVE_BROKEN_LARGEFILE" != x"yes"; then
 176    AC_SYS_LARGEFILE
 177 fi
 178
 179 ipv6type=unknown
 180 ipv6lib=none
 181 ipv6trylibc=yes
 182
 183 AC_ARG_ENABLE(ipv6,
 184         AC_HELP_STRING([--disable-ipv6], [don't even try to use IPv6]))
 185
 186 dnl Do you want to disable use of locale functions
 187 AH_TEMPLATE([CONFIG_LOCALE],
 188 [Undefine if you don't want locale features.  By default this is defined.])
 189 AC_ARG_ENABLE([locale],
 190         AC_HELP_STRING([--disable-locale], [turn off locale features]),
 191 [if test x$enableval = xyes; then
 192   AC_DEFINE(CONFIG_LOCALE)
 193 fi],
 194 AC_DEFINE(CONFIG_LOCALE)
 195 )
 196
 197 if test "x$enable_ipv6" != xno
 198 then
 199         AC_MSG_CHECKING([ipv6 stack type])
 200         for i in inria kame linux-glibc linux-inet6 toshiba v6d zeta; do
 201                 case $i in
 202                 inria)
 203                         # http://www.kame.net/
 204                         AC_EGREP_CPP(yes, [
 205 #include <netinet/in.h>
 206 #ifdef IPV6_INRIA_VERSION
 207 yes
 208 #endif],
 209                                 [ipv6type=$i;
 210                                 AC_DEFINE(INET6, 1, [true if you have IPv6])
 211                                 ])
 212                         ;;
 213                 kame)
 214                         # http://www.kame.net/
 215                         AC_EGREP_CPP(yes, [
 216 #include <netinet/in.h>
 217 #ifdef __KAME__
 218 yes
 219 #endif],
 220                                 [ipv6type=$i;
 221                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 222                         ;;
 223                 linux-glibc)
 224                         # http://www.v6.linux.or.jp/
 225                         AC_EGREP_CPP(yes, [
 226 #include <features.h>
 227 #if defined(__GLIBC__) && __GLIBC__ >= 2 && __GLIBC_MINOR__ >= 1
 228 yes
 229 #endif],
 230                                 [ipv6type=$i;
 231 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 232                         ;;
 233                 linux-inet6)
 234                         # http://www.v6.linux.or.jp/
 235                         if test -d /usr/inet6 -o -f /usr/inet6/lib/libinet6.a; then
 236                                 ipv6type=$i
 237                                 ipv6lib=inet6
 238                                 ipv6libdir=/usr/inet6/lib
 239                                 ipv6trylibc=yes;
 240                                 AC_DEFINE(INET6, 1, [true if you have IPv6])
 241                                 CFLAGS="-I/usr/inet6/include $CFLAGS"
 242                         fi
 243                         ;;
 244                 toshiba)
 245                         AC_EGREP_CPP(yes, [
 246 #include <sys/param.h>
 247 #ifdef _TOSHIBA_INET6
 248 yes
 249 #endif],
 250                                 [ipv6type=$i;
 251                                 ipv6lib=inet6;
 252                                 ipv6libdir=/usr/local/v6/lib;
 253                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 254                         ;;
 255                 v6d)
 256                         AC_EGREP_CPP(yes, [
 257 #include </usr/local/v6/include/sys/v6config.h>
 258 #ifdef __V6D__
 259 yes
 260 #endif],
 261                                 [ipv6type=$i;
 262                                 ipv6lib=v6;
 263                                 ipv6libdir=/usr/local/v6/lib;
 264                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 265                         ;;
 266                 zeta)
 267                         AC_EGREP_CPP(yes, [
 268 #include <sys/param.h>
 269 #ifdef _ZETA_MINAMI_INET6
 270 yes
 271 #endif],
 272                                 [ipv6type=$i;
 273                                 ipv6lib=inet6;
 274                                 ipv6libdir=/usr/local/v6/lib;
 275                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 276                         ;;
 277                 esac
 278                 if test "$ipv6type" != "unknown"; then
 279                         break
 280                 fi
 281         done
 282         AC_MSG_RESULT($ipv6type)
 283
 284         AC_SEARCH_LIBS(getaddrinfo, inet6)
 285 fi
 286
 287 AC_MSG_CHECKING([whether to call shutdown on all sockets])
 288 case $host_os in
 289         *cygwin* ) AC_MSG_RESULT(yes)
 290                    AC_DEFINE(SHUTDOWN_ALL_SOCKETS, 1,
 291                             [Define to 1 if sockets need to be shutdown])
 292                    ;;
 293                * ) AC_MSG_RESULT(no);;
 294 esac
 295
 296 AC_C_BIGENDIAN
 297 AC_HEADER_DIRENT
 298 AC_HEADER_TIME
 299 AC_HEADER_SYS_WAIT
 300 AC_CHECK_HEADERS(sys/fcntl.h sys/select.h fcntl.h sys/time.h sys/unistd.h \
 301     unistd.h utime.h grp.h compat.h sys/param.h ctype.h sys/wait.h \
 302     sys/ioctl.h sys/filio.h string.h stdlib.h sys/socket.h sys/mode.h \
 303     sys/un.h glob.h mcheck.h arpa/inet.h arpa/nameser.h locale.h \
 304     netdb.h malloc.h float.h)
 305 AC_HEADER_MAJOR
 306
 307 AC_CHECK_SIZEOF(int)
 308 AC_CHECK_SIZEOF(long)
 309 AC_CHECK_SIZEOF(long long)
 310 AC_CHECK_SIZEOF(short)
 311 AC_CHECK_SIZEOF(off_t)
 312 AC_CHECK_SIZEOF(off64_t)
 313
 314 AC_C_INLINE
 315 AC_C_LONG_DOUBLE
 316
 317 AC_TYPE_SIGNAL
 318 AC_TYPE_UID_T
 319 AC_TYPE_MODE_T
 320 AC_TYPE_OFF_T
 321 AC_TYPE_SIZE_T
 322 AC_TYPE_PID_T
 323 AC_TYPE_GETGROUPS
 324 AC_CHECK_MEMBERS([struct stat.st_rdev])
 325
 326 TYPE_SOCKLEN_T
 327
 328 AC_CACHE_CHECK([for errno in errno.h],rsync_cv_errno, [
 329     AC_TRY_COMPILE([#include <errno.h>],[int i = errno],
 330         rsync_cv_errno=yes,rsync_cv_have_errno_decl=no)])
 331 if test x"$rsync_cv_errno" = x"yes"; then
 332    AC_DEFINE(HAVE_ERRNO_DECL, 1, [Define to 1 if errno is declared in errno.h])
 333 fi
 334
 335 # The following test taken from the cvs sources
 336 # If we can't find connect, try looking in -lsocket, -lnsl, and -linet.
 337 # These need checks to be before checks for any other functions that
 338 #    might be in the same libraries.
 339 # The Irix 5 libc.so has connect and gethostbyname, but Irix 5 also has
 340 # libsocket.so which has a bad implementation of gethostbyname (it
 341 # only looks in /etc/hosts), so we only look for -lsocket if we need
 342 # it.
 343 AC_CHECK_FUNCS(connect)
 344 if test x"$ac_cv_func_connect" = x"no"; then
 345     case "$LIBS" in
 346     *-lnsl*) ;;
 347     *) AC_CHECK_LIB(nsl_s, printf) ;;
 348     esac
 349     case "$LIBS" in
 350     *-lnsl*) ;;
 351     *) AC_CHECK_LIB(nsl, printf) ;;
 352     esac
 353     case "$LIBS" in
 354     *-lsocket*) ;;
 355     *) AC_CHECK_LIB(socket, connect) ;;
 356     esac
 357     case "$LIBS" in
 358     *-linet*) ;;
 359     *) AC_CHECK_LIB(inet, connect) ;;
 360     esac
 361     dnl We can't just call AC_CHECK_FUNCS(connect) here, because the value
 362     dnl has been cached.
 363     if test x"$ac_cv_lib_socket_connect" = x"yes" ||
 364        test x"$ac_cv_lib_inet_connect" = x"yes"; then
 365         # ac_cv_func_connect=yes
 366         # don't!  it would cause AC_CHECK_FUNC to succeed next time configure is run
 367         AC_DEFINE(HAVE_CONNECT, 1, [Define to 1 if you have the "connect" function])
 368     fi
 369 fi
 370
 371 AC_CHECK_LIB(resolv, inet_ntop)
 372
 373 dnl AC_MSG_NOTICE([Looking in libraries: $LIBS])
 374
 375 AC_CHECK_FUNCS(inet_ntop, , [AC_LIBOBJ(lib/inet_ntop)])
 376 AC_CHECK_FUNCS(inet_pton, , [AC_LIBOBJ(lib/inet_pton)])
 377
 378 # Irix 6.5 has getaddrinfo but not the corresponding defines, so use
 379 #   builtin getaddrinfo if one of the defines don't exist
 380 AC_CACHE_CHECK([whether defines needed by getaddrinfo exist],
 381                rsync_cv_HAVE_GETADDR_DEFINES,[
 382                         AC_EGREP_CPP(yes, [
 383                         #include <sys/types.h>
 384                         #include <sys/socket.h>
 385                         #include <netdb.h>
 386                         #ifdef AI_PASSIVE
 387                         yes
 388                         #endif],
 389                         rsync_cv_HAVE_GETADDR_DEFINES=yes,
 390                         rsync_cv_HAVE_GETADDR_DEFINES=no)])
 391 if test x"$rsync_cv_HAVE_GETADDR_DEFINES" = x"yes"; then
 392         # Tru64 UNIX has getaddrinfo() but has it renamed in libc as
 393         # something else so we must include <netdb.h> to get the
 394         # redefinition.
 395         AC_CHECK_FUNCS(getaddrinfo, ,
 396                 [AC_MSG_CHECKING([for getaddrinfo by including <netdb.h>])
 397                 AC_TRY_LINK([#include <sys/types.h>
 398                 #include <sys/socket.h>
 399                 #include <netdb.h>],[getaddrinfo(NULL, NULL, NULL, NULL);],
 400                         [AC_MSG_RESULT([yes])
 401                         AC_DEFINE(HAVE_GETADDRINFO, 1,
 402                                 [Define to 1 if you have the "getaddrinfo" function.])],
 403                         [AC_MSG_RESULT([no])
 404                         AC_LIBOBJ(lib/getaddrinfo)])])
 405         AC_CHECK_FUNCS(getnameinfo, , [AC_LIBOBJ(lib/getnameinfo)])
 406 else
 407         AC_LIBOBJ(lib/getaddrinfo)
 408         AC_LIBOBJ(lib/getnameinfo)
 409 fi
 410
 411 AC_CHECK_MEMBER([struct sockaddr.sa_len],
 412                 [ AC_DEFINE(HAVE_SOCKADDR_LEN, 1, [Do we have sockaddr.sa_len?]) ],
 413                 [],
 414                 [
 415 #include <sys/types.h>
 416 #include <sys/socket.h>
 417 ])
 418
 419 AC_CHECK_MEMBER([struct sockaddr_in.sin_len],
 420                 [ AC_DEFINE(HAVE_SOCKADDR_IN_LEN, 1, [Do we have sockaddr_in.sin_len?]) ],
 421                 [],
 422                 [
 423 #include <sys/types.h>
 424 #include <sys/socket.h>
 425 #include <netinet/in.h>
 426 ])
 427
 428 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
 429                 [ AC_DEFINE(HAVE_SOCKADDR_UN_LEN, 1, [Do we have sockaddr_un.sun_len?]) ],
 430                 [],
 431                 [
 432 #include <sys/types.h>
 433 #include <sys/socket.h>
 434 #include <netinet/in.h>
 435 ])
 436
 437 AC_MSG_CHECKING(struct sockaddr_storage)
 438 AC_TRY_COMPILE([#include <sys/types.h>
 439 #include <sys/socket.h>],
 440 [struct sockaddr_storage x;],
 441         AC_MSG_RESULT(yes)
 442         AC_DEFINE(HAVE_SOCKADDR_STORAGE, 1,
 443                 [Define to 1 if you have struct sockaddr_storage.] ),
 444         AC_MSG_RESULT(no))
 445
 446 AC_CHECK_MEMBER([struct sockaddr_in6.sin6_scope_id],
 447                 [ AC_DEFINE(HAVE_SOCKADDR_IN6_SCOPE_ID, 1, [Do we have sockaddr_in6.sin6_scope_id?]) ],
 448                 [],
 449                 [
 450 #include <sys/types.h>
 451 #include <sys/socket.h>
 452 #include <netinet/in.h>
 453 ])
 454
 455 AC_MSG_CHECKING(struct stat64)
 456 AC_TRY_COMPILE([#include <stdio.h>
 457 #if HAVE_SYS_TYPES_H
 458 # include <sys/types.h>
 459 #endif
 460 #if HAVE_SYS_STAT_H
 461 # include <sys/stat.h>
 462 #endif
 463 #if STDC_HEADERS
 464 # include <stdlib.h>
 465 # include <stddef.h>
 466 #else
 467 # if HAVE_STDLIB_H
 468 #  include <stdlib.h>
 469 # endif
 470 #endif
 471 ],[struct stat64 st;],
 472     AC_MSG_RESULT(yes)
 473         AC_DEFINE(HAVE_STRUCT_STAT64,1,[Define to 1 if you have struct stat64.]),
 474     AC_MSG_RESULT(no))
 475
 476 # if we can't find strcasecmp, look in -lresolv (for Unixware at least)
 477 #
 478 AC_CHECK_FUNCS(strcasecmp)
 479 if test x"$ac_cv_func_strcasecmp" = x"no"; then
 480     AC_CHECK_LIB(resolv, strcasecmp)
 481 fi
 482
 483 dnl At the moment we don't test for a broken memcmp(), because all we
 484 dnl need to do is test for equality, not comparison, and it seems that
 485 dnl every platform has a memcmp that can do at least that.
 486 dnl AC_FUNC_MEMCMP
 487
 488 AC_FUNC_UTIME_NULL
 489 AC_FUNC_ALLOCA
 490 AC_CHECK_FUNCS(waitpid wait4 getcwd strdup strerror chown chmod mknod mkfifo \
 491     fchmod fstat strchr readlink link utime utimes strftime mtrace ftruncate \
 492     memmove lchown vsnprintf snprintf vasprintf asprintf setsid glob strpbrk \
 493     strlcat strlcpy strtol mallinfo getgroups setgroups geteuid getegid \
 494     setlocale setmode open64 lseek64 mkstemp64 va_copy __va_copy)
 495
 496 AC_CHECK_FUNCS(getpgrp tcgetpgrp)
 497 if test $ac_cv_func_getpgrp = yes; then
 498     AC_FUNC_GETPGRP
 499 fi
 500
 501 # Determine whether chown follows symlinks (it should).
 502 AC_CACHE_CHECK([whether chown() dereferences symlinks],rsync_cv_chown_follows_symlink,[
 503   AC_TRY_RUN([
 504 #if HAVE_UNISTD_H
 505 # include <unistd.h>
 506 #endif
 507 #include <stdlib.h>
 508 #include <errno.h>
 509     main() {
 510         char const *dangling_symlink = "conftest.dangle";
 511         unlink(dangling_symlink);
 512         if (symlink("conftest.no-such", dangling_symlink) < 0) abort();
 513         if (chown(dangling_symlink, getuid(), getgid()) < 0 && errno == ENOENT) exit(0);
 514         exit(1);
 515     }],
 516   rsync_cv_chown_follows_symlink=yes,rsync_cv_chown_follows_symlink=no,rsync_cv_chown_follows_symlink=yes)])
 517 if test $rsync_cv_chown_follows_symlink = no; then
 518   AC_DEFINE(CHOWN_MODIFIES_SYMLINK, 1, [Define to 1 if chown modifies symlinks.])
 519 fi
 520
 521 AC_CACHE_CHECK([for working socketpair],rsync_cv_HAVE_SOCKETPAIR,[
 522 AC_TRY_RUN([
 523 #include <sys/types.h>
 524 #include <sys/socket.h>
 525
 526 main() {
 527        int fd[2];
 528        exit((socketpair(AF_UNIX, SOCK_STREAM, 0, fd) != -1) ? 0 : 1);
 529 }],
 530 rsync_cv_HAVE_SOCKETPAIR=yes,rsync_cv_HAVE_SOCKETPAIR=no,rsync_cv_HAVE_SOCKETPAIR=cross)])
 531 if test x"$rsync_cv_HAVE_SOCKETPAIR" = x"yes"; then
 532     AC_DEFINE(HAVE_SOCKETPAIR, 1, [Define to 1 if you have the "socketpair" function])
 533 fi
 534
 535 if test x"$with_included_popt" != x"yes"
 536 then
 537     AC_CHECK_LIB(popt, poptGetContext, , [with_included_popt=yes])
 538 fi
 539
 540 AC_MSG_CHECKING([whether to use included libpopt])
 541 if test x"$with_included_popt" = x"yes"
 542 then
 543     AC_MSG_RESULT($srcdir/popt)
 544     BUILD_POPT='$(popt_OBJS)'
 545     CFLAGS="$CFLAGS -I$srcdir/popt"
 546     if test x"$ALLOCA" != x
 547     then
 548         # this can be removed when/if we add an included alloca.c;
 549         #  see autoconf documentation on AC_FUNC_ALLOCA
 550         AC_MSG_WARN([included libpopt will use malloc, not alloca (which wastes a small amount of memory)])
 551     fi
 552 else
 553     AC_MSG_RESULT(no)
 554 fi
 555
 556 AC_CACHE_CHECK([for unsigned char],rsync_cv_SIGNED_CHAR_OK,[
 557 AC_TRY_COMPILE([],[signed char *s = ""],
 558 rsync_cv_SIGNED_CHAR_OK=yes,rsync_cv_SIGNED_CHAR_OK=no)])
 559 if test x"$rsync_cv_SIGNED_CHAR_OK" = x"yes"; then
 560     AC_DEFINE(SIGNED_CHAR_OK, 1, [Define to 1 if "signed char" is a valid type])
 561 fi
 562
 563 AC_CACHE_CHECK([for broken readdir],rsync_cv_HAVE_BROKEN_READDIR,[
 564 AC_TRY_RUN([#include <sys/types.h>
 565 #include <dirent.h>
 566 main() { struct dirent *di; DIR *d = opendir("."); di = readdir(d);
 567 if (di && di->d_name[-2] == '.' && di->d_name[-1] == 0 &&
 568 di->d_name[0] == 0) exit(0); exit(1);} ],
 569 rsync_cv_HAVE_BROKEN_READDIR=yes,rsync_cv_HAVE_BROKEN_READDIR=no,rsync_cv_HAVE_BROKEN_READDIR=cross)])
 570 if test x"$rsync_cv_HAVE_BROKEN_READDIR" = x"yes"; then
 571     AC_DEFINE(HAVE_BROKEN_READDIR, 1, [Define to 1 if readdir() is broken])
 572 fi
 573
 574 AC_CACHE_CHECK([for utimbuf],rsync_cv_HAVE_UTIMBUF,[
 575 AC_TRY_COMPILE([#include <sys/types.h>
 576 #include <utime.h>],
 577 [struct utimbuf tbuf;  tbuf.actime = 0; tbuf.modtime = 1; exit(utime("foo.c",&tbuf));],
 578 rsync_cv_HAVE_UTIMBUF=yes,rsync_cv_HAVE_UTIMBUF=no)])
 579 if test x"$rsync_cv_HAVE_UTIMBUF" = x"yes"; then
 580     AC_DEFINE(HAVE_UTIMBUF, 1, [Define to 1 if you have the "struct utimbuf" type])
 581 fi
 582
 583 AC_CACHE_CHECK([if gettimeofday takes tz argument],rsync_cv_HAVE_GETTIMEOFDAY_TZ,[
 584 AC_TRY_COMPILE([#include <sys/time.h>
 585 #include <unistd.h>],
 586 [struct timeval tv; exit(gettimeofday(&tv, NULL));],
 587 rsync_cv_HAVE_GETTIMEOFDAY_TZ=yes,rsync_cv_HAVE_GETTIMEOFDAY_TZ=no)])
 588 if test x"$rsync_cv_HAVE_GETTIMEOFDAY_TZ" != x"no"; then
 589     AC_DEFINE(HAVE_GETTIMEOFDAY_TZ, 1, [Define to 1 if gettimeofday() takes a time-zone arg])
 590 fi
 591
 592 AC_CACHE_CHECK([for C99 vsnprintf],rsync_cv_HAVE_C99_VSNPRINTF,[
 593 AC_TRY_RUN([
 594 #include <sys/types.h>
 595 #include <stdarg.h>
 596 void foo(const char *format, ...) {
 597        va_list ap;
 598        int len;
 599        char buf[5];
 600
 601        va_start(ap, format);
 602        len = vsnprintf(0, 0, format, ap);
 603        va_end(ap);
 604        if (len != 5) exit(1);
 605
 606        if (snprintf(buf, 3, "hello") != 5 || strcmp(buf, "he") != 0) exit(1);
 607
 608        exit(0);
 609 }
 610 main() { foo("hello"); }
 611 ],
 612 rsync_cv_HAVE_C99_VSNPRINTF=yes,rsync_cv_HAVE_C99_VSNPRINTF=no,rsync_cv_HAVE_C99_VSNPRINTF=cross)])
 613 if test x"$rsync_cv_HAVE_C99_VSNPRINTF" = x"yes"; then
 614     AC_DEFINE(HAVE_C99_VSNPRINTF, 1, [Define to 1 if vsprintf has a C99-compatible return value])
 615 fi
 616
 617
 618 AC_CACHE_CHECK([for secure mkstemp],rsync_cv_HAVE_SECURE_MKSTEMP,[
 619 AC_TRY_RUN([#include <stdlib.h>
 620 #include <sys/types.h>
 621 #include <sys/stat.h>
 622 #include <unistd.h>
 623 main() {
 624   struct stat st;
 625   char tpl[20]="/tmp/test.XXXXXX";
 626   int fd = mkstemp(tpl);
 627   if (fd == -1) exit(1);
 628   unlink(tpl);
 629   if (fstat(fd, &st) != 0) exit(1);
 630   if ((st.st_mode & 0777) != 0600) exit(1);
 631   exit(0);
 632 }],
 633 rsync_cv_HAVE_SECURE_MKSTEMP=yes,
 634 rsync_cv_HAVE_SECURE_MKSTEMP=no,
 635 rsync_cv_HAVE_SECURE_MKSTEMP=cross)])
 636 if test x"$rsync_cv_HAVE_SECURE_MKSTEMP" = x"yes"; then
 637     case $target_os in
 638     hpux*)
 639         dnl HP-UX has a broken mkstemp() implementation they refuse to fix,
 640         dnl so we noisily skip using it.  See HP change request JAGaf34426
 641         dnl for details. (sbonds)
 642         AC_MSG_WARN(Skipping broken HP-UX mkstemp() -- using mktemp() instead)
 643         ;;
 644     *)
 645         AC_DEFINE(HAVE_SECURE_MKSTEMP, 1, [Define to 1 if mkstemp() is available and works right])
 646         ;;
 647     esac
 648 fi
 649
 650
 651 AC_CACHE_CHECK([for broken inet_ntoa],rsync_cv_REPLACE_INET_NTOA,[
 652 AC_TRY_RUN([
 653 #include <stdio.h>
 654 #include <sys/types.h>
 655 #include <netinet/in.h>
 656 #include <arpa/inet.h>
 657 main() { struct in_addr ip; ip.s_addr = 0x12345678;
 658 if (strcmp(inet_ntoa(ip),"18.52.86.120") &&
 659     strcmp(inet_ntoa(ip),"120.86.52.18")) { exit(1); }
 660 exit(0);}],
 661            rsync_cv_REPLACE_INET_NTOA=no,rsync_cv_REPLACE_INET_NTOA=yes,rsync_cv_REPLACE_INET_NTOA=cross)])
 662 if test x"$rsync_cv_REPLACE_INET_NTOA" = x"yes"; then
 663     AC_DEFINE(REPLACE_INET_NTOA, 1, [Define to 1 if inet_ntoa() needs to be replaced])
 664 fi
 665
 666
 667 AC_CACHE_CHECK([for broken inet_aton],rsync_cv_REPLACE_INET_ATON,[
 668 AC_TRY_RUN([
 669 #include <stdio.h>
 670 #include <sys/types.h>
 671 #include <netinet/in.h>
 672 #include <arpa/inet.h>
 673 main() { struct in_addr ip;
 674 if (inet_aton("example", &ip) == 0) exit(0); exit(1);}],
 675            rsync_cv_REPLACE_INET_ATON=no,rsync_cv_REPLACE_INET_ATON=yes,rsync_cv_REPLACE_INET_ATON=cross)])
 676 if test x"$rsync_cv_REPLACE_INET_ATON" = x"yes"; then
 677     AC_DEFINE(REPLACE_INET_ATON, 1, [Define to 1 if inet_aton() needs to be replaced])
 678 fi
 679
 680 AC_CACHE_CHECK([if mknod creates FIFOs],rsync_cv_MKNOD_CREATES_FIFOS,[
 681 AC_TRY_RUN([
 682 #include <stdio.h>
 683 #include <sys/stat.h>
 684 #include <errno.h>
 685 main() { int rc, ec; char *fn = "fifo-test";
 686 unlink(fn); rc = mknod(fn,S_IFIFO,0600); ec = errno; unlink(fn);
 687 if (rc) {printf("%d %d\n",rc,ec); return ec;}
 688 return 0;}],
 689            rsync_cv_MKNOD_CREATES_FIFOS=yes,rsync_cv_MKNOD_CREATES_FIFOS=no,rsync_cv_MKNOD_CREATES_FIFOS=cross)])
 690 if test x"$rsync_cv_MKNOD_CREATES_FIFOS" = x"yes"; then
 691     AC_DEFINE(MKNOD_CREATES_FIFOS, 1, [Define to 1 if mknod() can create FIFOs.])
 692 fi
 693
 694 AC_CACHE_CHECK([if mknod creates sockets],rsync_cv_MKNOD_CREATES_SOCKETS,[
 695 AC_TRY_RUN([
 696 #include <stdio.h>
 697 #include <sys/stat.h>
 698 #include <errno.h>
 699 main() { int rc, ec; char *fn = "sock-test";
 700 unlink(fn); rc = mknod(fn,S_IFSOCK,0600); ec = errno; unlink(fn);
 701 if (rc) {printf("%d %d\n",rc,ec); return ec;}
 702 return 0;}],
 703            rsync_cv_MKNOD_CREATES_SOCKETS=yes,rsync_cv_MKNOD_CREATES_SOCKETS=no,rsync_cv_MKNOD_CREATES_SOCKETS=cross)])
 704 if test x"$rsync_cv_MKNOD_CREATES_SOCKETS" = x"yes"; then
 705     AC_DEFINE(MKNOD_CREATES_SOCKETS, 1, [Define to 1 if mknod() can create sockets.])
 706 fi
 707
 708 #
 709 # The following test was mostly taken from the tcl/tk plus patches
 710 #
 711 AC_CACHE_CHECK([whether -c -o works],rsync_cv_DASHC_WORKS_WITH_DASHO,[
 712 rm -rf conftest*
 713 cat > conftest.$ac_ext <<EOF
 714 int main() { return 0; }
 715 EOF
 716 ${CC-cc} -c -o conftest..o conftest.$ac_ext
 717 if test -f conftest..o; then
 718     rsync_cv_DASHC_WORKS_WITH_DASHO=yes
 719 else
 720     rsync_cv_DASHC_WORKS_WITH_DASHO=no
 721 fi
 722 rm -rf conftest*
 723 ])
 724 if test x"$rsync_cv_DASHC_WORKS_WITH_DASHO" = x"yes"; then
 725     OBJ_SAVE="#"
 726     OBJ_RESTORE="#"
 727     CC_SHOBJ_FLAG='-o $@'
 728 else
 729     OBJ_SAVE='  @b=`basename $@ .o`;rm -f $$b.o.sav;if test -f $$b.o; then mv $$b.o $$b.o.sav;fi;'
 730     OBJ_RESTORE='       @b=`basename $@ .o`;if test "$$b.o" != "$@"; then mv $$b.o $@; if test -f $$b.o.sav; then mv $$b.o.sav $$b.o; fi; fi'
 731     CC_SHOBJ_FLAG=""
 732 fi
 733
 734 AC_SUBST(OBJ_SAVE)
 735 AC_SUBST(OBJ_RESTORE)
 736 AC_SUBST(CC_SHOBJ_FLAG)
 737 AC_SUBST(BUILD_POPT)
 738
 739 AC_CONFIG_FILES([Makefile lib/dummy zlib/dummy popt/dummy shconfig])
 740 AC_OUTPUT
 741
 742 AC_MSG_RESULT()
 743 AC_MSG_RESULT([    rsync ${RSYNC_VERSION} configuration successful])
 744 AC_MSG_RESULT()