configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_INIT([rsync],[ ],[https://rsync.samba.org/bug-tracking.html])
   4
   5 AC_C_BIGENDIAN
   6 AC_HEADER_DIRENT
   7 AC_HEADER_SYS_WAIT
   8 AC_CHECK_HEADERS(sys/fcntl.h sys/select.h fcntl.h sys/time.h sys/unistd.h \
   9     unistd.h utime.h compat.h sys/param.h ctype.h sys/wait.h sys/stat.h \
  10     sys/ioctl.h sys/filio.h string.h stdlib.h sys/socket.h sys/mode.h grp.h \
  11     sys/un.h sys/attr.h arpa/inet.h arpa/nameser.h locale.h sys/types.h \
  12     netdb.h malloc.h float.h limits.h iconv.h libcharset.h langinfo.h mcheck.h \
  13     sys/acl.h acl/libacl.h attr/xattr.h sys/xattr.h sys/extattr.h dl.h \
  14     popt.h popt/popt.h linux/falloc.h netinet/in_systm.h netgroup.h \
  15     zlib.h xxhash.h openssl/md4.h openssl/md5.h zstd.h lz4.h sys/file.h \
  16     bsd/string.h)
  17 AC_CHECK_HEADERS([netinet/ip.h], [], [], [[#include <netinet/in.h>]])
  18 AC_HEADER_MAJOR_FIXED
  19
  20 AC_CONFIG_MACRO_DIR([m4])
  21 AC_CONFIG_SRCDIR([byteorder.h])
  22 AC_CONFIG_HEADERS([config.h])
  23 AC_PREREQ([2.69])
  24
  25 PACKAGE_VERSION=`sed -n 's/.*RSYNC_VERSION.*"\(.*\)".*/\1/p' <$srcdir/version.h`
  26
  27 AC_MSG_NOTICE([Configuring rsync $PACKAGE_VERSION])
  28
  29 LDFLAGS=${LDFLAGS-""}
  30
  31 AC_CANONICAL_HOST
  32
  33 dnl define the directory for replacement function since AC_LIBOBJ does not
  34 dnl officially support subdirs and fails with automake
  35 AC_CONFIG_LIBOBJ_DIR([lib])
  36
  37 # We must decide this before testing the compiler.
  38
  39 # Please allow this to default to yes, so that your users have more
  40 # chance of getting a useful stack trace if problems occur.
  41
  42 AC_MSG_CHECKING([whether to include debugging symbols])
  43 AC_ARG_ENABLE(debug,
  44         AS_HELP_STRING([--disable-debug],[disable to omit debugging symbols and features]))
  45
  46 if test x"$enable_debug" = x"no"; then
  47     AC_MSG_RESULT(no)
  48     ac_cv_prog_cc_g=no
  49 else
  50     AC_MSG_RESULT([yes])
  51     dnl AC_DEFINE(DEBUG, 1, [Define to turn on debugging code that may slow normal operation])
  52     # leave ac_cv_prog_cc_g alone; AC_PROG_CC will try to include -g if it can
  53 fi
  54
  55 dnl Checks for programs.
  56 AC_PROG_CC
  57 AC_PROG_CPP
  58 AC_PROG_CXX
  59 AC_PROG_AWK
  60 AC_PROG_EGREP
  61 AC_PROG_INSTALL
  62 AC_PROG_MKDIR_P
  63 AC_SUBST(SHELL)
  64 AC_PATH_PROG([PERL], [perl])
  65 AC_PATH_PROG([PYTHON3], [python3])
  66
  67 AC_DEFINE([_GNU_SOURCE], 1,
  68           [Define _GNU_SOURCE so that we get all necessary prototypes])
  69
  70 if test x"$ac_cv_prog_cc_stdc" = x"no"; then
  71         AC_MSG_WARN([rsync requires an ANSI C compiler and you do not seem to have one])
  72 fi
  73
  74 no_lib=''
  75 err_msg=''
  76 nl='
  77 '
  78
  79 AC_ARG_ENABLE(profile,
  80         AS_HELP_STRING([--enable-profile],[enable to turn on CPU profiling]))
  81 if test x"$enable_profile" = x"yes"; then
  82         CFLAGS="$CFLAGS -pg"
  83 fi
  84
  85 AC_MSG_CHECKING([if md2man can create manpages])
  86 if test x"$ac_cv_path_PYTHON3" = x; then
  87     AC_MSG_RESULT(no - python3 not found)
  88     md2man_works=no
  89 else
  90     md2man_out=`"$srcdir/md2man" --test "$srcdir/rsync-ssl.1.md" 2>&1`
  91     if test $? = 0; then
  92         AC_MSG_RESULT(yes)
  93         md2man_works=yes
  94     else
  95         AC_MSG_RESULT(no)
  96         md2man_works=no
  97         echo "$md2man_out"
  98     fi
  99 fi
 100
 101 AC_MSG_CHECKING([if we require man-page building])
 102 AC_ARG_ENABLE([md2man],
 103         AS_HELP_STRING([--disable-md2man],[disable to omit manpage creation]))
 104 if test x"$enable_md2man" != x"no"; then
 105     if test -f "$srcdir/rsync.1"; then
 106         AC_MSG_RESULT(optional)
 107     else
 108         AC_MSG_RESULT(required)
 109         if test x"$md2man_works" = x"no"; then
 110             err_msg="$err_msg$nl- You need python3 and either the cmarkgfm OR commonmark python3 lib in order"
 111             err_msg="$err_msg$nl  to build manpages based on the git source (manpages are included in the"
 112             err_msg="$err_msg$nl  official release tar files)."
 113             no_lib="$no_lib md2man"
 114         fi
 115     fi
 116     MAKE_MAN=man
 117 else
 118     AC_MSG_RESULT(no)
 119 fi
 120
 121 # Specifically, this turns on panic_action handling.
 122 AC_ARG_ENABLE(maintainer-mode,
 123         AS_HELP_STRING([--enable-maintainer-mode],[enable to turn on extra debug features]))
 124 if test x"$enable_maintainer_mode" = x"yes"; then
 125         CFLAGS="$CFLAGS -DMAINTAINER_MODE"
 126 fi
 127
 128 # This is needed for our included version of popt.  Kind of silly, but
 129 # I don't want our version too far out of sync.
 130 CFLAGS="$CFLAGS -DHAVE_CONFIG_H"
 131
 132 # If GCC, turn on warnings.
 133 if test x"$GCC" = x"yes"; then
 134         CFLAGS="$CFLAGS -Wall -W"
 135 fi
 136
 137 AC_ARG_WITH(openssl-conf,
 138         AS_HELP_STRING([--with-openssl-conf=PATH],[set default OPENSSL_CONF path for rsync]))
 139 case "$with_openssl_conf" in
 140     *[^-/a-zA-Z0-9.,=@+_]*) AC_MSG_ERROR([Invalid path given to --with-openssl-conf]) ;;
 141     /*) CFLAGS="$CFLAGS -DSET_OPENSSL_CONF=$with_openssl_conf" ;;
 142     no|'') ;;
 143     yes) AC_MSG_ERROR([No path given to --with-openssl-conf]) ;;
 144     *) AC_MSG_ERROR([Non absolute path given to --with-openssl-conf]) ;;
 145 esac
 146
 147 AC_ARG_WITH(rrsync,
 148         AS_HELP_STRING([--with-rrsync],[also install the rrsync script and its manpage]))
 149 if test x"$with_rrsync" != x"yes"; then
 150     with_rrsync=no
 151 else
 152     MAKE_RRSYNC='rrsync'
 153     MAKE_RRSYNC_1='rrsync.1'
 154     GEN_RRSYNC='rrsync.1 rrsync.1.html'
 155 fi
 156 AC_SUBST(with_rrsync)
 157
 158 AC_ARG_WITH(included-popt,
 159         AS_HELP_STRING([--with-included-popt],[use bundled popt library, not from system]))
 160
 161 AC_ARG_WITH(included-zlib,
 162         AS_HELP_STRING([--with-included-zlib],[use bundled zlib library, not from system]))
 163
 164 AC_ARG_WITH(secluded-args,
 165         AS_HELP_STRING([--with-secluded-args],[make --secluded-args option the default]))
 166 if test x"$with_secluded_args" = x"yes"; then
 167         AC_DEFINE_UNQUOTED(RSYNC_USE_SECLUDED_ARGS, 1, [Define to 1 if --secluded-args should be the default])
 168 fi
 169
 170 AC_ARG_WITH(rsync-path,
 171         AS_HELP_STRING([--with-rsync-path=PATH],[set default --rsync-path to PATH (default: rsync)]),
 172         [ RSYNC_PATH="$with_rsync_path" ],
 173         [ RSYNC_PATH="rsync" ])
 174
 175 AC_DEFINE_UNQUOTED(RSYNC_PATH, "$RSYNC_PATH", [location of rsync on remote machine])
 176
 177 AC_ARG_WITH(rsyncd-conf,
 178         AS_HELP_STRING([--with-rsyncd-conf=PATH],[set configuration file for rsync server to PATH (default: /etc/rsyncd.conf)]),
 179         [ if test ! -z "$with_rsyncd_conf" ; then
 180                 case $with_rsyncd_conf in
 181                         yes|no)
 182                                 RSYNCD_SYSCONF="/etc/rsyncd.conf"
 183                                 ;;
 184                         /*)
 185                                 RSYNCD_SYSCONF="$with_rsyncd_conf"
 186                                 ;;
 187                         *)
 188                                 AC_MSG_ERROR(You must specify an absolute path to --with-rsyncd-conf=PATH)
 189                                 ;;
 190                 esac
 191         else
 192                 RSYNCD_SYSCONF="/etc/rsyncd.conf"
 193         fi ],
 194         [ RSYNCD_SYSCONF="/etc/rsyncd.conf" ])
 195
 196 AC_DEFINE_UNQUOTED(RSYNCD_SYSCONF, "$RSYNCD_SYSCONF", [location of configuration file for rsync server])
 197
 198 AC_ARG_WITH(rsh,
 199         AS_HELP_STRING([--with-rsh=CMD],[set remote shell command to CMD (default: ssh)]))
 200
 201 AC_CHECK_PROG(HAVE_REMSH, remsh, 1, 0)
 202 if test x$HAVE_REMSH = x1; then
 203         AC_DEFINE(HAVE_REMSH, 1, [Define to 1 if remote shell is remsh, not rsh])
 204 fi
 205
 206 if test x"$with_rsh" != x; then
 207         RSYNC_RSH="$with_rsh"
 208 else
 209         RSYNC_RSH="ssh"
 210 fi
 211 AC_DEFINE_UNQUOTED(RSYNC_RSH, "$RSYNC_RSH", [default -e command])
 212
 213 # Some programs on solaris are only found in /usr/xpg4/bin (or work better than others versions).
 214 AC_PATH_PROG(SHELL_PATH, sh, /bin/sh, [/usr/xpg4/bin$PATH_SEPARATOR$PATH])
 215 AC_PATH_PROG(FAKEROOT_PATH, fakeroot, /usr/bin/fakeroot, [/usr/xpg4/bin$PATH_SEPARATOR$PATH])
 216
 217 AC_ARG_WITH(nobody-user,
 218     AS_HELP_STRING([--with-nobody-user=USER],[set the default unprivileged user (default nobody)]),
 219     [ NOBODY_USER="$with_nobody_user" ],
 220     [ NOBODY_USER="nobody" ])
 221
 222 AC_ARG_WITH(nobody-group,
 223     AS_HELP_STRING([--with-nobody-group=GROUP],[set the default unprivileged group (default nobody or nogroup)]),
 224     [ NOBODY_GROUP="$with_nobody_group" ])
 225
 226 if test x"$with_nobody_group" = x; then
 227     AC_MSG_CHECKING([the group for user "nobody"])
 228     if grep '^nobody:' /etc/group >/dev/null 2>&1; then
 229         NOBODY_GROUP=nobody
 230     elif grep '^nogroup:' /etc/group >/dev/null 2>&1; then
 231         NOBODY_GROUP=nogroup
 232     else
 233         NOBODY_GROUP=nobody # test for others?
 234     fi
 235     AC_MSG_RESULT($NOBODY_GROUP)
 236 fi
 237
 238 AC_DEFINE_UNQUOTED(NOBODY_USER, "$NOBODY_USER", [unprivileged user--e.g. nobody])
 239 AC_DEFINE_UNQUOTED(NOBODY_GROUP, "$NOBODY_GROUP", [unprivileged group for unprivileged user])
 240
 241 # rolling-checksum SIMD optimizations
 242 ROLL_SIMD=
 243
 244 AC_MSG_CHECKING([whether to enable rolling-checksum SIMD optimizations])
 245 AC_ARG_ENABLE(roll-simd,
 246     AS_HELP_STRING([--enable-roll-simd],[enable/disable to control rolling-checksum SIMD optimizations (requires c++)]))
 247
 248 # Clag is crashing with -g -O2, so we'll get rid of -g for now.
 249 CXXFLAGS=`echo "$CXXFLAGS" | sed 's/-g //'`
 250 m4_define(SIMD_X86_64_TEST, [[#include <stdio.h>
 251 #if HAVE_STDLIB_H
 252 #include <stdlib.h>
 253 #endif
 254 #include <immintrin.h>
 255 __attribute__ ((target("default"))) int test_ssse3(int x) { return x; }
 256 __attribute__ ((target("default"))) int test_sse2(int x) { return x; }
 257 __attribute__ ((target("default"))) int test_avx2(int x) { return x; }
 258 __attribute__ ((target("ssse3"))) int test_ssse3(int x) { return x; }
 259 __attribute__ ((target("sse2"))) int test_sse2(int x) { return x; }
 260 __attribute__ ((target("avx2"))) int test_avx2(int x) { return x; }
 261 typedef long long __m128i_u __attribute__((__vector_size__(16), __may_alias__, __aligned__(1)));
 262 typedef long long __m256i_u __attribute__((__vector_size__(32), __may_alias__, __aligned__(1)));
 263 __attribute__ ((target("default"))) void more_testing(char* buf, int len) { }
 264 __attribute__ ((target("ssse3"))) void more_testing(char* buf, int len)
 265 {
 266     int i;
 267     for (i = 0; i < (len-32); i+=32) {
 268         __m128i in8_1, in8_2;
 269         in8_1 = _mm_lddqu_si128((__m128i_u*)&buf[i]);
 270         in8_2 = _mm_lddqu_si128((__m128i_u*)&buf[i + 16]);
 271     }
 272 }
 273 ]])
 274
 275 if test x"$enable_roll_simd" = x""; then
 276     case "$host_os" in
 277         *linux*) ;;
 278         *) enable_roll_simd=no ;;
 279     esac
 280 fi
 281
 282 if test x"$enable_roll_simd" != x"no"; then
 283     # For x86-64 SIMD, g++ >=5 or clang++ >=7 is required
 284     if test x"$host_cpu" = x"x86_64" || test x"$host_cpu" = x"amd64"; then
 285         AC_LANG(C++)
 286         if test x"$host" = x"$build"; then
 287             AC_RUN_IFELSE([AC_LANG_PROGRAM([SIMD_X86_64_TEST],[[if (test_ssse3(42) != 42 || test_sse2(42) != 42 || test_avx2(42) != 42) exit(1);]])],
 288                 [CXX_OK=yes],[CXX_OK=no])
 289         else
 290             AC_COMPILE_IFELSE([AC_LANG_PROGRAM([SIMD_X86_64_TEST])],[CXX_OK=yes],[CXX_OK=no])
 291         fi
 292         AC_LANG(C)
 293         if test x"$CXX_OK" = x"yes"; then
 294             # AC_MSG_RESULT() is called below.
 295             ROLL_SIMD="$host_cpu"
 296         elif test x"$enable_roll_simd" = x"yes"; then
 297             AC_MSG_RESULT(error)
 298             AC_MSG_ERROR(The rolling-checksum SIMD compilation test failed.
 299 Omit --enable-roll-simd to continue without it.)
 300         fi
 301     elif test x"$enable_roll_simd" = x"yes"; then
 302         AC_MSG_RESULT(unavailable)
 303         AC_MSG_ERROR(The rolling-checksum SIMD optimizations are currently x86_64|amd64 only.
 304 Omit --enable-roll-simd to continue without it.)
 305     fi
 306 fi
 307
 308 if test x"$ROLL_SIMD" != x""; then
 309     AC_MSG_RESULT([yes ($ROLL_SIMD)])
 310     AC_DEFINE(USE_ROLL_SIMD, 1, [Define to 1 to enable rolling-checksum SIMD optimizations])
 311     ROLL_SIMD='$(ROLL_SIMD_'"$ROLL_SIMD)"
 312     # We only use c++ for its target attribute dispatching, disable unneeded bulky features
 313     CXXFLAGS="$CXXFLAGS -fno-exceptions -fno-rtti"
 314     # Apple often has "g++" as a symlink for clang. Try to find out the truth.
 315     CXX_VERSION=`$CXX --version 2>/dev/null | head -n 2`
 316     case "$CXX_VERSION" in
 317     *clang*) CXXFLAGS="$CXXFLAGS -fno-slp-vectorize" ;; # avoid a performance hit
 318     esac
 319 else
 320     AC_MSG_RESULT(no)
 321 fi
 322
 323 AC_SUBST(ROLL_SIMD)
 324
 325 AC_MSG_CHECKING([if assembler accepts noexecstack])
 326 OLD_CFLAGS="$CFLAGS"
 327 CFLAGS="$CFLAGS -Wa,--noexecstack"
 328 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[ ]], [[return 0;]])],
 329 [ NOEXECSTACK='-Wa,--noexecstack' ; AC_MSG_RESULT(yes) ],
 330 [ NOEXECSTACK='' ; AC_MSG_RESULT(no) ])
 331 CFLAGS="$OLD_CFLAGS"
 332 AC_SUBST(NOEXECSTACK)
 333
 334 # arrgh. libc in some old debian version screwed up the largefile
 335 # stuff, getting byte range locking wrong
 336 AC_CACHE_CHECK([for broken largefile support],rsync_cv_HAVE_BROKEN_LARGEFILE,[
 337 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 338 #define _FILE_OFFSET_BITS 64
 339 $ac_includes_default
 340 #ifdef HAVE_FCNTL_H
 341 # include <fcntl.h>
 342 #elif defined HAVE_SYS_FCNTL_H
 343 # include <sys/fcntl.h>
 344 #endif
 345 #ifdef HAVE_SYS_WAIT_H
 346 #include <sys/wait.h>
 347 #endif
 348
 349 int main(void)
 350 {
 351         struct flock lock;
 352         int status;
 353         char tpl[32] = "/tmp/locktest.XXXXXX";
 354         int fd = mkstemp(tpl);
 355         if (fd < 0) {
 356                 strcpy(tpl, "conftest.dat");
 357                 fd = open(tpl, O_CREAT|O_RDWR, 0600);
 358         }
 359
 360         lock.l_type = F_WRLCK;
 361         lock.l_whence = SEEK_SET;
 362         lock.l_start = 0;
 363         lock.l_len = 1;
 364         lock.l_pid = 0;
 365         fcntl(fd,F_SETLK,&lock);
 366         if (fork() == 0) {
 367                 lock.l_start = 1;
 368                 _exit(fcntl(fd,F_SETLK,&lock) == 0);
 369         }
 370         wait(&status);
 371         unlink(tpl);
 372         return WEXITSTATUS(status);
 373 }
 374 ]])],[rsync_cv_HAVE_BROKEN_LARGEFILE=yes],[rsync_cv_HAVE_BROKEN_LARGEFILE=no],[rsync_cv_HAVE_BROKEN_LARGEFILE=cross])])
 375 if test x"$rsync_cv_HAVE_BROKEN_LARGEFILE" != x"yes"; then
 376    AC_SYS_LARGEFILE
 377 fi
 378
 379 AC_MSG_CHECKING([whether to enable ipv6])
 380 AC_ARG_ENABLE(ipv6,
 381 AS_HELP_STRING([--disable-ipv6],[disable to omit ipv6 support]),
 382 [ case "$enableval" in
 383   no)
 384         AC_MSG_RESULT(no)
 385         ;;
 386   *)    AC_MSG_RESULT(yes)
 387         AC_DEFINE(INET6, 1, [true if you have IPv6])
 388         ;;
 389   esac ],
 390
 391   AC_RUN_IFELSE([AC_LANG_SOURCE([[ /* AF_INET6 availability check */
 392 #include <stdlib.h>
 393 #include <sys/types.h>
 394 #include <sys/socket.h>
 395 int main()
 396 {
 397    if (socket(AF_INET6, SOCK_STREAM, 0) < 0)
 398      exit(1);
 399    else
 400      exit(0);
 401 }
 402 ]])],
 403   [AC_MSG_RESULT(yes)
 404   AC_DEFINE(INET6, 1, true if you have IPv6)],
 405   [AC_MSG_RESULT(no)],
 406   [AC_MSG_RESULT(no)]
 407 ))
 408
 409 dnl Do you want to disable use of locale functions
 410 AC_ARG_ENABLE([locale],
 411         AS_HELP_STRING([--disable-locale],[disable to omit locale features]))
 412 AH_TEMPLATE([CONFIG_LOCALE],
 413 [Undefine if you do not want locale features.  By default this is defined.])
 414 if test x"$enable_locale" != x"no"; then
 415         AC_DEFINE(CONFIG_LOCALE)
 416 fi
 417
 418 AC_MSG_CHECKING([whether to call shutdown on all sockets])
 419 case $host_os in
 420         *cygwin* ) AC_MSG_RESULT(yes)
 421                    AC_DEFINE(SHUTDOWN_ALL_SOCKETS, 1,
 422                             [Define to 1 if sockets need to be shutdown])
 423                    ;;
 424                * ) AC_MSG_RESULT(no);;
 425 esac
 426
 427 # We default to using our zlib unless --with-included-zlib=no is given.
 428 if test x"$with_included_zlib" != x"no"; then
 429     with_included_zlib=yes
 430 elif test x"$ac_cv_header_zlib_h" != x"yes"; then
 431     with_included_zlib=yes
 432 fi
 433 if test x"$with_included_zlib" != x"yes"; then
 434     AC_CHECK_LIB(z, deflateParams, , [with_included_zlib=yes])
 435 fi
 436
 437 AC_MSG_CHECKING([whether to use included zlib])
 438 if test x"$with_included_zlib" = x"yes"; then
 439     AC_MSG_RESULT($srcdir/zlib)
 440     BUILD_ZLIB='$(zlib_OBJS)'
 441     CFLAGS="-I$srcdir/zlib $CFLAGS"
 442 else
 443     AC_DEFINE(EXTERNAL_ZLIB, 1, [Define to 1 if using external zlib])
 444     AC_MSG_RESULT(no)
 445 fi
 446
 447 AC_MSG_CHECKING([whether to enable use of openssl crypto library])
 448 AC_ARG_ENABLE([openssl],
 449         AS_HELP_STRING([--disable-openssl],[disable to omit openssl crypto library]))
 450 AH_TEMPLATE([USE_OPENSSL],
 451 [Undefine if you do not want to use openssl crypto library.  By default this is defined.])
 452 if test x"$enable_openssl" != x"no"; then
 453     if test x"$ac_cv_header_openssl_md4_h" = x"yes" && test x"$ac_cv_header_openssl_md5_h" = x"yes"; then
 454       AC_MSG_RESULT(yes)
 455       AC_SEARCH_LIBS(EVP_MD_CTX_copy, crypto,
 456           [AC_DEFINE(USE_OPENSSL)
 457            enable_openssl=yes],
 458           [err_msg="$err_msg$nl- Failed to find EVP_MD_CTX_copy function in openssl crypto lib.";
 459            no_lib="$no_lib openssl"])
 460     else
 461         AC_MSG_RESULT(no)
 462         err_msg="$err_msg$nl- Failed to find openssl/md4.h and openssl/md5.h for openssl crypto lib support."
 463         no_lib="$no_lib openssl"
 464     fi
 465     if test x"$enable_md5_asm" != x"yes"; then
 466         enable_md5_asm=no
 467     fi
 468 else
 469     AC_MSG_RESULT(no)
 470 fi
 471
 472 MD5_ASM=
 473
 474 AC_MSG_CHECKING([whether to enable MD5 ASM optimizations])
 475 AC_ARG_ENABLE(md5-asm,
 476     AS_HELP_STRING([--enable-md5-asm],[enable/disable to control MD5 ASM optimizations]))
 477
 478 if test x"$enable_md5_asm" = x""; then
 479     case "$host_os" in
 480         *linux*) ;;
 481         *) enable_md5_asm=no ;;
 482     esac
 483 fi
 484
 485 if test x"$enable_md5_asm" != x"no"; then
 486     if test x"$host_cpu" = x"x86_64" || test x"$host_cpu" = x"amd64"; then
 487         MD5_ASM="$host_cpu"
 488     elif test x"$enable_md5_asm" = x"yes"; then
 489         AC_MSG_RESULT(unavailable)
 490         AC_MSG_ERROR(The ASM optimizations are currently x86_64|amd64 only.
 491 Omit --enable-md5-asm to continue without it.)
 492     fi
 493 fi
 494
 495 if test x"$MD5_ASM" != x""; then
 496     AC_MSG_RESULT([yes ($MD5_ASM)])
 497     AC_DEFINE(USE_MD5_ASM, 1, [Define to 1 to enable MD5 ASM optimizations])
 498     MD5_ASM='$(MD5_ASM_'"$MD5_ASM)"
 499 else
 500     AC_MSG_RESULT(no)
 501 fi
 502
 503 AC_SUBST(MD5_ASM)
 504
 505 ROLL_ASM=
 506
 507 AC_MSG_CHECKING([whether to enable rolling-checksum ASM optimizations])
 508 AC_ARG_ENABLE(roll-asm,
 509     AS_HELP_STRING([--enable-roll-asm],[enable/disable to control rolling-checksum ASM optimizations (requires --enable-roll-simd)]))
 510
 511 if test x"$ROLL_SIMD" = x""; then
 512     enable_roll_asm=no
 513 fi
 514
 515 if test x"$enable_roll_asm" = x"yes"; then
 516     ROLL_ASM="$host_cpu"
 517     AC_MSG_RESULT([yes ($ROLL_ASM)])
 518     AC_DEFINE(USE_ROLL_ASM, 1, [Define to 1 to enable rolling-checksum ASM optimizations (requires --enable-roll-simd)])
 519     ROLL_ASM='$(ROLL_ASM_'"$ROLL_ASM)"
 520 else
 521     AC_MSG_RESULT(no)
 522 fi
 523
 524 AC_SUBST(ROLL_ASM)
 525
 526 AC_MSG_CHECKING([whether to enable xxhash checksum support])
 527 AC_ARG_ENABLE([xxhash],
 528         AS_HELP_STRING([--disable-xxhash],[disable to omit xxhash checksums]))
 529 AH_TEMPLATE([SUPPORT_XXHASH],
 530 [Undefine if you do not want xxhash checksums.  By default this is defined.])
 531 if test x"$enable_xxhash" != x"no"; then
 532     if test x"$ac_cv_header_xxhash_h" = x"yes"; then
 533         AC_MSG_RESULT(yes)
 534         AC_SEARCH_LIBS(XXH64_createState, xxhash,
 535             [AC_DEFINE(SUPPORT_XXHASH)],
 536             [err_msg="$err_msg$nl- Failed to find XXH64_createState function in xxhash lib.";
 537              no_lib="$no_lib xxhash"])
 538     else
 539         AC_MSG_RESULT(no)
 540         err_msg="$err_msg$nl- Failed to find xxhash.h for xxhash checksum support.";
 541         no_lib="$no_lib xxhash"
 542     fi
 543 else
 544     AC_MSG_RESULT(no)
 545 fi
 546
 547 AC_MSG_CHECKING([whether to enable zstd compression])
 548 AC_ARG_ENABLE([zstd],
 549         AS_HELP_STRING([--disable-zstd], [disable to omit zstd compression]))
 550 AH_TEMPLATE([SUPPORT_ZSTD],
 551 [Undefine if you do not want zstd compression.  By default this is defined.])
 552 if test x"$enable_zstd" != x"no"; then
 553     if test x"$ac_cv_header_zstd_h" = x"yes"; then
 554         AC_MSG_RESULT(yes)
 555         AC_SEARCH_LIBS(ZSTD_minCLevel, zstd,
 556             [AC_DEFINE(SUPPORT_ZSTD)],
 557             [err_msg="$err_msg$nl- Failed to find ZSTD_minCLevel function in zstd lib.";
 558              no_lib="$no_lib zstd"])
 559     else
 560         AC_MSG_RESULT(no)
 561         err_msg="$err_msg$nl- Failed to find zstd.h for zstd compression support.";
 562         no_lib="$no_lib zstd"
 563     fi
 564 else
 565     AC_MSG_RESULT(no)
 566 fi
 567
 568 AC_MSG_CHECKING([whether to enable LZ4 compression])
 569 AC_ARG_ENABLE([lz4],
 570         AS_HELP_STRING([--disable-lz4], [disable to omit LZ4 compression]))
 571 AH_TEMPLATE([SUPPORT_LZ4],
 572 [Undefine if you do not want LZ4 compression.  By default this is defined.])
 573 if test x"$enable_lz4" != x"no"; then
 574     if test x"$ac_cv_header_lz4_h" = x"yes"; then
 575         AC_MSG_RESULT(yes)
 576         AC_SEARCH_LIBS(LZ4_compress_default, lz4,
 577             [AC_DEFINE(SUPPORT_LZ4)],
 578             [err_msg="$err_msg$nl- Failed to find LZ4_compress_default function in lz4 lib.";
 579              no_lib="$no_lib lz4"])
 580     else
 581         AC_MSG_RESULT(no)
 582         err_msg="$err_msg$nl- Failed to find lz4.h for lz4 compression support."
 583         no_lib="$no_lib lz4"
 584     fi
 585 else
 586     AC_MSG_RESULT(no)
 587 fi
 588
 589 if test x"$no_lib" != x; then
 590     echo ""
 591     echo "Configure found the following issues:"
 592     echo "$err_msg"
 593     echo ""
 594     echo "See the INSTALL file for hints on how to install the missing libraries and/or"
 595     echo "how to generate (or fetch) manpages:"
 596     echo "    https://github.com/RsyncProject/rsync/blob/master/INSTALL.md"
 597     echo ""
 598     echo "To disable one or more features, the relevant configure options are:"
 599     for lib in $no_lib; do
 600         echo "    --disable-$lib"
 601     done
 602     echo ""
 603     AC_MSG_ERROR(Aborting configure run)
 604 fi
 605
 606 AC_CACHE_CHECK([if makedev takes 3 args],rsync_cv_MAKEDEV_TAKES_3_ARGS,[
 607 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 608 #ifdef HAVE_SYS_TYPES_H
 609 #include <sys/types.h>
 610 #endif
 611 #ifdef MAJOR_IN_MKDEV
 612 #include <sys/mkdev.h>
 613 # if !defined makedev && (defined mkdev || defined _WIN32 || defined __WIN32__)
 614 #  define makedev mkdev
 615 # endif
 616 #elif defined MAJOR_IN_SYSMACROS
 617 #include <sys/sysmacros.h>
 618 #endif
 619
 620 int main(void)
 621 {
 622         dev_t dev = makedev(0, 5, 7);
 623         if (major(dev) != 5 || minor(dev) != 7)
 624                 return 1;
 625         return 0;
 626 }
 627 ]])],[rsync_cv_MAKEDEV_TAKES_3_ARGS=yes],[rsync_cv_MAKEDEV_TAKES_3_ARGS=no],[rsync_cv_MAKEDEV_TAKES_3_ARGS=no])])
 628 if test x"$rsync_cv_MAKEDEV_TAKES_3_ARGS" = x"yes"; then
 629    AC_DEFINE(MAKEDEV_TAKES_3_ARGS, 1, [Define to 1 if makedev() takes 3 args])
 630 fi
 631
 632 AC_CHECK_SIZEOF(int)
 633 AC_CHECK_SIZEOF(long)
 634 AC_CHECK_SIZEOF(long long)
 635 AC_CHECK_SIZEOF(short)
 636 AC_CHECK_SIZEOF(int16_t)
 637 AC_CHECK_SIZEOF(uint16_t)
 638 AC_CHECK_SIZEOF(int32_t)
 639 AC_CHECK_SIZEOF(uint32_t)
 640 AC_CHECK_SIZEOF(int64_t)
 641 AC_CHECK_SIZEOF(off_t)
 642 AC_CHECK_SIZEOF(off64_t)
 643 AC_CHECK_SIZEOF(time_t)
 644 AC_CHECK_SIZEOF(char*)
 645
 646 AC_C_INLINE
 647
 648 AC_TYPE_LONG_DOUBLE_WIDER
 649 ac_cv_c_long_double=$ac_cv_type_long_double_wider
 650 if test $ac_cv_c_long_double = yes; then
 651   AC_DEFINE([HAVE_LONG_DOUBLE],[1],[Define to 1 if the type `long double' works and has more range or precision than `double'.])
 652 fi
 653
 654 AC_TYPE_UID_T
 655 AC_CHECK_TYPES([mode_t,off_t,size_t,pid_t,id_t])
 656 if test "$cross_compiling" = no; then
 657     AC_TYPE_GETGROUPS
 658 else
 659     AC_DEFINE([GETGROUPS_T],[gid_t],[Define to the type of elements in the array set by `getgroups'. Usually this is either `int' or `gid_t'.])
 660 fi
 661 AC_CHECK_MEMBERS([struct stat.st_rdev,
 662                   struct stat.st_mtimensec,
 663                   struct stat.st_mtimespec.tv_nsec,
 664                   struct stat.st_mtim.tv_nsec],,,[
 665 #ifdef HAVE_SYS_TYPES_H
 666 #include <sys/types.h>
 667 #endif
 668 #ifdef HAVE_SYS_STAT_H
 669 #include <sys/stat.h>
 670 #endif
 671 #ifdef HAVE_UNISTD_H
 672 #include <unistd.h>
 673 #endif])
 674
 675 TYPE_SOCKLEN_T
 676
 677 AC_CACHE_CHECK([for errno in errno.h],rsync_cv_errno, [
 678     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <errno.h>]], [[int i = errno]])],[rsync_cv_errno=yes],[rsync_cv_have_errno_decl=no])])
 679 if test x"$rsync_cv_errno" = x"yes"; then
 680    AC_DEFINE(HAVE_ERRNO_DECL, 1, [Define to 1 if errno is declared in errno.h])
 681 fi
 682
 683 # The following test taken from the cvs sources
 684 # If we can't find connect, try looking in -lsocket, -lnsl, and -linet.
 685 # These need checks to be before checks for any other functions that
 686 #    might be in the same libraries.
 687 # The Irix 5 libc.so has connect and gethostbyname, but Irix 5 also has
 688 # libsocket.so which has a bad implementation of gethostbyname (it
 689 # only looks in /etc/hosts), so we only look for -lsocket if we need
 690 # it.
 691 AC_CHECK_FUNCS(connect)
 692 if test x"$ac_cv_func_connect" = x"no"; then
 693     case "$LIBS" in
 694     *-lnsl*) ;;
 695     *) AC_CHECK_LIB(nsl_s, printf) ;;
 696     esac
 697     case "$LIBS" in
 698     *-lnsl*) ;;
 699     *) AC_CHECK_LIB(nsl, printf) ;;
 700     esac
 701     case "$LIBS" in
 702     *-lsocket*) ;;
 703     *) AC_CHECK_LIB(socket, connect) ;;
 704     esac
 705     case "$LIBS" in
 706     *-linet*) ;;
 707     *) AC_CHECK_LIB(inet, connect) ;;
 708     esac
 709     dnl We can't just call AC_CHECK_FUNCS(connect) here, because the value
 710     dnl has been cached.
 711     if test x"$ac_cv_lib_socket_connect" = x"yes" ||
 712        test x"$ac_cv_lib_inet_connect" = x"yes"; then
 713         # ac_cv_func_connect=yes
 714         # don't!  it would cause AC_CHECK_FUNC to succeed next time configure is run
 715         AC_DEFINE(HAVE_CONNECT, 1, [Define to 1 if you have the "connect" function])
 716     fi
 717 fi
 718
 719 AC_SEARCH_LIBS(inet_ntop, resolv)
 720
 721 # For OS X, Solaris, HP-UX, etc.: figure out if -liconv is needed.  We'll
 722 # accept either iconv_open or libiconv_open, since some include files map
 723 # the former to the latter.
 724 AC_SEARCH_LIBS(iconv_open, iconv)
 725 AC_SEARCH_LIBS(libiconv_open, iconv)
 726
 727 AC_MSG_CHECKING([for iconv declaration])
 728 AC_CACHE_VAL(am_cv_proto_iconv, [
 729     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 730 #if HAVE_STDLIB_H
 731 #include <stdlib.h>
 732 #endif
 733 #include <iconv.h>
 734 extern
 735 #ifdef __cplusplus
 736 "C"
 737 #endif
 738 #if defined(__STDC__) || defined(__cplusplus)
 739 size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 740 #else
 741 size_t iconv();
 742 #endif
 743 ]], [[]])],[am_cv_proto_iconv_arg1=""],[am_cv_proto_iconv_arg1="const"])
 744       am_cv_proto_iconv="extern size_t iconv (iconv_t cd, $am_cv_proto_iconv_arg1 char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);"])
 745     am_cv_proto_iconv=`echo "[$]am_cv_proto_iconv" | tr -s ' ' | sed 's/( /(/'`
 746 AC_MSG_RESULT([$]{ac_t:-
 747          }[$]am_cv_proto_iconv)
 748 AC_DEFINE_UNQUOTED(ICONV_CONST, $am_cv_proto_iconv_arg1,
 749                    [Define as const if the declaration of iconv() needs const.])
 750
 751 dnl AC_MSG_NOTICE([Looking in libraries: $LIBS])
 752
 753 AC_REPLACE_FUNCS([inet_ntop inet_pton])
 754
 755 AC_HAVE_TYPE([struct addrinfo], [#include <netdb.h>])
 756 AC_HAVE_TYPE([struct sockaddr_storage], [
 757 #ifdef HAVE_SYS_TYPES_H
 758 #include <sys/types.h>
 759 #endif
 760 #ifdef HAVE_SYS_SOCKET_H
 761 #include <sys/socket.h>
 762 #endif])
 763
 764 # Irix 6.5 has getaddrinfo but not the corresponding defines, so use
 765 #   builtin getaddrinfo if one of the defines don't exist
 766 AC_CACHE_CHECK([whether defines needed by getaddrinfo exist],
 767                rsync_cv_HAVE_GETADDR_DEFINES,[
 768                         AC_EGREP_CPP(yes, [
 769 #ifdef HAVE_SYS_TYPES_H
 770 #include <sys/types.h>
 771 #endif
 772 #ifdef HAVE_SYS_SOCKET_H
 773 #include <sys/socket.h>
 774 #endif
 775 #ifdef HAVE_NETDB_H
 776 #include <netdb.h>
 777 #endif
 778 #ifdef AI_PASSIVE
 779 yes
 780 #endif],
 781                         rsync_cv_HAVE_GETADDR_DEFINES=yes,
 782                         rsync_cv_HAVE_GETADDR_DEFINES=no)])
 783 AS_IF([test x"$rsync_cv_HAVE_GETADDR_DEFINES" = x"yes" && test x"$ac_cv_type_struct_addrinfo" = x"yes"],[
 784         # Tru64 UNIX has getaddrinfo() but has it renamed in libc as
 785         # something else so we must include <netdb.h> to get the
 786         # redefinition.
 787         AC_CHECK_FUNCS(getaddrinfo, ,
 788                 [AC_MSG_CHECKING([for getaddrinfo by including <netdb.h>])
 789                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 790 #ifdef HAVE_SYS_TYPES_H
 791 #include <sys/types.h>
 792 #endif
 793 #ifdef HAVE_SYS_SOCKET_H
 794 #include <sys/socket.h>
 795 #endif
 796 #include <netdb.h>]], [[getaddrinfo(NULL, NULL, NULL, NULL);]])],[AC_MSG_RESULT([yes])
 797                         AC_DEFINE(HAVE_GETADDRINFO, 1,
 798                                 [Define to 1 if you have the "getaddrinfo" function and required types.])],[AC_MSG_RESULT([no])
 799                         AC_LIBOBJ([getaddrinfo])])])
 800     ],[AC_LIBOBJ([getaddrinfo])])
 801
 802 AC_CHECK_MEMBER([struct sockaddr.sa_len],
 803                 [ AC_DEFINE(HAVE_SOCKADDR_LEN, 1, [Do we have sockaddr.sa_len?]) ],
 804                 [],
 805                 [
 806 #ifdef HAVE_SYS_TYPES_H
 807 #include <sys/types.h>
 808 #endif
 809 #ifdef HAVE_SYS_SOCKET_H
 810 #include <sys/socket.h>
 811 #endif
 812 ])
 813
 814 AC_CHECK_MEMBER([struct sockaddr_in.sin_len],
 815                 [ AC_DEFINE(HAVE_SOCKADDR_IN_LEN, 1, [Do we have sockaddr_in.sin_len?]) ],
 816                 [],
 817                 [
 818 #ifdef HAVE_SYS_TYPES_H
 819 #include <sys/types.h>
 820 #endif
 821 #ifdef HAVE_SYS_SOCKET_H
 822 #include <sys/socket.h>
 823 #endif
 824 #include <netinet/in.h>
 825 ])
 826
 827 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
 828                 [ AC_DEFINE(HAVE_SOCKADDR_UN_LEN, 1, [Do we have sockaddr_un.sun_len?]) ],
 829                 [],
 830                 [
 831 #ifdef HAVE_SYS_TYPES_H
 832 #include <sys/types.h>
 833 #endif
 834 #ifdef HAVE_SYS_SOCKET_H
 835 #include <sys/socket.h>
 836 #endif
 837 #include <netinet/in.h>
 838 ])
 839
 840 AC_CHECK_MEMBER([struct sockaddr_in6.sin6_scope_id],
 841                 [ AC_DEFINE(HAVE_SOCKADDR_IN6_SCOPE_ID, 1, [Do we have sockaddr_in6.sin6_scope_id?]) ],
 842                 [],
 843                 [
 844 #ifdef HAVE_SYS_TYPES_H
 845 #include <sys/types.h>
 846 #endif
 847 #ifdef HAVE_SYS_SOCKET_H
 848 #include <sys/socket.h>
 849 #endif
 850 #include <netinet/in.h>
 851 ])
 852
 853 AC_HAVE_TYPE([struct stat64], [#include <stdio.h>
 854 #if HAVE_SYS_TYPES_H
 855 # include <sys/types.h>
 856 #endif
 857 #if HAVE_SYS_STAT_H
 858 # include <sys/stat.h>
 859 #endif
 860 #if STDC_HEADERS
 861 # include <stdlib.h>
 862 # include <stddef.h>
 863 #else
 864 # if HAVE_STDLIB_H
 865 #  include <stdlib.h>
 866 # endif
 867 #endif
 868 ])
 869
 870 # if we can't find strcasecmp, look in -lresolv (for Unixware at least)
 871 #
 872 AC_CHECK_FUNCS(strcasecmp)
 873 if test x"$ac_cv_func_strcasecmp" = x"no"; then
 874     AC_CHECK_LIB(resolv, strcasecmp)
 875 fi
 876
 877 AC_CHECK_FUNCS(aclsort)
 878 if test x"$ac_cv_func_aclsort" = x"no"; then
 879     AC_CHECK_LIB(sec, aclsort)
 880 fi
 881
 882 dnl At the moment we don't test for a broken memcmp(), because all we
 883 dnl need to do is test for equality, not comparison, and it seems that
 884 dnl every platform has a memcmp that can do at least that.
 885 dnl AC_FUNC_MEMCMP
 886
 887 AC_FUNC_UTIME_NULL
 888 AC_FUNC_ALLOCA
 889 AC_CHECK_FUNCS(waitpid wait4 getcwd chown chmod lchmod mknod mkfifo \
 890     fchmod fstat ftruncate strchr readlink link utime utimes lutimes strftime \
 891     chflags getattrlist mktime innetgr linkat \
 892     memmove lchown vsnprintf snprintf vasprintf asprintf setsid strpbrk \
 893     strlcat strlcpy stpcpy strtol mallinfo mallinfo2 getgroups setgroups geteuid getegid \
 894     setlocale setmode open64 lseek64 mkstemp64 mtrace va_copy __va_copy \
 895     seteuid strerror putenv iconv_open locale_charset nl_langinfo getxattr \
 896     extattr_get_link sigaction sigprocmask setattrlist getgrouplist \
 897     initgroups utimensat posix_fallocate attropen setvbuf nanosleep usleep \
 898     setenv unsetenv)
 899
 900 dnl cygwin iconv.h defines iconv_open as libiconv_open
 901 if test x"$ac_cv_func_iconv_open" != x"yes"; then
 902     AC_CHECK_FUNC(libiconv_open, [ac_cv_func_iconv_open=yes; AC_DEFINE(HAVE_ICONV_OPEN, 1)])
 903 fi
 904
 905 dnl Preallocation stuff (also fallocate, posix_fallocate function tests above):
 906
 907 AC_CACHE_CHECK([for useable fallocate],rsync_cv_have_fallocate,[
 908 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <fcntl.h>
 909 #ifdef HAVE_SYS_TYPES_H
 910 #include <sys/types.h>
 911 #endif]], [[fallocate(0, 0, 0, 0);]])],[rsync_cv_have_fallocate=yes],[rsync_cv_have_fallocate=no])])
 912 if test x"$rsync_cv_have_fallocate" = x"yes"; then
 913     AC_DEFINE(HAVE_FALLOCATE, 1, [Define to 1 if you have the fallocate function and it compiles and links without error])
 914 fi
 915
 916 AC_MSG_CHECKING([for FALLOC_FL_PUNCH_HOLE])
 917 AC_PREPROC_IFELSE([AC_LANG_SOURCE([[
 918         #define _GNU_SOURCE 1
 919         #include <linux/falloc.h>
 920         #ifndef FALLOC_FL_PUNCH_HOLE
 921         #error FALLOC_FL_PUNCH_HOLE is missing
 922         #endif
 923     ]])], [
 924         AC_MSG_RESULT([yes])
 925         AC_DEFINE([HAVE_FALLOC_FL_PUNCH_HOLE], [1], [Define if FALLOC_FL_PUNCH_HOLE is available.])
 926     ], [
 927         AC_MSG_RESULT([no])
 928     ]
 929 )
 930
 931 AC_MSG_CHECKING([for FALLOC_FL_ZERO_RANGE])
 932 AC_PREPROC_IFELSE([AC_LANG_SOURCE([[
 933         #define _GNU_SOURCE 1
 934         #include <linux/falloc.h>
 935         #ifndef FALLOC_FL_ZERO_RANGE
 936         #error FALLOC_FL_ZERO_RANGE is missing
 937         #endif
 938     ]])], [
 939         AC_MSG_RESULT([yes])
 940         AC_DEFINE([HAVE_FALLOC_FL_ZERO_RANGE], [1], [Define if FALLOC_FL_ZERO_RANGE is available.])
 941     ], [
 942         AC_MSG_RESULT([no])
 943     ]
 944 )
 945
 946 AC_CACHE_CHECK([for SYS_fallocate],rsync_cv_have_sys_fallocate,[
 947 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/syscall.h>
 948 #ifdef HAVE_UNISTD_H
 949 #include <unistd.h>
 950 #endif
 951 #ifdef HAVE_SYS_TYPES_H
 952 #include <sys/types.h>
 953 #endif]], [[syscall(SYS_fallocate, 0, 0, (loff_t)0, (loff_t)0);]])],[rsync_cv_have_sys_fallocate=yes],[rsync_cv_have_sys_fallocate=no])])
 954 if test x"$rsync_cv_have_sys_fallocate" = x"yes"; then
 955     AC_DEFINE(HAVE_SYS_FALLOCATE, 1, [Define to 1 if you have the SYS_fallocate syscall number])
 956 fi
 957
 958 if test x"$ac_cv_func_posix_fallocate" = x"yes"; then
 959     AC_MSG_CHECKING([whether posix_fallocate is efficient])
 960     case $host_os in
 961     *cygwin*)
 962         AC_MSG_RESULT(yes)
 963         AC_DEFINE(HAVE_EFFICIENT_POSIX_FALLOCATE, 1,
 964                   [Define if posix_fallocate is efficient (Cygwin)])
 965         ;;
 966     *)
 967         AC_MSG_RESULT(no)
 968         ;;
 969     esac
 970 fi
 971
 972 dnl End of preallocation stuff
 973
 974 AC_CHECK_FUNCS(getpgrp tcgetpgrp)
 975 if test $ac_cv_func_getpgrp = yes; then
 976     AC_FUNC_GETPGRP
 977 fi
 978
 979 AC_ARG_ENABLE(iconv-open,
 980     AS_HELP_STRING([--disable-iconv-open],[disable to avoid all use of iconv_open()]),
 981     [], [enable_iconv_open=$ac_cv_func_iconv_open])
 982
 983 if test x"$enable_iconv_open" != x"no"; then
 984     AC_DEFINE(USE_ICONV_OPEN, 1, [Define to 1 if you want rsync to make use of iconv_open()])
 985 fi
 986
 987 AC_ARG_ENABLE(iconv,
 988     AS_HELP_STRING([--disable-iconv],[disable to omit the --iconv option]),
 989     [], [enable_iconv=$enable_iconv_open])
 990 AH_TEMPLATE([ICONV_OPTION],
 991 [Define if you want the --iconv option.  Specifying a value will set the
 992 default iconv setting (a NULL means no --iconv processing by default).])
 993 if test x"$enable_iconv" != x"no"; then
 994         if test x"$enable_iconv" = x"yes"; then
 995                 AC_DEFINE(ICONV_OPTION, NULL)
 996         else
 997                 AC_DEFINE_UNQUOTED(ICONV_OPTION, "$enable_iconv")
 998         fi
 999         AC_DEFINE(UTF8_CHARSET, "UTF-8", [String to pass to iconv() for the UTF-8 charset.])
1000 fi
1001
1002 AC_CACHE_CHECK([whether chown() modifies symlinks],rsync_cv_chown_modifies_symlink,[
1003   AC_RUN_IFELSE([AC_LANG_SOURCE([[
1004 #if HAVE_UNISTD_H
1005 # include <unistd.h>
1006 #endif
1007 #include <stdlib.h>
1008 #include <errno.h>
1009 int main(void) {
1010         char const *dangling_symlink = "conftest.dangle";
1011         unlink(dangling_symlink);
1012         if (symlink("conftest.no-such", dangling_symlink) < 0) abort();
1013         if (chown(dangling_symlink, getuid(), getgid()) < 0 && errno == ENOENT) return 1;
1014         return 0;
1015     }]])],[rsync_cv_chown_modifies_symlink=yes],[rsync_cv_chown_modifies_symlink=no],[rsync_cv_chown_modifies_symlink=no])])
1016 if test $rsync_cv_chown_modifies_symlink = yes; then
1017   AC_DEFINE(CHOWN_MODIFIES_SYMLINK, 1, [Define to 1 if chown modifies symlinks.])
1018 fi
1019
1020 AC_CACHE_CHECK([whether link() can hard-link symlinks],rsync_cv_can_hardlink_symlink,[
1021   AC_RUN_IFELSE([AC_LANG_SOURCE([[
1022 #ifdef HAVE_FCNTL_H
1023 # include <fcntl.h>
1024 #elif defined HAVE_SYS_FCNTL_H
1025 # include <sys/fcntl.h>
1026 #endif
1027 #if HAVE_UNISTD_H
1028 # include <unistd.h>
1029 #endif
1030 #include <stdlib.h>
1031 #include <errno.h>
1032 #define FILENAME "conftest.dangle"
1033 int main(void) {
1034         unlink(FILENAME);
1035         if (symlink("conftest.no-such", FILENAME) < 0) abort();
1036         unlink(FILENAME "2");
1037 #ifdef HAVE_LINKAT
1038         if (linkat(AT_FDCWD, FILENAME, AT_FDCWD, FILENAME "2", 0) < 0) return 1;
1039 #else
1040         if (link(FILENAME, FILENAME "2") < 0) return 1;
1041 #endif
1042         return 0;
1043     }]])],[rsync_cv_can_hardlink_symlink=yes],[rsync_cv_can_hardlink_symlink=no],[rsync_cv_can_hardlink_symlink=no])])
1044 if test $rsync_cv_can_hardlink_symlink = yes; then
1045   AC_DEFINE(CAN_HARDLINK_SYMLINK, 1, [Define to 1 if link() can hard-link symlinks.])
1046 fi
1047
1048 AC_CACHE_CHECK([whether link() can hard-link special files],rsync_cv_can_hardlink_special,[
1049   AC_RUN_IFELSE([AC_LANG_SOURCE([[
1050 #if HAVE_UNISTD_H
1051 # include <unistd.h>
1052 #endif
1053 #ifdef HAVE_SYS_STAT_H
1054 #include <sys/stat.h>
1055 #endif
1056 #include <stdlib.h>
1057 #include <errno.h>
1058 #define FILENAME "conftest.fifi"
1059 int main(void) {
1060         unlink(FILENAME);
1061         if (mkfifo(FILENAME, 0777) < 0) abort();
1062         unlink(FILENAME "2");
1063         if (link(FILENAME, FILENAME "2") < 0) return 1;
1064         return 0;
1065     }]])],[rsync_cv_can_hardlink_special=yes],[rsync_cv_can_hardlink_special=no],[rsync_cv_can_hardlink_special=no])])
1066 if test $rsync_cv_can_hardlink_special = yes; then
1067     AC_DEFINE(CAN_HARDLINK_SPECIAL, 1, [Define to 1 if link() can hard-link special files.])
1068 fi
1069
1070 AC_CACHE_CHECK([for working socketpair],rsync_cv_HAVE_SOCKETPAIR,[
1071 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1072 #ifdef HAVE_SYS_TYPES_H
1073 #include <sys/types.h>
1074 #endif
1075 #ifdef HAVE_SYS_SOCKET_H
1076 #include <sys/socket.h>
1077 #endif
1078
1079 int main(void) {
1080        int fd[2];
1081        return (socketpair(AF_UNIX, SOCK_STREAM, 0, fd) != -1) ? 0 : 1;
1082 }]])],[rsync_cv_HAVE_SOCKETPAIR=yes],[rsync_cv_HAVE_SOCKETPAIR=no],[rsync_cv_HAVE_SOCKETPAIR=cross])])
1083 if test x"$rsync_cv_HAVE_SOCKETPAIR" = x"yes"; then
1084     AC_DEFINE(HAVE_SOCKETPAIR, 1, [Define to 1 if you have the "socketpair" function])
1085 fi
1086
1087 AC_REPLACE_FUNCS([getpass])
1088
1089 if test x"$with_included_popt" != x"yes"; then
1090     AC_CHECK_LIB(popt, poptGetContext, , [with_included_popt=yes])
1091 fi
1092 if test x"$ac_cv_header_popt_popt_h" = x"yes"; then
1093     # If the system has /usr/include/popt/popt.h, we enable the
1094     # included popt because an attempt to "#include <popt/popt.h>"
1095     # would use our included header file anyway (due to -I.), and
1096     # might conflict with the system popt.
1097     with_included_popt=yes
1098 elif test x"$ac_cv_header_popt_h" != x"yes"; then
1099     with_included_popt=yes
1100 fi
1101
1102 AC_MSG_CHECKING([whether to use included libpopt])
1103 if test x"$with_included_popt" = x"yes"; then
1104     AC_MSG_RESULT($srcdir/popt)
1105     BUILD_POPT='$(popt_OBJS)'
1106     CFLAGS="-I$srcdir/popt $CFLAGS"
1107     AC_DEFINE(POPT_SYSCONFDIR, "/etc", [sysconfig dir for popt])
1108     AC_DEFINE(PACKAGE, "rsync", [package name for rsync])
1109     if test x"$ALLOCA" != x
1110     then
1111         # this can be removed when/if we add an included alloca.c;
1112         #  see autoconf documentation on AC_FUNC_ALLOCA
1113         AC_MSG_WARN([included libpopt will use malloc, not alloca (which wastes a small amount of memory)])
1114     fi
1115 else
1116     AC_MSG_RESULT(no)
1117 fi
1118
1119 AC_CACHE_CHECK([for unsigned char],rsync_cv_SIGNED_CHAR_OK,[
1120 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[signed char *s = (signed char *)""]])],[rsync_cv_SIGNED_CHAR_OK=yes],[rsync_cv_SIGNED_CHAR_OK=no])])
1121 if test x"$rsync_cv_SIGNED_CHAR_OK" = x"yes"; then
1122     AC_DEFINE(SIGNED_CHAR_OK, 1, [Define to 1 if "signed char" is a valid type])
1123 fi
1124
1125 AC_CACHE_CHECK([for broken readdir],rsync_cv_HAVE_BROKEN_READDIR,[
1126 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1127 #ifdef HAVE_SYS_TYPES_H
1128 #include <sys/types.h>
1129 #endif
1130 #include <dirent.h>
1131 int main(void) { struct dirent *di; DIR *d = opendir("."); di = readdir(d);
1132 if (di && di->d_name[-2] == '.' && di->d_name[-1] == 0 &&
1133 di->d_name[0] == 0) return 0; return 1;} ]])],[rsync_cv_HAVE_BROKEN_READDIR=yes],[rsync_cv_HAVE_BROKEN_READDIR=no],[rsync_cv_HAVE_BROKEN_READDIR=cross])])
1134 if test x"$rsync_cv_HAVE_BROKEN_READDIR" = x"yes"; then
1135     AC_DEFINE(HAVE_BROKEN_READDIR, 1, [Define to 1 if readdir() is broken])
1136 fi
1137
1138 AC_CACHE_CHECK([for utimbuf],rsync_cv_HAVE_STRUCT_UTIMBUF,[
1139 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1140 #ifdef HAVE_SYS_TYPES_H
1141 #include <sys/types.h>
1142 #endif
1143 #include <utime.h>]], [[struct utimbuf tbuf;  tbuf.actime = 0; tbuf.modtime = 1; return utime("foo.c",&tbuf);]])],[rsync_cv_HAVE_STRUCT_UTIMBUF=yes],[rsync_cv_HAVE_STRUCT_UTIMBUF=no])])
1144 if test x"$rsync_cv_HAVE_STRUCT_UTIMBUF" = x"yes"; then
1145     AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if you have the "struct utimbuf" type])
1146 fi
1147
1148 AC_CACHE_CHECK([if gettimeofday takes tz argument],rsync_cv_HAVE_GETTIMEOFDAY_TZ,[
1149 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/time.h>
1150 #ifdef HAVE_UNISTD_H
1151 #include <unistd.h>
1152 #endif]], [[struct timeval tv; return gettimeofday(&tv, NULL);]])],[rsync_cv_HAVE_GETTIMEOFDAY_TZ=yes],[rsync_cv_HAVE_GETTIMEOFDAY_TZ=no])])
1153 if test x"$rsync_cv_HAVE_GETTIMEOFDAY_TZ" != x"no"; then
1154     AC_DEFINE(HAVE_GETTIMEOFDAY_TZ, 1, [Define to 1 if gettimeofday() takes a time-zone arg])
1155 fi
1156
1157 AC_CACHE_CHECK([for C99 vsnprintf],rsync_cv_HAVE_C99_VSNPRINTF,[
1158 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1159 #ifdef HAVE_SYS_TYPES_H
1160 #include <sys/types.h>
1161 #endif
1162 #include <stdarg.h>
1163 #include <stdio.h>
1164 #if HAVE_STDLIB_H
1165 #include <stdlib.h>
1166 #endif
1167 #include <string.h>
1168 void foo(const char *format, ...) {
1169        va_list ap;
1170        int len;
1171        static char buf[] = "12345678901234567890";
1172
1173        va_start(ap, format);
1174        len = vsnprintf(0, 0, format, ap);
1175        va_end(ap);
1176        if (len != 5) exit(1);
1177
1178        if (snprintf(buf, 3, "hello") != 5 || strcmp(buf, "he") != 0) exit(1);
1179 }
1180 int main(void) { foo("hello"); return 0; }
1181 ]])],[rsync_cv_HAVE_C99_VSNPRINTF=yes],[rsync_cv_HAVE_C99_VSNPRINTF=no],[rsync_cv_HAVE_C99_VSNPRINTF=cross])])
1182 if test x"$rsync_cv_HAVE_C99_VSNPRINTF" = x"yes"; then
1183     AC_DEFINE(HAVE_C99_VSNPRINTF, 1, [Define to 1 if vsprintf has a C99-compatible return value])
1184 fi
1185
1186
1187 AC_CACHE_CHECK([for secure mkstemp],rsync_cv_HAVE_SECURE_MKSTEMP,[
1188 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
1189 #ifdef HAVE_SYS_TYPES_H
1190 #include <sys/types.h>
1191 #endif
1192 #include <sys/stat.h>
1193 #ifdef HAVE_UNISTD_H
1194 #include <unistd.h>
1195 #endif
1196 int main(void) {
1197   struct stat st;
1198   char tpl[20]="/tmp/test.XXXXXX";
1199   int fd = mkstemp(tpl);
1200   if (fd == -1) return 1;
1201   unlink(tpl);
1202   if (fstat(fd, &st) != 0) return 1;
1203   if ((st.st_mode & 0777) != 0600) return 1;
1204   return 0;
1205 }]])],[rsync_cv_HAVE_SECURE_MKSTEMP=yes],[rsync_cv_HAVE_SECURE_MKSTEMP=no],[rsync_cv_HAVE_SECURE_MKSTEMP=cross])])
1206 if test x"$rsync_cv_HAVE_SECURE_MKSTEMP" = x"yes"; then
1207     case $host_os in
1208     hpux*)
1209         dnl HP-UX has a broken mkstemp() implementation they refuse to fix,
1210         dnl so we noisily skip using it.  See HP change request JAGaf34426
1211         dnl for details. (sbonds)
1212         AC_MSG_WARN(Skipping broken HP-UX mkstemp() -- using mktemp() instead)
1213         ;;
1214     *)
1215         AC_DEFINE(HAVE_SECURE_MKSTEMP, 1, [Define to 1 if mkstemp() is available and works right])
1216         ;;
1217     esac
1218 fi
1219
1220
1221 AC_CACHE_CHECK([if mknod creates FIFOs],rsync_cv_MKNOD_CREATES_FIFOS,[
1222 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1223 #include <stdio.h>
1224 #include <sys/stat.h>
1225 #include <errno.h>
1226 #if HAVE_UNISTD_H
1227 # include <unistd.h>
1228 #endif
1229 int main(void) { int rc, ec; char *fn = "fifo-test";
1230 unlink(fn); rc = mknod(fn,S_IFIFO,0600); ec = errno; unlink(fn);
1231 if (rc) {printf("(%d %d) ",rc,ec); return ec;}
1232 return 0;}]])],[rsync_cv_MKNOD_CREATES_FIFOS=yes],[rsync_cv_MKNOD_CREATES_FIFOS=no],[rsync_cv_MKNOD_CREATES_FIFOS=cross])])
1233 if test x"$rsync_cv_MKNOD_CREATES_FIFOS" = x"yes"; then
1234     AC_DEFINE(MKNOD_CREATES_FIFOS, 1, [Define to 1 if mknod() can create FIFOs.])
1235 fi
1236
1237 AC_CACHE_CHECK([if mknod creates sockets],rsync_cv_MKNOD_CREATES_SOCKETS,[
1238 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1239 #include <stdio.h>
1240 #include <sys/stat.h>
1241 #include <errno.h>
1242 #if HAVE_UNISTD_H
1243 # include <unistd.h>
1244 #endif
1245 int main(void) { int rc, ec; char *fn = "sock-test";
1246 unlink(fn); rc = mknod(fn,S_IFSOCK,0600); ec = errno; unlink(fn);
1247 if (rc) {printf("(%d %d) ",rc,ec); return ec;}
1248 return 0;}]])],[rsync_cv_MKNOD_CREATES_SOCKETS=yes],[rsync_cv_MKNOD_CREATES_SOCKETS=no],[rsync_cv_MKNOD_CREATES_SOCKETS=cross])])
1249 if test x"$rsync_cv_MKNOD_CREATES_SOCKETS" = x"yes"; then
1250     AC_DEFINE(MKNOD_CREATES_SOCKETS, 1, [Define to 1 if mknod() can create sockets.])
1251 fi
1252
1253 #
1254 # The following test was mostly taken from the tcl/tk plus patches
1255 #
1256 AC_CACHE_CHECK([whether -c -o works],rsync_cv_DASHC_WORKS_WITH_DASHO,[
1257 rm -rf conftest*
1258 cat > conftest.$ac_ext <<EOF
1259 int main(void) { return 0; }
1260 EOF
1261 ${CC-cc} -c -o conftest..o conftest.$ac_ext
1262 if test -f conftest..o; then
1263     rsync_cv_DASHC_WORKS_WITH_DASHO=yes
1264 else
1265     rsync_cv_DASHC_WORKS_WITH_DASHO=no
1266 fi
1267 rm -rf conftest*
1268 ])
1269 if test x"$rsync_cv_DASHC_WORKS_WITH_DASHO" = x"yes"; then
1270     OBJ_SAVE="#"
1271     OBJ_RESTORE="#"
1272     CC_SHOBJ_FLAG='-o $@'
1273 else
1274     OBJ_SAVE='  @b=`basename $@ .o`;rm -f $$b.o.sav;if test -f $$b.o; then mv $$b.o $$b.o.sav;fi;'
1275     OBJ_RESTORE='       @b=`basename $@ .o`;if test "$$b.o" != "$@"; then mv $$b.o $@; if test -f $$b.o.sav; then mv $$b.o.sav $$b.o; fi; fi'
1276     CC_SHOBJ_FLAG=""
1277 fi
1278
1279 AC_SUBST(OBJ_SAVE)
1280 AC_SUBST(OBJ_RESTORE)
1281 AC_SUBST(CC_SHOBJ_FLAG)
1282 AC_SUBST(BUILD_POPT)
1283 AC_SUBST(BUILD_ZLIB)
1284 AC_SUBST(MAKE_RRSYNC)
1285 AC_SUBST(MAKE_RRSYNC_1)
1286 AC_SUBST(GEN_RRSYNC)
1287 AC_SUBST(MAKE_MAN)
1288
1289 AC_CHECK_FUNCS(_acl __acl _facl __facl)
1290 #################################################
1291 # check for ACL support
1292
1293 AC_MSG_CHECKING([whether to support ACLs])
1294 AC_ARG_ENABLE(acl-support,
1295         AS_HELP_STRING([--disable-acl-support],[disable to omit ACL support]))
1296
1297 if test x"$enable_acl_support" = x"no"; then
1298     AC_MSG_RESULT(no)
1299 else
1300     case "$host_os" in
1301     *sysv5*)
1302         AC_MSG_RESULT(Using UnixWare ACLs)
1303         AC_DEFINE(HAVE_UNIXWARE_ACLS, 1, [true if you have UnixWare ACLs])
1304         AC_DEFINE(SUPPORT_ACLS, 1, [Define to 1 to add support for ACLs])
1305         ;;
1306     solaris*)
1307         AC_MSG_RESULT(Using solaris ACLs)
1308         AC_DEFINE(HAVE_SOLARIS_ACLS, 1, [true if you have solaris ACLs])
1309         AC_DEFINE(SUPPORT_ACLS, 1)
1310         ;;
1311     *irix*)
1312         AC_MSG_RESULT(Using IRIX ACLs)
1313         AC_DEFINE(HAVE_IRIX_ACLS, 1, [true if you have IRIX ACLs])
1314         AC_DEFINE(SUPPORT_ACLS, 1)
1315         ;;
1316     *aix*)
1317         AC_MSG_RESULT(Using AIX ACLs)
1318         AC_DEFINE(HAVE_AIX_ACLS, 1, [true if you have AIX ACLs])
1319         AC_DEFINE(SUPPORT_ACLS, 1)
1320         ;;
1321     *osf*)
1322         AC_MSG_RESULT(Using Tru64 ACLs)
1323         AC_DEFINE(HAVE_TRU64_ACLS, 1, [true if you have Tru64 ACLs])
1324         AC_DEFINE(SUPPORT_ACLS, 1)
1325         LIBS="$LIBS -lpacl"
1326         ;;
1327     darwin*)
1328         AC_MSG_RESULT(Using OS X ACLs)
1329         AC_DEFINE(HAVE_OSX_ACLS, 1, [true if you have Mac OS X ACLs])
1330         AC_DEFINE(SUPPORT_ACLS, 1)
1331         ;;
1332     *hpux*|*nsk*)
1333         AC_MSG_RESULT(Using HPUX ACLs)
1334         AC_DEFINE(HAVE_HPUX_ACLS, 1, [true if you have HPUX ACLs])
1335         AC_DEFINE(SUPPORT_ACLS, 1)
1336         ;;
1337     *)
1338         AC_MSG_RESULT(running tests:)
1339         AC_CHECK_LIB(acl,acl_get_file)
1340         AC_CACHE_CHECK([for ACL support],samba_cv_HAVE_POSIX_ACLS,[
1341             AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1342 #ifdef HAVE_SYS_TYPES_H
1343 #include <sys/types.h>
1344 #endif
1345 #ifdef HAVE_SYS_ACL_H
1346 #include <sys/acl.h>
1347 #endif]], [[ acl_t acl; int entry_id; acl_entry_t *entry_p; return acl_get_entry( acl, entry_id, entry_p);]])],[samba_cv_HAVE_POSIX_ACLS=yes],[samba_cv_HAVE_POSIX_ACLS=no])])
1348         AC_MSG_CHECKING(ACL test results)
1349         if test x"$samba_cv_HAVE_POSIX_ACLS" = x"yes"; then
1350             AC_MSG_RESULT(Using posix ACLs)
1351             AC_DEFINE(HAVE_POSIX_ACLS, 1, [true if you have posix ACLs])
1352             AC_DEFINE(SUPPORT_ACLS, 1)
1353             AC_CACHE_CHECK([for acl_get_perm_np],samba_cv_HAVE_ACL_GET_PERM_NP,[
1354                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1355 #ifdef HAVE_SYS_TYPES_H
1356 #include <sys/types.h>
1357 #endif
1358 #ifdef HAVE_SYS_ACL_H
1359 #include <sys/acl.h>
1360 #endif]], [[ acl_permset_t permset_d; acl_perm_t perm; return acl_get_perm_np( permset_d, perm);]])],[samba_cv_HAVE_ACL_GET_PERM_NP=yes],[samba_cv_HAVE_ACL_GET_PERM_NP=no])])
1361             if test x"$samba_cv_HAVE_ACL_GET_PERM_NP" = x"yes"; then
1362                 AC_DEFINE(HAVE_ACL_GET_PERM_NP, 1, [true if you have acl_get_perm_np])
1363             fi
1364         else
1365             if test x"$enable_acl_support" = x"yes"; then
1366                 AC_MSG_ERROR(Failed to find ACL support)
1367             else
1368                 AC_MSG_RESULT(No ACL support found)
1369             fi
1370         fi
1371         ;;
1372     esac
1373 fi
1374
1375 #################################################
1376 # check for extended attribute support
1377 AC_MSG_CHECKING(whether to support extended attributes)
1378 AC_ARG_ENABLE(xattr-support,
1379     AS_HELP_STRING([--disable-xattr-support],[disable to omit extended attributes]),
1380     [], [case "$ac_cv_func_getxattr$ac_cv_func_extattr_get_link$ac_cv_func_attropen" in
1381         *yes*) enable_xattr_support=maybe ;;
1382         *) enable_xattr_support=no ;;
1383         esac])
1384 AH_TEMPLATE([SUPPORT_XATTRS],
1385 [Define to 1 to add support for extended attributes])
1386 if test x"$enable_xattr_support" = x"no"; then
1387     AC_MSG_RESULT(no)
1388 else
1389     case "$host_os" in
1390     *linux*|*netbsd*|*cygwin*)
1391         AC_MSG_RESULT(Using Linux xattrs)
1392         AC_DEFINE(HAVE_LINUX_XATTRS, 1, [True if you have Linux xattrs (or equivalent)])
1393         AC_DEFINE(SUPPORT_XATTRS, 1)
1394         AC_DEFINE(NO_SYMLINK_USER_XATTRS, 1, [True if symlinks do not support user xattrs])
1395         AC_CHECK_LIB(attr,getxattr)
1396         ;;
1397     darwin*)
1398         AC_MSG_RESULT(Using OS X xattrs)
1399         AC_DEFINE(HAVE_OSX_XATTRS, 1, [True if you have Mac OS X xattrs])
1400         AC_DEFINE(SUPPORT_XATTRS, 1)
1401         AC_DEFINE(NO_DEVICE_XATTRS, 1, [True if device files do not support xattrs])
1402         AC_DEFINE(NO_SPECIAL_XATTRS, 1, [True if special files do not support xattrs])
1403         ;;
1404     freebsd*)
1405         AC_MSG_RESULT(Using FreeBSD extattrs)
1406         AC_DEFINE(HAVE_FREEBSD_XATTRS, 1, [True if you have FreeBSD xattrs])
1407         AC_DEFINE(SUPPORT_XATTRS, 1)
1408         ;;
1409     solaris*)
1410         AC_MSG_RESULT(Using Solaris xattrs)
1411         AC_DEFINE(HAVE_SOLARIS_XATTRS, 1, [True if you have Solaris xattrs])
1412         AC_DEFINE(SUPPORT_XATTRS, 1)
1413         AC_DEFINE(NO_SYMLINK_XATTRS, 1, [True if symlinks do not support xattrs])
1414         ;;
1415     *)
1416         if test x"$enable_xattr_support" = x"yes"; then
1417             AC_MSG_ERROR(Failed to find extended attribute support)
1418         else
1419             AC_MSG_RESULT(No extended attribute support found)
1420         fi
1421         ;;
1422     esac
1423 fi
1424
1425 if test x"$enable_acl_support" = x"no" || test x"$enable_xattr_support" = x"no" || test x"$enable_iconv" = x"no"; then
1426     AC_MSG_CHECKING([whether $CC supports -Wno-unused-parameter])
1427     OLD_CFLAGS="$CFLAGS"
1428     CFLAGS="$CFLAGS -Wno-unused-parameter"
1429     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdio.h>]], [[printf("hello\n");]])],[rsync_warn_flag=yes],[rsync_warn_flag=no])
1430     AC_MSG_RESULT([$rsync_warn_flag])
1431     if test x"$rsync_warn_flag" = x"no"; then
1432         CFLAGS="$OLD_CFLAGS"
1433     fi
1434 fi
1435
1436 case "$CC" in
1437 ' checker'*|checker*)
1438     AC_DEFINE(FORCE_FD_ZERO_MEMSET, 1, [Used to make "checker" understand that FD_ZERO() clears memory.])
1439     ;;
1440 esac
1441
1442 AC_CONFIG_FILES([Makefile lib/dummy zlib/dummy popt/dummy shconfig])
1443 AC_OUTPUT
1444
1445 AC_MSG_RESULT()
1446 AC_MSG_RESULT([    rsync $PACKAGE_VERSION configuration successful])
1447 AC_MSG_RESULT()