configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_INIT([rsync],[ ],[https://rsync.samba.org/bug-tracking.html])
   4
   5 AC_C_BIGENDIAN
   6 AC_HEADER_DIRENT
   7 AC_HEADER_TIME
   8 AC_HEADER_SYS_WAIT
   9 AC_CHECK_HEADERS(sys/fcntl.h sys/select.h fcntl.h sys/time.h sys/unistd.h \
  10     unistd.h utime.h compat.h sys/param.h ctype.h sys/wait.h sys/stat.h \
  11     sys/ioctl.h sys/filio.h string.h stdlib.h sys/socket.h sys/mode.h grp.h \
  12     sys/un.h sys/attr.h arpa/inet.h arpa/nameser.h locale.h sys/types.h \
  13     netdb.h malloc.h float.h limits.h iconv.h libcharset.h langinfo.h mcheck.h \
  14     sys/acl.h acl/libacl.h attr/xattr.h sys/xattr.h sys/extattr.h dl.h \
  15     popt.h popt/popt.h linux/falloc.h netinet/in_systm.h netgroup.h \
  16     zlib.h xxhash.h openssl/md4.h openssl/md5.h zstd.h lz4.h sys/file.h \
  17     bsd/string.h)
  18 AC_CHECK_HEADERS([netinet/ip.h], [], [], [[#include <netinet/in.h>]])
  19 AC_HEADER_MAJOR_FIXED
  20
  21 AC_CONFIG_MACRO_DIR([m4])
  22 AC_CONFIG_SRCDIR([byteorder.h])
  23 AC_CONFIG_HEADER(config.h)
  24 AC_PREREQ([2.69])
  25
  26 PACKAGE_VERSION=`sed -n 's/.*RSYNC_VERSION.*"\(.*\)".*/\1/p' <$srcdir/version.h`
  27
  28 AC_MSG_NOTICE([Configuring rsync $PACKAGE_VERSION])
  29
  30 LDFLAGS=${LDFLAGS-""}
  31
  32 AC_CANONICAL_HOST
  33
  34 dnl define the directory for replacement function since AC_LIBOBJ does not
  35 dnl officially support subdirs and fails with automake
  36 AC_CONFIG_LIBOBJ_DIR([lib])
  37
  38 # We must decide this before testing the compiler.
  39
  40 # Please allow this to default to yes, so that your users have more
  41 # chance of getting a useful stack trace if problems occur.
  42
  43 AC_MSG_CHECKING([whether to include debugging symbols])
  44 AC_ARG_ENABLE(debug,
  45         AS_HELP_STRING([--disable-debug],[disable to omit debugging symbols and features]))
  46
  47 if test x"$enable_debug" = x"no"; then
  48     AC_MSG_RESULT(no)
  49     ac_cv_prog_cc_g=no
  50 else
  51     AC_MSG_RESULT([yes])
  52     dnl AC_DEFINE(DEBUG, 1, [Define to turn on debugging code that may slow normal operation])
  53     # leave ac_cv_prog_cc_g alone; AC_PROG_CC will try to include -g if it can
  54 fi
  55
  56 dnl Checks for programs.
  57 AC_PROG_CC
  58 AC_PROG_CPP
  59 AC_PROG_CXX
  60 AC_PROG_AWK
  61 AC_PROG_EGREP
  62 AC_PROG_INSTALL
  63 AC_PROG_MKDIR_P
  64 AC_PROG_CC_STDC
  65 AC_SUBST(SHELL)
  66 AC_PATH_PROG([PERL], [perl])
  67 AC_PATH_PROG([PYTHON3], [python3])
  68
  69 AC_DEFINE([_GNU_SOURCE], 1,
  70           [Define _GNU_SOURCE so that we get all necessary prototypes])
  71
  72 if test x"$ac_cv_prog_cc_stdc" = x"no"; then
  73         AC_MSG_WARN([rsync requires an ANSI C compiler and you do not seem to have one])
  74 fi
  75
  76 no_lib=''
  77 err_msg=''
  78 nl='
  79 '
  80
  81 AC_ARG_ENABLE(profile,
  82         AS_HELP_STRING([--enable-profile],[enable to turn on CPU profiling]))
  83 if test x"$enable_profile" = x"yes"; then
  84         CFLAGS="$CFLAGS -pg"
  85 fi
  86
  87 AC_MSG_CHECKING([if md2man can create manpages])
  88 if test x"$ac_cv_path_PYTHON3" = x; then
  89     AC_MSG_RESULT(no - python3 not found)
  90     md2man_works=no
  91 else
  92     md2man_out=`"$srcdir/md2man" --test "$srcdir/rsync-ssl.1.md" 2>&1`
  93     if test $? = 0; then
  94         AC_MSG_RESULT(yes)
  95         md2man_works=yes
  96     else
  97         AC_MSG_RESULT(no)
  98         md2man_works=no
  99         echo "$md2man_out"
 100     fi
 101 fi
 102
 103 AC_MSG_CHECKING([if we require man-page building])
 104 AC_ARG_ENABLE([md2man],
 105         AS_HELP_STRING([--disable-md2man],[disable to omit manpage creation]))
 106 if test x"$enable_md2man" != x"no"; then
 107     if test -f "$srcdir/rsync.1"; then
 108         AC_MSG_RESULT(optional)
 109     else
 110         AC_MSG_RESULT(required)
 111         if test x"$md2man_works" = x"no"; then
 112             err_msg="$err_msg$nl- You need python3 and either the cmarkgfm OR commonmark python3 lib in order"
 113             err_msg="$err_msg$nl  to build manpages based on the git source (manpages are included in the"
 114             err_msg="$err_msg$nl  official release tar files)."
 115             no_lib="$no_lib md2man"
 116         fi
 117     fi
 118     MAKE_MAN=man
 119 else
 120     AC_MSG_RESULT(no)
 121 fi
 122
 123 # Specifically, this turns on panic_action handling.
 124 AC_ARG_ENABLE(maintainer-mode,
 125         AS_HELP_STRING([--enable-maintainer-mode],[enable to turn on extra debug features]))
 126 if test x"$enable_maintainer_mode" = x"yes"; then
 127         CFLAGS="$CFLAGS -DMAINTAINER_MODE"
 128 fi
 129
 130 # This is needed for our included version of popt.  Kind of silly, but
 131 # I don't want our version too far out of sync.
 132 CFLAGS="$CFLAGS -DHAVE_CONFIG_H"
 133
 134 # If GCC, turn on warnings.
 135 if test x"$GCC" = x"yes"; then
 136         CFLAGS="$CFLAGS -Wall -W"
 137 fi
 138
 139 AC_ARG_WITH(openssl-conf,
 140         AS_HELP_STRING([--with-openssl-conf=PATH],[set default OPENSSL_CONF path for rsync]))
 141 case "$with_openssl_conf" in
 142     *[^-/a-zA-Z0-9.,=@+_]*) AC_MSG_ERROR([Invalid path given to --with-openssl-conf]) ;;
 143     /*) CFLAGS="$CFLAGS -DSET_OPENSSL_CONF=$with_openssl_conf" ;;
 144     no|'') ;;
 145     yes) AC_MSG_ERROR([No path given to --with-openssl-conf]) ;;
 146     *) AC_MSG_ERROR([Non absolute path given to --with-openssl-conf]) ;;
 147 esac
 148
 149 AC_ARG_WITH(rrsync,
 150         AS_HELP_STRING([--with-rrsync],[also install the rrsync script and its manpage]))
 151 if test x"$with_rrsync" != x"yes"; then
 152     with_rrsync=no
 153 else
 154     MAKE_RRSYNC='rrsync'
 155     MAKE_RRSYNC_1='rrsync.1'
 156     GEN_RRSYNC='rrsync.1 rrsync.1.html'
 157 fi
 158 AC_SUBST(with_rrsync)
 159
 160 AC_ARG_WITH(included-popt,
 161         AS_HELP_STRING([--with-included-popt],[use bundled popt library, not from system]))
 162
 163 AC_ARG_WITH(included-zlib,
 164         AS_HELP_STRING([--with-included-zlib],[use bundled zlib library, not from system]))
 165
 166 AC_ARG_WITH(secluded-args,
 167         AS_HELP_STRING([--with-secluded-args],[make --secluded-args option the default]))
 168 if test x"$with_secluded_args" = x"yes"; then
 169         AC_DEFINE_UNQUOTED(RSYNC_USE_SECLUDED_ARGS, 1, [Define to 1 if --secluded-args should be the default])
 170 fi
 171
 172 AC_ARG_WITH(rsync-path,
 173         AS_HELP_STRING([--with-rsync-path=PATH],[set default --rsync-path to PATH (default: rsync)]),
 174         [ RSYNC_PATH="$with_rsync_path" ],
 175         [ RSYNC_PATH="rsync" ])
 176
 177 AC_DEFINE_UNQUOTED(RSYNC_PATH, "$RSYNC_PATH", [location of rsync on remote machine])
 178
 179 AC_ARG_WITH(rsyncd-conf,
 180         AS_HELP_STRING([--with-rsyncd-conf=PATH],[set configuration file for rsync server to PATH (default: /etc/rsyncd.conf)]),
 181         [ if test ! -z "$with_rsyncd_conf" ; then
 182                 case $with_rsyncd_conf in
 183                         yes|no)
 184                                 RSYNCD_SYSCONF="/etc/rsyncd.conf"
 185                                 ;;
 186                         /*)
 187                                 RSYNCD_SYSCONF="$with_rsyncd_conf"
 188                                 ;;
 189                         *)
 190                                 AC_MSG_ERROR(You must specify an absolute path to --with-rsyncd-conf=PATH)
 191                                 ;;
 192                 esac
 193         else
 194                 RSYNCD_SYSCONF="/etc/rsyncd.conf"
 195         fi ],
 196         [ RSYNCD_SYSCONF="/etc/rsyncd.conf" ])
 197
 198 AC_DEFINE_UNQUOTED(RSYNCD_SYSCONF, "$RSYNCD_SYSCONF", [location of configuration file for rsync server])
 199
 200 AC_ARG_WITH(rsh,
 201         AS_HELP_STRING([--with-rsh=CMD],[set remote shell command to CMD (default: ssh)]))
 202
 203 AC_CHECK_PROG(HAVE_REMSH, remsh, 1, 0)
 204 if test x$HAVE_REMSH = x1; then
 205         AC_DEFINE(HAVE_REMSH, 1, [Define to 1 if remote shell is remsh, not rsh])
 206 fi
 207
 208 if test x"$with_rsh" != x; then
 209         RSYNC_RSH="$with_rsh"
 210 else
 211         RSYNC_RSH="ssh"
 212 fi
 213 AC_DEFINE_UNQUOTED(RSYNC_RSH, "$RSYNC_RSH", [default -e command])
 214
 215 # Some programs on solaris are only found in /usr/xpg4/bin (or work better than others versions).
 216 AC_PATH_PROG(SHELL_PATH, sh, /bin/sh, [/usr/xpg4/bin$PATH_SEPARATOR$PATH])
 217 AC_PATH_PROG(FAKEROOT_PATH, fakeroot, /usr/bin/fakeroot, [/usr/xpg4/bin$PATH_SEPARATOR$PATH])
 218
 219 AC_ARG_WITH(nobody-user,
 220     AS_HELP_STRING([--with-nobody-user=USER],[set the default unprivileged user (default nobody)]),
 221     [ NOBODY_USER="$with_nobody_user" ],
 222     [ NOBODY_USER="nobody" ])
 223
 224 AC_ARG_WITH(nobody-group,
 225     AS_HELP_STRING([--with-nobody-group=GROUP],[set the default unprivileged group (default nobody or nogroup)]),
 226     [ NOBODY_GROUP="$with_nobody_group" ])
 227
 228 if test x"$with_nobody_group" = x; then
 229     AC_MSG_CHECKING([the group for user "nobody"])
 230     if grep '^nobody:' /etc/group >/dev/null 2>&1; then
 231         NOBODY_GROUP=nobody
 232     elif grep '^nogroup:' /etc/group >/dev/null 2>&1; then
 233         NOBODY_GROUP=nogroup
 234     else
 235         NOBODY_GROUP=nobody # test for others?
 236     fi
 237     AC_MSG_RESULT($NOBODY_GROUP)
 238 fi
 239
 240 AC_DEFINE_UNQUOTED(NOBODY_USER, "$NOBODY_USER", [unprivileged user--e.g. nobody])
 241 AC_DEFINE_UNQUOTED(NOBODY_GROUP, "$NOBODY_GROUP", [unprivileged group for unprivileged user])
 242
 243 # rolling-checksum SIMD optimizations
 244 ROLL_SIMD=
 245
 246 AC_MSG_CHECKING([whether to enable rolling-checksum SIMD optimizations])
 247 AC_ARG_ENABLE(roll-simd,
 248     AS_HELP_STRING([--enable-roll-simd],[enable/disable to control rolling-checksum SIMD optimizations (requires c++)]))
 249
 250 # Clag is crashing with -g -O2, so we'll get rid of -g for now.
 251 CXXFLAGS=`echo "$CXXFLAGS" | sed 's/-g //'`
 252 m4_define(SIMD_X86_64_TEST, [[#include <stdio.h>
 253 #if HAVE_STDLIB_H
 254 #include <stdlib.h>
 255 #endif
 256 #include <immintrin.h>
 257 __attribute__ ((target("default"))) int test_ssse3(int x) { return x; }
 258 __attribute__ ((target("default"))) int test_sse2(int x) { return x; }
 259 __attribute__ ((target("default"))) int test_avx2(int x) { return x; }
 260 __attribute__ ((target("ssse3"))) int test_ssse3(int x) { return x; }
 261 __attribute__ ((target("sse2"))) int test_sse2(int x) { return x; }
 262 __attribute__ ((target("avx2"))) int test_avx2(int x) { return x; }
 263 typedef long long __m128i_u __attribute__((__vector_size__(16), __may_alias__, __aligned__(1)));
 264 typedef long long __m256i_u __attribute__((__vector_size__(32), __may_alias__, __aligned__(1)));
 265 __attribute__ ((target("default"))) void more_testing(char* buf, int len) { }
 266 __attribute__ ((target("ssse3"))) void more_testing(char* buf, int len)
 267 {
 268     int i;
 269     for (i = 0; i < (len-32); i+=32) {
 270         __m128i in8_1, in8_2;
 271         in8_1 = _mm_lddqu_si128((__m128i_u*)&buf[i]);
 272         in8_2 = _mm_lddqu_si128((__m128i_u*)&buf[i + 16]);
 273     }
 274 }
 275 ]])
 276
 277 if test x"$enable_roll_simd" = x""; then
 278     case "$host_os" in
 279         *linux*) ;;
 280         *) enable_roll_simd=no ;;
 281     esac
 282 fi
 283
 284 if test x"$enable_roll_simd" != x"no"; then
 285     # For x86-64 SIMD, g++ >=5 or clang++ >=7 is required
 286     if test x"$host_cpu" = x"x86_64" || test x"$host_cpu" = x"amd64"; then
 287         AC_LANG(C++)
 288         if test x"$host" = x"$build"; then
 289             AC_RUN_IFELSE([AC_LANG_PROGRAM([SIMD_X86_64_TEST],[[if (test_ssse3(42) != 42 || test_sse2(42) != 42 || test_avx2(42) != 42) exit(1);]])],
 290                 [CXX_OK=yes],[CXX_OK=no])
 291         else
 292             AC_COMPILE_IFELSE([AC_LANG_PROGRAM([SIMD_X86_64_TEST])],[CXX_OK=yes],[CXX_OK=no])
 293         fi
 294         AC_LANG(C)
 295         if test x"$CXX_OK" = x"yes"; then
 296             # AC_MSG_RESULT() is called below.
 297             ROLL_SIMD="$host_cpu"
 298         elif test x"$enable_roll_simd" = x"yes"; then
 299             AC_MSG_RESULT(error)
 300             AC_MSG_ERROR(The rolling-checksum SIMD compilation test failed.
 301 Omit --enable-roll-simd to continue without it.)
 302         fi
 303     elif test x"$enable_roll_simd" = x"yes"; then
 304         AC_MSG_RESULT(unavailable)
 305         AC_MSG_ERROR(The rolling-checksum SIMD optimizations are currently x86_64|amd64 only.
 306 Omit --enable-roll-simd to continue without it.)
 307     fi
 308 fi
 309
 310 if test x"$ROLL_SIMD" != x""; then
 311     AC_MSG_RESULT([yes ($ROLL_SIMD)])
 312     AC_DEFINE(USE_ROLL_SIMD, 1, [Define to 1 to enable rolling-checksum SIMD optimizations])
 313     ROLL_SIMD='$(ROLL_SIMD_'"$ROLL_SIMD)"
 314     # We only use c++ for its target attribute dispatching, disable unneeded bulky features
 315     CXXFLAGS="$CXXFLAGS -fno-exceptions -fno-rtti"
 316     # Apple often has "g++" as a symlink for clang. Try to find out the truth.
 317     CXX_VERSION=`$CXX --version 2>/dev/null | head -n 2`
 318     case "$CXX_VERSION" in
 319     *clang*) CXXFLAGS="$CXXFLAGS -fno-slp-vectorize" ;; # avoid a performance hit
 320     esac
 321 else
 322     AC_MSG_RESULT(no)
 323 fi
 324
 325 AC_SUBST(ROLL_SIMD)
 326
 327 AC_MSG_CHECKING([if assembler accepts noexecstack])
 328 OLD_CFLAGS="$CFLAGS"
 329 CFLAGS="$CFLAGS -Wa,--noexecstack"
 330 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[ ]], [[return 0;]])],
 331 [ NOEXECSTACK='-Wa,--noexecstack' ; AC_MSG_RESULT(yes) ],
 332 [ NOEXECSTACK='' ; AC_MSG_RESULT(no) ])
 333 CFLAGS="$OLD_CFLAGS"
 334 AC_SUBST(NOEXECSTACK)
 335
 336 # arrgh. libc in some old debian version screwed up the largefile
 337 # stuff, getting byte range locking wrong
 338 AC_CACHE_CHECK([for broken largefile support],rsync_cv_HAVE_BROKEN_LARGEFILE,[
 339 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 340 #define _FILE_OFFSET_BITS 64
 341 $ac_includes_default
 342 #ifdef HAVE_FCNTL_H
 343 # include <fcntl.h>
 344 #elif defined HAVE_SYS_FCNTL_H
 345 # include <sys/fcntl.h>
 346 #endif
 347 #ifdef HAVE_SYS_WAIT_H
 348 #include <sys/wait.h>
 349 #endif
 350
 351 int main(void)
 352 {
 353         struct flock lock;
 354         int status;
 355         char tpl[32] = "/tmp/locktest.XXXXXX";
 356         int fd = mkstemp(tpl);
 357         if (fd < 0) {
 358                 strcpy(tpl, "conftest.dat");
 359                 fd = open(tpl, O_CREAT|O_RDWR, 0600);
 360         }
 361
 362         lock.l_type = F_WRLCK;
 363         lock.l_whence = SEEK_SET;
 364         lock.l_start = 0;
 365         lock.l_len = 1;
 366         lock.l_pid = 0;
 367         fcntl(fd,F_SETLK,&lock);
 368         if (fork() == 0) {
 369                 lock.l_start = 1;
 370                 _exit(fcntl(fd,F_SETLK,&lock) == 0);
 371         }
 372         wait(&status);
 373         unlink(tpl);
 374         return WEXITSTATUS(status);
 375 }
 376 ]])],[rsync_cv_HAVE_BROKEN_LARGEFILE=yes],[rsync_cv_HAVE_BROKEN_LARGEFILE=no],[rsync_cv_HAVE_BROKEN_LARGEFILE=cross])])
 377 if test x"$rsync_cv_HAVE_BROKEN_LARGEFILE" != x"yes"; then
 378    AC_SYS_LARGEFILE
 379 fi
 380
 381 AC_MSG_CHECKING([whether to enable ipv6])
 382 AC_ARG_ENABLE(ipv6,
 383 AS_HELP_STRING([--disable-ipv6],[disable to omit ipv6 support]),
 384 [ case "$enableval" in
 385   no)
 386         AC_MSG_RESULT(no)
 387         ;;
 388   *)    AC_MSG_RESULT(yes)
 389         AC_DEFINE(INET6, 1, [true if you have IPv6])
 390         ;;
 391   esac ],
 392
 393   AC_TRY_RUN([ /* AF_INET6 availability check */
 394 #include <stdlib.h>
 395 #include <sys/types.h>
 396 #include <sys/socket.h>
 397 main()
 398 {
 399    if (socket(AF_INET6, SOCK_STREAM, 0) < 0)
 400      exit(1);
 401    else
 402      exit(0);
 403 }
 404 ],
 405   AC_MSG_RESULT(yes)
 406   AC_DEFINE(INET6, 1, [true if you have IPv6]),
 407   AC_MSG_RESULT(no),
 408   AC_MSG_RESULT(no)
 409 ))
 410
 411 dnl Do you want to disable use of locale functions
 412 AC_ARG_ENABLE([locale],
 413         AS_HELP_STRING([--disable-locale],[disable to omit locale features]))
 414 AH_TEMPLATE([CONFIG_LOCALE],
 415 [Undefine if you do not want locale features.  By default this is defined.])
 416 if test x"$enable_locale" != x"no"; then
 417         AC_DEFINE(CONFIG_LOCALE)
 418 fi
 419
 420 AC_MSG_CHECKING([whether to call shutdown on all sockets])
 421 case $host_os in
 422         *cygwin* ) AC_MSG_RESULT(yes)
 423                    AC_DEFINE(SHUTDOWN_ALL_SOCKETS, 1,
 424                             [Define to 1 if sockets need to be shutdown])
 425                    ;;
 426                * ) AC_MSG_RESULT(no);;
 427 esac
 428
 429 AC_MSG_CHECKING([whether to enable use of openssl crypto library])
 430 AC_ARG_ENABLE([openssl],
 431         AS_HELP_STRING([--disable-openssl],[disable to omit openssl crypto library]))
 432 AH_TEMPLATE([USE_OPENSSL],
 433 [Undefine if you do not want to use openssl crypto library.  By default this is defined.])
 434 if test x"$enable_openssl" != x"no"; then
 435     if test x"$ac_cv_header_openssl_md4_h" = x"yes" && test x"$ac_cv_header_openssl_md5_h" = x"yes"; then
 436       AC_MSG_RESULT(yes)
 437       AC_SEARCH_LIBS(MD5_Init, crypto,
 438           [AC_DEFINE(USE_OPENSSL)
 439            enable_openssl=yes],
 440           [err_msg="$err_msg$nl- Failed to find MD5_Init function in openssl crypto lib.";
 441            no_lib="$no_lib openssl"])
 442     else
 443         AC_MSG_RESULT(no)
 444         err_msg="$err_msg$nl- Failed to find openssl/md4.h and openssl/md5.h for openssl crypto lib support."
 445         no_lib="$no_lib openssl"
 446     fi
 447     if test x"$enable_md5_asm" != x"yes"; then
 448         enable_md5_asm=no
 449     fi
 450 else
 451     AC_MSG_RESULT(no)
 452 fi
 453
 454 MD5_ASM=
 455
 456 AC_MSG_CHECKING([whether to enable MD5 ASM optimizations])
 457 AC_ARG_ENABLE(md5-asm,
 458     AS_HELP_STRING([--enable-md5-asm],[enable/disable to control MD5 ASM optimizations]))
 459
 460 if test x"$enable_md5_asm" = x""; then
 461     case "$host_os" in
 462         *linux*) ;;
 463         *) enable_md5_asm=no ;;
 464     esac
 465 fi
 466
 467 if test x"$enable_md5_asm" != x"no"; then
 468     if test x"$host_cpu" = x"x86_64" || test x"$host_cpu" = x"amd64"; then
 469         MD5_ASM="$host_cpu"
 470     elif test x"$enable_md5_asm" = x"yes"; then
 471         AC_MSG_RESULT(unavailable)
 472         AC_MSG_ERROR(The ASM optimizations are currently x86_64|amd64 only.
 473 Omit --enable-md5-asm to continue without it.)
 474     fi
 475 fi
 476
 477 if test x"$MD5_ASM" != x""; then
 478     AC_MSG_RESULT([yes ($MD5_ASM)])
 479     AC_DEFINE(USE_MD5_ASM, 1, [Define to 1 to enable MD5 ASM optimizations])
 480     MD5_ASM='$(MD5_ASM_'"$MD5_ASM)"
 481 else
 482     AC_MSG_RESULT(no)
 483 fi
 484
 485 AC_SUBST(MD5_ASM)
 486
 487 ROLL_ASM=
 488
 489 AC_MSG_CHECKING([whether to enable rolling-checksum ASM optimizations])
 490 AC_ARG_ENABLE(roll-asm,
 491     AS_HELP_STRING([--enable-roll-asm],[enable/disable to control rolling-checksum ASM optimizations (requires --enable-roll-simd)]))
 492
 493 if test x"$ROLL_SIMD" = x""; then
 494     enable_roll_asm=no
 495 fi
 496
 497 if test x"$enable_roll_asm" = x"yes"; then
 498     ROLL_ASM="$host_cpu"
 499     AC_MSG_RESULT([yes ($ROLL_ASM)])
 500     AC_DEFINE(USE_ROLL_ASM, 1, [Define to 1 to enable rolling-checksum ASM optimizations (requires --enable-roll-simd)])
 501     ROLL_ASM='$(ROLL_ASM_'"$ROLL_ASM)"
 502 else
 503     AC_MSG_RESULT(no)
 504 fi
 505
 506 AC_SUBST(ROLL_ASM)
 507
 508 AC_MSG_CHECKING([whether to enable xxhash checksum support])
 509 AC_ARG_ENABLE([xxhash],
 510         AS_HELP_STRING([--disable-xxhash],[disable to omit xxhash checksums]))
 511 AH_TEMPLATE([SUPPORT_XXHASH],
 512 [Undefine if you do not want xxhash checksums.  By default this is defined.])
 513 if test x"$enable_xxhash" != x"no"; then
 514     if test x"$ac_cv_header_xxhash_h" = x"yes"; then
 515         AC_MSG_RESULT(yes)
 516         AC_SEARCH_LIBS(XXH64_createState, xxhash,
 517             [AC_DEFINE(SUPPORT_XXHASH)],
 518             [err_msg="$err_msg$nl- Failed to find XXH64_createState function in xxhash lib.";
 519              no_lib="$no_lib xxhash"])
 520     else
 521         AC_MSG_RESULT(no)
 522         err_msg="$err_msg$nl- Failed to find xxhash.h for xxhash checksum support.";
 523         no_lib="$no_lib xxhash"
 524     fi
 525 else
 526     AC_MSG_RESULT(no)
 527 fi
 528
 529 AC_MSG_CHECKING([whether to enable zstd compression])
 530 AC_ARG_ENABLE([zstd],
 531         AS_HELP_STRING([--disable-zstd], [disable to omit zstd compression]))
 532 AH_TEMPLATE([SUPPORT_ZSTD],
 533 [Undefine if you do not want zstd compression.  By default this is defined.])
 534 if test x"$enable_zstd" != x"no"; then
 535     if test x"$ac_cv_header_zstd_h" = x"yes"; then
 536         AC_MSG_RESULT(yes)
 537         AC_SEARCH_LIBS(ZSTD_minCLevel, zstd,
 538             [AC_DEFINE(SUPPORT_ZSTD)],
 539             [err_msg="$err_msg$nl- Failed to find ZSTD_minCLevel function in zstd lib.";
 540              no_lib="$no_lib zstd"])
 541     else
 542         AC_MSG_RESULT(no)
 543         err_msg="$err_msg$nl- Failed to find zstd.h for zstd compression support.";
 544         no_lib="$no_lib zstd"
 545     fi
 546 else
 547     AC_MSG_RESULT(no)
 548 fi
 549
 550 AC_MSG_CHECKING([whether to enable LZ4 compression])
 551 AC_ARG_ENABLE([lz4],
 552         AS_HELP_STRING([--disable-lz4], [disable to omit LZ4 compression]))
 553 AH_TEMPLATE([SUPPORT_LZ4],
 554 [Undefine if you do not want LZ4 compression.  By default this is defined.])
 555 if test x"$enable_lz4" != x"no"; then
 556     if test x"$ac_cv_header_lz4_h" = x"yes"; then
 557         AC_MSG_RESULT(yes)
 558         AC_SEARCH_LIBS(LZ4_compress_default, lz4,
 559             [AC_DEFINE(SUPPORT_LZ4)],
 560             [err_msg="$err_msg$nl- Failed to find LZ4_compress_default function in lz4 lib.";
 561              no_lib="$no_lib lz4"])
 562     else
 563         AC_MSG_RESULT(no)
 564         err_msg="$err_msg$nl- Failed to find lz4.h for lz4 compression support."
 565         no_lib="$no_lib lz4"
 566     fi
 567 else
 568     AC_MSG_RESULT(no)
 569 fi
 570
 571 if test x"$no_lib" != x; then
 572     echo ""
 573     echo "Configure found the following issues:"
 574     echo "$err_msg"
 575     echo ""
 576     echo "See the INSTALL file for hints on how to install the missing libraries and/or"
 577     echo "how to generate (or fetch) manpages:"
 578     echo "    https://github.com/WayneD/rsync/blob/master/INSTALL.md"
 579     echo ""
 580     echo "To disable one or more features, the relevant configure options are:"
 581     for lib in $no_lib; do
 582         echo "    --disable-$lib"
 583     done
 584     echo ""
 585     AC_MSG_ERROR(Aborting configure run)
 586 fi
 587
 588 AC_CACHE_CHECK([if makedev takes 3 args],rsync_cv_MAKEDEV_TAKES_3_ARGS,[
 589 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 590 #ifdef HAVE_SYS_TYPES_H
 591 #include <sys/types.h>
 592 #endif
 593 #ifdef MAJOR_IN_MKDEV
 594 #include <sys/mkdev.h>
 595 # if !defined makedev && (defined mkdev || defined _WIN32 || defined __WIN32__)
 596 #  define makedev mkdev
 597 # endif
 598 #elif defined MAJOR_IN_SYSMACROS
 599 #include <sys/sysmacros.h>
 600 #endif
 601
 602 int main(void)
 603 {
 604         dev_t dev = makedev(0, 5, 7);
 605         if (major(dev) != 5 || minor(dev) != 7)
 606                 return 1;
 607         return 0;
 608 }
 609 ]])],[rsync_cv_MAKEDEV_TAKES_3_ARGS=yes],[rsync_cv_MAKEDEV_TAKES_3_ARGS=no],[rsync_cv_MAKEDEV_TAKES_3_ARGS=no])])
 610 if test x"$rsync_cv_MAKEDEV_TAKES_3_ARGS" = x"yes"; then
 611    AC_DEFINE(MAKEDEV_TAKES_3_ARGS, 1, [Define to 1 if makedev() takes 3 args])
 612 fi
 613
 614 AC_CHECK_SIZEOF(int)
 615 AC_CHECK_SIZEOF(long)
 616 AC_CHECK_SIZEOF(long long)
 617 AC_CHECK_SIZEOF(short)
 618 AC_CHECK_SIZEOF(int16_t)
 619 AC_CHECK_SIZEOF(uint16_t)
 620 AC_CHECK_SIZEOF(int32_t)
 621 AC_CHECK_SIZEOF(uint32_t)
 622 AC_CHECK_SIZEOF(int64_t)
 623 AC_CHECK_SIZEOF(off_t)
 624 AC_CHECK_SIZEOF(off64_t)
 625 AC_CHECK_SIZEOF(time_t)
 626 AC_CHECK_SIZEOF(char*)
 627
 628 AC_C_INLINE
 629
 630 AC_TYPE_LONG_DOUBLE_WIDER
 631 ac_cv_c_long_double=$ac_cv_type_long_double_wider
 632 if test $ac_cv_c_long_double = yes; then
 633   AC_DEFINE([HAVE_LONG_DOUBLE],[1],[Define to 1 if the type `long double' works and has more range or precision than `double'.])
 634 fi
 635
 636 AC_TYPE_UID_T
 637 AC_CHECK_TYPES([mode_t,off_t,size_t,pid_t,id_t])
 638 if test "$cross_compiling" = no; then
 639     AC_TYPE_GETGROUPS
 640 else
 641     AC_DEFINE([GETGROUPS_T],[gid_t],[Define to the type of elements in the array set by `getgroups'. Usually this is either `int' or `gid_t'.])
 642 fi
 643 AC_CHECK_MEMBERS([struct stat.st_rdev,
 644                   struct stat.st_mtimensec,
 645                   struct stat.st_mtimespec.tv_nsec,
 646                   struct stat.st_mtim.tv_nsec],,,[
 647 #ifdef HAVE_SYS_TYPES_H
 648 #include <sys/types.h>
 649 #endif
 650 #ifdef HAVE_SYS_STAT_H
 651 #include <sys/stat.h>
 652 #endif
 653 #ifdef HAVE_UNISTD_H
 654 #include <unistd.h>
 655 #endif])
 656
 657 TYPE_SOCKLEN_T
 658
 659 AC_CACHE_CHECK([for errno in errno.h],rsync_cv_errno, [
 660     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <errno.h>]], [[int i = errno]])],[rsync_cv_errno=yes],[rsync_cv_have_errno_decl=no])])
 661 if test x"$rsync_cv_errno" = x"yes"; then
 662    AC_DEFINE(HAVE_ERRNO_DECL, 1, [Define to 1 if errno is declared in errno.h])
 663 fi
 664
 665 # The following test taken from the cvs sources
 666 # If we can't find connect, try looking in -lsocket, -lnsl, and -linet.
 667 # These need checks to be before checks for any other functions that
 668 #    might be in the same libraries.
 669 # The Irix 5 libc.so has connect and gethostbyname, but Irix 5 also has
 670 # libsocket.so which has a bad implementation of gethostbyname (it
 671 # only looks in /etc/hosts), so we only look for -lsocket if we need
 672 # it.
 673 AC_CHECK_FUNCS(connect)
 674 if test x"$ac_cv_func_connect" = x"no"; then
 675     case "$LIBS" in
 676     *-lnsl*) ;;
 677     *) AC_CHECK_LIB(nsl_s, printf) ;;
 678     esac
 679     case "$LIBS" in
 680     *-lnsl*) ;;
 681     *) AC_CHECK_LIB(nsl, printf) ;;
 682     esac
 683     case "$LIBS" in
 684     *-lsocket*) ;;
 685     *) AC_CHECK_LIB(socket, connect) ;;
 686     esac
 687     case "$LIBS" in
 688     *-linet*) ;;
 689     *) AC_CHECK_LIB(inet, connect) ;;
 690     esac
 691     dnl We can't just call AC_CHECK_FUNCS(connect) here, because the value
 692     dnl has been cached.
 693     if test x"$ac_cv_lib_socket_connect" = x"yes" ||
 694        test x"$ac_cv_lib_inet_connect" = x"yes"; then
 695         # ac_cv_func_connect=yes
 696         # don't!  it would cause AC_CHECK_FUNC to succeed next time configure is run
 697         AC_DEFINE(HAVE_CONNECT, 1, [Define to 1 if you have the "connect" function])
 698     fi
 699 fi
 700
 701 AC_SEARCH_LIBS(inet_ntop, resolv)
 702
 703 # For OS X, Solaris, HP-UX, etc.: figure out if -liconv is needed.  We'll
 704 # accept either iconv_open or libiconv_open, since some include files map
 705 # the former to the latter.
 706 AC_SEARCH_LIBS(iconv_open, iconv)
 707 AC_SEARCH_LIBS(libiconv_open, iconv)
 708
 709 AC_MSG_CHECKING([for iconv declaration])
 710 AC_CACHE_VAL(am_cv_proto_iconv, [
 711     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 712 #if HAVE_STDLIB_H
 713 #include <stdlib.h>
 714 #endif
 715 #include <iconv.h>
 716 extern
 717 #ifdef __cplusplus
 718 "C"
 719 #endif
 720 #if defined(__STDC__) || defined(__cplusplus)
 721 size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 722 #else
 723 size_t iconv();
 724 #endif
 725 ]], [[]])],[am_cv_proto_iconv_arg1=""],[am_cv_proto_iconv_arg1="const"])
 726       am_cv_proto_iconv="extern size_t iconv (iconv_t cd, $am_cv_proto_iconv_arg1 char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);"])
 727     am_cv_proto_iconv=`echo "[$]am_cv_proto_iconv" | tr -s ' ' | sed 's/( /(/'`
 728 AC_MSG_RESULT([$]{ac_t:-
 729          }[$]am_cv_proto_iconv)
 730 AC_DEFINE_UNQUOTED(ICONV_CONST, $am_cv_proto_iconv_arg1,
 731                    [Define as const if the declaration of iconv() needs const.])
 732
 733 dnl AC_MSG_NOTICE([Looking in libraries: $LIBS])
 734
 735 AC_REPLACE_FUNCS([inet_ntop inet_pton])
 736
 737 AC_HAVE_TYPE([struct addrinfo], [#include <netdb.h>])
 738 AC_HAVE_TYPE([struct sockaddr_storage], [
 739 #ifdef HAVE_SYS_TYPES_H
 740 #include <sys/types.h>
 741 #endif
 742 #ifdef HAVE_SYS_SOCKET_H
 743 #include <sys/socket.h>
 744 #endif])
 745
 746 # Irix 6.5 has getaddrinfo but not the corresponding defines, so use
 747 #   builtin getaddrinfo if one of the defines don't exist
 748 AC_CACHE_CHECK([whether defines needed by getaddrinfo exist],
 749                rsync_cv_HAVE_GETADDR_DEFINES,[
 750                         AC_EGREP_CPP(yes, [
 751 #ifdef HAVE_SYS_TYPES_H
 752 #include <sys/types.h>
 753 #endif
 754 #ifdef HAVE_SYS_SOCKET_H
 755 #include <sys/socket.h>
 756 #endif
 757 #ifdef HAVE_NETDB_H
 758 #include <netdb.h>
 759 #endif
 760 #ifdef AI_PASSIVE
 761 yes
 762 #endif],
 763                         rsync_cv_HAVE_GETADDR_DEFINES=yes,
 764                         rsync_cv_HAVE_GETADDR_DEFINES=no)])
 765 AS_IF([test x"$rsync_cv_HAVE_GETADDR_DEFINES" = x"yes" && test x"$ac_cv_type_struct_addrinfo" = x"yes"],[
 766         # Tru64 UNIX has getaddrinfo() but has it renamed in libc as
 767         # something else so we must include <netdb.h> to get the
 768         # redefinition.
 769         AC_CHECK_FUNCS(getaddrinfo, ,
 770                 [AC_MSG_CHECKING([for getaddrinfo by including <netdb.h>])
 771                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 772 #ifdef HAVE_SYS_TYPES_H
 773 #include <sys/types.h>
 774 #endif
 775 #ifdef HAVE_SYS_SOCKET_H
 776 #include <sys/socket.h>
 777 #endif
 778 #include <netdb.h>]], [[getaddrinfo(NULL, NULL, NULL, NULL);]])],[AC_MSG_RESULT([yes])
 779                         AC_DEFINE(HAVE_GETADDRINFO, 1,
 780                                 [Define to 1 if you have the "getaddrinfo" function and required types.])],[AC_MSG_RESULT([no])
 781                         AC_LIBOBJ([getaddrinfo])])])
 782     ],[AC_LIBOBJ([getaddrinfo])])
 783
 784 AC_CHECK_MEMBER([struct sockaddr.sa_len],
 785                 [ AC_DEFINE(HAVE_SOCKADDR_LEN, 1, [Do we have sockaddr.sa_len?]) ],
 786                 [],
 787                 [
 788 #ifdef HAVE_SYS_TYPES_H
 789 #include <sys/types.h>
 790 #endif
 791 #ifdef HAVE_SYS_SOCKET_H
 792 #include <sys/socket.h>
 793 #endif
 794 ])
 795
 796 AC_CHECK_MEMBER([struct sockaddr_in.sin_len],
 797                 [ AC_DEFINE(HAVE_SOCKADDR_IN_LEN, 1, [Do we have sockaddr_in.sin_len?]) ],
 798                 [],
 799                 [
 800 #ifdef HAVE_SYS_TYPES_H
 801 #include <sys/types.h>
 802 #endif
 803 #ifdef HAVE_SYS_SOCKET_H
 804 #include <sys/socket.h>
 805 #endif
 806 #include <netinet/in.h>
 807 ])
 808
 809 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
 810                 [ AC_DEFINE(HAVE_SOCKADDR_UN_LEN, 1, [Do we have sockaddr_un.sun_len?]) ],
 811                 [],
 812                 [
 813 #ifdef HAVE_SYS_TYPES_H
 814 #include <sys/types.h>
 815 #endif
 816 #ifdef HAVE_SYS_SOCKET_H
 817 #include <sys/socket.h>
 818 #endif
 819 #include <netinet/in.h>
 820 ])
 821
 822 AC_CHECK_MEMBER([struct sockaddr_in6.sin6_scope_id],
 823                 [ AC_DEFINE(HAVE_SOCKADDR_IN6_SCOPE_ID, 1, [Do we have sockaddr_in6.sin6_scope_id?]) ],
 824                 [],
 825                 [
 826 #ifdef HAVE_SYS_TYPES_H
 827 #include <sys/types.h>
 828 #endif
 829 #ifdef HAVE_SYS_SOCKET_H
 830 #include <sys/socket.h>
 831 #endif
 832 #include <netinet/in.h>
 833 ])
 834
 835 AC_HAVE_TYPE([struct stat64], [#include <stdio.h>
 836 #if HAVE_SYS_TYPES_H
 837 # include <sys/types.h>
 838 #endif
 839 #if HAVE_SYS_STAT_H
 840 # include <sys/stat.h>
 841 #endif
 842 #if STDC_HEADERS
 843 # include <stdlib.h>
 844 # include <stddef.h>
 845 #else
 846 # if HAVE_STDLIB_H
 847 #  include <stdlib.h>
 848 # endif
 849 #endif
 850 ])
 851
 852 # if we can't find strcasecmp, look in -lresolv (for Unixware at least)
 853 #
 854 AC_CHECK_FUNCS(strcasecmp)
 855 if test x"$ac_cv_func_strcasecmp" = x"no"; then
 856     AC_CHECK_LIB(resolv, strcasecmp)
 857 fi
 858
 859 AC_CHECK_FUNCS(aclsort)
 860 if test x"$ac_cv_func_aclsort" = x"no"; then
 861     AC_CHECK_LIB(sec, aclsort)
 862 fi
 863
 864 dnl At the moment we don't test for a broken memcmp(), because all we
 865 dnl need to do is test for equality, not comparison, and it seems that
 866 dnl every platform has a memcmp that can do at least that.
 867 dnl AC_FUNC_MEMCMP
 868
 869 AC_FUNC_UTIME_NULL
 870 AC_FUNC_ALLOCA
 871 AC_CHECK_FUNCS(waitpid wait4 getcwd chown chmod lchmod mknod mkfifo \
 872     fchmod fstat ftruncate strchr readlink link utime utimes lutimes strftime \
 873     chflags getattrlist mktime innetgr linkat \
 874     memmove lchown vsnprintf snprintf vasprintf asprintf setsid strpbrk \
 875     strlcat strlcpy strtol mallinfo mallinfo2 getgroups setgroups geteuid getegid \
 876     setlocale setmode open64 lseek64 mkstemp64 mtrace va_copy __va_copy \
 877     seteuid strerror putenv iconv_open locale_charset nl_langinfo getxattr \
 878     extattr_get_link sigaction sigprocmask setattrlist getgrouplist \
 879     initgroups utimensat posix_fallocate attropen setvbuf nanosleep usleep \
 880     setenv unsetenv)
 881
 882 dnl cygwin iconv.h defines iconv_open as libiconv_open
 883 if test x"$ac_cv_func_iconv_open" != x"yes"; then
 884     AC_CHECK_FUNC(libiconv_open, [ac_cv_func_iconv_open=yes; AC_DEFINE(HAVE_ICONV_OPEN, 1)])
 885 fi
 886
 887 dnl Preallocation stuff (also fallocate, posix_fallocate function tests above):
 888
 889 AC_CACHE_CHECK([for useable fallocate],rsync_cv_have_fallocate,[
 890 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <fcntl.h>
 891 #ifdef HAVE_SYS_TYPES_H
 892 #include <sys/types.h>
 893 #endif]], [[fallocate(0, 0, 0, 0);]])],[rsync_cv_have_fallocate=yes],[rsync_cv_have_fallocate=no])])
 894 if test x"$rsync_cv_have_fallocate" = x"yes"; then
 895     AC_DEFINE(HAVE_FALLOCATE, 1, [Define to 1 if you have the fallocate function and it compiles and links without error])
 896 fi
 897
 898 AC_MSG_CHECKING([for FALLOC_FL_PUNCH_HOLE])
 899 AC_PREPROC_IFELSE([AC_LANG_SOURCE([[
 900         #define _GNU_SOURCE 1
 901         #include <linux/falloc.h>
 902         #ifndef FALLOC_FL_PUNCH_HOLE
 903         #error FALLOC_FL_PUNCH_HOLE is missing
 904         #endif
 905     ]])], [
 906         AC_MSG_RESULT([yes])
 907         AC_DEFINE([HAVE_FALLOC_FL_PUNCH_HOLE], [1], [Define if FALLOC_FL_PUNCH_HOLE is available.])
 908     ], [
 909         AC_MSG_RESULT([no])
 910     ]
 911 )
 912
 913 AC_MSG_CHECKING([for FALLOC_FL_ZERO_RANGE])
 914 AC_PREPROC_IFELSE([AC_LANG_SOURCE([[
 915         #define _GNU_SOURCE 1
 916         #include <linux/falloc.h>
 917         #ifndef FALLOC_FL_ZERO_RANGE
 918         #error FALLOC_FL_ZERO_RANGE is missing
 919         #endif
 920     ]])], [
 921         AC_MSG_RESULT([yes])
 922         AC_DEFINE([HAVE_FALLOC_FL_ZERO_RANGE], [1], [Define if FALLOC_FL_ZERO_RANGE is available.])
 923     ], [
 924         AC_MSG_RESULT([no])
 925     ]
 926 )
 927
 928 AC_CACHE_CHECK([for SYS_fallocate],rsync_cv_have_sys_fallocate,[
 929 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/syscall.h>
 930 #ifdef HAVE_UNISTD_H
 931 #include <unistd.h>
 932 #endif
 933 #ifdef HAVE_SYS_TYPES_H
 934 #include <sys/types.h>
 935 #endif]], [[syscall(SYS_fallocate, 0, 0, (loff_t)0, (loff_t)0);]])],[rsync_cv_have_sys_fallocate=yes],[rsync_cv_have_sys_fallocate=no])])
 936 if test x"$rsync_cv_have_sys_fallocate" = x"yes"; then
 937     AC_DEFINE(HAVE_SYS_FALLOCATE, 1, [Define to 1 if you have the SYS_fallocate syscall number])
 938 fi
 939
 940 if test x"$ac_cv_func_posix_fallocate" = x"yes"; then
 941     AC_MSG_CHECKING([whether posix_fallocate is efficient])
 942     case $host_os in
 943     *cygwin*)
 944         AC_MSG_RESULT(yes)
 945         AC_DEFINE(HAVE_EFFICIENT_POSIX_FALLOCATE, 1,
 946                   [Define if posix_fallocate is efficient (Cygwin)])
 947         ;;
 948     *)
 949         AC_MSG_RESULT(no)
 950         ;;
 951     esac
 952 fi
 953
 954 dnl End of preallocation stuff
 955
 956 AC_CHECK_FUNCS(getpgrp tcgetpgrp)
 957 if test $ac_cv_func_getpgrp = yes; then
 958     AC_FUNC_GETPGRP
 959 fi
 960
 961 AC_ARG_ENABLE(iconv-open,
 962     AS_HELP_STRING([--disable-iconv-open],[disable to avoid all use of iconv_open()]),
 963     [], [enable_iconv_open=$ac_cv_func_iconv_open])
 964
 965 if test x"$enable_iconv_open" != x"no"; then
 966     AC_DEFINE(USE_ICONV_OPEN, 1, [Define to 1 if you want rsync to make use of iconv_open()])
 967 fi
 968
 969 AC_ARG_ENABLE(iconv,
 970     AS_HELP_STRING([--disable-iconv],[disable to omit the --iconv option]),
 971     [], [enable_iconv=$enable_iconv_open])
 972 AH_TEMPLATE([ICONV_OPTION],
 973 [Define if you want the --iconv option.  Specifying a value will set the
 974 default iconv setting (a NULL means no --iconv processing by default).])
 975 if test x"$enable_iconv" != x"no"; then
 976         if test x"$enable_iconv" = x"yes"; then
 977                 AC_DEFINE(ICONV_OPTION, NULL)
 978         else
 979                 AC_DEFINE_UNQUOTED(ICONV_OPTION, "$enable_iconv")
 980         fi
 981         AC_DEFINE(UTF8_CHARSET, "UTF-8", [String to pass to iconv() for the UTF-8 charset.])
 982 fi
 983
 984 AC_CACHE_CHECK([whether chown() modifies symlinks],rsync_cv_chown_modifies_symlink,[
 985   AC_RUN_IFELSE([AC_LANG_SOURCE([[
 986 #if HAVE_UNISTD_H
 987 # include <unistd.h>
 988 #endif
 989 #include <stdlib.h>
 990 #include <errno.h>
 991 int main(void) {
 992         char const *dangling_symlink = "conftest.dangle";
 993         unlink(dangling_symlink);
 994         if (symlink("conftest.no-such", dangling_symlink) < 0) abort();
 995         if (chown(dangling_symlink, getuid(), getgid()) < 0 && errno == ENOENT) return 1;
 996         return 0;
 997     }]])],[rsync_cv_chown_modifies_symlink=yes],[rsync_cv_chown_modifies_symlink=no],[rsync_cv_chown_modifies_symlink=no])])
 998 if test $rsync_cv_chown_modifies_symlink = yes; then
 999   AC_DEFINE(CHOWN_MODIFIES_SYMLINK, 1, [Define to 1 if chown modifies symlinks.])
1000 fi
1001
1002 AC_CACHE_CHECK([whether link() can hard-link symlinks],rsync_cv_can_hardlink_symlink,[
1003   AC_RUN_IFELSE([AC_LANG_SOURCE([[
1004 #ifdef HAVE_FCNTL_H
1005 # include <fcntl.h>
1006 #elif defined HAVE_SYS_FCNTL_H
1007 # include <sys/fcntl.h>
1008 #endif
1009 #if HAVE_UNISTD_H
1010 # include <unistd.h>
1011 #endif
1012 #include <stdlib.h>
1013 #include <errno.h>
1014 #define FILENAME "conftest.dangle"
1015 int main(void) {
1016         unlink(FILENAME);
1017         if (symlink("conftest.no-such", FILENAME) < 0) abort();
1018         unlink(FILENAME "2");
1019 #ifdef HAVE_LINKAT
1020         if (linkat(AT_FDCWD, FILENAME, AT_FDCWD, FILENAME "2", 0) < 0) return 1;
1021 #else
1022         if (link(FILENAME, FILENAME "2") < 0) return 1;
1023 #endif
1024         return 0;
1025     }]])],[rsync_cv_can_hardlink_symlink=yes],[rsync_cv_can_hardlink_symlink=no],[rsync_cv_can_hardlink_symlink=no])])
1026 if test $rsync_cv_can_hardlink_symlink = yes; then
1027   AC_DEFINE(CAN_HARDLINK_SYMLINK, 1, [Define to 1 if link() can hard-link symlinks.])
1028 fi
1029
1030 AC_CACHE_CHECK([whether link() can hard-link special files],rsync_cv_can_hardlink_special,[
1031   AC_RUN_IFELSE([AC_LANG_SOURCE([[
1032 #if HAVE_UNISTD_H
1033 # include <unistd.h>
1034 #endif
1035 #ifdef HAVE_SYS_STAT_H
1036 #include <sys/stat.h>
1037 #endif
1038 #include <stdlib.h>
1039 #include <errno.h>
1040 #define FILENAME "conftest.fifi"
1041 int main(void) {
1042         unlink(FILENAME);
1043         if (mkfifo(FILENAME, 0777) < 0) abort();
1044         unlink(FILENAME "2");
1045         if (link(FILENAME, FILENAME "2") < 0) return 1;
1046         return 0;
1047     }]])],[rsync_cv_can_hardlink_special=yes],[rsync_cv_can_hardlink_special=no],[rsync_cv_can_hardlink_special=no])])
1048 if test $rsync_cv_can_hardlink_special = yes; then
1049     AC_DEFINE(CAN_HARDLINK_SPECIAL, 1, [Define to 1 if link() can hard-link special files.])
1050 fi
1051
1052 AC_CACHE_CHECK([for working socketpair],rsync_cv_HAVE_SOCKETPAIR,[
1053 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1054 #ifdef HAVE_SYS_TYPES_H
1055 #include <sys/types.h>
1056 #endif
1057 #ifdef HAVE_SYS_SOCKET_H
1058 #include <sys/socket.h>
1059 #endif
1060
1061 int main(void) {
1062        int fd[2];
1063        return (socketpair(AF_UNIX, SOCK_STREAM, 0, fd) != -1) ? 0 : 1;
1064 }]])],[rsync_cv_HAVE_SOCKETPAIR=yes],[rsync_cv_HAVE_SOCKETPAIR=no],[rsync_cv_HAVE_SOCKETPAIR=cross])])
1065 if test x"$rsync_cv_HAVE_SOCKETPAIR" = x"yes"; then
1066     AC_DEFINE(HAVE_SOCKETPAIR, 1, [Define to 1 if you have the "socketpair" function])
1067 fi
1068
1069 AC_REPLACE_FUNCS([getpass])
1070
1071 if test x"$with_included_popt" != x"yes"; then
1072     AC_CHECK_LIB(popt, poptGetContext, , [with_included_popt=yes])
1073 fi
1074 if test x"$ac_cv_header_popt_popt_h" = x"yes"; then
1075     # If the system has /usr/include/popt/popt.h, we enable the
1076     # included popt because an attempt to "#include <popt/popt.h>"
1077     # would use our included header file anyway (due to -I.), and
1078     # might conflict with the system popt.
1079     with_included_popt=yes
1080 elif test x"$ac_cv_header_popt_h" != x"yes"; then
1081     with_included_popt=yes
1082 fi
1083
1084 AC_MSG_CHECKING([whether to use included libpopt])
1085 if test x"$with_included_popt" = x"yes"; then
1086     AC_MSG_RESULT($srcdir/popt)
1087     BUILD_POPT='$(popt_OBJS)'
1088     CFLAGS="-I$srcdir/popt $CFLAGS"
1089     if test x"$ALLOCA" != x
1090     then
1091         # this can be removed when/if we add an included alloca.c;
1092         #  see autoconf documentation on AC_FUNC_ALLOCA
1093         AC_MSG_WARN([included libpopt will use malloc, not alloca (which wastes a small amount of memory)])
1094     fi
1095 else
1096     AC_MSG_RESULT(no)
1097 fi
1098
1099 # We default to using our zlib unless --with-included-zlib=no is given.
1100 if test x"$with_included_zlib" != x"no"; then
1101     with_included_zlib=yes
1102 elif test x"$ac_cv_header_zlib_h" != x"yes"; then
1103     with_included_zlib=yes
1104 fi
1105 if test x"$with_included_zlib" != x"yes"; then
1106     AC_CHECK_LIB(z, deflateParams, , [with_included_zlib=yes])
1107 fi
1108
1109 AC_MSG_CHECKING([whether to use included zlib])
1110 if test x"$with_included_zlib" = x"yes"; then
1111     AC_MSG_RESULT($srcdir/zlib)
1112     BUILD_ZLIB='$(zlib_OBJS)'
1113     CFLAGS="-I$srcdir/zlib $CFLAGS"
1114 else
1115     AC_DEFINE(EXTERNAL_ZLIB, 1, [Define to 1 if using external zlib])
1116     AC_MSG_RESULT(no)
1117 fi
1118
1119 AC_CACHE_CHECK([for unsigned char],rsync_cv_SIGNED_CHAR_OK,[
1120 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[signed char *s = (signed char *)""]])],[rsync_cv_SIGNED_CHAR_OK=yes],[rsync_cv_SIGNED_CHAR_OK=no])])
1121 if test x"$rsync_cv_SIGNED_CHAR_OK" = x"yes"; then
1122     AC_DEFINE(SIGNED_CHAR_OK, 1, [Define to 1 if "signed char" is a valid type])
1123 fi
1124
1125 AC_CACHE_CHECK([for broken readdir],rsync_cv_HAVE_BROKEN_READDIR,[
1126 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1127 #ifdef HAVE_SYS_TYPES_H
1128 #include <sys/types.h>
1129 #endif
1130 #include <dirent.h>
1131 int main(void) { struct dirent *di; DIR *d = opendir("."); di = readdir(d);
1132 if (di && di->d_name[-2] == '.' && di->d_name[-1] == 0 &&
1133 di->d_name[0] == 0) return 0; return 1;} ]])],[rsync_cv_HAVE_BROKEN_READDIR=yes],[rsync_cv_HAVE_BROKEN_READDIR=no],[rsync_cv_HAVE_BROKEN_READDIR=cross])])
1134 if test x"$rsync_cv_HAVE_BROKEN_READDIR" = x"yes"; then
1135     AC_DEFINE(HAVE_BROKEN_READDIR, 1, [Define to 1 if readdir() is broken])
1136 fi
1137
1138 AC_CACHE_CHECK([for utimbuf],rsync_cv_HAVE_STRUCT_UTIMBUF,[
1139 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1140 #ifdef HAVE_SYS_TYPES_H
1141 #include <sys/types.h>
1142 #endif
1143 #include <utime.h>]], [[struct utimbuf tbuf;  tbuf.actime = 0; tbuf.modtime = 1; return utime("foo.c",&tbuf);]])],[rsync_cv_HAVE_STRUCT_UTIMBUF=yes],[rsync_cv_HAVE_STRUCT_UTIMBUF=no])])
1144 if test x"$rsync_cv_HAVE_STRUCT_UTIMBUF" = x"yes"; then
1145     AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if you have the "struct utimbuf" type])
1146 fi
1147
1148 AC_CACHE_CHECK([if gettimeofday takes tz argument],rsync_cv_HAVE_GETTIMEOFDAY_TZ,[
1149 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/time.h>
1150 #ifdef HAVE_UNISTD_H
1151 #include <unistd.h>
1152 #endif]], [[struct timeval tv; return gettimeofday(&tv, NULL);]])],[rsync_cv_HAVE_GETTIMEOFDAY_TZ=yes],[rsync_cv_HAVE_GETTIMEOFDAY_TZ=no])])
1153 if test x"$rsync_cv_HAVE_GETTIMEOFDAY_TZ" != x"no"; then
1154     AC_DEFINE(HAVE_GETTIMEOFDAY_TZ, 1, [Define to 1 if gettimeofday() takes a time-zone arg])
1155 fi
1156
1157 AC_CACHE_CHECK([for C99 vsnprintf],rsync_cv_HAVE_C99_VSNPRINTF,[
1158 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1159 #ifdef HAVE_SYS_TYPES_H
1160 #include <sys/types.h>
1161 #endif
1162 #include <stdarg.h>
1163 #include <stdio.h>
1164 #if HAVE_STDLIB_H
1165 #include <stdlib.h>
1166 #endif
1167 #include <string.h>
1168 void foo(const char *format, ...) {
1169        va_list ap;
1170        int len;
1171        static char buf[] = "12345678901234567890";
1172
1173        va_start(ap, format);
1174        len = vsnprintf(0, 0, format, ap);
1175        va_end(ap);
1176        if (len != 5) exit(1);
1177
1178        if (snprintf(buf, 3, "hello") != 5 || strcmp(buf, "he") != 0) exit(1);
1179 }
1180 int main(void) { foo("hello"); return 0; }
1181 ]])],[rsync_cv_HAVE_C99_VSNPRINTF=yes],[rsync_cv_HAVE_C99_VSNPRINTF=no],[rsync_cv_HAVE_C99_VSNPRINTF=cross])])
1182 if test x"$rsync_cv_HAVE_C99_VSNPRINTF" = x"yes"; then
1183     AC_DEFINE(HAVE_C99_VSNPRINTF, 1, [Define to 1 if vsprintf has a C99-compatible return value])
1184 fi
1185
1186
1187 AC_CACHE_CHECK([for secure mkstemp],rsync_cv_HAVE_SECURE_MKSTEMP,[
1188 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
1189 #ifdef HAVE_SYS_TYPES_H
1190 #include <sys/types.h>
1191 #endif
1192 #include <sys/stat.h>
1193 #ifdef HAVE_UNISTD_H
1194 #include <unistd.h>
1195 #endif
1196 int main(void) {
1197   struct stat st;
1198   char tpl[20]="/tmp/test.XXXXXX";
1199   int fd = mkstemp(tpl);
1200   if (fd == -1) return 1;
1201   unlink(tpl);
1202   if (fstat(fd, &st) != 0) return 1;
1203   if ((st.st_mode & 0777) != 0600) return 1;
1204   return 0;
1205 }]])],[rsync_cv_HAVE_SECURE_MKSTEMP=yes],[rsync_cv_HAVE_SECURE_MKSTEMP=no],[rsync_cv_HAVE_SECURE_MKSTEMP=cross])])
1206 if test x"$rsync_cv_HAVE_SECURE_MKSTEMP" = x"yes"; then
1207     case $host_os in
1208     hpux*)
1209         dnl HP-UX has a broken mkstemp() implementation they refuse to fix,
1210         dnl so we noisily skip using it.  See HP change request JAGaf34426
1211         dnl for details. (sbonds)
1212         AC_MSG_WARN(Skipping broken HP-UX mkstemp() -- using mktemp() instead)
1213         ;;
1214     *)
1215         AC_DEFINE(HAVE_SECURE_MKSTEMP, 1, [Define to 1 if mkstemp() is available and works right])
1216         ;;
1217     esac
1218 fi
1219
1220
1221 AC_CACHE_CHECK([if mknod creates FIFOs],rsync_cv_MKNOD_CREATES_FIFOS,[
1222 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1223 #include <stdio.h>
1224 #include <sys/stat.h>
1225 #include <errno.h>
1226 #if HAVE_UNISTD_H
1227 # include <unistd.h>
1228 #endif
1229 int main(void) { int rc, ec; char *fn = "fifo-test";
1230 unlink(fn); rc = mknod(fn,S_IFIFO,0600); ec = errno; unlink(fn);
1231 if (rc) {printf("(%d %d) ",rc,ec); return ec;}
1232 return 0;}]])],[rsync_cv_MKNOD_CREATES_FIFOS=yes],[rsync_cv_MKNOD_CREATES_FIFOS=no],[rsync_cv_MKNOD_CREATES_FIFOS=cross])])
1233 if test x"$rsync_cv_MKNOD_CREATES_FIFOS" = x"yes"; then
1234     AC_DEFINE(MKNOD_CREATES_FIFOS, 1, [Define to 1 if mknod() can create FIFOs.])
1235 fi
1236
1237 AC_CACHE_CHECK([if mknod creates sockets],rsync_cv_MKNOD_CREATES_SOCKETS,[
1238 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1239 #include <stdio.h>
1240 #include <sys/stat.h>
1241 #include <errno.h>
1242 #if HAVE_UNISTD_H
1243 # include <unistd.h>
1244 #endif
1245 int main(void) { int rc, ec; char *fn = "sock-test";
1246 unlink(fn); rc = mknod(fn,S_IFSOCK,0600); ec = errno; unlink(fn);
1247 if (rc) {printf("(%d %d) ",rc,ec); return ec;}
1248 return 0;}]])],[rsync_cv_MKNOD_CREATES_SOCKETS=yes],[rsync_cv_MKNOD_CREATES_SOCKETS=no],[rsync_cv_MKNOD_CREATES_SOCKETS=cross])])
1249 if test x"$rsync_cv_MKNOD_CREATES_SOCKETS" = x"yes"; then
1250     AC_DEFINE(MKNOD_CREATES_SOCKETS, 1, [Define to 1 if mknod() can create sockets.])
1251 fi
1252
1253 #
1254 # The following test was mostly taken from the tcl/tk plus patches
1255 #
1256 AC_CACHE_CHECK([whether -c -o works],rsync_cv_DASHC_WORKS_WITH_DASHO,[
1257 rm -rf conftest*
1258 cat > conftest.$ac_ext <<EOF
1259 int main(void) { return 0; }
1260 EOF
1261 ${CC-cc} -c -o conftest..o conftest.$ac_ext
1262 if test -f conftest..o; then
1263     rsync_cv_DASHC_WORKS_WITH_DASHO=yes
1264 else
1265     rsync_cv_DASHC_WORKS_WITH_DASHO=no
1266 fi
1267 rm -rf conftest*
1268 ])
1269 if test x"$rsync_cv_DASHC_WORKS_WITH_DASHO" = x"yes"; then
1270     OBJ_SAVE="#"
1271     OBJ_RESTORE="#"
1272     CC_SHOBJ_FLAG='-o $@'
1273 else
1274     OBJ_SAVE='  @b=`basename $@ .o`;rm -f $$b.o.sav;if test -f $$b.o; then mv $$b.o $$b.o.sav;fi;'
1275     OBJ_RESTORE='       @b=`basename $@ .o`;if test "$$b.o" != "$@"; then mv $$b.o $@; if test -f $$b.o.sav; then mv $$b.o.sav $$b.o; fi; fi'
1276     CC_SHOBJ_FLAG=""
1277 fi
1278
1279 AC_SUBST(OBJ_SAVE)
1280 AC_SUBST(OBJ_RESTORE)
1281 AC_SUBST(CC_SHOBJ_FLAG)
1282 AC_SUBST(BUILD_POPT)
1283 AC_SUBST(BUILD_ZLIB)
1284 AC_SUBST(MAKE_RRSYNC)
1285 AC_SUBST(MAKE_RRSYNC_1)
1286 AC_SUBST(GEN_RRSYNC)
1287 AC_SUBST(MAKE_MAN)
1288
1289 AC_CHECK_FUNCS(_acl __acl _facl __facl)
1290 #################################################
1291 # check for ACL support
1292
1293 AC_MSG_CHECKING([whether to support ACLs])
1294 AC_ARG_ENABLE(acl-support,
1295         AS_HELP_STRING([--disable-acl-support],[disable to omit ACL support]))
1296
1297 if test x"$enable_acl_support" = x"no"; then
1298     AC_MSG_RESULT(no)
1299 else
1300     case "$host_os" in
1301     *sysv5*)
1302         AC_MSG_RESULT(Using UnixWare ACLs)
1303         AC_DEFINE(HAVE_UNIXWARE_ACLS, 1, [true if you have UnixWare ACLs])
1304         AC_DEFINE(SUPPORT_ACLS, 1, [Define to 1 to add support for ACLs])
1305         ;;
1306     solaris*)
1307         AC_MSG_RESULT(Using solaris ACLs)
1308         AC_DEFINE(HAVE_SOLARIS_ACLS, 1, [true if you have solaris ACLs])
1309         AC_DEFINE(SUPPORT_ACLS, 1)
1310         ;;
1311     *irix*)
1312         AC_MSG_RESULT(Using IRIX ACLs)
1313         AC_DEFINE(HAVE_IRIX_ACLS, 1, [true if you have IRIX ACLs])
1314         AC_DEFINE(SUPPORT_ACLS, 1)
1315         ;;
1316     *aix*)
1317         AC_MSG_RESULT(Using AIX ACLs)
1318         AC_DEFINE(HAVE_AIX_ACLS, 1, [true if you have AIX ACLs])
1319         AC_DEFINE(SUPPORT_ACLS, 1)
1320         ;;
1321     *osf*)
1322         AC_MSG_RESULT(Using Tru64 ACLs)
1323         AC_DEFINE(HAVE_TRU64_ACLS, 1, [true if you have Tru64 ACLs])
1324         AC_DEFINE(SUPPORT_ACLS, 1)
1325         LIBS="$LIBS -lpacl"
1326         ;;
1327     darwin*)
1328         AC_MSG_RESULT(Using OS X ACLs)
1329         AC_DEFINE(HAVE_OSX_ACLS, 1, [true if you have Mac OS X ACLs])
1330         AC_DEFINE(SUPPORT_ACLS, 1)
1331         ;;
1332     *hpux*|*nsk*)
1333         AC_MSG_RESULT(Using HPUX ACLs)
1334         AC_DEFINE(HAVE_HPUX_ACLS, 1, [true if you have HPUX ACLs])
1335         AC_DEFINE(SUPPORT_ACLS, 1)
1336         ;;
1337     *)
1338         AC_MSG_RESULT(running tests:)
1339         AC_CHECK_LIB(acl,acl_get_file)
1340         AC_CACHE_CHECK([for ACL support],samba_cv_HAVE_POSIX_ACLS,[
1341             AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1342 #ifdef HAVE_SYS_TYPES_H
1343 #include <sys/types.h>
1344 #endif
1345 #ifdef HAVE_SYS_ACL_H
1346 #include <sys/acl.h>
1347 #endif]], [[ acl_t acl; int entry_id; acl_entry_t *entry_p; return acl_get_entry( acl, entry_id, entry_p);]])],[samba_cv_HAVE_POSIX_ACLS=yes],[samba_cv_HAVE_POSIX_ACLS=no])])
1348         AC_MSG_CHECKING(ACL test results)
1349         if test x"$samba_cv_HAVE_POSIX_ACLS" = x"yes"; then
1350             AC_MSG_RESULT(Using posix ACLs)
1351             AC_DEFINE(HAVE_POSIX_ACLS, 1, [true if you have posix ACLs])
1352             AC_DEFINE(SUPPORT_ACLS, 1)
1353             AC_CACHE_CHECK([for acl_get_perm_np],samba_cv_HAVE_ACL_GET_PERM_NP,[
1354                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1355 #ifdef HAVE_SYS_TYPES_H
1356 #include <sys/types.h>
1357 #endif
1358 #ifdef HAVE_SYS_ACL_H
1359 #include <sys/acl.h>
1360 #endif]], [[ acl_permset_t permset_d; acl_perm_t perm; return acl_get_perm_np( permset_d, perm);]])],[samba_cv_HAVE_ACL_GET_PERM_NP=yes],[samba_cv_HAVE_ACL_GET_PERM_NP=no])])
1361             if test x"$samba_cv_HAVE_ACL_GET_PERM_NP" = x"yes"; then
1362                 AC_DEFINE(HAVE_ACL_GET_PERM_NP, 1, [true if you have acl_get_perm_np])
1363             fi
1364         else
1365             if test x"$enable_acl_support" = x"yes"; then
1366                 AC_MSG_ERROR(Failed to find ACL support)
1367             else
1368                 AC_MSG_RESULT(No ACL support found)
1369             fi
1370         fi
1371         ;;
1372     esac
1373 fi
1374
1375 #################################################
1376 # check for extended attribute support
1377 AC_MSG_CHECKING(whether to support extended attributes)
1378 AC_ARG_ENABLE(xattr-support,
1379     AS_HELP_STRING([--disable-xattr-support],[disable to omit extended attributes]),
1380     [], [case "$ac_cv_func_getxattr$ac_cv_func_extattr_get_link$ac_cv_func_attropen" in
1381         *yes*) enable_xattr_support=maybe ;;
1382         *) enable_xattr_support=no ;;
1383         esac])
1384 AH_TEMPLATE([SUPPORT_XATTRS],
1385 [Define to 1 to add support for extended attributes])
1386 if test x"$enable_xattr_support" = x"no"; then
1387     AC_MSG_RESULT(no)
1388 else
1389     case "$host_os" in
1390     *linux*|*netbsd*|*cygwin*)
1391         AC_MSG_RESULT(Using Linux xattrs)
1392         AC_DEFINE(HAVE_LINUX_XATTRS, 1, [True if you have Linux xattrs (or equivalent)])
1393         AC_DEFINE(SUPPORT_XATTRS, 1)
1394         AC_DEFINE(NO_SYMLINK_USER_XATTRS, 1, [True if symlinks do not support user xattrs])
1395         AC_CHECK_LIB(attr,getxattr)
1396         ;;
1397     darwin*)
1398         AC_MSG_RESULT(Using OS X xattrs)
1399         AC_DEFINE(HAVE_OSX_XATTRS, 1, [True if you have Mac OS X xattrs])
1400         AC_DEFINE(SUPPORT_XATTRS, 1)
1401         AC_DEFINE(NO_DEVICE_XATTRS, 1, [True if device files do not support xattrs])
1402         AC_DEFINE(NO_SPECIAL_XATTRS, 1, [True if special files do not support xattrs])
1403         ;;
1404     freebsd*)
1405         AC_MSG_RESULT(Using FreeBSD extattrs)
1406         AC_DEFINE(HAVE_FREEBSD_XATTRS, 1, [True if you have FreeBSD xattrs])
1407         AC_DEFINE(SUPPORT_XATTRS, 1)
1408         ;;
1409     solaris*)
1410         AC_MSG_RESULT(Using Solaris xattrs)
1411         AC_DEFINE(HAVE_SOLARIS_XATTRS, 1, [True if you have Solaris xattrs])
1412         AC_DEFINE(SUPPORT_XATTRS, 1)
1413         AC_DEFINE(NO_SYMLINK_XATTRS, 1, [True if symlinks do not support xattrs])
1414         ;;
1415     *)
1416         if test x"$enable_xattr_support" = x"yes"; then
1417             AC_MSG_ERROR(Failed to find extended attribute support)
1418         else
1419             AC_MSG_RESULT(No extended attribute support found)
1420         fi
1421         ;;
1422     esac
1423 fi
1424
1425 if test x"$enable_acl_support" = x"no" || test x"$enable_xattr_support" = x"no" || test x"$enable_iconv" = x"no"; then
1426     AC_MSG_CHECKING([whether $CC supports -Wno-unused-parameter])
1427     OLD_CFLAGS="$CFLAGS"
1428     CFLAGS="$CFLAGS -Wno-unused-parameter"
1429     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdio.h>]], [[printf("hello\n");]])],[rsync_warn_flag=yes],[rsync_warn_flag=no])
1430     AC_MSG_RESULT([$rsync_warn_flag])
1431     if test x"$rsync_warn_flag" = x"no"; then
1432         CFLAGS="$OLD_CFLAGS"
1433     fi
1434 fi
1435
1436 case "$CC" in
1437 ' checker'*|checker*)
1438     AC_DEFINE(FORCE_FD_ZERO_MEMSET, 1, [Used to make "checker" understand that FD_ZERO() clears memory.])
1439     ;;
1440 esac
1441
1442 AC_CONFIG_FILES([Makefile lib/dummy zlib/dummy popt/dummy shconfig])
1443 AC_OUTPUT
1444
1445 AC_MSG_RESULT()
1446 AC_MSG_RESULT([    rsync $PACKAGE_VERSION configuration successful])
1447 AC_MSG_RESULT()