configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_INIT()
   4 AC_CONFIG_SRCDIR([byteorder.h])
   5 AC_CONFIG_HEADER(config.h)
   6 AC_PREREQ(2.59)
   7
   8 RSYNC_VERSION=3.0.0pre5
   9 AC_SUBST(RSYNC_VERSION)
  10 AC_MSG_NOTICE([Configuring rsync $RSYNC_VERSION])
  11
  12 AC_DEFINE_UNQUOTED(RSYNC_VERSION, ["$RSYNC_VERSION"], [rsync release version])
  13
  14 LDFLAGS=${LDFLAGS-""}
  15
  16 AC_CANONICAL_TARGET([])
  17
  18 dnl Checks for programs.
  19 AC_PROG_CC
  20 AC_PROG_CPP
  21 AC_PROG_EGREP
  22 AC_PROG_INSTALL
  23 AC_PROG_CC_STDC
  24 AC_SUBST(SHELL)
  25
  26 AC_DEFINE([_GNU_SOURCE], 1,
  27           [Define _GNU_SOURCE so that we get all necessary prototypes])
  28
  29 if test x"$ac_cv_prog_cc_stdc" = x"no"; then
  30         AC_MSG_WARN([rsync requires an ANSI C compiler and you don't seem to have one])
  31 fi
  32
  33 # We must decide this before testing the compiler.
  34
  35 # Please allow this to default to yes, so that your users have more
  36 # chance of getting a useful stack trace if problems occur.
  37
  38 AC_MSG_CHECKING([whether to include debugging symbols])
  39 AC_ARG_ENABLE(debug,
  40         AC_HELP_STRING([--disable-debug],
  41                 [disable debugging symbols and features]))
  42
  43 if test x"$enable_debug" = x"no"; then
  44     AC_MSG_RESULT(no)
  45     CFLAGS=${CFLAGS-"-O"}
  46 else
  47     AC_MSG_RESULT([yes])
  48     # leave CFLAGS alone; AC_PROG_CC will try to include -g if it can
  49     dnl AC_DEFINE(DEBUG, 1, [Define to turn on debugging code that may slow normal operation])
  50     dnl CFLAGS=${CFLAGS-"-g"}
  51 fi
  52
  53
  54 AC_ARG_ENABLE(profile,
  55         AC_HELP_STRING([--enable-profile],
  56                 [turn on CPU profiling]))
  57 if test x"$enable_profile" = x"yes"; then
  58         CFLAGS="$CFLAGS -pg"
  59 fi
  60
  61
  62 # Specifically, this turns on panic_action handling.
  63 AC_ARG_ENABLE(maintainer-mode,
  64         AC_HELP_STRING([--enable-maintainer-mode],
  65                 [turn on extra debug features]))
  66 if test x"$enable_maintainer_mode" = x"yes"; then
  67         CFLAGS="$CFLAGS -DMAINTAINER_MODE"
  68 fi
  69
  70
  71 # This is needed for our included version of popt.  Kind of silly, but
  72 # I don't want our version too far out of sync.
  73 CFLAGS="$CFLAGS -DHAVE_CONFIG_H"
  74
  75 # If GCC, turn on warnings.
  76 if test x"$GCC" = x"yes"; then
  77         CFLAGS="$CFLAGS -Wall -W"
  78 fi
  79
  80 AC_ARG_WITH(included-popt,
  81         AC_HELP_STRING([--with-included-popt], [use bundled popt library, not from system]))
  82
  83 AC_ARG_WITH(rsync-path,
  84         AC_HELP_STRING([--with-rsync-path=PATH], [set default --rsync-path to PATH (default: rsync)]),
  85         [ RSYNC_PATH="$with_rsync_path" ],
  86         [ RSYNC_PATH="rsync" ])
  87
  88 AC_DEFINE_UNQUOTED(RSYNC_PATH, "$RSYNC_PATH", [location of rsync on remote machine])
  89
  90 AC_ARG_WITH(rsyncd-conf,
  91         AC_HELP_STRING([--with-rsyncd-conf=PATH], [set configuration file for rsync server to PATH (default: /etc/rsyncd.conf)]),
  92         [ if test ! -z "$with_rsyncd_conf" ; then
  93                 case $with_rsyncd_conf in
  94                         yes|no)
  95                                 RSYNCD_SYSCONF="/etc/rsyncd.conf"
  96                                 ;;
  97                         /*)
  98                                 RSYNCD_SYSCONF="$with_rsyncd_conf"
  99                                 ;;
 100                         *)
 101                                 AC_MSG_ERROR(You must specify an absolute path to --with-rsyncd-conf=PATH)
 102                                 ;;
 103                 esac
 104         else
 105                 RSYNCD_SYSCONF="/etc/rsyncd.conf"
 106         fi ],
 107         [ RSYNCD_SYSCONF="/etc/rsyncd.conf" ])
 108
 109 AC_DEFINE_UNQUOTED(RSYNCD_SYSCONF, "$RSYNCD_SYSCONF", [location of configuration file for rsync server])
 110
 111 AC_ARG_WITH(rsh,
 112         AC_HELP_STRING([--with-rsh=CMD], [set remote shell command to CMD (default: ssh)]))
 113
 114 AC_CHECK_PROG(HAVE_REMSH, remsh, 1, 0)
 115 if test x$HAVE_REMSH = x1; then
 116         AC_DEFINE(HAVE_REMSH, 1, [Define to 1 if remote shell is remsh, not rsh])
 117 fi
 118
 119 if test x"$with_rsh" != x; then
 120         RSYNC_RSH="$with_rsh"
 121 else
 122         RSYNC_RSH="ssh"
 123 fi
 124 AC_DEFINE_UNQUOTED(RSYNC_RSH, "$RSYNC_RSH", [default -e command])
 125
 126 AC_ARG_WITH(nobody-group,
 127     AC_HELP_STRING([--with-nobody-group=GROUP],
 128                    [set the default unprivileged group (default nobody or nogroup)]),
 129     [ NOBODY_GROUP="$with_nobody_group" ])
 130
 131 if test x"$with_nobody_group" = x; then
 132     AC_MSG_CHECKING([the group for user "nobody"])
 133     if grep '^nobody:' /etc/group >/dev/null 2>&1; then
 134         NOBODY_GROUP=nobody
 135     elif grep '^nogroup:' /etc/group >/dev/null 2>&1; then
 136         NOBODY_GROUP=nogroup
 137     else
 138         NOBODY_GROUP=nobody # test for others?
 139     fi
 140     AC_MSG_RESULT($NOBODY_GROUP)
 141 fi
 142
 143 AC_DEFINE_UNQUOTED(NOBODY_USER, "nobody", [unprivileged user--e.g. nobody])
 144 AC_DEFINE_UNQUOTED(NOBODY_GROUP, "$NOBODY_GROUP", [unprivileged group for unprivileged user])
 145
 146 # arrgh. libc in some old debian version screwed up the largefile
 147 # stuff, getting byte range locking wrong
 148 AC_CACHE_CHECK([for broken largefile support],rsync_cv_HAVE_BROKEN_LARGEFILE,[
 149 AC_TRY_RUN([
 150 #define _FILE_OFFSET_BITS 64
 151 #include <stdio.h>
 152 #include <fcntl.h>
 153 #include <sys/types.h>
 154 #include <sys/wait.h>
 155
 156 int main(void)
 157 {
 158         struct flock lock;
 159         int status;
 160         char tpl[32] = "/tmp/locktest.XXXXXX";
 161         int fd = mkstemp(tpl);
 162         if (fd < 0) {
 163                 strcpy(tpl, "conftest.dat");
 164                 fd = open(tpl, O_CREAT|O_RDWR, 0600);
 165         }
 166
 167         lock.l_type = F_WRLCK;
 168         lock.l_whence = SEEK_SET;
 169         lock.l_start = 0;
 170         lock.l_len = 1;
 171         lock.l_pid = 0;
 172         fcntl(fd,F_SETLK,&lock);
 173         if (fork() == 0) {
 174                 lock.l_start = 1;
 175                 _exit(fcntl(fd,F_SETLK,&lock) == 0);
 176         }
 177         wait(&status);
 178         unlink(tpl);
 179         exit(WEXITSTATUS(status));
 180 }
 181 ],
 182 rsync_cv_HAVE_BROKEN_LARGEFILE=yes,rsync_cv_HAVE_BROKEN_LARGEFILE=no,rsync_cv_HAVE_BROKEN_LARGEFILE=cross)])
 183 if test x"$rsync_cv_HAVE_BROKEN_LARGEFILE" != x"yes"; then
 184    AC_SYS_LARGEFILE
 185 fi
 186
 187 ipv6type=unknown
 188 ipv6lib=none
 189 ipv6trylibc=yes
 190
 191 AC_ARG_ENABLE(ipv6,
 192         AC_HELP_STRING([--disable-ipv6],
 193                 [don't even try to use IPv6]))
 194 if test x"$enable_ipv6" != x"no"; then
 195         AC_MSG_CHECKING([ipv6 stack type])
 196         for i in inria kame linux-glibc linux-inet6 toshiba v6d zeta; do
 197                 case $i in
 198                 inria)
 199                         # http://www.kame.net/
 200                         AC_EGREP_CPP(yes, [
 201 #include <netinet/in.h>
 202 #ifdef IPV6_INRIA_VERSION
 203 yes
 204 #endif],
 205                                 [ipv6type=$i;
 206                                 AC_DEFINE(INET6, 1, [true if you have IPv6])
 207                                 ])
 208                         ;;
 209                 kame)
 210                         # http://www.kame.net/
 211                         AC_EGREP_CPP(yes, [
 212 #include <netinet/in.h>
 213 #ifdef __KAME__
 214 yes
 215 #endif],
 216                                 [ipv6type=$i;
 217                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 218                         ;;
 219                 linux-glibc)
 220                         # http://www.v6.linux.or.jp/
 221                         AC_EGREP_CPP(yes, [
 222 #include <features.h>
 223 #if defined(__GLIBC__) && __GLIBC__ >= 2 && __GLIBC_MINOR__ >= 1
 224 yes
 225 #endif],
 226                                 [ipv6type=$i;
 227 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 228                         ;;
 229                 linux-inet6)
 230                         # http://www.v6.linux.or.jp/
 231                         if test -d /usr/inet6 -o -f /usr/inet6/lib/libinet6.a; then
 232                                 ipv6type=$i
 233                                 ipv6lib=inet6
 234                                 ipv6libdir=/usr/inet6/lib
 235                                 ipv6trylibc=yes;
 236                                 AC_DEFINE(INET6, 1, [true if you have IPv6])
 237                                 CFLAGS="-I/usr/inet6/include $CFLAGS"
 238                         fi
 239                         ;;
 240                 toshiba)
 241                         AC_EGREP_CPP(yes, [
 242 #include <sys/param.h>
 243 #ifdef _TOSHIBA_INET6
 244 yes
 245 #endif],
 246                                 [ipv6type=$i;
 247                                 ipv6lib=inet6;
 248                                 ipv6libdir=/usr/local/v6/lib;
 249                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 250                         ;;
 251                 v6d)
 252                         AC_EGREP_CPP(yes, [
 253 #include </usr/local/v6/include/sys/v6config.h>
 254 #ifdef __V6D__
 255 yes
 256 #endif],
 257                                 [ipv6type=$i;
 258                                 ipv6lib=v6;
 259                                 ipv6libdir=/usr/local/v6/lib;
 260                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 261                         ;;
 262                 zeta)
 263                         AC_EGREP_CPP(yes, [
 264 #include <sys/param.h>
 265 #ifdef _ZETA_MINAMI_INET6
 266 yes
 267 #endif],
 268                                 [ipv6type=$i;
 269                                 ipv6lib=inet6;
 270                                 ipv6libdir=/usr/local/v6/lib;
 271                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 272                         ;;
 273                 esac
 274                 if test "$ipv6type" != "unknown"; then
 275                         break
 276                 fi
 277         done
 278         AC_MSG_RESULT($ipv6type)
 279
 280         AC_SEARCH_LIBS(getaddrinfo, inet6)
 281 fi
 282
 283 dnl Do you want to disable use of locale functions
 284 AC_ARG_ENABLE([locale],
 285         AC_HELP_STRING([--disable-locale],
 286                 [disable locale features]))
 287 AH_TEMPLATE([CONFIG_LOCALE],
 288 [Undefine if you don't want locale features.  By default this is defined.])
 289 if test x"$enable_locale" != x"no"; then
 290         AC_DEFINE(CONFIG_LOCALE)
 291 fi
 292
 293 AC_MSG_CHECKING([whether to call shutdown on all sockets])
 294 case $host_os in
 295         *cygwin* ) AC_MSG_RESULT(yes)
 296                    AC_DEFINE(SHUTDOWN_ALL_SOCKETS, 1,
 297                             [Define to 1 if sockets need to be shutdown])
 298                    ;;
 299                * ) AC_MSG_RESULT(no);;
 300 esac
 301
 302 AC_C_BIGENDIAN
 303 AC_HEADER_DIRENT
 304 AC_HEADER_TIME
 305 AC_HEADER_SYS_WAIT
 306 AC_CHECK_HEADERS(sys/fcntl.h sys/select.h fcntl.h sys/time.h sys/unistd.h \
 307     unistd.h utime.h grp.h compat.h sys/param.h ctype.h sys/wait.h \
 308     sys/ioctl.h sys/filio.h string.h stdlib.h sys/socket.h sys/mode.h \
 309     sys/un.h sys/attr.h glob.h mcheck.h arpa/inet.h arpa/nameser.h locale.h \
 310     netdb.h malloc.h float.h limits.h iconv.h libcharset.h langinfo.h)
 311 AC_HEADER_MAJOR
 312
 313 AC_CACHE_CHECK([if makedev takes 3 args],rsync_cv_MAKEDEV_TAKES_3_ARGS,[
 314 AC_TRY_RUN([
 315 #include <sys/types.h>
 316 #ifdef MAJOR_IN_MKDEV
 317 #include <sys/mkdev.h>
 318 # if !defined makedev && (defined mkdev || defined _WIN32 || defined __WIN32__)
 319 #  define makedev mkdev
 320 # endif
 321 #elif defined MAJOR_IN_SYSMACROS
 322 #include <sys/sysmacros.h>
 323 #endif
 324
 325 int main(void)
 326 {
 327         dev_t dev = makedev(0, 5, 7);
 328         if (major(dev) != 5 || minor(dev) != 7)
 329                 exit(1);
 330         return 0;
 331 }
 332 ],
 333 rsync_cv_MAKEDEV_TAKES_3_ARGS=yes,rsync_cv_MAKEDEV_TAKES_3_ARGS=no,rsync_cv_MAKEDEV_TAKES_3_ARGS=no)])
 334 if test x"$rsync_cv_MAKEDEV_TAKES_3_ARGS" = x"yes"; then
 335    AC_DEFINE(MAKEDEV_TAKES_3_ARGS, 1, [Define to 1 if makedev() takes 3 args])
 336 fi
 337
 338 AC_CHECK_SIZEOF(int)
 339 AC_CHECK_SIZEOF(long)
 340 AC_CHECK_SIZEOF(long long)
 341 AC_CHECK_SIZEOF(short)
 342 AC_CHECK_SIZEOF(int16_t)
 343 AC_CHECK_SIZEOF(uint16_t)
 344 AC_CHECK_SIZEOF(int32_t)
 345 AC_CHECK_SIZEOF(uint32_t)
 346 AC_CHECK_SIZEOF(int64_t)
 347 AC_CHECK_SIZEOF(off_t)
 348 AC_CHECK_SIZEOF(off64_t)
 349 AC_CHECK_SIZEOF(time_t)
 350
 351 AC_C_INLINE
 352 AC_C_LONG_DOUBLE
 353
 354 AC_TYPE_SIGNAL
 355 AC_TYPE_UID_T
 356 AC_CHECK_TYPES([mode_t,off_t,size_t,pid_t,id_t])
 357 AC_TYPE_GETGROUPS
 358 AC_CHECK_MEMBERS([struct stat.st_rdev])
 359
 360 TYPE_SOCKLEN_T
 361
 362 AC_CACHE_CHECK([for errno in errno.h],rsync_cv_errno, [
 363     AC_TRY_COMPILE([#include <errno.h>],[int i = errno],
 364         rsync_cv_errno=yes,rsync_cv_have_errno_decl=no)])
 365 if test x"$rsync_cv_errno" = x"yes"; then
 366    AC_DEFINE(HAVE_ERRNO_DECL, 1, [Define to 1 if errno is declared in errno.h])
 367 fi
 368
 369 # The following test taken from the cvs sources
 370 # If we can't find connect, try looking in -lsocket, -lnsl, and -linet.
 371 # These need checks to be before checks for any other functions that
 372 #    might be in the same libraries.
 373 # The Irix 5 libc.so has connect and gethostbyname, but Irix 5 also has
 374 # libsocket.so which has a bad implementation of gethostbyname (it
 375 # only looks in /etc/hosts), so we only look for -lsocket if we need
 376 # it.
 377 AC_CHECK_FUNCS(connect)
 378 if test x"$ac_cv_func_connect" = x"no"; then
 379     case "$LIBS" in
 380     *-lnsl*) ;;
 381     *) AC_CHECK_LIB(nsl_s, printf) ;;
 382     esac
 383     case "$LIBS" in
 384     *-lnsl*) ;;
 385     *) AC_CHECK_LIB(nsl, printf) ;;
 386     esac
 387     case "$LIBS" in
 388     *-lsocket*) ;;
 389     *) AC_CHECK_LIB(socket, connect) ;;
 390     esac
 391     case "$LIBS" in
 392     *-linet*) ;;
 393     *) AC_CHECK_LIB(inet, connect) ;;
 394     esac
 395     dnl We can't just call AC_CHECK_FUNCS(connect) here, because the value
 396     dnl has been cached.
 397     if test x"$ac_cv_lib_socket_connect" = x"yes" ||
 398        test x"$ac_cv_lib_inet_connect" = x"yes"; then
 399         # ac_cv_func_connect=yes
 400         # don't!  it would cause AC_CHECK_FUNC to succeed next time configure is run
 401         AC_DEFINE(HAVE_CONNECT, 1, [Define to 1 if you have the "connect" function])
 402     fi
 403 fi
 404
 405 AC_SEARCH_LIBS(inet_ntop, resolv)
 406
 407 # Solaris and HP-UX weirdness:
 408 # Search for libiconv_open (not iconv_open) to discover if -liconv is needed!
 409 AC_SEARCH_LIBS(libiconv_open, iconv)
 410
 411 AC_MSG_CHECKING([for iconv declaration])
 412 AC_CACHE_VAL(am_cv_proto_iconv, [
 413     AC_TRY_COMPILE([
 414 #include <stdlib.h>
 415 #include <iconv.h>
 416 extern
 417 #ifdef __cplusplus
 418 "C"
 419 #endif
 420 #if defined(__STDC__) || defined(__cplusplus)
 421 size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 422 #else
 423 size_t iconv();
 424 #endif
 425 ], [], am_cv_proto_iconv_arg1="", am_cv_proto_iconv_arg1="const")
 426       am_cv_proto_iconv="extern size_t iconv (iconv_t cd, $am_cv_proto_iconv_arg1 char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);"])
 427     am_cv_proto_iconv=`echo "[$]am_cv_proto_iconv" | tr -s ' ' | sed -e 's/( /(/'`
 428 AC_MSG_RESULT([$]{ac_t:-
 429          }[$]am_cv_proto_iconv)
 430 AC_DEFINE_UNQUOTED(ICONV_CONST, $am_cv_proto_iconv_arg1,
 431                    [Define as const if the declaration of iconv() needs const.])
 432
 433 dnl AC_MSG_NOTICE([Looking in libraries: $LIBS])
 434
 435 AC_CHECK_FUNCS(inet_ntop, , [AC_LIBOBJ(lib/inet_ntop)])
 436 AC_CHECK_FUNCS(inet_pton, , [AC_LIBOBJ(lib/inet_pton)])
 437
 438 AC_HAVE_TYPE([struct addrinfo], [#include <netdb.h>])
 439 AC_HAVE_TYPE([struct sockaddr_storage], [#include <sys/types.h>
 440 #include <sys/socket.h>])
 441
 442 # Irix 6.5 has getaddrinfo but not the corresponding defines, so use
 443 #   builtin getaddrinfo if one of the defines don't exist
 444 AC_CACHE_CHECK([whether defines needed by getaddrinfo exist],
 445                rsync_cv_HAVE_GETADDR_DEFINES,[
 446                         AC_EGREP_CPP(yes, [
 447                         #include <sys/types.h>
 448                         #include <sys/socket.h>
 449                         #include <netdb.h>
 450                         #ifdef AI_PASSIVE
 451                         yes
 452                         #endif],
 453                         rsync_cv_HAVE_GETADDR_DEFINES=yes,
 454                         rsync_cv_HAVE_GETADDR_DEFINES=no)])
 455 if test x"$rsync_cv_HAVE_GETADDR_DEFINES" = x"yes" -a x"$ac_cv_type_struct_addrinfo" = x"yes"; then
 456         # Tru64 UNIX has getaddrinfo() but has it renamed in libc as
 457         # something else so we must include <netdb.h> to get the
 458         # redefinition.
 459         AC_CHECK_FUNCS(getaddrinfo, ,
 460                 [AC_MSG_CHECKING([for getaddrinfo by including <netdb.h>])
 461                 AC_TRY_LINK([#include <sys/types.h>
 462                 #include <sys/socket.h>
 463                 #include <netdb.h>],[getaddrinfo(NULL, NULL, NULL, NULL);],
 464                         [AC_MSG_RESULT([yes])
 465                         AC_DEFINE(HAVE_GETADDRINFO, 1,
 466                                 [Define to 1 if you have the "getaddrinfo" function and required types.])],
 467                         [AC_MSG_RESULT([no])
 468                         AC_LIBOBJ(lib/getaddrinfo)])])
 469 else
 470         AC_LIBOBJ(lib/getaddrinfo)
 471 fi
 472
 473 AC_CHECK_MEMBER([struct sockaddr.sa_len],
 474                 [ AC_DEFINE(HAVE_SOCKADDR_LEN, 1, [Do we have sockaddr.sa_len?]) ],
 475                 [],
 476                 [
 477 #include <sys/types.h>
 478 #include <sys/socket.h>
 479 ])
 480
 481 AC_CHECK_MEMBER([struct sockaddr_in.sin_len],
 482                 [ AC_DEFINE(HAVE_SOCKADDR_IN_LEN, 1, [Do we have sockaddr_in.sin_len?]) ],
 483                 [],
 484                 [
 485 #include <sys/types.h>
 486 #include <sys/socket.h>
 487 #include <netinet/in.h>
 488 ])
 489
 490 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
 491                 [ AC_DEFINE(HAVE_SOCKADDR_UN_LEN, 1, [Do we have sockaddr_un.sun_len?]) ],
 492                 [],
 493                 [
 494 #include <sys/types.h>
 495 #include <sys/socket.h>
 496 #include <netinet/in.h>
 497 ])
 498
 499 AC_CHECK_MEMBER([struct sockaddr_in6.sin6_scope_id],
 500                 [ AC_DEFINE(HAVE_SOCKADDR_IN6_SCOPE_ID, 1, [Do we have sockaddr_in6.sin6_scope_id?]) ],
 501                 [],
 502                 [
 503 #include <sys/types.h>
 504 #include <sys/socket.h>
 505 #include <netinet/in.h>
 506 ])
 507
 508 AC_HAVE_TYPE([struct stat64], [#include <stdio.h>
 509 #if HAVE_SYS_TYPES_H
 510 # include <sys/types.h>
 511 #endif
 512 #if HAVE_SYS_STAT_H
 513 # include <sys/stat.h>
 514 #endif
 515 #if STDC_HEADERS
 516 # include <stdlib.h>
 517 # include <stddef.h>
 518 #else
 519 # if HAVE_STDLIB_H
 520 #  include <stdlib.h>
 521 # endif
 522 #endif
 523 ])
 524
 525 # if we can't find strcasecmp, look in -lresolv (for Unixware at least)
 526 #
 527 AC_CHECK_FUNCS(strcasecmp)
 528 if test x"$ac_cv_func_strcasecmp" = x"no"; then
 529     AC_CHECK_LIB(resolv, strcasecmp)
 530 fi
 531
 532 AC_CHECK_FUNCS(aclsort)
 533 if test x"$ac_cv_func_aclsort" = x"no"; then
 534     AC_CHECK_LIB(sec, aclsort)
 535 fi
 536
 537 dnl At the moment we don't test for a broken memcmp(), because all we
 538 dnl need to do is test for equality, not comparison, and it seems that
 539 dnl every platform has a memcmp that can do at least that.
 540 dnl AC_FUNC_MEMCMP
 541
 542 AC_FUNC_UTIME_NULL
 543 AC_FUNC_ALLOCA
 544 AC_CHECK_FUNCS(waitpid wait4 getcwd strdup chown chmod lchmod mknod mkfifo \
 545     fchmod fstat ftruncate strchr readlink link utime utimes lutimes strftime \
 546     memmove lchown vsnprintf snprintf vasprintf asprintf setsid glob strpbrk \
 547     strlcat strlcpy strtol mallinfo getgroups setgroups geteuid getegid \
 548     setlocale setmode open64 lseek64 mkstemp64 mtrace va_copy __va_copy \
 549     strerror putenv iconv_open locale_charset nl_langinfo getxattr \
 550     extattr_get_link sigaction sigprocmask setattrlist)
 551
 552 AC_CHECK_FUNCS(getpgrp tcgetpgrp)
 553 if test $ac_cv_func_getpgrp = yes; then
 554     AC_FUNC_GETPGRP
 555 fi
 556
 557 AC_ARG_ENABLE(iconv,
 558     AC_HELP_STRING([--disable-iconv],
 559             [disable rsync's --iconv option]),
 560     [], [enable_iconv=$ac_cv_func_iconv_open])
 561 AH_TEMPLATE([ICONV_OPTION],
 562 [Define if you want the --iconv option.  Specifing a value will set the
 563 default iconv setting (a NULL means no --iconv processing by default).])
 564 if test x"$enable_iconv" != x"no"; then
 565         if test x"$enable_iconv" = x"yes"; then
 566                 AC_DEFINE(ICONV_OPTION, NULL)
 567         else
 568                 AC_DEFINE_UNQUOTED(ICONV_OPTION, "$enable_iconv")
 569         fi
 570         AC_DEFINE(UTF8_CHARSET, "UTF-8", [String to pass to iconv() for the UTF-8 charset.])
 571 fi
 572
 573 AC_CACHE_CHECK([whether chown() modifies symlinks],rsync_cv_chown_modifies_symlink,[
 574   AC_TRY_RUN([
 575 #if HAVE_UNISTD_H
 576 # include <unistd.h>
 577 #endif
 578 #include <stdlib.h>
 579 #include <errno.h>
 580     main() {
 581         char const *dangling_symlink = "conftest.dangle";
 582         unlink(dangling_symlink);
 583         if (symlink("conftest.no-such", dangling_symlink) < 0) abort();
 584         if (chown(dangling_symlink, getuid(), getgid()) < 0 && errno == ENOENT) exit(1);
 585         exit(0);
 586     }],
 587   rsync_cv_chown_modifies_symlink=yes,rsync_cv_chown_modifies_symlink=no,rsync_cv_chown_modifies_symlink=no)])
 588 if test $rsync_cv_chown_modifies_symlink = yes; then
 589   AC_DEFINE(CHOWN_MODIFIES_SYMLINK, 1, [Define to 1 if chown modifies symlinks.])
 590 fi
 591
 592 AC_CACHE_CHECK([whether link() can hard-link symlinks],rsync_cv_can_hardlink_symlink,[
 593   AC_TRY_RUN([
 594 #if HAVE_UNISTD_H
 595 # include <unistd.h>
 596 #endif
 597 #include <stdlib.h>
 598 #include <errno.h>
 599 #define FILENAME "conftest.dangle"
 600     main() {
 601         unlink(FILENAME);
 602         if (symlink("conftest.no-such", FILENAME) < 0) abort();
 603         if (link(FILENAME, FILENAME "2") < 0) exit(1);
 604         exit(0);
 605     }],
 606   rsync_cv_can_hardlink_symlink=yes,rsync_cv_can_hardlink_symlink=no,rsync_cv_can_hardlink_symlink=no)])
 607 if test $rsync_cv_can_hardlink_symlink = yes; then
 608   AC_DEFINE(CAN_HARDLINK_SYMLINK, 1, [Define to 1 if link() can hard-link symlinks.])
 609 fi
 610
 611 AC_CACHE_CHECK([whether link() can hard-link special files],rsync_cv_can_hardlink_special,[
 612   AC_TRY_RUN([
 613 #if HAVE_UNISTD_H
 614 # include <unistd.h>
 615 #endif
 616 #include <stdlib.h>
 617 #include <errno.h>
 618 #define FILENAME "conftest.fifi"
 619     main() {
 620         unlink(FILENAME);
 621         if (mkfifo(FILENAME, 0777) < 0) abort();
 622         if (link(FILENAME, FILENAME "2") < 0) exit(1);
 623         exit(0);
 624     }],
 625   rsync_cv_can_hardlink_special=yes,rsync_cv_can_hardlink_special=no,rsync_cv_can_hardlink_special=no)])
 626 if test $rsync_cv_can_hardlink_special = yes; then
 627     AC_DEFINE(CAN_HARDLINK_SPECIAL, 1, [Define to 1 if link() can hard-link special files.])
 628 fi
 629
 630 AC_CACHE_CHECK([for working socketpair],rsync_cv_HAVE_SOCKETPAIR,[
 631 AC_TRY_RUN([
 632 #include <sys/types.h>
 633 #include <sys/socket.h>
 634
 635 main() {
 636        int fd[2];
 637        exit((socketpair(AF_UNIX, SOCK_STREAM, 0, fd) != -1) ? 0 : 1);
 638 }],
 639 rsync_cv_HAVE_SOCKETPAIR=yes,rsync_cv_HAVE_SOCKETPAIR=no,rsync_cv_HAVE_SOCKETPAIR=cross)])
 640 if test x"$rsync_cv_HAVE_SOCKETPAIR" = x"yes"; then
 641     AC_DEFINE(HAVE_SOCKETPAIR, 1, [Define to 1 if you have the "socketpair" function])
 642 fi
 643
 644 if test x"$with_included_popt" != x"yes"; then
 645     AC_CHECK_LIB(popt, poptGetContext, , [with_included_popt=yes])
 646 fi
 647
 648 AC_MSG_CHECKING([whether to use included libpopt])
 649 if test x"$with_included_popt" = x"yes"; then
 650     AC_MSG_RESULT($srcdir/popt)
 651     BUILD_POPT='$(popt_OBJS)'
 652     CFLAGS="$CFLAGS -I$srcdir/popt"
 653     if test x"$ALLOCA" != x
 654     then
 655         # this can be removed when/if we add an included alloca.c;
 656         #  see autoconf documentation on AC_FUNC_ALLOCA
 657         AC_MSG_WARN([included libpopt will use malloc, not alloca (which wastes a small amount of memory)])
 658     fi
 659 else
 660     AC_MSG_RESULT(no)
 661 fi
 662
 663 AC_CACHE_CHECK([for unsigned char],rsync_cv_SIGNED_CHAR_OK,[
 664 AC_TRY_COMPILE([],[signed char *s = ""],
 665 rsync_cv_SIGNED_CHAR_OK=yes,rsync_cv_SIGNED_CHAR_OK=no)])
 666 if test x"$rsync_cv_SIGNED_CHAR_OK" = x"yes"; then
 667     AC_DEFINE(SIGNED_CHAR_OK, 1, [Define to 1 if "signed char" is a valid type])
 668 fi
 669
 670 AC_CACHE_CHECK([for broken readdir],rsync_cv_HAVE_BROKEN_READDIR,[
 671 AC_TRY_RUN([#include <sys/types.h>
 672 #include <dirent.h>
 673 main() { struct dirent *di; DIR *d = opendir("."); di = readdir(d);
 674 if (di && di->d_name[-2] == '.' && di->d_name[-1] == 0 &&
 675 di->d_name[0] == 0) exit(0); exit(1);} ],
 676 rsync_cv_HAVE_BROKEN_READDIR=yes,rsync_cv_HAVE_BROKEN_READDIR=no,rsync_cv_HAVE_BROKEN_READDIR=cross)])
 677 if test x"$rsync_cv_HAVE_BROKEN_READDIR" = x"yes"; then
 678     AC_DEFINE(HAVE_BROKEN_READDIR, 1, [Define to 1 if readdir() is broken])
 679 fi
 680
 681 AC_CACHE_CHECK([for utimbuf],rsync_cv_HAVE_STRUCT_UTIMBUF,[
 682 AC_TRY_COMPILE([#include <sys/types.h>
 683 #include <utime.h>],
 684 [struct utimbuf tbuf;  tbuf.actime = 0; tbuf.modtime = 1; exit(utime("foo.c",&tbuf));],
 685 rsync_cv_HAVE_STRUCT_UTIMBUF=yes,rsync_cv_HAVE_STRUCT_UTIMBUF=no)])
 686 if test x"$rsync_cv_HAVE_STRUCT_UTIMBUF" = x"yes"; then
 687     AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if you have the "struct utimbuf" type])
 688 fi
 689
 690 AC_CACHE_CHECK([if gettimeofday takes tz argument],rsync_cv_HAVE_GETTIMEOFDAY_TZ,[
 691 AC_TRY_COMPILE([#include <sys/time.h>
 692 #include <unistd.h>],
 693 [struct timeval tv; exit(gettimeofday(&tv, NULL));],
 694 rsync_cv_HAVE_GETTIMEOFDAY_TZ=yes,rsync_cv_HAVE_GETTIMEOFDAY_TZ=no)])
 695 if test x"$rsync_cv_HAVE_GETTIMEOFDAY_TZ" != x"no"; then
 696     AC_DEFINE(HAVE_GETTIMEOFDAY_TZ, 1, [Define to 1 if gettimeofday() takes a time-zone arg])
 697 fi
 698
 699 AC_CACHE_CHECK([for C99 vsnprintf],rsync_cv_HAVE_C99_VSNPRINTF,[
 700 AC_TRY_RUN([
 701 #include <sys/types.h>
 702 #include <stdarg.h>
 703 void foo(const char *format, ...) {
 704        va_list ap;
 705        int len;
 706        char buf[5];
 707
 708        va_start(ap, format);
 709        len = vsnprintf(0, 0, format, ap);
 710        va_end(ap);
 711        if (len != 5) exit(1);
 712
 713        if (snprintf(buf, 3, "hello") != 5 || strcmp(buf, "he") != 0) exit(1);
 714
 715        exit(0);
 716 }
 717 main() { foo("hello"); }
 718 ],
 719 rsync_cv_HAVE_C99_VSNPRINTF=yes,rsync_cv_HAVE_C99_VSNPRINTF=no,rsync_cv_HAVE_C99_VSNPRINTF=cross)])
 720 if test x"$rsync_cv_HAVE_C99_VSNPRINTF" = x"yes"; then
 721     AC_DEFINE(HAVE_C99_VSNPRINTF, 1, [Define to 1 if vsprintf has a C99-compatible return value])
 722 fi
 723
 724
 725 AC_CACHE_CHECK([for secure mkstemp],rsync_cv_HAVE_SECURE_MKSTEMP,[
 726 AC_TRY_RUN([#include <stdlib.h>
 727 #include <sys/types.h>
 728 #include <sys/stat.h>
 729 #include <unistd.h>
 730 main() {
 731   struct stat st;
 732   char tpl[20]="/tmp/test.XXXXXX";
 733   int fd = mkstemp(tpl);
 734   if (fd == -1) exit(1);
 735   unlink(tpl);
 736   if (fstat(fd, &st) != 0) exit(1);
 737   if ((st.st_mode & 0777) != 0600) exit(1);
 738   exit(0);
 739 }],
 740 rsync_cv_HAVE_SECURE_MKSTEMP=yes,
 741 rsync_cv_HAVE_SECURE_MKSTEMP=no,
 742 rsync_cv_HAVE_SECURE_MKSTEMP=cross)])
 743 if test x"$rsync_cv_HAVE_SECURE_MKSTEMP" = x"yes"; then
 744     case $target_os in
 745     hpux*)
 746         dnl HP-UX has a broken mkstemp() implementation they refuse to fix,
 747         dnl so we noisily skip using it.  See HP change request JAGaf34426
 748         dnl for details. (sbonds)
 749         AC_MSG_WARN(Skipping broken HP-UX mkstemp() -- using mktemp() instead)
 750         ;;
 751     *)
 752         AC_DEFINE(HAVE_SECURE_MKSTEMP, 1, [Define to 1 if mkstemp() is available and works right])
 753         ;;
 754     esac
 755 fi
 756
 757
 758 AC_CACHE_CHECK([if mknod creates FIFOs],rsync_cv_MKNOD_CREATES_FIFOS,[
 759 AC_TRY_RUN([
 760 #include <stdio.h>
 761 #include <sys/stat.h>
 762 #include <errno.h>
 763 main() { int rc, ec; char *fn = "fifo-test";
 764 unlink(fn); rc = mknod(fn,S_IFIFO,0600); ec = errno; unlink(fn);
 765 if (rc) {printf("(%d %d) ",rc,ec); return ec;}
 766 return 0;}],
 767            rsync_cv_MKNOD_CREATES_FIFOS=yes,rsync_cv_MKNOD_CREATES_FIFOS=no,rsync_cv_MKNOD_CREATES_FIFOS=cross)])
 768 if test x"$rsync_cv_MKNOD_CREATES_FIFOS" = x"yes"; then
 769     AC_DEFINE(MKNOD_CREATES_FIFOS, 1, [Define to 1 if mknod() can create FIFOs.])
 770 fi
 771
 772 AC_CACHE_CHECK([if mknod creates sockets],rsync_cv_MKNOD_CREATES_SOCKETS,[
 773 AC_TRY_RUN([
 774 #include <stdio.h>
 775 #include <sys/stat.h>
 776 #include <errno.h>
 777 main() { int rc, ec; char *fn = "sock-test";
 778 unlink(fn); rc = mknod(fn,S_IFSOCK,0600); ec = errno; unlink(fn);
 779 if (rc) {printf("(%d %d) ",rc,ec); return ec;}
 780 return 0;}],
 781            rsync_cv_MKNOD_CREATES_SOCKETS=yes,rsync_cv_MKNOD_CREATES_SOCKETS=no,rsync_cv_MKNOD_CREATES_SOCKETS=cross)])
 782 if test x"$rsync_cv_MKNOD_CREATES_SOCKETS" = x"yes"; then
 783     AC_DEFINE(MKNOD_CREATES_SOCKETS, 1, [Define to 1 if mknod() can create sockets.])
 784 fi
 785
 786 #
 787 # The following test was mostly taken from the tcl/tk plus patches
 788 #
 789 AC_CACHE_CHECK([whether -c -o works],rsync_cv_DASHC_WORKS_WITH_DASHO,[
 790 rm -rf conftest*
 791 cat > conftest.$ac_ext <<EOF
 792 int main() { return 0; }
 793 EOF
 794 ${CC-cc} -c -o conftest..o conftest.$ac_ext
 795 if test -f conftest..o; then
 796     rsync_cv_DASHC_WORKS_WITH_DASHO=yes
 797 else
 798     rsync_cv_DASHC_WORKS_WITH_DASHO=no
 799 fi
 800 rm -rf conftest*
 801 ])
 802 if test x"$rsync_cv_DASHC_WORKS_WITH_DASHO" = x"yes"; then
 803     OBJ_SAVE="#"
 804     OBJ_RESTORE="#"
 805     CC_SHOBJ_FLAG='-o $@'
 806 else
 807     OBJ_SAVE='  @b=`basename $@ .o`;rm -f $$b.o.sav;if test -f $$b.o; then mv $$b.o $$b.o.sav;fi;'
 808     OBJ_RESTORE='       @b=`basename $@ .o`;if test "$$b.o" != "$@"; then mv $$b.o $@; if test -f $$b.o.sav; then mv $$b.o.sav $$b.o; fi; fi'
 809     CC_SHOBJ_FLAG=""
 810 fi
 811
 812 AC_SUBST(OBJ_SAVE)
 813 AC_SUBST(OBJ_RESTORE)
 814 AC_SUBST(CC_SHOBJ_FLAG)
 815 AC_SUBST(BUILD_POPT)
 816
 817 AC_CHECK_HEADERS(sys/acl.h acl/libacl.h)
 818 AC_CHECK_FUNCS(_acl __acl _facl __facl)
 819 #################################################
 820 # check for ACL support
 821
 822 AC_MSG_CHECKING([whether to support ACLs])
 823 AC_ARG_ENABLE(acl-support,
 824         AC_HELP_STRING([--disable-acl-support],
 825                        [disable ACL support]))
 826
 827 if test x"$enable_acl_support" = x"no"; then
 828     AC_MSG_RESULT(no)
 829 else
 830     case "$host_os" in
 831     *sysv5*)
 832         AC_MSG_RESULT(Using UnixWare ACLs)
 833         AC_DEFINE(HAVE_UNIXWARE_ACLS, 1, [true if you have UnixWare ACLs])
 834         AC_DEFINE(SUPPORT_ACLS, 1, [Define to 1 to add support for ACLs])
 835         ;;
 836     *solaris*|*cygwin*)
 837         AC_MSG_RESULT(Using solaris ACLs)
 838         AC_DEFINE(HAVE_SOLARIS_ACLS, 1, [true if you have solaris ACLs])
 839         AC_DEFINE(SUPPORT_ACLS, 1)
 840         ;;
 841     *hpux*)
 842         AC_MSG_RESULT(Using HPUX ACLs)
 843         AC_DEFINE(HAVE_HPUX_ACLS, 1, [true if you have HPUX ACLs])
 844         AC_DEFINE(SUPPORT_ACLS, 1)
 845         ;;
 846     *irix*)
 847         AC_MSG_RESULT(Using IRIX ACLs)
 848         AC_DEFINE(HAVE_IRIX_ACLS, 1, [true if you have IRIX ACLs])
 849         AC_DEFINE(SUPPORT_ACLS, 1)
 850         ;;
 851     *aix*)
 852         AC_MSG_RESULT(Using AIX ACLs)
 853         AC_DEFINE(HAVE_AIX_ACLS, 1, [true if you have AIX ACLs])
 854         AC_DEFINE(SUPPORT_ACLS, 1)
 855         ;;
 856     *osf*)
 857         AC_MSG_RESULT(Using Tru64 ACLs)
 858         AC_DEFINE(HAVE_TRU64_ACLS, 1, [true if you have Tru64 ACLs])
 859         AC_DEFINE(SUPPORT_ACLS, 1)
 860         LIBS="$LIBS -lpacl"
 861         ;;
 862     darwin*)
 863         AC_MSG_RESULT(Using OS X ACLs)
 864         AC_DEFINE(HAVE_OSX_ACLS, 1, [true if you have Mac OS X ACLs])
 865         AC_DEFINE(SUPPORT_ACLS, 1)
 866         ;;
 867     *)
 868         AC_MSG_RESULT(running tests:)
 869         AC_CHECK_LIB(acl,acl_get_file)
 870             AC_CACHE_CHECK([for ACL support],samba_cv_HAVE_POSIX_ACLS,[
 871             AC_TRY_LINK([#include <sys/types.h>
 872 #include <sys/acl.h>],
 873 [ acl_t acl; int entry_id; acl_entry_t *entry_p; return acl_get_entry( acl, entry_id, entry_p);],
 874 samba_cv_HAVE_POSIX_ACLS=yes,samba_cv_HAVE_POSIX_ACLS=no)])
 875         AC_MSG_CHECKING(ACL test results)
 876         if test x"$samba_cv_HAVE_POSIX_ACLS" = x"yes"; then
 877             AC_MSG_RESULT(Using posix ACLs)
 878             AC_DEFINE(HAVE_POSIX_ACLS, 1, [true if you have posix ACLs])
 879             AC_DEFINE(SUPPORT_ACLS, 1)
 880             AC_CACHE_CHECK([for acl_get_perm_np],samba_cv_HAVE_ACL_GET_PERM_NP,[
 881                 AC_TRY_LINK([#include <sys/types.h>
 882 #include <sys/acl.h>],
 883 [ acl_permset_t permset_d; acl_perm_t perm; return acl_get_perm_np( permset_d, perm);],
 884 samba_cv_HAVE_ACL_GET_PERM_NP=yes,samba_cv_HAVE_ACL_GET_PERM_NP=no)])
 885             if test x"$samba_cv_HAVE_ACL_GET_PERM_NP" = x"yes"; then
 886                 AC_DEFINE(HAVE_ACL_GET_PERM_NP, 1, [true if you have acl_get_perm_np])
 887             fi
 888         else
 889             if test x"$enable_acl_support" = x"yes"; then
 890                 AC_MSG_ERROR(Failed to find ACL support)
 891             else
 892                 AC_MSG_RESULT(No ACL support found)
 893             fi
 894         fi
 895         ;;
 896     esac
 897 fi
 898
 899 AC_CHECK_HEADERS(attr/xattr.h)
 900 AC_CHECK_HEADERS(sys/xattr.h)
 901 AC_CHECK_HEADERS(sys/extattr.h)
 902
 903 #################################################
 904 # check for extended attribute support
 905 AC_MSG_CHECKING(whether to support extended attributes)
 906 AC_ARG_ENABLE(xattr-support,
 907     AC_HELP_STRING([--disable-xattr-support],
 908             [disable extended attributes]),
 909     [], [case "$ac_cv_func_getxattr$ac_cv_func_extattr_get_link" in
 910         *yes*) enable_xattr_support=maybe ;;
 911         *) enable_xattr_support=no ;;
 912         esac])
 913 AH_TEMPLATE([SUPPORT_XATTRS],
 914 [Define to 1 to add support for extended attributes])
 915 if test x"$enable_xattr_support" = x"no"; then
 916     AC_MSG_RESULT(no)
 917 else
 918     case "$host_os" in
 919     *linux*)
 920         AC_MSG_RESULT(Using Linux xattrs)
 921         AC_DEFINE(HAVE_LINUX_XATTRS, 1, [True if you have Linux xattrs])
 922         AC_DEFINE(SUPPORT_XATTRS, 1)
 923         ;;
 924     darwin*)
 925         AC_MSG_RESULT(Using OS X xattrs)
 926         AC_DEFINE(HAVE_OSX_XATTRS, 1, [True if you have Mac OS X xattrs])
 927         AC_DEFINE(SUPPORT_XATTRS, 1)
 928         ;;
 929     freebsd*)
 930         AC_MSG_RESULT(Using FreeBSD extattrs)
 931         AC_DEFINE(HAVE_FREEBSD_XATTRS, 1, [True if you have FreeBSD xattrs])
 932         AC_DEFINE(SUPPORT_XATTRS, 1)
 933         ;;
 934     *)
 935         if test x"$enable_xattr_support" = x"yes"; then
 936             AC_MSG_ERROR(Failed to find extended attribute support)
 937         else
 938             AC_MSG_RESULT(No extended attribute support found)
 939         fi
 940         ;;
 941     esac
 942 fi
 943
 944 AC_CONFIG_FILES([Makefile lib/dummy zlib/dummy popt/dummy shconfig])
 945 AC_OUTPUT
 946
 947 AC_MSG_RESULT()
 948 AC_MSG_RESULT([    rsync ${RSYNC_VERSION} configuration successful])
 949 AC_MSG_RESULT()