configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_INIT()
   4 AC_CONFIG_SRCDIR([byteorder.h])
   5 AC_CONFIG_HEADER(config.h)
   6 AC_PREREQ(2.52)
   7
   8 RSYNC_VERSION=2.6.0pre1
   9 AC_SUBST(RSYNC_VERSION)
  10 AC_MSG_NOTICE([Configuring rsync $RSYNC_VERSION])
  11
  12 AC_DEFINE_UNQUOTED(RSYNC_VERSION, ["$RSYNC_VERSION"], [rsync release version])
  13
  14 LDFLAGS=${LDFLAGS-""}
  15
  16 AC_CANONICAL_TARGET([])
  17
  18 dnl Checks for programs.
  19 AC_PROG_CC
  20 AC_PROG_CPP
  21 AC_PROG_INSTALL
  22 AC_PROG_CC_STDC
  23 AC_SUBST(SHELL)
  24
  25 AC_DEFINE([_GNU_SOURCE], 1,
  26           [Define _GNU_SOURCE so that we get all necessary prototypes])
  27
  28 if test "x$ac_cv_prog_cc_stdc" = xno
  29 then
  30         AC_MSG_WARN([rsync requires an ANSI C compiler and you don't seem to have one])
  31 fi
  32
  33 # We must decide this before testing the compiler.
  34
  35 # Please allow this to default to yes, so that your users have more
  36 # chance of getting a useful stack trace if problems occur.
  37
  38 AC_MSG_CHECKING([whether to include debugging symbols])
  39 AC_ARG_ENABLE(debug,
  40         AC_HELP_STRING([--enable-debug],
  41                 [including debugging symbols and features (default yes)]),
  42                 [], [])
  43
  44 if test x"$enable_debug" = x"no"
  45 then
  46     AC_MSG_RESULT(no)
  47     CFLAGS=${CFLAGS-"-O"}
  48 else
  49     AC_MSG_RESULT([yes])
  50     # leave CFLAGS alone; AC_PROG_CC will try to include -g if it can
  51     dnl AC_DEFINE(DEBUG, 1, [Define to turn on debugging code that may slow normal operation])
  52     dnl CFLAGS=${CFLAGS-"-g"}
  53 fi
  54
  55
  56
  57
  58 AC_ARG_ENABLE(profile,
  59         AC_HELP_STRING([--enable-profile],
  60                 [turn on CPU profiling (default no)],
  61                 [], []))
  62 if test x"$enable_profile" = xyes
  63 then
  64         CFLAGS="$CFLAGS -pg"
  65 fi
  66
  67
  68 # Specifically, this turns on panic_action handling.
  69 AC_ARG_ENABLE(maintainer-mode,
  70         AC_HELP_STRING([--enable-maintainer-mode],
  71                 [turn on extra debug features],
  72                 [], []))
  73 if test x"$enable_maintainer_mode" = xyes
  74 then
  75         CFLAGS="$CFLAGS -DMAINTAINER_MODE"
  76 fi
  77
  78
  79 # This is needed for our included version of popt.  Kind of silly, but
  80 # I don't want our version too far out of sync.
  81 CFLAGS="$CFLAGS -DHAVE_CONFIG_H"
  82
  83 # If GCC, turn on warnings.
  84 if test "x$GCC" = "xyes"
  85 then
  86         CFLAGS="$CFLAGS -Wall -W"
  87 fi
  88
  89 AC_ARG_WITH(included-popt,
  90         [  --with-included-popt    use bundled popt library, not from system])
  91
  92 AC_ARG_WITH(rsync-path,
  93         [  --with-rsync-path=PATH  set default --rsync-path to PATH (default: rsync)],
  94         [ RSYNC_PATH="$with_rsync_path" ],
  95         [ RSYNC_PATH="rsync" ])
  96
  97 AC_DEFINE_UNQUOTED(RSYNC_PATH, "$RSYNC_PATH", [location of rsync on remote machine])
  98
  99 AC_ARG_WITH(rsh,
 100         AC_HELP_STRING([--with-rsh=CMD], [set remote shell command to CMD (default: ssh)]))
 101
 102 AC_CHECK_PROG(HAVE_REMSH, remsh, 1, 0)
 103 AC_DEFINE_UNQUOTED(HAVE_REMSH, $HAVE_REMSH, [remote shell is remsh not rsh])
 104
 105 if test x"$with_rsh" != x
 106 then
 107         RSYNC_RSH="$with_rsh"
 108 else
 109         RSYNC_RSH="ssh"
 110 fi
 111
 112 AC_DEFINE_UNQUOTED(RSYNC_RSH, "$RSYNC_RSH", [default -e command])
 113
 114 # arrgh. libc in the current debian stable screws up the largefile
 115 # stuff, getting byte range locking wrong
 116 AC_CACHE_CHECK([for broken largefile support],rsync_cv_HAVE_BROKEN_LARGEFILE,[
 117 AC_TRY_RUN([
 118 #define _FILE_OFFSET_BITS 64
 119 #include <stdio.h>
 120 #include <fcntl.h>
 121 #include <sys/types.h>
 122 #include <sys/wait.h>
 123
 124 int main(void)
 125 {
 126         struct flock lock;
 127         int status;
 128         int fd = open("conftest.dat", O_CREAT|O_RDWR, 0600);
 129         lock.l_type = F_WRLCK;
 130         lock.l_whence = SEEK_SET;
 131         lock.l_start = 0;
 132         lock.l_len = 1;
 133         lock.l_pid = 0;
 134
 135         fcntl(fd,F_SETLK,&lock);
 136         if (fork() == 0) {
 137                 lock.l_start = 1;
 138                 exit(fcntl(fd,F_SETLK,&lock) == 0);
 139         }
 140         wait(&status);
 141         unlink("conftest.dat");
 142         exit(WEXITSTATUS(status));
 143 }
 144 ],
 145 rsync_cv_HAVE_BROKEN_LARGEFILE=yes,rsync_cv_HAVE_BROKEN_LARGEFILE=no,rsync_cv_HAVE_BROKEN_LARGEFILE=cross)])
 146 if test x"$rsync_cv_HAVE_BROKEN_LARGEFILE" != x"yes"; then
 147    AC_SYS_LARGEFILE
 148 fi
 149
 150 ipv6type=unknown
 151 ipv6lib=none
 152 ipv6trylibc=yes
 153
 154 AC_ARG_ENABLE(ipv6,
 155         AC_HELP_STRING([--disable-ipv6], [don't even try to use IPv6]))
 156
 157 if test "x$enable_ipv6" != xno
 158 then
 159         AC_MSG_CHECKING([ipv6 stack type])
 160         for i in inria kame linux-glibc linux-inet6 toshiba v6d zeta; do
 161                 case $i in
 162                 inria)
 163                         # http://www.kame.net/
 164                         AC_EGREP_CPP(yes, [
 165 #include <netinet/in.h>
 166 #ifdef IPV6_INRIA_VERSION
 167 yes
 168 #endif],
 169                                 [ipv6type=$i;
 170                                 AC_DEFINE(INET6, 1, [true if you have IPv6])
 171                                 ])
 172                         ;;
 173                 kame)
 174                         # http://www.kame.net/
 175                         AC_EGREP_CPP(yes, [
 176 #include <netinet/in.h>
 177 #ifdef __KAME__
 178 yes
 179 #endif],
 180                                 [ipv6type=$i;
 181                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 182                         ;;
 183                 linux-glibc)
 184                         # http://www.v6.linux.or.jp/
 185                         AC_EGREP_CPP(yes, [
 186 #include <features.h>
 187 #if defined(__GLIBC__) && __GLIBC__ >= 2 && __GLIBC_MINOR__ >= 1
 188 yes
 189 #endif],
 190                                 [ipv6type=$i;
 191 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 192                         ;;
 193                 linux-inet6)
 194                         # http://www.v6.linux.or.jp/
 195                         if test -d /usr/inet6 -o -f /usr/inet6/lib/libinet6.a; then
 196                                 ipv6type=$i
 197                                 ipv6lib=inet6
 198                                 ipv6libdir=/usr/inet6/lib
 199                                 ipv6trylibc=yes;
 200                                 AC_DEFINE(INET6, 1, [true if you have IPv6])
 201                                 CFLAGS="-I/usr/inet6/include $CFLAGS"
 202                         fi
 203                         ;;
 204                 toshiba)
 205                         AC_EGREP_CPP(yes, [
 206 #include <sys/param.h>
 207 #ifdef _TOSHIBA_INET6
 208 yes
 209 #endif],
 210                                 [ipv6type=$i;
 211                                 ipv6lib=inet6;
 212                                 ipv6libdir=/usr/local/v6/lib;
 213                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 214                         ;;
 215                 v6d)
 216                         AC_EGREP_CPP(yes, [
 217 #include </usr/local/v6/include/sys/v6config.h>
 218 #ifdef __V6D__
 219 yes
 220 #endif],
 221                                 [ipv6type=$i;
 222                                 ipv6lib=v6;
 223                                 ipv6libdir=/usr/local/v6/lib;
 224                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 225                         ;;
 226                 zeta)
 227                         AC_EGREP_CPP(yes, [
 228 #include <sys/param.h>
 229 #ifdef _ZETA_MINAMI_INET6
 230 yes
 231 #endif],
 232                                 [ipv6type=$i;
 233                                 ipv6lib=inet6;
 234                                 ipv6libdir=/usr/local/v6/lib;
 235                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 236                         ;;
 237                 esac
 238                 if test "$ipv6type" != "unknown"; then
 239                         break
 240                 fi
 241         done
 242         AC_MSG_RESULT($ipv6type)
 243
 244         AC_SEARCH_LIBS(getaddrinfo, inet6)
 245 fi
 246
 247 AC_MSG_CHECKING([whether to call shutdown on all sockets])
 248 case $host_os in
 249         *cygwin* ) AC_MSG_RESULT(yes)
 250                    AC_DEFINE(SHUTDOWN_ALL_SOCKETS, 1,
 251                             [Define if sockets need to be shutdown])
 252                    ;;
 253                * ) AC_MSG_RESULT(no);;
 254 esac
 255
 256 AC_C_BIGENDIAN
 257 AC_HEADER_DIRENT
 258 AC_HEADER_TIME
 259 AC_HEADER_SYS_WAIT
 260 AC_CHECK_HEADERS(sys/fcntl.h sys/select.h fcntl.h sys/time.h sys/unistd.h unistd.h utime.h grp.h)
 261 AC_CHECK_HEADERS(compat.h sys/param.h ctype.h sys/wait.h sys/ioctl.h)
 262 AC_CHECK_HEADERS(sys/filio.h string.h stdlib.h sys/socket.h sys/mode.h sys/un.h)
 263 AC_CHECK_HEADERS(glob.h mcheck.h sys/sysctl.h arpa/inet.h arpa/nameser.h)
 264 AC_CHECK_HEADERS(netdb.h)
 265 AC_CHECK_HEADERS(malloc.h)
 266 AC_CHECK_HEADERS(float.h)
 267
 268 AC_CHECK_SIZEOF(int)
 269 AC_CHECK_SIZEOF(long)
 270 AC_CHECK_SIZEOF(short)
 271
 272 AC_C_INLINE
 273
 274 AC_TYPE_SIGNAL
 275 AC_TYPE_UID_T
 276 AC_TYPE_MODE_T
 277 AC_TYPE_OFF_T
 278 AC_TYPE_SIZE_T
 279 AC_TYPE_PID_T
 280 AC_TYPE_GETGROUPS
 281 AC_CHECK_MEMBERS([struct stat.st_rdev])
 282
 283 AC_CHECK_TYPE([ino_t], [unsigned])
 284 TYPE_SOCKLEN_T
 285
 286 AC_CACHE_CHECK([for errno in errno.h],rsync_cv_errno, [
 287     AC_TRY_COMPILE([#include <errno.h>],[int i = errno],
 288         rsync_cv_errno=yes,rsync_cv_have_errno_decl=no)])
 289 if test x"$rsync_cv_errno" = x"yes"; then
 290    AC_DEFINE(HAVE_ERRNO_DECL, 1, [ ])
 291 fi
 292
 293 # The following test taken from the cvs sources
 294 # If we can't find connect, try looking in -lsocket, -lnsl, and -linet.
 295 # These need checks to be before checks for any other functions that
 296 #    might be in the same libraries.
 297 # The Irix 5 libc.so has connect and gethostbyname, but Irix 5 also has
 298 # libsocket.so which has a bad implementation of gethostbyname (it
 299 # only looks in /etc/hosts), so we only look for -lsocket if we need
 300 # it.
 301 AC_CHECK_FUNCS(connect)
 302 if test x"$ac_cv_func_connect" = x"no"; then
 303     case "$LIBS" in
 304     *-lnsl*) ;;
 305     *) AC_CHECK_LIB(nsl_s, printf) ;;
 306     esac
 307     case "$LIBS" in
 308     *-lnsl*) ;;
 309     *) AC_CHECK_LIB(nsl, printf) ;;
 310     esac
 311     case "$LIBS" in
 312     *-lsocket*) ;;
 313     *) AC_CHECK_LIB(socket, connect) ;;
 314     esac
 315     case "$LIBS" in
 316     *-linet*) ;;
 317     *) AC_CHECK_LIB(inet, connect) ;;
 318     esac
 319     dnl We can't just call AC_CHECK_FUNCS(connect) here, because the value
 320     dnl has been cached.
 321     if test x"$ac_cv_lib_socket_connect" = x"yes" ||
 322        test x"$ac_cv_lib_inet_connect" = x"yes"; then
 323         # ac_cv_func_connect=yes
 324         # don't!  it would cause AC_CHECK_FUNC to succeed next time configure is run
 325         AC_DEFINE(HAVE_CONNECT, 1, [ ])
 326     fi
 327 fi
 328
 329 AC_CHECK_LIB(resolv, inet_ntop)
 330
 331 dnl AC_MSG_NOTICE([Looking in libraries: $LIBS])
 332
 333 AC_CHECK_FUNCS(inet_ntop, , AC_LIBOBJ(lib/inet_ntop))
 334 AC_CHECK_FUNCS(inet_pton, , AC_LIBOBJ(lib/inet_pton))
 335
 336 # Irix 6.5 has getaddrinfo but not the corresponding defines, so use
 337 #   builtin getaddrinfo if one of the defines don't exist
 338 AC_CACHE_CHECK([whether defines needed by getaddrinfo exist],
 339                rsync_cv_HAVE_GETADDR_DEFINES,[
 340                         AC_EGREP_CPP(yes, [
 341                         #include <sys/types.h>
 342                         #include <sys/socket.h>
 343                         #include <netdb.h>
 344                         #ifdef AI_PASSIVE
 345                         yes
 346                         #endif],
 347                         rsync_cv_HAVE_GETADDR_DEFINES=yes,
 348                         rsync_cv_HAVE_GETADDR_DEFINES=no)])
 349 if test x"$rsync_cv_HAVE_GETADDR_DEFINES" = x"yes"; then
 350         # Tru64 UNIX has getaddrinfo() but has it renamed in libc as
 351         # something else so we must include <netdb.h> to get the
 352         # redefinition.
 353         AC_CHECK_FUNCS(getaddrinfo, ,
 354                 [AC_MSG_CHECKING([for getaddrinfo by including <netdb.h>])
 355                 AC_TRY_LINK([#include <sys/types.h>
 356                 #include <sys/socket.h>
 357                 #include <netdb.h>],[getaddrinfo(NULL, NULL, NULL, NULL);],
 358                         [AC_MSG_RESULT([yes])
 359                         AC_DEFINE(HAVE_GETADDRINFO, 1,
 360                                 [Define if you have the `getaddrinfo' function.])],
 361                         [AC_MSG_RESULT([no])
 362                         AC_LIBOBJ(lib/getaddrinfo)])])
 363         AC_CHECK_FUNCS(getnameinfo, , AC_LIBOBJ(lib/getnameinfo))
 364 else
 365         AC_LIBOBJ(lib/getaddrinfo)
 366         AC_LIBOBJ(lib/getnameinfo)
 367 fi
 368
 369
 370 AC_CHECK_MEMBER([struct sockaddr.sa_len],
 371                 [ AC_DEFINE(HAVE_SOCKADDR_LEN) ],
 372                 [],
 373                 [
 374 #include <sys/types.h>
 375 #include <sys/socket.h>
 376 ])
 377
 378 AC_MSG_CHECKING(struct sockaddr_storage)
 379 AC_TRY_COMPILE([#include <sys/types.h>
 380 #include <sys/socket.h>],
 381 [struct sockaddr_storage x;],
 382         AC_MSG_RESULT(yes)
 383         AC_DEFINE(HAVE_SOCKADDR_STORAGE, 1,
 384                 [Define if you have strct sockaddr_storage.] ),
 385         AC_MSG_RESULT(no))
 386
 387 AC_CHECK_MEMBER([struct sockaddr_in6.sin6_scope_id],
 388                 [ AC_DEFINE(HAVE_SOCKADDR_IN6_SCOPE_ID) ],
 389                 [],
 390                 [
 391 #include <sys/types.h>
 392 #include <sys/socket.h>
 393 #include <netinet/in.h>
 394 ])
 395
 396 # if we can't find strcasecmp, look in -lresolv (for Unixware at least)
 397 #
 398 AC_CHECK_FUNCS(strcasecmp)
 399 if test x"$ac_cv_func_strcasecmp" = x"no"; then
 400     AC_CHECK_LIB(resolv, strcasecmp)
 401 fi
 402
 403 dnl At the moment we don't test for a broken memcmp(), because all we
 404 dnl need to do is test for equality, not comparison, and it seems that
 405 dnl every platform has a memcmp that can do at least that.
 406 dnl AC_FUNC_MEMCMP
 407
 408 AC_FUNC_UTIME_NULL
 409 AC_FUNC_ALLOCA
 410 AC_CHECK_FUNCS(waitpid wait4 getcwd strdup strerror chown chmod mknod mkfifo)
 411 AC_CHECK_FUNCS(fchmod fstat strchr readlink link utime utimes strftime)
 412 AC_CHECK_FUNCS(memmove lchown vsnprintf snprintf asprintf setsid glob strpbrk)
 413 AC_CHECK_FUNCS(strlcat strlcpy strtol mtrace mallinfo setgroups)
 414
 415 AC_CACHE_CHECK([for working socketpair],rsync_cv_HAVE_SOCKETPAIR,[
 416 AC_TRY_RUN([
 417 #include <sys/types.h>
 418 #include <sys/socket.h>
 419
 420 main() {
 421        int fd[2];
 422        exit((socketpair(AF_UNIX, SOCK_STREAM, 0, fd) != -1) ? 0 : 1);
 423 }],
 424 rsync_cv_HAVE_SOCKETPAIR=yes,rsync_cv_HAVE_SOCKETPAIR=no,rsync_cv_HAVE_SOCKETPAIR=cross)])
 425 if test x"$rsync_cv_HAVE_SOCKETPAIR" = x"yes"; then
 426     AC_DEFINE(HAVE_SOCKETPAIR, 1, [ ])
 427 fi
 428
 429 if test x"$with_included_popt" != x"yes"
 430 then
 431     AC_CHECK_LIB(popt, poptGetContext, , [with_included_popt=yes])
 432 fi
 433
 434 AC_MSG_CHECKING([whether to use included libpopt])
 435 if test x"$with_included_popt" = x"yes"
 436 then
 437     AC_MSG_RESULT($srcdir/popt)
 438     BUILD_POPT='$(popt_OBJS)'
 439     CFLAGS="$CFLAGS -I$srcdir/popt"
 440     if test x"$ALLOCA" != x
 441     then
 442         # this can be removed when/if we add an included alloca.c;
 443         #  see autoconf documentation on AC_FUNC_ALLOCA
 444         AC_MSG_WARN([included libpopt will use malloc, not alloca (which wastes a small amount of memory)])
 445     fi
 446 else
 447     AC_MSG_RESULT(no)
 448 fi
 449
 450 AC_CACHE_CHECK([for long long],rsync_cv_HAVE_LONGLONG,[
 451 AC_TRY_RUN([#include <stdio.h>
 452 main() { long long x = 1000000; x *= x; exit(((x/1000000) == 1000000)? 0: 1); }],
 453 rsync_cv_HAVE_LONGLONG=yes,rsync_cv_HAVE_LONGLONG=no,rsync_cv_HAVE_LONGLONG=cross)])
 454 if test x"$rsync_cv_HAVE_LONGLONG" = x"yes"; then
 455     AC_DEFINE(HAVE_LONGLONG, 1, [ ])
 456 fi
 457
 458 AC_CACHE_CHECK([for off64_t],rsync_cv_HAVE_OFF64_T,[
 459 AC_TRY_RUN([#include <stdio.h>
 460 #include <sys/stat.h>
 461 main() { struct stat64 st; off64_t s; if (sizeof(off_t) == sizeof(off64_t)) exit(1); exit((lstat64("/dev/null", &st)==0)?0:1); }],
 462 rsync_cv_HAVE_OFF64_T=yes,rsync_cv_HAVE_OFF64_T=no,rsync_cv_HAVE_OFF64_T=cross)])
 463 if test x"$rsync_cv_HAVE_OFF64_T" = x"yes"; then
 464     AC_DEFINE(HAVE_OFF64_T, 1, [ ])
 465 fi
 466
 467 AC_CACHE_CHECK([for short ino_t],rsync_cv_HAVE_SHORT_INO_T,[
 468 AC_TRY_RUN([#include <stdio.h>
 469 #include <sys/types.h>
 470 #include <sys/stat.h>
 471 main() { if (sizeof(ino_t) < sizeof(unsigned int)) return 0; return 1; }],
 472 rsync_cv_HAVE_SHORT_INO_T=yes,rsync_cv_HAVE_SHORT_INO_T=no,rsync_cv_HAVE_SHORT_INO_T=cross)])
 473 if test x"$rsync_cv_HAVE_SHORT_INO_T" = x"yes"; then
 474     AC_DEFINE(HAVE_SHORT_INO_T, 1, [ ])
 475 fi
 476
 477 AC_CACHE_CHECK([for unsigned char],rsync_cv_HAVE_UNSIGNED_CHAR,[
 478 AC_TRY_RUN([#include <stdio.h>
 479 main() { char c; c=250; exit((c > 0)?0:1); }],
 480 rsync_cv_HAVE_UNSIGNED_CHAR=yes,rsync_cv_HAVE_UNSIGNED_CHAR=no,rsync_cv_HAVE_UNSIGNED_CHAR=cross)])
 481 if test x"$rsync_cv_HAVE_UNSIGNED_CHAR" = x"yes"; then
 482     AC_DEFINE(HAVE_UNSIGNED_CHAR, 1, [ ])
 483 fi
 484
 485 AC_CACHE_CHECK([for broken readdir],rsync_cv_HAVE_BROKEN_READDIR,[
 486 AC_TRY_RUN([#include <sys/types.h>
 487 #include <dirent.h>
 488 main() { struct dirent *di; DIR *d = opendir("."); di = readdir(d);
 489 if (di && di->d_name[-2] == '.' && di->d_name[-1] == 0 &&
 490 di->d_name[0] == 0) exit(0); exit(1);} ],
 491 rsync_cv_HAVE_BROKEN_READDIR=yes,rsync_cv_HAVE_BROKEN_READDIR=no,rsync_cv_HAVE_BROKEN_READDIR=cross)])
 492 if test x"$rsync_cv_HAVE_BROKEN_READDIR" = x"yes"; then
 493     AC_DEFINE(HAVE_BROKEN_READDIR, 1, [ ])
 494 fi
 495
 496 AC_CACHE_CHECK([for utimbuf],rsync_cv_HAVE_UTIMBUF,[
 497 AC_TRY_COMPILE([#include <sys/types.h>
 498 #include <utime.h>],
 499 [struct utimbuf tbuf;  tbuf.actime = 0; tbuf.modtime = 1; exit(utime("foo.c",&tbuf));],
 500 rsync_cv_HAVE_UTIMBUF=yes,rsync_cv_HAVE_UTIMBUF=no,rsync_cv_HAVE_UTIMBUF=cross)])
 501 if test x"$rsync_cv_HAVE_UTIMBUF" = x"yes"; then
 502     AC_DEFINE(HAVE_UTIMBUF, 1, [ ])
 503 fi
 504
 505 AC_CACHE_CHECK([if gettimeofday takes tz argument],rsync_cv_HAVE_GETTIMEOFDAY_TZ,[
 506 AC_TRY_RUN([
 507 #include <sys/time.h>
 508 #include <unistd.h>
 509 main() { struct timeval tv; exit(gettimeofday(&tv, NULL));}],
 510            rsync_cv_HAVE_GETTIMEOFDAY_TZ=yes,rsync_cv_HAVE_GETTIMEOFDAY_TZ=no,rsync_cv_HAVE_GETTIMEOFDAY_TZ=cross)])
 511 if test x"$rsync_cv_HAVE_GETTIMEOFDAY_TZ" = x"yes"; then
 512     AC_DEFINE(HAVE_GETTIMEOFDAY_TZ, 1, [ ])
 513 fi
 514
 515 AC_CACHE_CHECK([for C99 vsnprintf],rsync_cv_HAVE_C99_VSNPRINTF,[
 516 AC_TRY_RUN([
 517 #include <sys/types.h>
 518 #include <stdarg.h>
 519 void foo(const char *format, ...) {
 520        va_list ap;
 521        int len;
 522        char buf[5];
 523
 524        va_start(ap, format);
 525        len = vsnprintf(0, 0, format, ap);
 526        va_end(ap);
 527        if (len != 5) exit(1);
 528
 529        if (snprintf(buf, 3, "hello") != 5 || strcmp(buf, "he") != 0) exit(1);
 530
 531        exit(0);
 532 }
 533 main() { foo("hello"); }
 534 ],
 535 rsync_cv_HAVE_C99_VSNPRINTF=yes,rsync_cv_HAVE_C99_VSNPRINTF=no,rsync_cv_HAVE_C99_VSNPRINTF=cross)])
 536 if test x"$rsync_cv_HAVE_C99_VSNPRINTF" = x"yes"; then
 537     AC_DEFINE(HAVE_C99_VSNPRINTF, 1, [ ])
 538 fi
 539
 540
 541 AC_CACHE_CHECK([for secure mkstemp],rsync_cv_HAVE_SECURE_MKSTEMP,[
 542 AC_TRY_RUN([#include <stdlib.h>
 543 #include <sys/types.h>
 544 #include <sys/stat.h>
 545 #include <unistd.h>
 546 main() {
 547   struct stat st;
 548   char tpl[20]="/tmp/test.XXXXXX";
 549   int fd = mkstemp(tpl);
 550   if (fd == -1) exit(1);
 551   unlink(tpl);
 552   if (fstat(fd, &st) != 0) exit(1);
 553   if ((st.st_mode & 0777) != 0600) exit(1);
 554   exit(0);
 555 }],
 556 rsync_cv_HAVE_SECURE_MKSTEMP=yes,
 557 rsync_cv_HAVE_SECURE_MKSTEMP=no,
 558 rsync_cv_HAVE_SECURE_MKSTEMP=cross)])
 559 if test x"$rsync_cv_HAVE_SECURE_MKSTEMP" = x"yes"; then
 560     AC_DEFINE(HAVE_SECURE_MKSTEMP, 1, [ ])
 561 fi
 562
 563
 564 AC_CACHE_CHECK([for broken inet_ntoa],rsync_cv_REPLACE_INET_NTOA,[
 565 AC_TRY_RUN([
 566 #include <stdio.h>
 567 #include <sys/types.h>
 568 #include <netinet/in.h>
 569 #include <arpa/inet.h>
 570 main() { struct in_addr ip; ip.s_addr = 0x12345678;
 571 if (strcmp(inet_ntoa(ip),"18.52.86.120") &&
 572     strcmp(inet_ntoa(ip),"120.86.52.18")) { exit(1); }
 573 exit(0);}],
 574            rsync_cv_REPLACE_INET_NTOA=no,rsync_cv_REPLACE_INET_NTOA=yes,rsync_cv_REPLACE_INET_NTOA=cross)])
 575 if test x"$rsync_cv_REPLACE_INET_NTOA" = x"yes"; then
 576     AC_DEFINE(REPLACE_INET_NTOA, 1, [ ])
 577 fi
 578
 579
 580 AC_CACHE_CHECK([for broken inet_aton],rsync_cv_REPLACE_INET_ATON,[
 581 AC_TRY_RUN([
 582 #include <stdio.h>
 583 #include <sys/types.h>
 584 #include <netinet/in.h>
 585 #include <arpa/inet.h>
 586 main() { struct in_addr ip;
 587 if (inet_aton("example", &ip) == 0) exit(0); exit(1);}],
 588            rsync_cv_REPLACE_INET_ATON=no,rsync_cv_REPLACE_INET_ATON=yes,rsync_cv_REPLACE_INET_ATON=cross)])
 589 if test x"$rsync_cv_REPLACE_INET_ATON" = x"yes"; then
 590     AC_DEFINE(REPLACE_INET_ATON, 1, [ ])
 591 fi
 592
 593 #
 594 # The following test was mostly taken from the tcl/tk plus patches
 595 #
 596 AC_CACHE_CHECK([whether -c -o works],rsync_cv_DASHC_WORKS_WITH_DASHO,[
 597 rm -rf conftest*
 598 cat > conftest.$ac_ext <<EOF
 599 int main() { return 0; }
 600 EOF
 601 ${CC-cc} -c -o conftest..o conftest.$ac_ext
 602 if test -f conftest..o; then
 603     rsync_cv_DASHC_WORKS_WITH_DASHO=yes
 604 else
 605     rsync_cv_DASHC_WORKS_WITH_DASHO=no
 606 fi
 607 rm -rf conftest*
 608 ])
 609 if test x"$rsync_cv_DASHC_WORKS_WITH_DASHO" = x"yes"; then
 610     OBJ_SAVE="#"
 611     OBJ_RESTORE="#"
 612     CC_SHOBJ_FLAG='-o $@'
 613 else
 614     OBJ_SAVE='  @b=`basename $@ .o`;rm -f $$b.o.sav;if test -f $$b.o; then mv $$b.o $$b.o.sav;fi;'
 615     OBJ_RESTORE='       @b=`basename $@ .o`;if test "$$b.o" != "$@"; then mv $$b.o $@; if test -f $$b.o.sav; then mv $$b.o.sav $$b.o; fi; fi'
 616     CC_SHOBJ_FLAG=""
 617 fi
 618
 619 AC_SUBST(OBJ_SAVE)
 620 AC_SUBST(OBJ_RESTORE)
 621 AC_SUBST(CC_SHOBJ_FLAG)
 622 AC_SUBST(BUILD_POPT)
 623
 624 AC_CONFIG_FILES([Makefile lib/dummy zlib/dummy popt/dummy shconfig])
 625 AC_OUTPUT
 626
 627 AC_MSG_RESULT()
 628 AC_MSG_RESULT([    rsync ${RSYNC_VERSION} configuration successful])
 629 AC_MSG_RESULT()