configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_INIT()
   4 AC_CONFIG_SRCDIR([byteorder.h])
   5 AC_CONFIG_HEADER(config.h)
   6 AC_PREREQ(2.59)
   7
   8 RSYNC_VERSION=3.0.0pre4
   9 AC_SUBST(RSYNC_VERSION)
  10 AC_MSG_NOTICE([Configuring rsync $RSYNC_VERSION])
  11
  12 AC_DEFINE_UNQUOTED(RSYNC_VERSION, ["$RSYNC_VERSION"], [rsync release version])
  13
  14 LDFLAGS=${LDFLAGS-""}
  15
  16 AC_CANONICAL_TARGET([])
  17
  18 dnl Checks for programs.
  19 AC_PROG_CC
  20 AC_PROG_CPP
  21 AC_PROG_EGREP
  22 AC_PROG_INSTALL
  23 AC_PROG_CC_STDC
  24 AC_SUBST(SHELL)
  25
  26 AC_DEFINE([_GNU_SOURCE], 1,
  27           [Define _GNU_SOURCE so that we get all necessary prototypes])
  28
  29 if test x"$ac_cv_prog_cc_stdc" = x"no"; then
  30         AC_MSG_WARN([rsync requires an ANSI C compiler and you don't seem to have one])
  31 fi
  32
  33 # We must decide this before testing the compiler.
  34
  35 # Please allow this to default to yes, so that your users have more
  36 # chance of getting a useful stack trace if problems occur.
  37
  38 AC_MSG_CHECKING([whether to include debugging symbols])
  39 AC_ARG_ENABLE(debug,
  40         AC_HELP_STRING([--disable-debug],
  41                 [disable debugging symbols and features]))
  42
  43 if test x"$enable_debug" = x"no"; then
  44     AC_MSG_RESULT(no)
  45     CFLAGS=${CFLAGS-"-O"}
  46 else
  47     AC_MSG_RESULT([yes])
  48     # leave CFLAGS alone; AC_PROG_CC will try to include -g if it can
  49     dnl AC_DEFINE(DEBUG, 1, [Define to turn on debugging code that may slow normal operation])
  50     dnl CFLAGS=${CFLAGS-"-g"}
  51 fi
  52
  53
  54 AC_ARG_ENABLE(profile,
  55         AC_HELP_STRING([--enable-profile],
  56                 [turn on CPU profiling]))
  57 if test x"$enable_profile" = x"yes"; then
  58         CFLAGS="$CFLAGS -pg"
  59 fi
  60
  61
  62 # Specifically, this turns on panic_action handling.
  63 AC_ARG_ENABLE(maintainer-mode,
  64         AC_HELP_STRING([--enable-maintainer-mode],
  65                 [turn on extra debug features]))
  66 if test x"$enable_maintainer_mode" = x"yes"; then
  67         CFLAGS="$CFLAGS -DMAINTAINER_MODE"
  68 fi
  69
  70
  71 # This is needed for our included version of popt.  Kind of silly, but
  72 # I don't want our version too far out of sync.
  73 CFLAGS="$CFLAGS -DHAVE_CONFIG_H"
  74
  75 # If GCC, turn on warnings.
  76 if test x"$GCC" = x"yes"; then
  77         CFLAGS="$CFLAGS -Wall -W"
  78 fi
  79
  80 AC_ARG_WITH(included-popt,
  81         AC_HELP_STRING([--with-included-popt], [use bundled popt library, not from system]))
  82
  83 AC_ARG_WITH(rsync-path,
  84         AC_HELP_STRING([--with-rsync-path=PATH], [set default --rsync-path to PATH (default: rsync)]),
  85         [ RSYNC_PATH="$with_rsync_path" ],
  86         [ RSYNC_PATH="rsync" ])
  87
  88 AC_DEFINE_UNQUOTED(RSYNC_PATH, "$RSYNC_PATH", [location of rsync on remote machine])
  89
  90 AC_ARG_WITH(rsyncd-conf,
  91         AC_HELP_STRING([--with-rsyncd-conf=PATH], [set configuration file for rsync server to PATH (default: /etc/rsyncd.conf)]),
  92         [ if test ! -z "$with_rsyncd_conf" ; then
  93                 case $with_rsyncd_conf in
  94                         yes|no)
  95                                 RSYNCD_SYSCONF="/etc/rsyncd.conf"
  96                                 ;;
  97                         /*)
  98                                 RSYNCD_SYSCONF="$with_rsyncd_conf"
  99                                 ;;
 100                         *)
 101                                 AC_MSG_ERROR(You must specify an absolute path to --with-rsyncd-conf=PATH)
 102                                 ;;
 103                 esac
 104         else
 105                 RSYNCD_SYSCONF="/etc/rsyncd.conf"
 106         fi ],
 107         [ RSYNCD_SYSCONF="/etc/rsyncd.conf" ])
 108
 109 AC_DEFINE_UNQUOTED(RSYNCD_SYSCONF, "$RSYNCD_SYSCONF", [location of configuration file for rsync server])
 110
 111 AC_ARG_WITH(rsh,
 112         AC_HELP_STRING([--with-rsh=CMD], [set remote shell command to CMD (default: ssh)]))
 113
 114 AC_CHECK_PROG(HAVE_REMSH, remsh, 1, 0)
 115 if test x$HAVE_REMSH = x1; then
 116         AC_DEFINE(HAVE_REMSH, 1, [Define to 1 if remote shell is remsh, not rsh])
 117 fi
 118
 119 if test x"$with_rsh" != x; then
 120         RSYNC_RSH="$with_rsh"
 121 else
 122         RSYNC_RSH="ssh"
 123 fi
 124 AC_DEFINE_UNQUOTED(RSYNC_RSH, "$RSYNC_RSH", [default -e command])
 125
 126 AC_ARG_WITH(nobody-group,
 127     AC_HELP_STRING([--with-nobody-group=GROUP],
 128                    [set the default unprivileged group (default nobody or nogroup)]),
 129     [ NOBODY_GROUP="$with_nobody_group" ])
 130
 131 if test x"$with_nobody_group" = x; then
 132     AC_MSG_CHECKING([the group for user "nobody"])
 133     if grep '^nobody:' /etc/group >/dev/null 2>&1; then
 134         NOBODY_GROUP=nobody
 135     elif grep '^nogroup:' /etc/group >/dev/null 2>&1; then
 136         NOBODY_GROUP=nogroup
 137     else
 138         NOBODY_GROUP=nobody # test for others?
 139     fi
 140     AC_MSG_RESULT($NOBODY_GROUP)
 141 fi
 142
 143 AC_DEFINE_UNQUOTED(NOBODY_USER, "nobody", [unprivileged user--e.g. nobody])
 144 AC_DEFINE_UNQUOTED(NOBODY_GROUP, "$NOBODY_GROUP", [unprivileged group for unprivileged user])
 145
 146 # arrgh. libc in some old debian version screwed up the largefile
 147 # stuff, getting byte range locking wrong
 148 AC_CACHE_CHECK([for broken largefile support],rsync_cv_HAVE_BROKEN_LARGEFILE,[
 149 AC_TRY_RUN([
 150 #define _FILE_OFFSET_BITS 64
 151 #include <stdio.h>
 152 #include <fcntl.h>
 153 #include <sys/types.h>
 154 #include <sys/wait.h>
 155
 156 int main(void)
 157 {
 158         struct flock lock;
 159         int status;
 160         char tpl[32] = "/tmp/locktest.XXXXXX";
 161         int fd = mkstemp(tpl);
 162         if (fd < 0) {
 163                 strcpy(tpl, "conftest.dat");
 164                 fd = open(tpl, O_CREAT|O_RDWR, 0600);
 165         }
 166
 167         lock.l_type = F_WRLCK;
 168         lock.l_whence = SEEK_SET;
 169         lock.l_start = 0;
 170         lock.l_len = 1;
 171         lock.l_pid = 0;
 172         fcntl(fd,F_SETLK,&lock);
 173         if (fork() == 0) {
 174                 lock.l_start = 1;
 175                 _exit(fcntl(fd,F_SETLK,&lock) == 0);
 176         }
 177         wait(&status);
 178         unlink(tpl);
 179         exit(WEXITSTATUS(status));
 180 }
 181 ],
 182 rsync_cv_HAVE_BROKEN_LARGEFILE=yes,rsync_cv_HAVE_BROKEN_LARGEFILE=no,rsync_cv_HAVE_BROKEN_LARGEFILE=cross)])
 183 if test x"$rsync_cv_HAVE_BROKEN_LARGEFILE" != x"yes"; then
 184    AC_SYS_LARGEFILE
 185 fi
 186
 187 ipv6type=unknown
 188 ipv6lib=none
 189 ipv6trylibc=yes
 190
 191 AC_ARG_ENABLE(ipv6,
 192         AC_HELP_STRING([--disable-ipv6],
 193                 [don't even try to use IPv6]))
 194 if test x"$enable_ipv6" != x"no"; then
 195         AC_MSG_CHECKING([ipv6 stack type])
 196         for i in inria kame linux-glibc linux-inet6 toshiba v6d zeta; do
 197                 case $i in
 198                 inria)
 199                         # http://www.kame.net/
 200                         AC_EGREP_CPP(yes, [
 201 #include <netinet/in.h>
 202 #ifdef IPV6_INRIA_VERSION
 203 yes
 204 #endif],
 205                                 [ipv6type=$i;
 206                                 AC_DEFINE(INET6, 1, [true if you have IPv6])
 207                                 ])
 208                         ;;
 209                 kame)
 210                         # http://www.kame.net/
 211                         AC_EGREP_CPP(yes, [
 212 #include <netinet/in.h>
 213 #ifdef __KAME__
 214 yes
 215 #endif],
 216                                 [ipv6type=$i;
 217                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 218                         ;;
 219                 linux-glibc)
 220                         # http://www.v6.linux.or.jp/
 221                         AC_EGREP_CPP(yes, [
 222 #include <features.h>
 223 #if defined(__GLIBC__) && __GLIBC__ >= 2 && __GLIBC_MINOR__ >= 1
 224 yes
 225 #endif],
 226                                 [ipv6type=$i;
 227 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 228                         ;;
 229                 linux-inet6)
 230                         # http://www.v6.linux.or.jp/
 231                         if test -d /usr/inet6 -o -f /usr/inet6/lib/libinet6.a; then
 232                                 ipv6type=$i
 233                                 ipv6lib=inet6
 234                                 ipv6libdir=/usr/inet6/lib
 235                                 ipv6trylibc=yes;
 236                                 AC_DEFINE(INET6, 1, [true if you have IPv6])
 237                                 CFLAGS="-I/usr/inet6/include $CFLAGS"
 238                         fi
 239                         ;;
 240                 toshiba)
 241                         AC_EGREP_CPP(yes, [
 242 #include <sys/param.h>
 243 #ifdef _TOSHIBA_INET6
 244 yes
 245 #endif],
 246                                 [ipv6type=$i;
 247                                 ipv6lib=inet6;
 248                                 ipv6libdir=/usr/local/v6/lib;
 249                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 250                         ;;
 251                 v6d)
 252                         AC_EGREP_CPP(yes, [
 253 #include </usr/local/v6/include/sys/v6config.h>
 254 #ifdef __V6D__
 255 yes
 256 #endif],
 257                                 [ipv6type=$i;
 258                                 ipv6lib=v6;
 259                                 ipv6libdir=/usr/local/v6/lib;
 260                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 261                         ;;
 262                 zeta)
 263                         AC_EGREP_CPP(yes, [
 264 #include <sys/param.h>
 265 #ifdef _ZETA_MINAMI_INET6
 266 yes
 267 #endif],
 268                                 [ipv6type=$i;
 269                                 ipv6lib=inet6;
 270                                 ipv6libdir=/usr/local/v6/lib;
 271                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 272                         ;;
 273                 esac
 274                 if test "$ipv6type" != "unknown"; then
 275                         break
 276                 fi
 277         done
 278         AC_MSG_RESULT($ipv6type)
 279
 280         AC_SEARCH_LIBS(getaddrinfo, inet6)
 281 fi
 282
 283 dnl Do you want to disable use of locale functions
 284 AC_ARG_ENABLE([locale],
 285         AC_HELP_STRING([--disable-locale],
 286                 [disable locale features]))
 287 AH_TEMPLATE([CONFIG_LOCALE],
 288 [Undefine if you don't want locale features.  By default this is defined.])
 289 if test x"$enable_locale" != x"no"; then
 290         AC_DEFINE(CONFIG_LOCALE)
 291 fi
 292
 293 AC_MSG_CHECKING([whether to call shutdown on all sockets])
 294 case $host_os in
 295         *cygwin* ) AC_MSG_RESULT(yes)
 296                    AC_DEFINE(SHUTDOWN_ALL_SOCKETS, 1,
 297                             [Define to 1 if sockets need to be shutdown])
 298                    ;;
 299                * ) AC_MSG_RESULT(no);;
 300 esac
 301
 302 AC_C_BIGENDIAN
 303 AC_HEADER_DIRENT
 304 AC_HEADER_TIME
 305 AC_HEADER_SYS_WAIT
 306 AC_CHECK_HEADERS(sys/fcntl.h sys/select.h fcntl.h sys/time.h sys/unistd.h \
 307     unistd.h utime.h grp.h compat.h sys/param.h ctype.h sys/wait.h \
 308     sys/ioctl.h sys/filio.h string.h stdlib.h sys/socket.h sys/mode.h \
 309     sys/un.h sys/attr.h glob.h mcheck.h arpa/inet.h arpa/nameser.h locale.h \
 310     netdb.h malloc.h float.h limits.h iconv.h libcharset.h langinfo.h)
 311 AC_HEADER_MAJOR
 312
 313 AC_CACHE_CHECK([if makedev takes 3 args],rsync_cv_MAKEDEV_TAKES_3_ARGS,[
 314 AC_TRY_RUN([
 315 #include <sys/types.h>
 316 #ifdef MAJOR_IN_MKDEV
 317 #include <sys/mkdev.h>
 318 # if !defined makedev && (defined mkdev || defined _WIN32 || defined __WIN32__)
 319 #  define makedev mkdev
 320 # endif
 321 #elif defined MAJOR_IN_SYSMACROS
 322 #include <sys/sysmacros.h>
 323 #endif
 324
 325 int main(void)
 326 {
 327         dev_t dev = makedev(0, 5, 7);
 328         if (major(dev) != 5 || minor(dev) != 7)
 329                 exit(1);
 330         return 0;
 331 }
 332 ],
 333 rsync_cv_MAKEDEV_TAKES_3_ARGS=yes,rsync_cv_MAKEDEV_TAKES_3_ARGS=no,rsync_cv_MAKEDEV_TAKES_3_ARGS=no)])
 334 if test x"$rsync_cv_MAKEDEV_TAKES_3_ARGS" = x"yes"; then
 335    AC_DEFINE(MAKEDEV_TAKES_3_ARGS, 1, [Define to 1 if makedev() takes 3 args])
 336 fi
 337
 338 AC_CHECK_SIZEOF(int)
 339 AC_CHECK_SIZEOF(long)
 340 AC_CHECK_SIZEOF(long long)
 341 AC_CHECK_SIZEOF(short)
 342 AC_CHECK_SIZEOF(int16_t)
 343 AC_CHECK_SIZEOF(uint16_t)
 344 AC_CHECK_SIZEOF(int32_t)
 345 AC_CHECK_SIZEOF(uint32_t)
 346 AC_CHECK_SIZEOF(int64_t)
 347 AC_CHECK_SIZEOF(off_t)
 348 AC_CHECK_SIZEOF(off64_t)
 349 AC_CHECK_SIZEOF(time_t)
 350
 351 AC_C_INLINE
 352 AC_C_LONG_DOUBLE
 353
 354 AC_TYPE_SIGNAL
 355 AC_TYPE_UID_T
 356 AC_CHECK_TYPES([mode_t,off_t,size_t,pid_t,id_t])
 357 AC_TYPE_GETGROUPS
 358 AC_CHECK_MEMBERS([struct stat.st_rdev])
 359
 360 TYPE_SOCKLEN_T
 361
 362 AC_CACHE_CHECK([for errno in errno.h],rsync_cv_errno, [
 363     AC_TRY_COMPILE([#include <errno.h>],[int i = errno],
 364         rsync_cv_errno=yes,rsync_cv_have_errno_decl=no)])
 365 if test x"$rsync_cv_errno" = x"yes"; then
 366    AC_DEFINE(HAVE_ERRNO_DECL, 1, [Define to 1 if errno is declared in errno.h])
 367 fi
 368
 369 # The following test taken from the cvs sources
 370 # If we can't find connect, try looking in -lsocket, -lnsl, and -linet.
 371 # These need checks to be before checks for any other functions that
 372 #    might be in the same libraries.
 373 # The Irix 5 libc.so has connect and gethostbyname, but Irix 5 also has
 374 # libsocket.so which has a bad implementation of gethostbyname (it
 375 # only looks in /etc/hosts), so we only look for -lsocket if we need
 376 # it.
 377 AC_CHECK_FUNCS(connect)
 378 if test x"$ac_cv_func_connect" = x"no"; then
 379     case "$LIBS" in
 380     *-lnsl*) ;;
 381     *) AC_CHECK_LIB(nsl_s, printf) ;;
 382     esac
 383     case "$LIBS" in
 384     *-lnsl*) ;;
 385     *) AC_CHECK_LIB(nsl, printf) ;;
 386     esac
 387     case "$LIBS" in
 388     *-lsocket*) ;;
 389     *) AC_CHECK_LIB(socket, connect) ;;
 390     esac
 391     case "$LIBS" in
 392     *-linet*) ;;
 393     *) AC_CHECK_LIB(inet, connect) ;;
 394     esac
 395     dnl We can't just call AC_CHECK_FUNCS(connect) here, because the value
 396     dnl has been cached.
 397     if test x"$ac_cv_lib_socket_connect" = x"yes" ||
 398        test x"$ac_cv_lib_inet_connect" = x"yes"; then
 399         # ac_cv_func_connect=yes
 400         # don't!  it would cause AC_CHECK_FUNC to succeed next time configure is run
 401         AC_DEFINE(HAVE_CONNECT, 1, [Define to 1 if you have the "connect" function])
 402     fi
 403 fi
 404
 405 AC_SEARCH_LIBS(inet_ntop, resolv)
 406
 407 # Solaris and HP-UX weirdness:
 408 # Search for libiconv_open (not iconv_open) to discover if -liconv is needed!
 409 AC_SEARCH_LIBS(libiconv_open, iconv)
 410
 411 AC_MSG_CHECKING([for iconv declaration])
 412 AC_CACHE_VAL(am_cv_proto_iconv, [
 413     AC_TRY_COMPILE([
 414 #include <stdlib.h>
 415 #include <iconv.h>
 416 extern
 417 #ifdef __cplusplus
 418 "C"
 419 #endif
 420 #if defined(__STDC__) || defined(__cplusplus)
 421 size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 422 #else
 423 size_t iconv();
 424 #endif
 425 ], [], am_cv_proto_iconv_arg1="", am_cv_proto_iconv_arg1="const")
 426       am_cv_proto_iconv="extern size_t iconv (iconv_t cd, $am_cv_proto_iconv_arg1 char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);"])
 427     am_cv_proto_iconv=`echo "[$]am_cv_proto_iconv" | tr -s ' ' | sed -e 's/( /(/'`
 428 AC_MSG_RESULT([$]{ac_t:-
 429          }[$]am_cv_proto_iconv)
 430 AC_DEFINE_UNQUOTED(ICONV_CONST, $am_cv_proto_iconv_arg1,
 431                    [Define as const if the declaration of iconv() needs const.])
 432
 433 dnl AC_MSG_NOTICE([Looking in libraries: $LIBS])
 434
 435 AC_CHECK_FUNCS(inet_ntop, , [AC_LIBOBJ(lib/inet_ntop)])
 436 AC_CHECK_FUNCS(inet_pton, , [AC_LIBOBJ(lib/inet_pton)])
 437
 438 # Irix 6.5 has getaddrinfo but not the corresponding defines, so use
 439 #   builtin getaddrinfo if one of the defines don't exist
 440 AC_CACHE_CHECK([whether defines needed by getaddrinfo exist],
 441                rsync_cv_HAVE_GETADDR_DEFINES,[
 442                         AC_EGREP_CPP(yes, [
 443                         #include <sys/types.h>
 444                         #include <sys/socket.h>
 445                         #include <netdb.h>
 446                         #ifdef AI_PASSIVE
 447                         yes
 448                         #endif],
 449                         rsync_cv_HAVE_GETADDR_DEFINES=yes,
 450                         rsync_cv_HAVE_GETADDR_DEFINES=no)])
 451 if test x"$rsync_cv_HAVE_GETADDR_DEFINES" = x"yes"; then
 452         # Tru64 UNIX has getaddrinfo() but has it renamed in libc as
 453         # something else so we must include <netdb.h> to get the
 454         # redefinition.
 455         AC_CHECK_FUNCS(getaddrinfo, ,
 456                 [AC_MSG_CHECKING([for getaddrinfo by including <netdb.h>])
 457                 AC_TRY_LINK([#include <sys/types.h>
 458                 #include <sys/socket.h>
 459                 #include <netdb.h>],[getaddrinfo(NULL, NULL, NULL, NULL);],
 460                         [AC_MSG_RESULT([yes])
 461                         AC_DEFINE(HAVE_GETADDRINFO, 1,
 462                                 [Define to 1 if you have the "getaddrinfo" function.])],
 463                         [AC_MSG_RESULT([no])
 464                         AC_LIBOBJ(lib/getaddrinfo)])])
 465         AC_CHECK_FUNCS(getnameinfo, , [AC_LIBOBJ(lib/getnameinfo)])
 466 else
 467         AC_LIBOBJ(lib/getaddrinfo)
 468         AC_LIBOBJ(lib/getnameinfo)
 469 fi
 470
 471 AC_CHECK_MEMBER([struct sockaddr.sa_len],
 472                 [ AC_DEFINE(HAVE_SOCKADDR_LEN, 1, [Do we have sockaddr.sa_len?]) ],
 473                 [],
 474                 [
 475 #include <sys/types.h>
 476 #include <sys/socket.h>
 477 ])
 478
 479 AC_CHECK_MEMBER([struct sockaddr_in.sin_len],
 480                 [ AC_DEFINE(HAVE_SOCKADDR_IN_LEN, 1, [Do we have sockaddr_in.sin_len?]) ],
 481                 [],
 482                 [
 483 #include <sys/types.h>
 484 #include <sys/socket.h>
 485 #include <netinet/in.h>
 486 ])
 487
 488 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
 489                 [ AC_DEFINE(HAVE_SOCKADDR_UN_LEN, 1, [Do we have sockaddr_un.sun_len?]) ],
 490                 [],
 491                 [
 492 #include <sys/types.h>
 493 #include <sys/socket.h>
 494 #include <netinet/in.h>
 495 ])
 496
 497 AC_MSG_CHECKING(struct sockaddr_storage)
 498 AC_TRY_COMPILE([#include <sys/types.h>
 499 #include <sys/socket.h>],
 500 [struct sockaddr_storage x;],
 501         AC_MSG_RESULT(yes)
 502         AC_DEFINE(HAVE_SOCKADDR_STORAGE, 1,
 503                 [Define to 1 if you have struct sockaddr_storage.] ),
 504         AC_MSG_RESULT(no))
 505
 506 AC_CHECK_MEMBER([struct sockaddr_in6.sin6_scope_id],
 507                 [ AC_DEFINE(HAVE_SOCKADDR_IN6_SCOPE_ID, 1, [Do we have sockaddr_in6.sin6_scope_id?]) ],
 508                 [],
 509                 [
 510 #include <sys/types.h>
 511 #include <sys/socket.h>
 512 #include <netinet/in.h>
 513 ])
 514
 515 AC_MSG_CHECKING(struct stat64)
 516 AC_TRY_COMPILE([#include <stdio.h>
 517 #if HAVE_SYS_TYPES_H
 518 # include <sys/types.h>
 519 #endif
 520 #if HAVE_SYS_STAT_H
 521 # include <sys/stat.h>
 522 #endif
 523 #if STDC_HEADERS
 524 # include <stdlib.h>
 525 # include <stddef.h>
 526 #else
 527 # if HAVE_STDLIB_H
 528 #  include <stdlib.h>
 529 # endif
 530 #endif
 531 ],[struct stat64 st;],
 532     AC_MSG_RESULT(yes)
 533         AC_DEFINE(HAVE_STRUCT_STAT64,1,[Define to 1 if you have struct stat64.]),
 534     AC_MSG_RESULT(no))
 535
 536 # if we can't find strcasecmp, look in -lresolv (for Unixware at least)
 537 #
 538 AC_CHECK_FUNCS(strcasecmp)
 539 if test x"$ac_cv_func_strcasecmp" = x"no"; then
 540     AC_CHECK_LIB(resolv, strcasecmp)
 541 fi
 542
 543 AC_CHECK_FUNCS(aclsort)
 544 if test x"$ac_cv_func_aclsort" = x"no"; then
 545     AC_CHECK_LIB(sec, aclsort)
 546 fi
 547
 548 dnl At the moment we don't test for a broken memcmp(), because all we
 549 dnl need to do is test for equality, not comparison, and it seems that
 550 dnl every platform has a memcmp that can do at least that.
 551 dnl AC_FUNC_MEMCMP
 552
 553 AC_FUNC_UTIME_NULL
 554 AC_FUNC_ALLOCA
 555 AC_CHECK_FUNCS(waitpid wait4 getcwd strdup chown chmod lchmod mknod mkfifo \
 556     fchmod fstat ftruncate strchr readlink link utime utimes lutimes strftime \
 557     memmove lchown vsnprintf snprintf vasprintf asprintf setsid glob strpbrk \
 558     strlcat strlcpy strtol mallinfo getgroups setgroups geteuid getegid \
 559     setlocale setmode open64 lseek64 mkstemp64 mtrace va_copy __va_copy \
 560     strerror putenv iconv_open locale_charset nl_langinfo getxattr \
 561     extattr_get_link sigaction sigprocmask setattrlist)
 562
 563 AC_CHECK_FUNCS(getpgrp tcgetpgrp)
 564 if test $ac_cv_func_getpgrp = yes; then
 565     AC_FUNC_GETPGRP
 566 fi
 567
 568 AC_ARG_ENABLE(iconv,
 569     AC_HELP_STRING([--disable-iconv],
 570             [disable rsync's --iconv option]),
 571     [], [enable_iconv=$ac_cv_func_iconv_open])
 572 AH_TEMPLATE([ICONV_OPTION],
 573 [Define if you want the --iconv option.  Specifing a value will set the
 574 default iconv setting (a NULL means no --iconv processing by default).])
 575 if test x"$enable_iconv" != x"no"; then
 576         if test x"$enable_iconv" = x"yes"; then
 577                 AC_DEFINE(ICONV_OPTION, NULL)
 578         else
 579                 AC_DEFINE_UNQUOTED(ICONV_OPTION, "$enable_iconv")
 580         fi
 581         AC_DEFINE(UTF8_CHARSET, "UTF-8", [String to pass to iconv() for the UTF-8 charset.])
 582 fi
 583
 584 AC_CACHE_CHECK([whether chown() modifies symlinks],rsync_cv_chown_modifies_symlink,[
 585   AC_TRY_RUN([
 586 #if HAVE_UNISTD_H
 587 # include <unistd.h>
 588 #endif
 589 #include <stdlib.h>
 590 #include <errno.h>
 591     main() {
 592         char const *dangling_symlink = "conftest.dangle";
 593         unlink(dangling_symlink);
 594         if (symlink("conftest.no-such", dangling_symlink) < 0) abort();
 595         if (chown(dangling_symlink, getuid(), getgid()) < 0 && errno == ENOENT) exit(1);
 596         exit(0);
 597     }],
 598   rsync_cv_chown_modifies_symlink=yes,rsync_cv_chown_modifies_symlink=no,rsync_cv_chown_modifies_symlink=no)])
 599 if test $rsync_cv_chown_modifies_symlink = yes; then
 600   AC_DEFINE(CHOWN_MODIFIES_SYMLINK, 1, [Define to 1 if chown modifies symlinks.])
 601 fi
 602
 603 AC_CACHE_CHECK([whether link() can hard-link symlinks],rsync_cv_can_hardlink_symlink,[
 604   AC_TRY_RUN([
 605 #if HAVE_UNISTD_H
 606 # include <unistd.h>
 607 #endif
 608 #include <stdlib.h>
 609 #include <errno.h>
 610 #define FILENAME "conftest.dangle"
 611     main() {
 612         unlink(FILENAME);
 613         if (symlink("conftest.no-such", FILENAME) < 0) abort();
 614         if (link(FILENAME, FILENAME "2") < 0) exit(1);
 615         exit(0);
 616     }],
 617   rsync_cv_can_hardlink_symlink=yes,rsync_cv_can_hardlink_symlink=no,rsync_cv_can_hardlink_symlink=no)])
 618 if test $rsync_cv_can_hardlink_symlink = yes; then
 619   AC_DEFINE(CAN_HARDLINK_SYMLINK, 1, [Define to 1 if link() can hard-link symlinks.])
 620 fi
 621
 622 AC_CACHE_CHECK([whether link() can hard-link special files],rsync_cv_can_hardlink_special,[
 623   AC_TRY_RUN([
 624 #if HAVE_UNISTD_H
 625 # include <unistd.h>
 626 #endif
 627 #include <stdlib.h>
 628 #include <errno.h>
 629 #define FILENAME "conftest.fifi"
 630     main() {
 631         unlink(FILENAME);
 632         if (mkfifo(FILENAME, 0777) < 0) abort();
 633         if (link(FILENAME, FILENAME "2") < 0) exit(1);
 634         exit(0);
 635     }],
 636   rsync_cv_can_hardlink_special=yes,rsync_cv_can_hardlink_special=no,rsync_cv_can_hardlink_special=no)])
 637 if test $rsync_cv_can_hardlink_special = yes; then
 638     AC_DEFINE(CAN_HARDLINK_SPECIAL, 1, [Define to 1 if link() can hard-link special files.])
 639 fi
 640
 641 AC_CACHE_CHECK([for working socketpair],rsync_cv_HAVE_SOCKETPAIR,[
 642 AC_TRY_RUN([
 643 #include <sys/types.h>
 644 #include <sys/socket.h>
 645
 646 main() {
 647        int fd[2];
 648        exit((socketpair(AF_UNIX, SOCK_STREAM, 0, fd) != -1) ? 0 : 1);
 649 }],
 650 rsync_cv_HAVE_SOCKETPAIR=yes,rsync_cv_HAVE_SOCKETPAIR=no,rsync_cv_HAVE_SOCKETPAIR=cross)])
 651 if test x"$rsync_cv_HAVE_SOCKETPAIR" = x"yes"; then
 652     AC_DEFINE(HAVE_SOCKETPAIR, 1, [Define to 1 if you have the "socketpair" function])
 653 fi
 654
 655 if test x"$with_included_popt" != x"yes"; then
 656     AC_CHECK_LIB(popt, poptGetContext, , [with_included_popt=yes])
 657 fi
 658
 659 AC_MSG_CHECKING([whether to use included libpopt])
 660 if test x"$with_included_popt" = x"yes"; then
 661     AC_MSG_RESULT($srcdir/popt)
 662     BUILD_POPT='$(popt_OBJS)'
 663     CFLAGS="$CFLAGS -I$srcdir/popt"
 664     if test x"$ALLOCA" != x
 665     then
 666         # this can be removed when/if we add an included alloca.c;
 667         #  see autoconf documentation on AC_FUNC_ALLOCA
 668         AC_MSG_WARN([included libpopt will use malloc, not alloca (which wastes a small amount of memory)])
 669     fi
 670 else
 671     AC_MSG_RESULT(no)
 672 fi
 673
 674 AC_CACHE_CHECK([for unsigned char],rsync_cv_SIGNED_CHAR_OK,[
 675 AC_TRY_COMPILE([],[signed char *s = ""],
 676 rsync_cv_SIGNED_CHAR_OK=yes,rsync_cv_SIGNED_CHAR_OK=no)])
 677 if test x"$rsync_cv_SIGNED_CHAR_OK" = x"yes"; then
 678     AC_DEFINE(SIGNED_CHAR_OK, 1, [Define to 1 if "signed char" is a valid type])
 679 fi
 680
 681 AC_CACHE_CHECK([for broken readdir],rsync_cv_HAVE_BROKEN_READDIR,[
 682 AC_TRY_RUN([#include <sys/types.h>
 683 #include <dirent.h>
 684 main() { struct dirent *di; DIR *d = opendir("."); di = readdir(d);
 685 if (di && di->d_name[-2] == '.' && di->d_name[-1] == 0 &&
 686 di->d_name[0] == 0) exit(0); exit(1);} ],
 687 rsync_cv_HAVE_BROKEN_READDIR=yes,rsync_cv_HAVE_BROKEN_READDIR=no,rsync_cv_HAVE_BROKEN_READDIR=cross)])
 688 if test x"$rsync_cv_HAVE_BROKEN_READDIR" = x"yes"; then
 689     AC_DEFINE(HAVE_BROKEN_READDIR, 1, [Define to 1 if readdir() is broken])
 690 fi
 691
 692 AC_CACHE_CHECK([for utimbuf],rsync_cv_HAVE_UTIMBUF,[
 693 AC_TRY_COMPILE([#include <sys/types.h>
 694 #include <utime.h>],
 695 [struct utimbuf tbuf;  tbuf.actime = 0; tbuf.modtime = 1; exit(utime("foo.c",&tbuf));],
 696 rsync_cv_HAVE_UTIMBUF=yes,rsync_cv_HAVE_UTIMBUF=no)])
 697 if test x"$rsync_cv_HAVE_UTIMBUF" = x"yes"; then
 698     AC_DEFINE(HAVE_UTIMBUF, 1, [Define to 1 if you have the "struct utimbuf" type])
 699 fi
 700
 701 AC_CACHE_CHECK([if gettimeofday takes tz argument],rsync_cv_HAVE_GETTIMEOFDAY_TZ,[
 702 AC_TRY_COMPILE([#include <sys/time.h>
 703 #include <unistd.h>],
 704 [struct timeval tv; exit(gettimeofday(&tv, NULL));],
 705 rsync_cv_HAVE_GETTIMEOFDAY_TZ=yes,rsync_cv_HAVE_GETTIMEOFDAY_TZ=no)])
 706 if test x"$rsync_cv_HAVE_GETTIMEOFDAY_TZ" != x"no"; then
 707     AC_DEFINE(HAVE_GETTIMEOFDAY_TZ, 1, [Define to 1 if gettimeofday() takes a time-zone arg])
 708 fi
 709
 710 AC_CACHE_CHECK([for C99 vsnprintf],rsync_cv_HAVE_C99_VSNPRINTF,[
 711 AC_TRY_RUN([
 712 #include <sys/types.h>
 713 #include <stdarg.h>
 714 void foo(const char *format, ...) {
 715        va_list ap;
 716        int len;
 717        char buf[5];
 718
 719        va_start(ap, format);
 720        len = vsnprintf(0, 0, format, ap);
 721        va_end(ap);
 722        if (len != 5) exit(1);
 723
 724        if (snprintf(buf, 3, "hello") != 5 || strcmp(buf, "he") != 0) exit(1);
 725
 726        exit(0);
 727 }
 728 main() { foo("hello"); }
 729 ],
 730 rsync_cv_HAVE_C99_VSNPRINTF=yes,rsync_cv_HAVE_C99_VSNPRINTF=no,rsync_cv_HAVE_C99_VSNPRINTF=cross)])
 731 if test x"$rsync_cv_HAVE_C99_VSNPRINTF" = x"yes"; then
 732     AC_DEFINE(HAVE_C99_VSNPRINTF, 1, [Define to 1 if vsprintf has a C99-compatible return value])
 733 fi
 734
 735
 736 AC_CACHE_CHECK([for secure mkstemp],rsync_cv_HAVE_SECURE_MKSTEMP,[
 737 AC_TRY_RUN([#include <stdlib.h>
 738 #include <sys/types.h>
 739 #include <sys/stat.h>
 740 #include <unistd.h>
 741 main() {
 742   struct stat st;
 743   char tpl[20]="/tmp/test.XXXXXX";
 744   int fd = mkstemp(tpl);
 745   if (fd == -1) exit(1);
 746   unlink(tpl);
 747   if (fstat(fd, &st) != 0) exit(1);
 748   if ((st.st_mode & 0777) != 0600) exit(1);
 749   exit(0);
 750 }],
 751 rsync_cv_HAVE_SECURE_MKSTEMP=yes,
 752 rsync_cv_HAVE_SECURE_MKSTEMP=no,
 753 rsync_cv_HAVE_SECURE_MKSTEMP=cross)])
 754 if test x"$rsync_cv_HAVE_SECURE_MKSTEMP" = x"yes"; then
 755     case $target_os in
 756     hpux*)
 757         dnl HP-UX has a broken mkstemp() implementation they refuse to fix,
 758         dnl so we noisily skip using it.  See HP change request JAGaf34426
 759         dnl for details. (sbonds)
 760         AC_MSG_WARN(Skipping broken HP-UX mkstemp() -- using mktemp() instead)
 761         ;;
 762     *)
 763         AC_DEFINE(HAVE_SECURE_MKSTEMP, 1, [Define to 1 if mkstemp() is available and works right])
 764         ;;
 765     esac
 766 fi
 767
 768
 769 AC_CACHE_CHECK([if mknod creates FIFOs],rsync_cv_MKNOD_CREATES_FIFOS,[
 770 AC_TRY_RUN([
 771 #include <stdio.h>
 772 #include <sys/stat.h>
 773 #include <errno.h>
 774 main() { int rc, ec; char *fn = "fifo-test";
 775 unlink(fn); rc = mknod(fn,S_IFIFO,0600); ec = errno; unlink(fn);
 776 if (rc) {printf("(%d %d) ",rc,ec); return ec;}
 777 return 0;}],
 778            rsync_cv_MKNOD_CREATES_FIFOS=yes,rsync_cv_MKNOD_CREATES_FIFOS=no,rsync_cv_MKNOD_CREATES_FIFOS=cross)])
 779 if test x"$rsync_cv_MKNOD_CREATES_FIFOS" = x"yes"; then
 780     AC_DEFINE(MKNOD_CREATES_FIFOS, 1, [Define to 1 if mknod() can create FIFOs.])
 781 fi
 782
 783 AC_CACHE_CHECK([if mknod creates sockets],rsync_cv_MKNOD_CREATES_SOCKETS,[
 784 AC_TRY_RUN([
 785 #include <stdio.h>
 786 #include <sys/stat.h>
 787 #include <errno.h>
 788 main() { int rc, ec; char *fn = "sock-test";
 789 unlink(fn); rc = mknod(fn,S_IFSOCK,0600); ec = errno; unlink(fn);
 790 if (rc) {printf("(%d %d) ",rc,ec); return ec;}
 791 return 0;}],
 792            rsync_cv_MKNOD_CREATES_SOCKETS=yes,rsync_cv_MKNOD_CREATES_SOCKETS=no,rsync_cv_MKNOD_CREATES_SOCKETS=cross)])
 793 if test x"$rsync_cv_MKNOD_CREATES_SOCKETS" = x"yes"; then
 794     AC_DEFINE(MKNOD_CREATES_SOCKETS, 1, [Define to 1 if mknod() can create sockets.])
 795 fi
 796
 797 #
 798 # The following test was mostly taken from the tcl/tk plus patches
 799 #
 800 AC_CACHE_CHECK([whether -c -o works],rsync_cv_DASHC_WORKS_WITH_DASHO,[
 801 rm -rf conftest*
 802 cat > conftest.$ac_ext <<EOF
 803 int main() { return 0; }
 804 EOF
 805 ${CC-cc} -c -o conftest..o conftest.$ac_ext
 806 if test -f conftest..o; then
 807     rsync_cv_DASHC_WORKS_WITH_DASHO=yes
 808 else
 809     rsync_cv_DASHC_WORKS_WITH_DASHO=no
 810 fi
 811 rm -rf conftest*
 812 ])
 813 if test x"$rsync_cv_DASHC_WORKS_WITH_DASHO" = x"yes"; then
 814     OBJ_SAVE="#"
 815     OBJ_RESTORE="#"
 816     CC_SHOBJ_FLAG='-o $@'
 817 else
 818     OBJ_SAVE='  @b=`basename $@ .o`;rm -f $$b.o.sav;if test -f $$b.o; then mv $$b.o $$b.o.sav;fi;'
 819     OBJ_RESTORE='       @b=`basename $@ .o`;if test "$$b.o" != "$@"; then mv $$b.o $@; if test -f $$b.o.sav; then mv $$b.o.sav $$b.o; fi; fi'
 820     CC_SHOBJ_FLAG=""
 821 fi
 822
 823 AC_SUBST(OBJ_SAVE)
 824 AC_SUBST(OBJ_RESTORE)
 825 AC_SUBST(CC_SHOBJ_FLAG)
 826 AC_SUBST(BUILD_POPT)
 827
 828 AC_CHECK_HEADERS(sys/acl.h acl/libacl.h)
 829 AC_CHECK_FUNCS(_acl __acl _facl __facl)
 830 #################################################
 831 # check for ACL support
 832
 833 AC_MSG_CHECKING([whether to support ACLs])
 834 AC_ARG_ENABLE(acl-support,
 835         AC_HELP_STRING([--disable-acl-support],
 836                        [disable ACL support]))
 837
 838 if test x"$enable_acl_support" = x"no"; then
 839     AC_MSG_RESULT(no)
 840 else
 841     case "$host_os" in
 842     *sysv5*)
 843         AC_MSG_RESULT(Using UnixWare ACLs)
 844         AC_DEFINE(HAVE_UNIXWARE_ACLS, 1, [true if you have UnixWare ACLs])
 845         AC_DEFINE(SUPPORT_ACLS, 1, [Define to 1 to add support for ACLs])
 846         ;;
 847     *solaris*|*cygwin*)
 848         AC_MSG_RESULT(Using solaris ACLs)
 849         AC_DEFINE(HAVE_SOLARIS_ACLS, 1, [true if you have solaris ACLs])
 850         AC_DEFINE(SUPPORT_ACLS, 1)
 851         ;;
 852     *hpux*)
 853         AC_MSG_RESULT(Using HPUX ACLs)
 854         AC_DEFINE(HAVE_HPUX_ACLS, 1, [true if you have HPUX ACLs])
 855         AC_DEFINE(SUPPORT_ACLS, 1)
 856         ;;
 857     *irix*)
 858         AC_MSG_RESULT(Using IRIX ACLs)
 859         AC_DEFINE(HAVE_IRIX_ACLS, 1, [true if you have IRIX ACLs])
 860         AC_DEFINE(SUPPORT_ACLS, 1)
 861         ;;
 862     *aix*)
 863         AC_MSG_RESULT(Using AIX ACLs)
 864         AC_DEFINE(HAVE_AIX_ACLS, 1, [true if you have AIX ACLs])
 865         AC_DEFINE(SUPPORT_ACLS, 1)
 866         ;;
 867     *osf*)
 868         AC_MSG_RESULT(Using Tru64 ACLs)
 869         AC_DEFINE(HAVE_TRU64_ACLS, 1, [true if you have Tru64 ACLs])
 870         AC_DEFINE(SUPPORT_ACLS, 1)
 871         LIBS="$LIBS -lpacl"
 872         ;;
 873     darwin*)
 874         AC_MSG_RESULT(Using OS X ACLs)
 875         AC_DEFINE(HAVE_OSX_ACLS, 1, [true if you have Mac OS X ACLs])
 876         AC_DEFINE(SUPPORT_ACLS, 1)
 877         ;;
 878     *)
 879         AC_MSG_RESULT(running tests:)
 880         AC_CHECK_LIB(acl,acl_get_file)
 881             AC_CACHE_CHECK([for ACL support],samba_cv_HAVE_POSIX_ACLS,[
 882             AC_TRY_LINK([#include <sys/types.h>
 883 #include <sys/acl.h>],
 884 [ acl_t acl; int entry_id; acl_entry_t *entry_p; return acl_get_entry( acl, entry_id, entry_p);],
 885 samba_cv_HAVE_POSIX_ACLS=yes,samba_cv_HAVE_POSIX_ACLS=no)])
 886         AC_MSG_CHECKING(ACL test results)
 887         if test x"$samba_cv_HAVE_POSIX_ACLS" = x"yes"; then
 888             AC_MSG_RESULT(Using posix ACLs)
 889             AC_DEFINE(HAVE_POSIX_ACLS, 1, [true if you have posix ACLs])
 890             AC_DEFINE(SUPPORT_ACLS, 1)
 891             AC_CACHE_CHECK([for acl_get_perm_np],samba_cv_HAVE_ACL_GET_PERM_NP,[
 892                 AC_TRY_LINK([#include <sys/types.h>
 893 #include <sys/acl.h>],
 894 [ acl_permset_t permset_d; acl_perm_t perm; return acl_get_perm_np( permset_d, perm);],
 895 samba_cv_HAVE_ACL_GET_PERM_NP=yes,samba_cv_HAVE_ACL_GET_PERM_NP=no)])
 896             if test x"$samba_cv_HAVE_ACL_GET_PERM_NP" = x"yes"; then
 897                 AC_DEFINE(HAVE_ACL_GET_PERM_NP, 1, [true if you have acl_get_perm_np])
 898             fi
 899         else
 900             if test x"$enable_acl_support" = x"yes"; then
 901                 AC_MSG_ERROR(Failed to find ACL support)
 902             else
 903                 AC_MSG_RESULT(No ACL support found)
 904             fi
 905         fi
 906         ;;
 907     esac
 908 fi
 909
 910 AC_CHECK_HEADERS(attr/xattr.h)
 911 AC_CHECK_HEADERS(sys/xattr.h)
 912 AC_CHECK_HEADERS(sys/extattr.h)
 913
 914 #################################################
 915 # check for extended attribute support
 916 AC_MSG_CHECKING(whether to support extended attributes)
 917 AC_ARG_ENABLE(xattr-support,
 918     AC_HELP_STRING([--disable-xattr-support],
 919             [disable extended attributes]),
 920     [], [case "$ac_cv_func_getxattr$ac_cv_func_extattr_get_link" in
 921         *yes*) enable_xattr_support=maybe ;;
 922         *) enable_xattr_support=no ;;
 923         esac])
 924 AH_TEMPLATE([SUPPORT_XATTRS],
 925 [Define to 1 to add support for extended attributes])
 926 if test x"$enable_xattr_support" = x"no"; then
 927     AC_MSG_RESULT(no)
 928 else
 929     case "$host_os" in
 930     *linux*)
 931         AC_MSG_RESULT(Using Linux xattrs)
 932         AC_DEFINE(HAVE_LINUX_XATTRS, 1, [True if you have Linux xattrs])
 933         AC_DEFINE(SUPPORT_XATTRS, 1)
 934         ;;
 935     darwin*)
 936         AC_MSG_RESULT(Using OS X xattrs)
 937         AC_DEFINE(HAVE_OSX_XATTRS, 1, [True if you have Mac OS X xattrs])
 938         AC_DEFINE(SUPPORT_XATTRS, 1)
 939         ;;
 940     freebsd*)
 941         AC_MSG_RESULT(Using FreeBSD extattrs)
 942         AC_DEFINE(HAVE_FREEBSD_XATTRS, 1, [True if you have FreeBSD xattrs])
 943         AC_DEFINE(SUPPORT_XATTRS, 1)
 944         ;;
 945     *)
 946         if test x"$enable_xattr_support" = x"yes"; then
 947             AC_MSG_ERROR(Failed to find extended attribute support)
 948         else
 949             AC_MSG_RESULT(No extended attribute support found)
 950         fi
 951         ;;
 952     esac
 953 fi
 954
 955 AC_CONFIG_FILES([Makefile lib/dummy zlib/dummy popt/dummy shconfig])
 956 AC_OUTPUT
 957
 958 AC_MSG_RESULT()
 959 AC_MSG_RESULT([    rsync ${RSYNC_VERSION} configuration successful])
 960 AC_MSG_RESULT()