configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_INIT([rsync],[3.2.0dev],[http://rsync.samba.org/bugzilla.html])
   4
   5 AC_CONFIG_MACRO_DIR([m4])
   6 AC_CONFIG_SRCDIR([byteorder.h])
   7 AC_CONFIG_HEADER(config.h)
   8 AC_PREREQ([2.69])
   9
  10 AC_SUBST(RSYNC_VERSION, $PACKAGE_VERSION)
  11 AC_MSG_NOTICE([Configuring rsync $PACKAGE_VERSION])
  12
  13 AC_DEFINE_UNQUOTED(RSYNC_VERSION, ["$PACKAGE_VERSION"], [rsync release version])
  14
  15 LDFLAGS=${LDFLAGS-""}
  16
  17 AC_CANONICAL_HOST
  18
  19 dnl define the directory for replacement function since AC_LIBOBJ does not
  20 dnl officially support subdirs and fails with automake
  21 AC_CONFIG_LIBOBJ_DIR([lib])
  22
  23 # We must decide this before testing the compiler.
  24
  25 # Please allow this to default to yes, so that your users have more
  26 # chance of getting a useful stack trace if problems occur.
  27
  28 AC_MSG_CHECKING([whether to include debugging symbols])
  29 AC_ARG_ENABLE(debug,
  30         AS_HELP_STRING([--disable-debug],[disable debugging symbols and features]))
  31
  32 if test x"$enable_debug" = x"no"; then
  33     AC_MSG_RESULT(no)
  34     ac_cv_prog_cc_g=no
  35 else
  36     AC_MSG_RESULT([yes])
  37     dnl AC_DEFINE(DEBUG, 1, [Define to turn on debugging code that may slow normal operation])
  38     # leave ac_cv_prog_cc_g alone; AC_PROG_CC will try to include -g if it can
  39 fi
  40
  41 dnl Checks for programs.
  42 AC_PROG_CC
  43 AC_PROG_CPP
  44 AC_PROG_CXX
  45 AC_PROG_EGREP
  46 AC_PROG_INSTALL
  47 AC_PROG_MKDIR_P
  48 AC_PROG_CC_STDC
  49 AC_SUBST(SHELL)
  50 AC_PATH_PROG([PERL], [perl])
  51
  52 AC_DEFINE([_GNU_SOURCE], 1,
  53           [Define _GNU_SOURCE so that we get all necessary prototypes])
  54
  55 if test x"$ac_cv_prog_cc_stdc" = x"no"; then
  56         AC_MSG_WARN([rsync requires an ANSI C compiler and you do not seem to have one])
  57 fi
  58
  59 AC_ARG_ENABLE(profile,
  60         AS_HELP_STRING([--enable-profile],[turn on CPU profiling]))
  61 if test x"$enable_profile" = x"yes"; then
  62         CFLAGS="$CFLAGS -pg"
  63 fi
  64
  65
  66 # Specifically, this turns on panic_action handling.
  67 AC_ARG_ENABLE(maintainer-mode,
  68         AS_HELP_STRING([--enable-maintainer-mode],[turn on extra debug features]))
  69 if test x"$enable_maintainer_mode" = x"yes"; then
  70         CFLAGS="$CFLAGS -DMAINTAINER_MODE"
  71 fi
  72
  73
  74 # This is needed for our included version of popt.  Kind of silly, but
  75 # I don't want our version too far out of sync.
  76 CFLAGS="$CFLAGS -DHAVE_CONFIG_H"
  77
  78 # If GCC, turn on warnings.
  79 if test x"$GCC" = x"yes"; then
  80         CFLAGS="$CFLAGS -Wall -W"
  81 fi
  82
  83 AC_ARG_WITH(included-popt,
  84         AS_HELP_STRING([--with-included-popt],[use bundled popt library, not from system]))
  85
  86 AC_ARG_WITH(included-zlib,
  87         AS_HELP_STRING([--with-included-zlib],[use bundled zlib library, not from system]))
  88
  89 AC_ARG_WITH(protected-args,
  90         AS_HELP_STRING([--with-protected-args],[make --protected-args option the default]))
  91 if test x"$with_protected_args" = x"yes"; then
  92         AC_DEFINE_UNQUOTED(RSYNC_USE_PROTECTED_ARGS, 1, [Define to 1 if --protected-args should be the default])
  93 fi
  94
  95 AC_ARG_WITH(rsync-path,
  96         AS_HELP_STRING([--with-rsync-path=PATH],[set default --rsync-path to PATH (default: rsync)]),
  97         [ RSYNC_PATH="$with_rsync_path" ],
  98         [ RSYNC_PATH="rsync" ])
  99
 100 AC_DEFINE_UNQUOTED(RSYNC_PATH, "$RSYNC_PATH", [location of rsync on remote machine])
 101
 102 AC_ARG_WITH(rsyncd-conf,
 103         AS_HELP_STRING([--with-rsyncd-conf=PATH],[set configuration file for rsync server to PATH (default: /etc/rsyncd.conf)]),
 104         [ if test ! -z "$with_rsyncd_conf" ; then
 105                 case $with_rsyncd_conf in
 106                         yes|no)
 107                                 RSYNCD_SYSCONF="/etc/rsyncd.conf"
 108                                 ;;
 109                         /*)
 110                                 RSYNCD_SYSCONF="$with_rsyncd_conf"
 111                                 ;;
 112                         *)
 113                                 AC_MSG_ERROR(You must specify an absolute path to --with-rsyncd-conf=PATH)
 114                                 ;;
 115                 esac
 116         else
 117                 RSYNCD_SYSCONF="/etc/rsyncd.conf"
 118         fi ],
 119         [ RSYNCD_SYSCONF="/etc/rsyncd.conf" ])
 120
 121 AC_DEFINE_UNQUOTED(RSYNCD_SYSCONF, "$RSYNCD_SYSCONF", [location of configuration file for rsync server])
 122
 123 AC_ARG_WITH(rsh,
 124         AS_HELP_STRING([--with-rsh=CMD],[set remote shell command to CMD (default: ssh)]))
 125
 126 AC_CHECK_PROG(HAVE_REMSH, remsh, 1, 0)
 127 if test x$HAVE_REMSH = x1; then
 128         AC_DEFINE(HAVE_REMSH, 1, [Define to 1 if remote shell is remsh, not rsh])
 129 fi
 130
 131 if test x"$with_rsh" != x; then
 132         RSYNC_RSH="$with_rsh"
 133 else
 134         RSYNC_RSH="ssh"
 135 fi
 136 AC_DEFINE_UNQUOTED(RSYNC_RSH, "$RSYNC_RSH", [default -e command])
 137
 138 AC_CHECK_PROG(HAVE_YODL2MAN, yodl2man, 1, 0)
 139 if test x$HAVE_YODL2MAN = x1; then
 140     MAKE_MAN=man
 141 else
 142     MAKE_MAN=man-copy
 143 fi
 144
 145 # Some programs on solaris are only found in /usr/xpg4/bin (or work better than others versions).
 146 AC_PATH_PROG(SHELL_PATH, sh, /bin/sh, [/usr/xpg4/bin$PATH_SEPARATOR$PATH])
 147 AC_PATH_PROG(FAKEROOT_PATH, fakeroot, /usr/bin/fakeroot, [/usr/xpg4/bin$PATH_SEPARATOR$PATH])
 148
 149 AC_ARG_WITH(nobody-group,
 150     AS_HELP_STRING([--with-nobody-group=GROUP],[set the default unprivileged group (default nobody or nogroup)]),
 151     [ NOBODY_GROUP="$with_nobody_group" ])
 152
 153 if test x"$with_nobody_group" = x; then
 154     AC_MSG_CHECKING([the group for user "nobody"])
 155     if grep '^nobody:' /etc/group >/dev/null 2>&1; then
 156         NOBODY_GROUP=nobody
 157     elif grep '^nogroup:' /etc/group >/dev/null 2>&1; then
 158         NOBODY_GROUP=nogroup
 159     else
 160         NOBODY_GROUP=nobody # test for others?
 161     fi
 162     AC_MSG_RESULT($NOBODY_GROUP)
 163 fi
 164
 165 AC_DEFINE_UNQUOTED(NOBODY_USER, "nobody", [unprivileged user--e.g. nobody])
 166 AC_DEFINE_UNQUOTED(NOBODY_GROUP, "$NOBODY_GROUP", [unprivileged group for unprivileged user])
 167
 168 # SIMD optimizations
 169 SIMD=
 170
 171 AC_MSG_CHECKING([whether to enable SIMD optimizations])
 172 AC_ARG_ENABLE(simd,
 173     AS_HELP_STRING([--enable-simd],[enable SIMD optimizations]))
 174
 175 if test x"$enable_simd" = x"yes"; then
 176     # For x86-64 SIMD, g++ is also required
 177     if test x"$build_cpu" = x"x86_64" && test x"$CXX" = x"g++"; then
 178         SIMD="$SIMD x86_64"
 179     fi
 180 fi
 181
 182 if test x"$SIMD" != x""; then
 183     SIMD=`echo "$SIMD" | sed -e 's/^ *//'`
 184     AC_MSG_RESULT([yes ($SIMD)])
 185         AC_DEFINE(HAVE_SIMD, 1, [Define to 1 to enable SIMD optimizations])
 186     SIMD=`echo "$SIMD" | sed -e 's/[[^ ]]\+/$(SIMD_&)/g'`
 187 else
 188     AC_MSG_RESULT(no)
 189 fi
 190
 191 AC_SUBST(SIMD)
 192
 193 # We only use g++ for its target attribute dispatching, disable unneeded bulky features
 194 if test x"$CXXOBJ" != x""; then
 195     CXXFLAGS="$CXXFLAGS -fno-exceptions -fno-rtti"
 196 fi
 197
 198 # arrgh. libc in some old debian version screwed up the largefile
 199 # stuff, getting byte range locking wrong
 200 AC_CACHE_CHECK([for broken largefile support],rsync_cv_HAVE_BROKEN_LARGEFILE,[
 201 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 202 #define _FILE_OFFSET_BITS 64
 203 #include <stdio.h>
 204 #include <fcntl.h>
 205 #include <sys/types.h>
 206 #include <sys/wait.h>
 207 #if HAVE_UNISTD_H
 208 #include <unistd.h>
 209 #endif
 210
 211 int main(void)
 212 {
 213         struct flock lock;
 214         int status;
 215         char tpl[32] = "/tmp/locktest.XXXXXX";
 216         int fd = mkstemp(tpl);
 217         if (fd < 0) {
 218                 strcpy(tpl, "conftest.dat");
 219                 fd = open(tpl, O_CREAT|O_RDWR, 0600);
 220         }
 221
 222         lock.l_type = F_WRLCK;
 223         lock.l_whence = SEEK_SET;
 224         lock.l_start = 0;
 225         lock.l_len = 1;
 226         lock.l_pid = 0;
 227         fcntl(fd,F_SETLK,&lock);
 228         if (fork() == 0) {
 229                 lock.l_start = 1;
 230                 _exit(fcntl(fd,F_SETLK,&lock) == 0);
 231         }
 232         wait(&status);
 233         unlink(tpl);
 234         return WEXITSTATUS(status);
 235 }
 236 ]])],[rsync_cv_HAVE_BROKEN_LARGEFILE=yes],[rsync_cv_HAVE_BROKEN_LARGEFILE=no],[rsync_cv_HAVE_BROKEN_LARGEFILE=cross])])
 237 if test x"$rsync_cv_HAVE_BROKEN_LARGEFILE" != x"yes"; then
 238    AC_SYS_LARGEFILE
 239 fi
 240
 241 ipv6type=unknown
 242 ipv6lib=none
 243 ipv6trylibc=yes
 244
 245 AC_ARG_ENABLE(ipv6,
 246         AS_HELP_STRING([--disable-ipv6],[do not even try to use IPv6]))
 247 if test x"$enable_ipv6" != x"no"; then
 248         AC_MSG_CHECKING([ipv6 stack type])
 249         for i in inria kame linux-glibc linux-inet6 solaris toshiba v6d zeta cygwin; do
 250                 case $i in
 251                 inria)
 252                         # http://www.kame.net/
 253                         AC_EGREP_CPP(yes, [
 254 #include <netinet/in.h>
 255 #ifdef IPV6_INRIA_VERSION
 256 yes
 257 #endif],
 258                                 [ipv6type=$i;
 259                                 AC_DEFINE(INET6, 1, [true if you have IPv6])
 260                                 ])
 261                         ;;
 262                 kame)
 263                         # http://www.kame.net/
 264                         AC_EGREP_CPP(yes, [
 265 #include <netinet/in.h>
 266 #ifdef __KAME__
 267 yes
 268 #endif],
 269                                 [ipv6type=$i;
 270                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 271                         ;;
 272                 linux-glibc)
 273                         # http://www.v6.linux.or.jp/
 274                         AC_EGREP_CPP(yes, [
 275 #include <features.h>
 276 #if defined(__GLIBC__) && __GLIBC__ >= 2 && __GLIBC_MINOR__ >= 1
 277 yes
 278 #endif],
 279                                 [ipv6type=$i;
 280 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 281                         ;;
 282                 linux-inet6)
 283                         # http://www.v6.linux.or.jp/
 284                         if test -d /usr/inet6 -o -f /usr/inet6/lib/libinet6.a; then
 285                                 ipv6type=$i
 286                                 ipv6lib=inet6
 287                                 ipv6libdir=/usr/inet6/lib
 288                                 ipv6trylibc=yes;
 289                                 AC_DEFINE(INET6, 1, [true if you have IPv6])
 290                                 CFLAGS="-I/usr/inet6/include $CFLAGS"
 291                         fi
 292                         ;;
 293                 solaris)
 294                         # http://www.sun.com
 295                         AC_EGREP_CPP(yes, [
 296 #include <netinet/ip6.h>
 297 #ifdef __sun
 298 yes
 299 #endif],
 300                                 [ipv6type=$i;
 301                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 302                         ;;
 303                 toshiba)
 304                         AC_EGREP_CPP(yes, [
 305 #include <sys/param.h>
 306 #ifdef _TOSHIBA_INET6
 307 yes
 308 #endif],
 309                                 [ipv6type=$i;
 310                                 ipv6lib=inet6;
 311                                 ipv6libdir=/usr/local/v6/lib;
 312                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 313                         ;;
 314                 v6d)
 315                         AC_EGREP_CPP(yes, [
 316 #include </usr/local/v6/include/sys/v6config.h>
 317 #ifdef __V6D__
 318 yes
 319 #endif],
 320                                 [ipv6type=$i;
 321                                 ipv6lib=v6;
 322                                 ipv6libdir=/usr/local/v6/lib;
 323                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 324                         ;;
 325                 zeta)
 326                         AC_EGREP_CPP(yes, [
 327 #include <sys/param.h>
 328 #ifdef _ZETA_MINAMI_INET6
 329 yes
 330 #endif],
 331                                 [ipv6type=$i;
 332                                 ipv6lib=inet6;
 333                                 ipv6libdir=/usr/local/v6/lib;
 334                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 335                         ;;
 336                 cygwin)
 337                         AC_EGREP_CPP(yes, [
 338 #include <netinet/in.h>
 339 #ifdef _CYGWIN_IN6_H
 340 yes
 341 #endif],
 342                                 [ipv6type=$i;
 343                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 344                         ;;
 345                 esac
 346                 if test "$ipv6type" != "unknown"; then
 347                         break
 348                 fi
 349         done
 350         AC_MSG_RESULT($ipv6type)
 351
 352         AC_SEARCH_LIBS(getaddrinfo, inet6)
 353 fi
 354
 355 dnl Do you want to disable use of locale functions
 356 AC_ARG_ENABLE([locale],
 357         AS_HELP_STRING([--disable-locale],[disable locale features]))
 358 AH_TEMPLATE([CONFIG_LOCALE],
 359 [Undefine if you do not want locale features.  By default this is defined.])
 360 if test x"$enable_locale" != x"no"; then
 361         AC_DEFINE(CONFIG_LOCALE)
 362 fi
 363
 364 AC_MSG_CHECKING([whether to call shutdown on all sockets])
 365 case $host_os in
 366         *cygwin* ) AC_MSG_RESULT(yes)
 367                    AC_DEFINE(SHUTDOWN_ALL_SOCKETS, 1,
 368                             [Define to 1 if sockets need to be shutdown])
 369                    ;;
 370                * ) AC_MSG_RESULT(no);;
 371 esac
 372
 373 AC_C_BIGENDIAN
 374 AC_HEADER_DIRENT
 375 AC_HEADER_TIME
 376 AC_HEADER_SYS_WAIT
 377 AC_CHECK_HEADERS(sys/fcntl.h sys/select.h fcntl.h sys/time.h sys/unistd.h \
 378     unistd.h utime.h grp.h compat.h sys/param.h ctype.h sys/wait.h \
 379     sys/ioctl.h sys/filio.h string.h stdlib.h sys/socket.h sys/mode.h \
 380     sys/un.h sys/attr.h mcheck.h arpa/inet.h arpa/nameser.h locale.h \
 381     netdb.h malloc.h float.h limits.h iconv.h libcharset.h langinfo.h \
 382     sys/acl.h acl/libacl.h attr/xattr.h sys/xattr.h sys/extattr.h \
 383     popt.h popt/popt.h linux/falloc.h netinet/in_systm.h netinet/ip.h \
 384     zlib.h xxhash.h openssl/md4.h openssl/md5.h zstd.h lz4.h)
 385 AC_HEADER_MAJOR_FIXED
 386
 387 AC_MSG_CHECKING([whether to enable use of openssl crypto library])
 388 AC_ARG_ENABLE([openssl],
 389         AS_HELP_STRING([--disable-openssl],[disable openssl crypto library]))
 390 AH_TEMPLATE([USE_OPENSSL],
 391 [Undefine if you do not want to use openssl crypto library.  By default this is defined.])
 392 if test x"$enable_openssl" != x"no" && test x"$ac_cv_header_openssl_md4_h" = x"yes" && test x"$ac_cv_header_openssl_md5_h" = x"yes"; then
 393     AC_MSG_RESULT(yes)
 394     AC_SEARCH_LIBS(MD5_Init, crypto, [AC_DEFINE(USE_OPENSSL)])
 395 else
 396     AC_MSG_RESULT(no)
 397 fi
 398
 399 AC_MSG_CHECKING([whether to enable xxhash checksum support])
 400 AC_ARG_ENABLE([xxhash],
 401         AS_HELP_STRING([--disable-xxhash],[disable xxhash checksums]))
 402 AH_TEMPLATE([SUPPORT_XXHASH],
 403 [Undefine if you do not want xxhash checksums.  By default this is defined.])
 404 if test x"$enable_xxhash" != x"no" && test x"$ac_cv_header_xxhash_h" = x"yes"; then
 405     AC_MSG_RESULT(yes)
 406     AC_SEARCH_LIBS(XXH64_createState, xxhash, [AC_DEFINE(SUPPORT_XXHASH)])
 407 else
 408     AC_MSG_RESULT(no)
 409 fi
 410
 411 AC_MSG_CHECKING([whether to enable zstd compression])
 412 AC_ARG_ENABLE([zstd],
 413         AC_HELP_STRING([--disable-zstd], [disable zstd compression]))
 414 AH_TEMPLATE([SUPPORT_ZSTD],
 415 [Undefine if you do not want zstd compression.  By default this is defined.])
 416 if test x"$enable_zstd" != x"no" && test x"$ac_cv_header_zstd_h" = x"yes"; then
 417     AC_MSG_RESULT(yes)
 418     AC_SEARCH_LIBS(ZSTD_minCLevel, zstd, [AC_DEFINE(SUPPORT_ZSTD)])
 419 else
 420     AC_MSG_RESULT(no)
 421 fi
 422
 423 AC_MSG_CHECKING([whether to enable LZ4 compression])
 424 AC_ARG_ENABLE([lz4],
 425         AC_HELP_STRING([--disable-lz4], [disable LZ4 compression]))
 426 AH_TEMPLATE([SUPPORT_LZ4],
 427 [Undefine if you do not want LZ4 compression.  By default this is defined.])
 428 if test x"$enable_lz4" != x"no" && test x"$ac_cv_header_lz4_h" = x"yes"; then
 429     AC_MSG_RESULT(yes)
 430     AC_SEARCH_LIBS(LZ4_compress, lz4, [AC_DEFINE(SUPPORT_LZ4)])
 431 else
 432     AC_MSG_RESULT(no)
 433 fi
 434
 435 AC_CACHE_CHECK([if makedev takes 3 args],rsync_cv_MAKEDEV_TAKES_3_ARGS,[
 436 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 437 #include <sys/types.h>
 438 #ifdef MAJOR_IN_MKDEV
 439 #include <sys/mkdev.h>
 440 # if !defined makedev && (defined mkdev || defined _WIN32 || defined __WIN32__)
 441 #  define makedev mkdev
 442 # endif
 443 #elif defined MAJOR_IN_SYSMACROS
 444 #include <sys/sysmacros.h>
 445 #endif
 446
 447 int main(void)
 448 {
 449         dev_t dev = makedev(0, 5, 7);
 450         if (major(dev) != 5 || minor(dev) != 7)
 451                 return 1;
 452         return 0;
 453 }
 454 ]])],[rsync_cv_MAKEDEV_TAKES_3_ARGS=yes],[rsync_cv_MAKEDEV_TAKES_3_ARGS=no],[rsync_cv_MAKEDEV_TAKES_3_ARGS=no])])
 455 if test x"$rsync_cv_MAKEDEV_TAKES_3_ARGS" = x"yes"; then
 456    AC_DEFINE(MAKEDEV_TAKES_3_ARGS, 1, [Define to 1 if makedev() takes 3 args])
 457 fi
 458
 459 AC_CHECK_SIZEOF(int)
 460 AC_CHECK_SIZEOF(long)
 461 AC_CHECK_SIZEOF(long long)
 462 AC_CHECK_SIZEOF(short)
 463 AC_CHECK_SIZEOF(int16_t)
 464 AC_CHECK_SIZEOF(uint16_t)
 465 AC_CHECK_SIZEOF(int32_t)
 466 AC_CHECK_SIZEOF(uint32_t)
 467 AC_CHECK_SIZEOF(int64_t)
 468 AC_CHECK_SIZEOF(off_t)
 469 AC_CHECK_SIZEOF(off64_t)
 470 AC_CHECK_SIZEOF(time_t)
 471 AC_CHECK_SIZEOF(char*)
 472
 473 AC_C_INLINE
 474
 475 AC_TYPE_LONG_DOUBLE_WIDER
 476 ac_cv_c_long_double=$ac_cv_type_long_double_wider
 477 if test $ac_cv_c_long_double = yes; then
 478   AC_DEFINE([HAVE_LONG_DOUBLE],[1],[Define to 1 if the type `long double' works and has more range or precision than `double'.])
 479 fi
 480
 481 AC_TYPE_UID_T
 482 AC_CHECK_TYPES([mode_t,off_t,size_t,pid_t,id_t])
 483 AC_TYPE_GETGROUPS
 484 AC_CHECK_MEMBERS([struct stat.st_rdev,
 485                   struct stat.st_mtimensec,
 486                   struct stat.st_mtimespec.tv_nsec,
 487                   struct stat.st_mtim.tv_nsec],,,[
 488 #ifdef HAVE_SYS_TYPES_H
 489 #include <sys/types.h>
 490 #endif
 491 #ifdef HAVE_SYS_STAT_H
 492 #include <sys/stat.h>
 493 #endif
 494 #ifdef HAVE_UNISTD_H
 495 #include <unistd.h>
 496 #endif])
 497
 498 TYPE_SOCKLEN_T
 499
 500 AC_CACHE_CHECK([for errno in errno.h],rsync_cv_errno, [
 501     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <errno.h>]], [[int i = errno]])],[rsync_cv_errno=yes],[rsync_cv_have_errno_decl=no])])
 502 if test x"$rsync_cv_errno" = x"yes"; then
 503    AC_DEFINE(HAVE_ERRNO_DECL, 1, [Define to 1 if errno is declared in errno.h])
 504 fi
 505
 506 # The following test taken from the cvs sources
 507 # If we can't find connect, try looking in -lsocket, -lnsl, and -linet.
 508 # These need checks to be before checks for any other functions that
 509 #    might be in the same libraries.
 510 # The Irix 5 libc.so has connect and gethostbyname, but Irix 5 also has
 511 # libsocket.so which has a bad implementation of gethostbyname (it
 512 # only looks in /etc/hosts), so we only look for -lsocket if we need
 513 # it.
 514 AC_CHECK_FUNCS(connect)
 515 if test x"$ac_cv_func_connect" = x"no"; then
 516     case "$LIBS" in
 517     *-lnsl*) ;;
 518     *) AC_CHECK_LIB(nsl_s, printf) ;;
 519     esac
 520     case "$LIBS" in
 521     *-lnsl*) ;;
 522     *) AC_CHECK_LIB(nsl, printf) ;;
 523     esac
 524     case "$LIBS" in
 525     *-lsocket*) ;;
 526     *) AC_CHECK_LIB(socket, connect) ;;
 527     esac
 528     case "$LIBS" in
 529     *-linet*) ;;
 530     *) AC_CHECK_LIB(inet, connect) ;;
 531     esac
 532     dnl We can't just call AC_CHECK_FUNCS(connect) here, because the value
 533     dnl has been cached.
 534     if test x"$ac_cv_lib_socket_connect" = x"yes" ||
 535        test x"$ac_cv_lib_inet_connect" = x"yes"; then
 536         # ac_cv_func_connect=yes
 537         # don't!  it would cause AC_CHECK_FUNC to succeed next time configure is run
 538         AC_DEFINE(HAVE_CONNECT, 1, [Define to 1 if you have the "connect" function])
 539     fi
 540 fi
 541
 542 AC_SEARCH_LIBS(inet_ntop, resolv)
 543
 544 # For OS X, Solaris, HP-UX, etc.: figure out if -liconv is needed.  We'll
 545 # accept either iconv_open or libiconv_open, since some include files map
 546 # the former to the latter.
 547 AC_SEARCH_LIBS(iconv_open, iconv)
 548 AC_SEARCH_LIBS(libiconv_open, iconv)
 549
 550 AC_MSG_CHECKING([for iconv declaration])
 551 AC_CACHE_VAL(am_cv_proto_iconv, [
 552     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 553 #include <stdlib.h>
 554 #include <iconv.h>
 555 extern
 556 #ifdef __cplusplus
 557 "C"
 558 #endif
 559 #if defined(__STDC__) || defined(__cplusplus)
 560 size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 561 #else
 562 size_t iconv();
 563 #endif
 564 ]], [[]])],[am_cv_proto_iconv_arg1=""],[am_cv_proto_iconv_arg1="const"])
 565       am_cv_proto_iconv="extern size_t iconv (iconv_t cd, $am_cv_proto_iconv_arg1 char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);"])
 566     am_cv_proto_iconv=`echo "[$]am_cv_proto_iconv" | tr -s ' ' | sed -e 's/( /(/'`
 567 AC_MSG_RESULT([$]{ac_t:-
 568          }[$]am_cv_proto_iconv)
 569 AC_DEFINE_UNQUOTED(ICONV_CONST, $am_cv_proto_iconv_arg1,
 570                    [Define as const if the declaration of iconv() needs const.])
 571
 572 dnl AC_MSG_NOTICE([Looking in libraries: $LIBS])
 573
 574 AC_REPLACE_FUNCS([inet_ntop inet_pton])
 575
 576 AC_HAVE_TYPE([struct addrinfo], [#include <netdb.h>])
 577 AC_HAVE_TYPE([struct sockaddr_storage], [#include <sys/types.h>
 578 #include <sys/socket.h>])
 579
 580 # Irix 6.5 has getaddrinfo but not the corresponding defines, so use
 581 #   builtin getaddrinfo if one of the defines don't exist
 582 AC_CACHE_CHECK([whether defines needed by getaddrinfo exist],
 583                rsync_cv_HAVE_GETADDR_DEFINES,[
 584                         AC_EGREP_CPP(yes, [
 585                         #include <sys/types.h>
 586                         #include <sys/socket.h>
 587                         #include <netdb.h>
 588                         #ifdef AI_PASSIVE
 589                         yes
 590                         #endif],
 591                         rsync_cv_HAVE_GETADDR_DEFINES=yes,
 592                         rsync_cv_HAVE_GETADDR_DEFINES=no)])
 593 AS_IF([test x"$rsync_cv_HAVE_GETADDR_DEFINES" = x"yes" -a x"$ac_cv_type_struct_addrinfo" = x"yes"],[
 594         # Tru64 UNIX has getaddrinfo() but has it renamed in libc as
 595         # something else so we must include <netdb.h> to get the
 596         # redefinition.
 597         AC_CHECK_FUNCS(getaddrinfo, ,
 598                 [AC_MSG_CHECKING([for getaddrinfo by including <netdb.h>])
 599                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 600                 #include <sys/socket.h>
 601                 #include <netdb.h>]], [[getaddrinfo(NULL, NULL, NULL, NULL);]])],[AC_MSG_RESULT([yes])
 602                         AC_DEFINE(HAVE_GETADDRINFO, 1,
 603                                 [Define to 1 if you have the "getaddrinfo" function and required types.])],[AC_MSG_RESULT([no])
 604                         AC_LIBOBJ([getaddrinfo])])])
 605     ],[AC_LIBOBJ([getaddrinfo])])
 606
 607 AC_CHECK_MEMBER([struct sockaddr.sa_len],
 608                 [ AC_DEFINE(HAVE_SOCKADDR_LEN, 1, [Do we have sockaddr.sa_len?]) ],
 609                 [],
 610                 [
 611 #include <sys/types.h>
 612 #include <sys/socket.h>
 613 ])
 614
 615 AC_CHECK_MEMBER([struct sockaddr_in.sin_len],
 616                 [ AC_DEFINE(HAVE_SOCKADDR_IN_LEN, 1, [Do we have sockaddr_in.sin_len?]) ],
 617                 [],
 618                 [
 619 #include <sys/types.h>
 620 #include <sys/socket.h>
 621 #include <netinet/in.h>
 622 ])
 623
 624 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
 625                 [ AC_DEFINE(HAVE_SOCKADDR_UN_LEN, 1, [Do we have sockaddr_un.sun_len?]) ],
 626                 [],
 627                 [
 628 #include <sys/types.h>
 629 #include <sys/socket.h>
 630 #include <netinet/in.h>
 631 ])
 632
 633 AC_CHECK_MEMBER([struct sockaddr_in6.sin6_scope_id],
 634                 [ AC_DEFINE(HAVE_SOCKADDR_IN6_SCOPE_ID, 1, [Do we have sockaddr_in6.sin6_scope_id?]) ],
 635                 [],
 636                 [
 637 #include <sys/types.h>
 638 #include <sys/socket.h>
 639 #include <netinet/in.h>
 640 ])
 641
 642 AC_HAVE_TYPE([struct stat64], [#include <stdio.h>
 643 #if HAVE_SYS_TYPES_H
 644 # include <sys/types.h>
 645 #endif
 646 #if HAVE_SYS_STAT_H
 647 # include <sys/stat.h>
 648 #endif
 649 #if STDC_HEADERS
 650 # include <stdlib.h>
 651 # include <stddef.h>
 652 #else
 653 # if HAVE_STDLIB_H
 654 #  include <stdlib.h>
 655 # endif
 656 #endif
 657 ])
 658
 659 # if we can't find strcasecmp, look in -lresolv (for Unixware at least)
 660 #
 661 AC_CHECK_FUNCS(strcasecmp)
 662 if test x"$ac_cv_func_strcasecmp" = x"no"; then
 663     AC_CHECK_LIB(resolv, strcasecmp)
 664 fi
 665
 666 AC_CHECK_FUNCS(aclsort)
 667 if test x"$ac_cv_func_aclsort" = x"no"; then
 668     AC_CHECK_LIB(sec, aclsort)
 669 fi
 670
 671 dnl At the moment we don't test for a broken memcmp(), because all we
 672 dnl need to do is test for equality, not comparison, and it seems that
 673 dnl every platform has a memcmp that can do at least that.
 674 dnl AC_FUNC_MEMCMP
 675
 676 AC_FUNC_UTIME_NULL
 677 AC_FUNC_ALLOCA
 678 AC_CHECK_FUNCS(waitpid wait4 getcwd strdup chown chmod lchmod mknod mkfifo \
 679     fchmod fstat ftruncate strchr readlink link utime utimes lutimes strftime \
 680     chflags getattrlist \
 681     memmove lchown vsnprintf snprintf vasprintf asprintf setsid strpbrk \
 682     strlcat strlcpy strtol mallinfo getgroups setgroups geteuid getegid \
 683     setlocale setmode open64 lseek64 mkstemp64 mtrace va_copy __va_copy \
 684     seteuid strerror putenv iconv_open locale_charset nl_langinfo getxattr \
 685     extattr_get_link sigaction sigprocmask setattrlist getgrouplist \
 686     initgroups utimensat posix_fallocate attropen setvbuf nanosleep usleep)
 687
 688 dnl cygwin iconv.h defines iconv_open as libiconv_open
 689 if test x"$ac_cv_func_iconv_open" != x"yes"; then
 690     AC_CHECK_FUNC(libiconv_open, [ac_cv_func_iconv_open=yes; AC_DEFINE(HAVE_ICONV_OPEN, 1)])
 691 fi
 692
 693 dnl Preallocation stuff (also fallocate, posix_fallocate function tests above):
 694
 695 AC_CACHE_CHECK([for useable fallocate],rsync_cv_have_fallocate,[
 696 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <fcntl.h>
 697 #include <sys/types.h>]], [[fallocate(0, 0, 0, 0);]])],[rsync_cv_have_fallocate=yes],[rsync_cv_have_fallocate=no])])
 698 if test x"$rsync_cv_have_fallocate" = x"yes"; then
 699     AC_DEFINE(HAVE_FALLOCATE, 1, [Define to 1 if you have the fallocate function and it compiles and links without error])
 700 fi
 701
 702 AC_MSG_CHECKING([for FALLOC_FL_PUNCH_HOLE])
 703 AC_PREPROC_IFELSE([AC_LANG_SOURCE([[
 704         #define _GNU_SOURCE 1
 705         #include <linux/falloc.h>
 706         #ifndef FALLOC_FL_PUNCH_HOLE
 707         #error FALLOC_FL_PUNCH_HOLE is missing
 708         #endif
 709     ]])], [
 710         AC_MSG_RESULT([yes])
 711         AC_DEFINE([HAVE_FALLOC_FL_PUNCH_HOLE], [1], [Define if FALLOC_FL_PUNCH_HOLE is available.])
 712     ], [
 713         AC_MSG_RESULT([no])
 714     ]
 715 )
 716
 717 AC_MSG_CHECKING([for FALLOC_FL_ZERO_RANGE])
 718 AC_PREPROC_IFELSE([AC_LANG_SOURCE([[
 719         #define _GNU_SOURCE 1
 720         #include <linux/falloc.h>
 721         #ifndef FALLOC_FL_ZERO_RANGE
 722         #error FALLOC_FL_ZERO_RANGE is missing
 723         #endif
 724     ]])], [
 725         AC_MSG_RESULT([yes])
 726         AC_DEFINE([HAVE_FALLOC_FL_ZERO_RANGE], [1], [Define if FALLOC_FL_ZERO_RANGE is available.])
 727     ], [
 728         AC_MSG_RESULT([no])
 729     ]
 730 )
 731
 732 AC_CACHE_CHECK([for SYS_fallocate],rsync_cv_have_sys_fallocate,[
 733 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/syscall.h>
 734 #include <unistd.h>
 735 #include <sys/types.h>]], [[syscall(SYS_fallocate, 0, 0, (loff_t)0, (loff_t)0);]])],[rsync_cv_have_sys_fallocate=yes],[rsync_cv_have_sys_fallocate=no])])
 736 if test x"$rsync_cv_have_sys_fallocate" = x"yes"; then
 737     AC_DEFINE(HAVE_SYS_FALLOCATE, 1, [Define to 1 if you have the SYS_fallocate syscall number])
 738 fi
 739
 740 if test x"$ac_cv_func_posix_fallocate" = x"yes"; then
 741     AC_MSG_CHECKING([whether posix_fallocate is efficient])
 742     case $host_os in
 743     *cygwin*)
 744         AC_MSG_RESULT(yes)
 745         AC_DEFINE(HAVE_EFFICIENT_POSIX_FALLOCATE, 1,
 746                   [Define if posix_fallocate is efficient (Cygwin)])
 747         ;;
 748     *)
 749         AC_MSG_RESULT(no)
 750         ;;
 751     esac
 752 fi
 753
 754 dnl End of preallocation stuff
 755
 756 AC_CHECK_FUNCS(getpgrp tcgetpgrp)
 757 if test $ac_cv_func_getpgrp = yes; then
 758     AC_FUNC_GETPGRP
 759 fi
 760
 761 AC_ARG_ENABLE(iconv-open,
 762     AS_HELP_STRING([--disable-iconv-open],[disable all use of iconv_open() function]),
 763     [], [enable_iconv_open=$ac_cv_func_iconv_open])
 764
 765 if test x"$enable_iconv_open" != x"no"; then
 766     AC_DEFINE(USE_ICONV_OPEN, 1, [Define to 1 if you want rsync to make use of iconv_open()])
 767 fi
 768
 769 AC_ARG_ENABLE(iconv,
 770     AS_HELP_STRING([--disable-iconv],[disable rsync's --iconv option]),
 771     [], [enable_iconv=$enable_iconv_open])
 772 AH_TEMPLATE([ICONV_OPTION],
 773 [Define if you want the --iconv option.  Specifing a value will set the
 774 default iconv setting (a NULL means no --iconv processing by default).])
 775 if test x"$enable_iconv" != x"no"; then
 776         if test x"$enable_iconv" = x"yes"; then
 777                 AC_DEFINE(ICONV_OPTION, NULL)
 778         else
 779                 AC_DEFINE_UNQUOTED(ICONV_OPTION, "$enable_iconv")
 780         fi
 781         AC_DEFINE(UTF8_CHARSET, "UTF-8", [String to pass to iconv() for the UTF-8 charset.])
 782 fi
 783
 784 AC_CACHE_CHECK([whether chown() modifies symlinks],rsync_cv_chown_modifies_symlink,[
 785   AC_RUN_IFELSE([AC_LANG_SOURCE([[
 786 #if HAVE_UNISTD_H
 787 # include <unistd.h>
 788 #endif
 789 #include <stdlib.h>
 790 #include <errno.h>
 791 int main(void) {
 792         char const *dangling_symlink = "conftest.dangle";
 793         unlink(dangling_symlink);
 794         if (symlink("conftest.no-such", dangling_symlink) < 0) abort();
 795         if (chown(dangling_symlink, getuid(), getgid()) < 0 && errno == ENOENT) return 1;
 796         return 0;
 797     }]])],[rsync_cv_chown_modifies_symlink=yes],[rsync_cv_chown_modifies_symlink=no],[rsync_cv_chown_modifies_symlink=no])])
 798 if test $rsync_cv_chown_modifies_symlink = yes; then
 799   AC_DEFINE(CHOWN_MODIFIES_SYMLINK, 1, [Define to 1 if chown modifies symlinks.])
 800 fi
 801
 802 AC_CACHE_CHECK([whether link() can hard-link symlinks],rsync_cv_can_hardlink_symlink,[
 803   AC_RUN_IFELSE([AC_LANG_SOURCE([[
 804 #if HAVE_UNISTD_H
 805 # include <unistd.h>
 806 #endif
 807 #include <stdlib.h>
 808 #include <errno.h>
 809 #define FILENAME "conftest.dangle"
 810 int main(void) {
 811         unlink(FILENAME);
 812         if (symlink("conftest.no-such", FILENAME) < 0) abort();
 813         unlink(FILENAME "2");
 814         if (link(FILENAME, FILENAME "2") < 0) return 1;
 815         return 0;
 816     }]])],[rsync_cv_can_hardlink_symlink=yes],[rsync_cv_can_hardlink_symlink=no],[rsync_cv_can_hardlink_symlink=no])])
 817 if test $rsync_cv_can_hardlink_symlink = yes; then
 818   AC_DEFINE(CAN_HARDLINK_SYMLINK, 1, [Define to 1 if link() can hard-link symlinks.])
 819 fi
 820
 821 AC_CACHE_CHECK([whether link() can hard-link special files],rsync_cv_can_hardlink_special,[
 822   AC_RUN_IFELSE([AC_LANG_SOURCE([[
 823 #if HAVE_UNISTD_H
 824 # include <unistd.h>
 825 #endif
 826 #ifdef HAVE_SYS_STAT_H
 827 #include <sys/stat.h>
 828 #endif
 829 #include <stdlib.h>
 830 #include <errno.h>
 831 #define FILENAME "conftest.fifi"
 832 int main(void) {
 833         unlink(FILENAME);
 834         if (mkfifo(FILENAME, 0777) < 0) abort();
 835         unlink(FILENAME "2");
 836         if (link(FILENAME, FILENAME "2") < 0) return 1;
 837         return 0;
 838     }]])],[rsync_cv_can_hardlink_special=yes],[rsync_cv_can_hardlink_special=no],[rsync_cv_can_hardlink_special=no])])
 839 if test $rsync_cv_can_hardlink_special = yes; then
 840     AC_DEFINE(CAN_HARDLINK_SPECIAL, 1, [Define to 1 if link() can hard-link special files.])
 841 fi
 842
 843 AC_CACHE_CHECK([for working socketpair],rsync_cv_HAVE_SOCKETPAIR,[
 844 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 845 #include <sys/types.h>
 846 #include <sys/socket.h>
 847
 848 int main(void) {
 849        int fd[2];
 850        return (socketpair(AF_UNIX, SOCK_STREAM, 0, fd) != -1) ? 0 : 1;
 851 }]])],[rsync_cv_HAVE_SOCKETPAIR=yes],[rsync_cv_HAVE_SOCKETPAIR=no],[rsync_cv_HAVE_SOCKETPAIR=cross])])
 852 if test x"$rsync_cv_HAVE_SOCKETPAIR" = x"yes"; then
 853     AC_DEFINE(HAVE_SOCKETPAIR, 1, [Define to 1 if you have the "socketpair" function])
 854 fi
 855
 856 AC_REPLACE_FUNCS([getpass])
 857
 858 if test x"$with_included_popt" != x"yes"; then
 859     AC_CHECK_LIB(popt, poptGetContext, , [with_included_popt=yes])
 860 fi
 861 if test x"$ac_cv_header_popt_popt_h" = x"yes"; then
 862     # If the system has /usr/include/popt/popt.h, we enable the
 863     # included popt because an attempt to "#include <popt/popt.h>"
 864     # would use our included header file anyway (due to -I.), and
 865     # might conflict with the system popt.
 866     with_included_popt=yes
 867 elif test x"$ac_cv_header_popt_h" != x"yes"; then
 868     with_included_popt=yes
 869 fi
 870
 871 AC_MSG_CHECKING([whether to use included libpopt])
 872 if test x"$with_included_popt" = x"yes"; then
 873     AC_MSG_RESULT($srcdir/popt)
 874     BUILD_POPT='$(popt_OBJS)'
 875     CFLAGS="-I$srcdir/popt $CFLAGS"
 876     if test x"$ALLOCA" != x
 877     then
 878         # this can be removed when/if we add an included alloca.c;
 879         #  see autoconf documentation on AC_FUNC_ALLOCA
 880         AC_MSG_WARN([included libpopt will use malloc, not alloca (which wastes a small amount of memory)])
 881     fi
 882 else
 883     AC_MSG_RESULT(no)
 884 fi
 885
 886 # We default to using our zlib unless --with-included-zlib=no is given.
 887 if test x"$with_included_zlib" != x"no"; then
 888     with_included_zlib=yes
 889 elif test x"$ac_cv_header_zlib_h" != x"yes"; then
 890     with_included_zlib=yes
 891 fi
 892 if test x"$with_included_zlib" != x"yes"; then
 893     AC_CHECK_LIB(z, deflateParams, , [with_included_zlib=yes])
 894 fi
 895
 896 AC_MSG_CHECKING([whether to use included zlib])
 897 if test x"$with_included_zlib" = x"yes"; then
 898     AC_MSG_RESULT($srcdir/zlib)
 899     BUILD_ZLIB='$(zlib_OBJS)'
 900     CFLAGS="-I$srcdir/zlib $CFLAGS"
 901 else
 902     AC_DEFINE(EXTERNAL_ZLIB, 1, [Define to 1 if using external zlib])
 903     AC_MSG_RESULT(no)
 904 fi
 905
 906 AC_CACHE_CHECK([for unsigned char],rsync_cv_SIGNED_CHAR_OK,[
 907 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[signed char *s = ""]])],[rsync_cv_SIGNED_CHAR_OK=yes],[rsync_cv_SIGNED_CHAR_OK=no])])
 908 if test x"$rsync_cv_SIGNED_CHAR_OK" = x"yes"; then
 909     AC_DEFINE(SIGNED_CHAR_OK, 1, [Define to 1 if "signed char" is a valid type])
 910 fi
 911
 912 AC_CACHE_CHECK([for broken readdir],rsync_cv_HAVE_BROKEN_READDIR,[
 913 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <sys/types.h>
 914 #include <dirent.h>
 915 int main(void) { struct dirent *di; DIR *d = opendir("."); di = readdir(d);
 916 if (di && di->d_name[-2] == '.' && di->d_name[-1] == 0 &&
 917 di->d_name[0] == 0) return 0; return 1;} ]])],[rsync_cv_HAVE_BROKEN_READDIR=yes],[rsync_cv_HAVE_BROKEN_READDIR=no],[rsync_cv_HAVE_BROKEN_READDIR=cross])])
 918 if test x"$rsync_cv_HAVE_BROKEN_READDIR" = x"yes"; then
 919     AC_DEFINE(HAVE_BROKEN_READDIR, 1, [Define to 1 if readdir() is broken])
 920 fi
 921
 922 AC_CACHE_CHECK([for utimbuf],rsync_cv_HAVE_STRUCT_UTIMBUF,[
 923 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 924 #include <utime.h>]], [[struct utimbuf tbuf;  tbuf.actime = 0; tbuf.modtime = 1; return utime("foo.c",&tbuf);]])],[rsync_cv_HAVE_STRUCT_UTIMBUF=yes],[rsync_cv_HAVE_STRUCT_UTIMBUF=no])])
 925 if test x"$rsync_cv_HAVE_STRUCT_UTIMBUF" = x"yes"; then
 926     AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if you have the "struct utimbuf" type])
 927 fi
 928
 929 AC_CACHE_CHECK([if gettimeofday takes tz argument],rsync_cv_HAVE_GETTIMEOFDAY_TZ,[
 930 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/time.h>
 931 #include <unistd.h>]], [[struct timeval tv; return gettimeofday(&tv, NULL);]])],[rsync_cv_HAVE_GETTIMEOFDAY_TZ=yes],[rsync_cv_HAVE_GETTIMEOFDAY_TZ=no])])
 932 if test x"$rsync_cv_HAVE_GETTIMEOFDAY_TZ" != x"no"; then
 933     AC_DEFINE(HAVE_GETTIMEOFDAY_TZ, 1, [Define to 1 if gettimeofday() takes a time-zone arg])
 934 fi
 935
 936 AC_CACHE_CHECK([for C99 vsnprintf],rsync_cv_HAVE_C99_VSNPRINTF,[
 937 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 938 #include <sys/types.h>
 939 #include <stdarg.h>
 940 #include <stdio.h>
 941 #include <stdlib.h>
 942 #include <string.h>
 943 void foo(const char *format, ...) {
 944        va_list ap;
 945        int len;
 946        char buf[5];
 947
 948        va_start(ap, format);
 949        len = vsnprintf(0, 0, format, ap);
 950        va_end(ap);
 951        if (len != 5) exit(1);
 952
 953        if (snprintf(buf, 3, "hello") != 5 || strcmp(buf, "he") != 0) exit(1);
 954 }
 955 int main(void) { foo("hello"); return 0; }
 956 ]])],[rsync_cv_HAVE_C99_VSNPRINTF=yes],[rsync_cv_HAVE_C99_VSNPRINTF=no],[rsync_cv_HAVE_C99_VSNPRINTF=cross])])
 957 if test x"$rsync_cv_HAVE_C99_VSNPRINTF" = x"yes"; then
 958     AC_DEFINE(HAVE_C99_VSNPRINTF, 1, [Define to 1 if vsprintf has a C99-compatible return value])
 959 fi
 960
 961
 962 AC_CACHE_CHECK([for secure mkstemp],rsync_cv_HAVE_SECURE_MKSTEMP,[
 963 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
 964 #include <sys/types.h>
 965 #include <sys/stat.h>
 966 #include <unistd.h>
 967 int main(void) {
 968   struct stat st;
 969   char tpl[20]="/tmp/test.XXXXXX";
 970   int fd = mkstemp(tpl);
 971   if (fd == -1) return 1;
 972   unlink(tpl);
 973   if (fstat(fd, &st) != 0) return 1;
 974   if ((st.st_mode & 0777) != 0600) return 1;
 975   return 0;
 976 }]])],[rsync_cv_HAVE_SECURE_MKSTEMP=yes],[rsync_cv_HAVE_SECURE_MKSTEMP=no],[rsync_cv_HAVE_SECURE_MKSTEMP=cross])])
 977 if test x"$rsync_cv_HAVE_SECURE_MKSTEMP" = x"yes"; then
 978     case $host_os in
 979     hpux*)
 980         dnl HP-UX has a broken mkstemp() implementation they refuse to fix,
 981         dnl so we noisily skip using it.  See HP change request JAGaf34426
 982         dnl for details. (sbonds)
 983         AC_MSG_WARN(Skipping broken HP-UX mkstemp() -- using mktemp() instead)
 984         ;;
 985     *)
 986         AC_DEFINE(HAVE_SECURE_MKSTEMP, 1, [Define to 1 if mkstemp() is available and works right])
 987         ;;
 988     esac
 989 fi
 990
 991
 992 AC_CACHE_CHECK([if mknod creates FIFOs],rsync_cv_MKNOD_CREATES_FIFOS,[
 993 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 994 #include <stdio.h>
 995 #include <sys/stat.h>
 996 #include <errno.h>
 997 #if HAVE_UNISTD_H
 998 # include <unistd.h>
 999 #endif
1000 int main(void) { int rc, ec; char *fn = "fifo-test";
1001 unlink(fn); rc = mknod(fn,S_IFIFO,0600); ec = errno; unlink(fn);
1002 if (rc) {printf("(%d %d) ",rc,ec); return ec;}
1003 return 0;}]])],[rsync_cv_MKNOD_CREATES_FIFOS=yes],[rsync_cv_MKNOD_CREATES_FIFOS=no],[rsync_cv_MKNOD_CREATES_FIFOS=cross])])
1004 if test x"$rsync_cv_MKNOD_CREATES_FIFOS" = x"yes"; then
1005     AC_DEFINE(MKNOD_CREATES_FIFOS, 1, [Define to 1 if mknod() can create FIFOs.])
1006 fi
1007
1008 AC_CACHE_CHECK([if mknod creates sockets],rsync_cv_MKNOD_CREATES_SOCKETS,[
1009 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1010 #include <stdio.h>
1011 #include <sys/stat.h>
1012 #include <errno.h>
1013 #if HAVE_UNISTD_H
1014 # include <unistd.h>
1015 #endif
1016 int main(void) { int rc, ec; char *fn = "sock-test";
1017 unlink(fn); rc = mknod(fn,S_IFSOCK,0600); ec = errno; unlink(fn);
1018 if (rc) {printf("(%d %d) ",rc,ec); return ec;}
1019 return 0;}]])],[rsync_cv_MKNOD_CREATES_SOCKETS=yes],[rsync_cv_MKNOD_CREATES_SOCKETS=no],[rsync_cv_MKNOD_CREATES_SOCKETS=cross])])
1020 if test x"$rsync_cv_MKNOD_CREATES_SOCKETS" = x"yes"; then
1021     AC_DEFINE(MKNOD_CREATES_SOCKETS, 1, [Define to 1 if mknod() can create sockets.])
1022 fi
1023
1024 #
1025 # The following test was mostly taken from the tcl/tk plus patches
1026 #
1027 AC_CACHE_CHECK([whether -c -o works],rsync_cv_DASHC_WORKS_WITH_DASHO,[
1028 rm -rf conftest*
1029 cat > conftest.$ac_ext <<EOF
1030 int main(void) { return 0; }
1031 EOF
1032 ${CC-cc} -c -o conftest..o conftest.$ac_ext
1033 if test -f conftest..o; then
1034     rsync_cv_DASHC_WORKS_WITH_DASHO=yes
1035 else
1036     rsync_cv_DASHC_WORKS_WITH_DASHO=no
1037 fi
1038 rm -rf conftest*
1039 ])
1040 if test x"$rsync_cv_DASHC_WORKS_WITH_DASHO" = x"yes"; then
1041     OBJ_SAVE="#"
1042     OBJ_RESTORE="#"
1043     CC_SHOBJ_FLAG='-o $@'
1044 else
1045     OBJ_SAVE='  @b=`basename $@ .o`;rm -f $$b.o.sav;if test -f $$b.o; then mv $$b.o $$b.o.sav;fi;'
1046     OBJ_RESTORE='       @b=`basename $@ .o`;if test "$$b.o" != "$@"; then mv $$b.o $@; if test -f $$b.o.sav; then mv $$b.o.sav $$b.o; fi; fi'
1047     CC_SHOBJ_FLAG=""
1048 fi
1049
1050 AC_SUBST(OBJ_SAVE)
1051 AC_SUBST(OBJ_RESTORE)
1052 AC_SUBST(CC_SHOBJ_FLAG)
1053 AC_SUBST(BUILD_POPT)
1054 AC_SUBST(BUILD_ZLIB)
1055 AC_SUBST(MAKE_MAN)
1056
1057 AC_CHECK_FUNCS(_acl __acl _facl __facl)
1058 #################################################
1059 # check for ACL support
1060
1061 AC_MSG_CHECKING([whether to support ACLs])
1062 AC_ARG_ENABLE(acl-support,
1063         AS_HELP_STRING([--disable-acl-support],[disable ACL support]))
1064
1065 if test x"$enable_acl_support" = x"no"; then
1066     AC_MSG_RESULT(no)
1067 else
1068     case "$host_os" in
1069     *sysv5*)
1070         AC_MSG_RESULT(Using UnixWare ACLs)
1071         AC_DEFINE(HAVE_UNIXWARE_ACLS, 1, [true if you have UnixWare ACLs])
1072         AC_DEFINE(SUPPORT_ACLS, 1, [Define to 1 to add support for ACLs])
1073         ;;
1074     solaris*)
1075         AC_MSG_RESULT(Using solaris ACLs)
1076         AC_DEFINE(HAVE_SOLARIS_ACLS, 1, [true if you have solaris ACLs])
1077         AC_DEFINE(SUPPORT_ACLS, 1)
1078         ;;
1079     *hpux*)
1080         AC_MSG_RESULT(Using HPUX ACLs)
1081         AC_DEFINE(HAVE_HPUX_ACLS, 1, [true if you have HPUX ACLs])
1082         AC_DEFINE(SUPPORT_ACLS, 1)
1083         ;;
1084     *irix*)
1085         AC_MSG_RESULT(Using IRIX ACLs)
1086         AC_DEFINE(HAVE_IRIX_ACLS, 1, [true if you have IRIX ACLs])
1087         AC_DEFINE(SUPPORT_ACLS, 1)
1088         ;;
1089     *aix*)
1090         AC_MSG_RESULT(Using AIX ACLs)
1091         AC_DEFINE(HAVE_AIX_ACLS, 1, [true if you have AIX ACLs])
1092         AC_DEFINE(SUPPORT_ACLS, 1)
1093         ;;
1094     *osf*)
1095         AC_MSG_RESULT(Using Tru64 ACLs)
1096         AC_DEFINE(HAVE_TRU64_ACLS, 1, [true if you have Tru64 ACLs])
1097         AC_DEFINE(SUPPORT_ACLS, 1)
1098         LIBS="$LIBS -lpacl"
1099         ;;
1100     darwin*)
1101         AC_MSG_RESULT(Using OS X ACLs)
1102         AC_DEFINE(HAVE_OSX_ACLS, 1, [true if you have Mac OS X ACLs])
1103         AC_DEFINE(SUPPORT_ACLS, 1)
1104         ;;
1105     *)
1106         AC_MSG_RESULT(running tests:)
1107         AC_CHECK_LIB(acl,acl_get_file)
1108         AC_CACHE_CHECK([for ACL support],samba_cv_HAVE_POSIX_ACLS,[
1109             AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1110 #include <sys/acl.h>]], [[ acl_t acl; int entry_id; acl_entry_t *entry_p; return acl_get_entry( acl, entry_id, entry_p);]])],[samba_cv_HAVE_POSIX_ACLS=yes],[samba_cv_HAVE_POSIX_ACLS=no])])
1111         AC_MSG_CHECKING(ACL test results)
1112         if test x"$samba_cv_HAVE_POSIX_ACLS" = x"yes"; then
1113             AC_MSG_RESULT(Using posix ACLs)
1114             AC_DEFINE(HAVE_POSIX_ACLS, 1, [true if you have posix ACLs])
1115             AC_DEFINE(SUPPORT_ACLS, 1)
1116             AC_CACHE_CHECK([for acl_get_perm_np],samba_cv_HAVE_ACL_GET_PERM_NP,[
1117                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1118 #include <sys/acl.h>]], [[ acl_permset_t permset_d; acl_perm_t perm; return acl_get_perm_np( permset_d, perm);]])],[samba_cv_HAVE_ACL_GET_PERM_NP=yes],[samba_cv_HAVE_ACL_GET_PERM_NP=no])])
1119             if test x"$samba_cv_HAVE_ACL_GET_PERM_NP" = x"yes"; then
1120                 AC_DEFINE(HAVE_ACL_GET_PERM_NP, 1, [true if you have acl_get_perm_np])
1121             fi
1122         else
1123             if test x"$enable_acl_support" = x"yes"; then
1124                 AC_MSG_ERROR(Failed to find ACL support)
1125             else
1126                 AC_MSG_RESULT(No ACL support found)
1127             fi
1128         fi
1129         ;;
1130     esac
1131 fi
1132
1133 #################################################
1134 # check for extended attribute support
1135 AC_MSG_CHECKING(whether to support extended attributes)
1136 AC_ARG_ENABLE(xattr-support,
1137     AS_HELP_STRING([--disable-xattr-support],[disable extended attributes]),
1138     [], [case "$ac_cv_func_getxattr$ac_cv_func_extattr_get_link$ac_cv_func_attropen" in
1139         *yes*) enable_xattr_support=maybe ;;
1140         *) enable_xattr_support=no ;;
1141         esac])
1142 AH_TEMPLATE([SUPPORT_XATTRS],
1143 [Define to 1 to add support for extended attributes])
1144 if test x"$enable_xattr_support" = x"no"; then
1145     AC_MSG_RESULT(no)
1146 else
1147     case "$host_os" in
1148     *linux*|*netbsd*)
1149         AC_MSG_RESULT(Using Linux xattrs)
1150         AC_DEFINE(HAVE_LINUX_XATTRS, 1, [True if you have Linux xattrs (or equivalent)])
1151         AC_DEFINE(SUPPORT_XATTRS, 1)
1152         AC_DEFINE(NO_SYMLINK_USER_XATTRS, 1, [True if symlinks do not support user xattrs])
1153         AC_CHECK_LIB(attr,getxattr)
1154         ;;
1155     darwin*)
1156         AC_MSG_RESULT(Using OS X xattrs)
1157         AC_DEFINE(HAVE_OSX_XATTRS, 1, [True if you have Mac OS X xattrs])
1158         AC_DEFINE(SUPPORT_XATTRS, 1)
1159         AC_DEFINE(NO_DEVICE_XATTRS, 1, [True if device files do not support xattrs])
1160         AC_DEFINE(NO_SPECIAL_XATTRS, 1, [True if special files do not support xattrs])
1161         ;;
1162     freebsd*)
1163         AC_MSG_RESULT(Using FreeBSD extattrs)
1164         AC_DEFINE(HAVE_FREEBSD_XATTRS, 1, [True if you have FreeBSD xattrs])
1165         AC_DEFINE(SUPPORT_XATTRS, 1)
1166         ;;
1167     solaris*)
1168         AC_MSG_RESULT(Using Solaris xattrs)
1169         AC_DEFINE(HAVE_SOLARIS_XATTRS, 1, [True if you have Solaris xattrs])
1170         AC_DEFINE(SUPPORT_XATTRS, 1)
1171         AC_DEFINE(NO_SYMLINK_XATTRS, 1, [True if symlinks do not support xattrs])
1172         ;;
1173     *)
1174         if test x"$enable_xattr_support" = x"yes"; then
1175             AC_MSG_ERROR(Failed to find extended attribute support)
1176         else
1177             AC_MSG_RESULT(No extended attribute support found)
1178         fi
1179         ;;
1180     esac
1181 fi
1182
1183 if test x"$enable_acl_support" = x"no" -o x"$enable_xattr_support" = x"no" -o x"$enable_iconv" = x"no"; then
1184     AC_MSG_CHECKING([whether $CC supports -Wno-unused-parameter])
1185     OLD_CFLAGS="$CFLAGS"
1186     CFLAGS="$CFLAGS -Wno-unused-parameter"
1187     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdio.h>]], [[printf("hello\n");]])],[rsync_warn_flag=yes],[rsync_warn_flag=no])
1188     AC_MSG_RESULT([$rsync_warn_flag])
1189     if test x"$rsync_warn_flag" = x"no"; then
1190         CFLAGS="$OLD_CFLAGS"
1191     fi
1192 fi
1193
1194 case "$CC" in
1195 ' checker'*|checker*)
1196     AC_DEFINE(FORCE_FD_ZERO_MEMSET, 1, [Used to make "checker" understand that FD_ZERO() clears memory.])
1197     ;;
1198 esac
1199
1200 AC_CONFIG_FILES([Makefile lib/dummy zlib/dummy popt/dummy shconfig])
1201 AC_OUTPUT
1202
1203 AC_MSG_RESULT()
1204 AC_MSG_RESULT([    rsync ${RSYNC_VERSION} configuration successful])
1205 AC_MSG_RESULT()
1206 if test x$HAVE_YODL2MAN != x1; then
1207     AC_MSG_RESULT([    Note that yodl2man was not found, so pre-existing manpage files will be])
1208     AC_MSG_RESULT([    used w/o change (if available) -- no .yo file changes will be used.])
1209     AC_MSG_RESULT()
1210 fi