configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_INIT()
   4 AC_CONFIG_SRCDIR([byteorder.h])
   5 AC_CONFIG_HEADER(config.h)
   6 AC_PREREQ(2.59)
   7
   8 RSYNC_VERSION=3.0.0pre6
   9 AC_SUBST(RSYNC_VERSION)
  10 AC_MSG_NOTICE([Configuring rsync $RSYNC_VERSION])
  11
  12 AC_DEFINE_UNQUOTED(RSYNC_VERSION, ["$RSYNC_VERSION"], [rsync release version])
  13
  14 LDFLAGS=${LDFLAGS-""}
  15
  16 AC_CANONICAL_TARGET([])
  17
  18 dnl Checks for programs.
  19 AC_PROG_CC
  20 AC_PROG_CPP
  21 AC_PROG_EGREP
  22 AC_PROG_INSTALL
  23 AC_PROG_CC_STDC
  24 AC_SUBST(SHELL)
  25
  26 AC_DEFINE([_GNU_SOURCE], 1,
  27           [Define _GNU_SOURCE so that we get all necessary prototypes])
  28
  29 if test x"$ac_cv_prog_cc_stdc" = x"no"; then
  30         AC_MSG_WARN([rsync requires an ANSI C compiler and you don't seem to have one])
  31 fi
  32
  33 # We must decide this before testing the compiler.
  34
  35 # Please allow this to default to yes, so that your users have more
  36 # chance of getting a useful stack trace if problems occur.
  37
  38 AC_MSG_CHECKING([whether to include debugging symbols])
  39 AC_ARG_ENABLE(debug,
  40         AC_HELP_STRING([--disable-debug],
  41                 [disable debugging symbols and features]))
  42
  43 if test x"$enable_debug" = x"no"; then
  44     AC_MSG_RESULT(no)
  45     CFLAGS=${CFLAGS-"-O"}
  46 else
  47     AC_MSG_RESULT([yes])
  48     # leave CFLAGS alone; AC_PROG_CC will try to include -g if it can
  49     dnl AC_DEFINE(DEBUG, 1, [Define to turn on debugging code that may slow normal operation])
  50     dnl CFLAGS=${CFLAGS-"-g"}
  51 fi
  52
  53
  54 AC_ARG_ENABLE(profile,
  55         AC_HELP_STRING([--enable-profile],
  56                 [turn on CPU profiling]))
  57 if test x"$enable_profile" = x"yes"; then
  58         CFLAGS="$CFLAGS -pg"
  59 fi
  60
  61
  62 # Specifically, this turns on panic_action handling.
  63 AC_ARG_ENABLE(maintainer-mode,
  64         AC_HELP_STRING([--enable-maintainer-mode],
  65                 [turn on extra debug features]))
  66 if test x"$enable_maintainer_mode" = x"yes"; then
  67         CFLAGS="$CFLAGS -DMAINTAINER_MODE"
  68 fi
  69
  70
  71 # This is needed for our included version of popt.  Kind of silly, but
  72 # I don't want our version too far out of sync.
  73 CFLAGS="$CFLAGS -DHAVE_CONFIG_H"
  74
  75 # If GCC, turn on warnings.
  76 if test x"$GCC" = x"yes"; then
  77         CFLAGS="$CFLAGS -Wall -W"
  78 fi
  79
  80 AC_ARG_WITH(included-popt,
  81         AC_HELP_STRING([--with-included-popt], [use bundled popt library, not from system]))
  82
  83 AC_ARG_WITH(rsync-path,
  84         AC_HELP_STRING([--with-rsync-path=PATH], [set default --rsync-path to PATH (default: rsync)]),
  85         [ RSYNC_PATH="$with_rsync_path" ],
  86         [ RSYNC_PATH="rsync" ])
  87
  88 AC_DEFINE_UNQUOTED(RSYNC_PATH, "$RSYNC_PATH", [location of rsync on remote machine])
  89
  90 AC_ARG_WITH(rsyncd-conf,
  91         AC_HELP_STRING([--with-rsyncd-conf=PATH], [set configuration file for rsync server to PATH (default: /etc/rsyncd.conf)]),
  92         [ if test ! -z "$with_rsyncd_conf" ; then
  93                 case $with_rsyncd_conf in
  94                         yes|no)
  95                                 RSYNCD_SYSCONF="/etc/rsyncd.conf"
  96                                 ;;
  97                         /*)
  98                                 RSYNCD_SYSCONF="$with_rsyncd_conf"
  99                                 ;;
 100                         *)
 101                                 AC_MSG_ERROR(You must specify an absolute path to --with-rsyncd-conf=PATH)
 102                                 ;;
 103                 esac
 104         else
 105                 RSYNCD_SYSCONF="/etc/rsyncd.conf"
 106         fi ],
 107         [ RSYNCD_SYSCONF="/etc/rsyncd.conf" ])
 108
 109 AC_DEFINE_UNQUOTED(RSYNCD_SYSCONF, "$RSYNCD_SYSCONF", [location of configuration file for rsync server])
 110
 111 AC_ARG_WITH(rsh,
 112         AC_HELP_STRING([--with-rsh=CMD], [set remote shell command to CMD (default: ssh)]))
 113
 114 AC_CHECK_PROG(HAVE_REMSH, remsh, 1, 0)
 115 if test x$HAVE_REMSH = x1; then
 116         AC_DEFINE(HAVE_REMSH, 1, [Define to 1 if remote shell is remsh, not rsh])
 117 fi
 118
 119 if test x"$with_rsh" != x; then
 120         RSYNC_RSH="$with_rsh"
 121 else
 122         RSYNC_RSH="ssh"
 123 fi
 124 AC_DEFINE_UNQUOTED(RSYNC_RSH, "$RSYNC_RSH", [default -e command])
 125
 126 AC_CHECK_PROG(HAVE_YODL2MAN, yodl2man, 1, 0)
 127 if test x$HAVE_YODL2MAN = x1; then
 128     MAKE_MAN=man
 129 fi
 130
 131 AC_ARG_WITH(nobody-group,
 132     AC_HELP_STRING([--with-nobody-group=GROUP],
 133                    [set the default unprivileged group (default nobody or nogroup)]),
 134     [ NOBODY_GROUP="$with_nobody_group" ])
 135
 136 if test x"$with_nobody_group" = x; then
 137     AC_MSG_CHECKING([the group for user "nobody"])
 138     if grep '^nobody:' /etc/group >/dev/null 2>&1; then
 139         NOBODY_GROUP=nobody
 140     elif grep '^nogroup:' /etc/group >/dev/null 2>&1; then
 141         NOBODY_GROUP=nogroup
 142     else
 143         NOBODY_GROUP=nobody # test for others?
 144     fi
 145     AC_MSG_RESULT($NOBODY_GROUP)
 146 fi
 147
 148 AC_DEFINE_UNQUOTED(NOBODY_USER, "nobody", [unprivileged user--e.g. nobody])
 149 AC_DEFINE_UNQUOTED(NOBODY_GROUP, "$NOBODY_GROUP", [unprivileged group for unprivileged user])
 150
 151 # arrgh. libc in some old debian version screwed up the largefile
 152 # stuff, getting byte range locking wrong
 153 AC_CACHE_CHECK([for broken largefile support],rsync_cv_HAVE_BROKEN_LARGEFILE,[
 154 AC_TRY_RUN([
 155 #define _FILE_OFFSET_BITS 64
 156 #include <stdio.h>
 157 #include <fcntl.h>
 158 #include <sys/types.h>
 159 #include <sys/wait.h>
 160
 161 int main(void)
 162 {
 163         struct flock lock;
 164         int status;
 165         char tpl[32] = "/tmp/locktest.XXXXXX";
 166         int fd = mkstemp(tpl);
 167         if (fd < 0) {
 168                 strcpy(tpl, "conftest.dat");
 169                 fd = open(tpl, O_CREAT|O_RDWR, 0600);
 170         }
 171
 172         lock.l_type = F_WRLCK;
 173         lock.l_whence = SEEK_SET;
 174         lock.l_start = 0;
 175         lock.l_len = 1;
 176         lock.l_pid = 0;
 177         fcntl(fd,F_SETLK,&lock);
 178         if (fork() == 0) {
 179                 lock.l_start = 1;
 180                 _exit(fcntl(fd,F_SETLK,&lock) == 0);
 181         }
 182         wait(&status);
 183         unlink(tpl);
 184         exit(WEXITSTATUS(status));
 185 }
 186 ],
 187 rsync_cv_HAVE_BROKEN_LARGEFILE=yes,rsync_cv_HAVE_BROKEN_LARGEFILE=no,rsync_cv_HAVE_BROKEN_LARGEFILE=cross)])
 188 if test x"$rsync_cv_HAVE_BROKEN_LARGEFILE" != x"yes"; then
 189    AC_SYS_LARGEFILE
 190 fi
 191
 192 ipv6type=unknown
 193 ipv6lib=none
 194 ipv6trylibc=yes
 195
 196 AC_ARG_ENABLE(ipv6,
 197         AC_HELP_STRING([--disable-ipv6],
 198                 [don't even try to use IPv6]))
 199 if test x"$enable_ipv6" != x"no"; then
 200         AC_MSG_CHECKING([ipv6 stack type])
 201         for i in inria kame linux-glibc linux-inet6 toshiba v6d zeta; do
 202                 case $i in
 203                 inria)
 204                         # http://www.kame.net/
 205                         AC_EGREP_CPP(yes, [
 206 #include <netinet/in.h>
 207 #ifdef IPV6_INRIA_VERSION
 208 yes
 209 #endif],
 210                                 [ipv6type=$i;
 211                                 AC_DEFINE(INET6, 1, [true if you have IPv6])
 212                                 ])
 213                         ;;
 214                 kame)
 215                         # http://www.kame.net/
 216                         AC_EGREP_CPP(yes, [
 217 #include <netinet/in.h>
 218 #ifdef __KAME__
 219 yes
 220 #endif],
 221                                 [ipv6type=$i;
 222                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 223                         ;;
 224                 linux-glibc)
 225                         # http://www.v6.linux.or.jp/
 226                         AC_EGREP_CPP(yes, [
 227 #include <features.h>
 228 #if defined(__GLIBC__) && __GLIBC__ >= 2 && __GLIBC_MINOR__ >= 1
 229 yes
 230 #endif],
 231                                 [ipv6type=$i;
 232 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 233                         ;;
 234                 linux-inet6)
 235                         # http://www.v6.linux.or.jp/
 236                         if test -d /usr/inet6 -o -f /usr/inet6/lib/libinet6.a; then
 237                                 ipv6type=$i
 238                                 ipv6lib=inet6
 239                                 ipv6libdir=/usr/inet6/lib
 240                                 ipv6trylibc=yes;
 241                                 AC_DEFINE(INET6, 1, [true if you have IPv6])
 242                                 CFLAGS="-I/usr/inet6/include $CFLAGS"
 243                         fi
 244                         ;;
 245                 toshiba)
 246                         AC_EGREP_CPP(yes, [
 247 #include <sys/param.h>
 248 #ifdef _TOSHIBA_INET6
 249 yes
 250 #endif],
 251                                 [ipv6type=$i;
 252                                 ipv6lib=inet6;
 253                                 ipv6libdir=/usr/local/v6/lib;
 254                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 255                         ;;
 256                 v6d)
 257                         AC_EGREP_CPP(yes, [
 258 #include </usr/local/v6/include/sys/v6config.h>
 259 #ifdef __V6D__
 260 yes
 261 #endif],
 262                                 [ipv6type=$i;
 263                                 ipv6lib=v6;
 264                                 ipv6libdir=/usr/local/v6/lib;
 265                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 266                         ;;
 267                 zeta)
 268                         AC_EGREP_CPP(yes, [
 269 #include <sys/param.h>
 270 #ifdef _ZETA_MINAMI_INET6
 271 yes
 272 #endif],
 273                                 [ipv6type=$i;
 274                                 ipv6lib=inet6;
 275                                 ipv6libdir=/usr/local/v6/lib;
 276                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 277                         ;;
 278                 esac
 279                 if test "$ipv6type" != "unknown"; then
 280                         break
 281                 fi
 282         done
 283         AC_MSG_RESULT($ipv6type)
 284
 285         AC_SEARCH_LIBS(getaddrinfo, inet6)
 286 fi
 287
 288 dnl Do you want to disable use of locale functions
 289 AC_ARG_ENABLE([locale],
 290         AC_HELP_STRING([--disable-locale],
 291                 [disable locale features]))
 292 AH_TEMPLATE([CONFIG_LOCALE],
 293 [Undefine if you don't want locale features.  By default this is defined.])
 294 if test x"$enable_locale" != x"no"; then
 295         AC_DEFINE(CONFIG_LOCALE)
 296 fi
 297
 298 AC_MSG_CHECKING([whether to call shutdown on all sockets])
 299 case $host_os in
 300         *cygwin* ) AC_MSG_RESULT(yes)
 301                    AC_DEFINE(SHUTDOWN_ALL_SOCKETS, 1,
 302                             [Define to 1 if sockets need to be shutdown])
 303                    ;;
 304                * ) AC_MSG_RESULT(no);;
 305 esac
 306
 307 AC_C_BIGENDIAN
 308 AC_HEADER_DIRENT
 309 AC_HEADER_TIME
 310 AC_HEADER_SYS_WAIT
 311 AC_CHECK_HEADERS(sys/fcntl.h sys/select.h fcntl.h sys/time.h sys/unistd.h \
 312     unistd.h utime.h grp.h compat.h sys/param.h ctype.h sys/wait.h \
 313     sys/ioctl.h sys/filio.h string.h stdlib.h sys/socket.h sys/mode.h \
 314     sys/un.h sys/attr.h glob.h mcheck.h arpa/inet.h arpa/nameser.h locale.h \
 315     netdb.h malloc.h float.h limits.h iconv.h libcharset.h langinfo.h)
 316 AC_HEADER_MAJOR
 317
 318 AC_CACHE_CHECK([if makedev takes 3 args],rsync_cv_MAKEDEV_TAKES_3_ARGS,[
 319 AC_TRY_RUN([
 320 #include <sys/types.h>
 321 #ifdef MAJOR_IN_MKDEV
 322 #include <sys/mkdev.h>
 323 # if !defined makedev && (defined mkdev || defined _WIN32 || defined __WIN32__)
 324 #  define makedev mkdev
 325 # endif
 326 #elif defined MAJOR_IN_SYSMACROS
 327 #include <sys/sysmacros.h>
 328 #endif
 329
 330 int main(void)
 331 {
 332         dev_t dev = makedev(0, 5, 7);
 333         if (major(dev) != 5 || minor(dev) != 7)
 334                 exit(1);
 335         return 0;
 336 }
 337 ],
 338 rsync_cv_MAKEDEV_TAKES_3_ARGS=yes,rsync_cv_MAKEDEV_TAKES_3_ARGS=no,rsync_cv_MAKEDEV_TAKES_3_ARGS=no)])
 339 if test x"$rsync_cv_MAKEDEV_TAKES_3_ARGS" = x"yes"; then
 340    AC_DEFINE(MAKEDEV_TAKES_3_ARGS, 1, [Define to 1 if makedev() takes 3 args])
 341 fi
 342
 343 AC_CHECK_SIZEOF(int)
 344 AC_CHECK_SIZEOF(long)
 345 AC_CHECK_SIZEOF(long long)
 346 AC_CHECK_SIZEOF(short)
 347 AC_CHECK_SIZEOF(int16_t)
 348 AC_CHECK_SIZEOF(uint16_t)
 349 AC_CHECK_SIZEOF(int32_t)
 350 AC_CHECK_SIZEOF(uint32_t)
 351 AC_CHECK_SIZEOF(int64_t)
 352 AC_CHECK_SIZEOF(off_t)
 353 AC_CHECK_SIZEOF(off64_t)
 354 AC_CHECK_SIZEOF(time_t)
 355
 356 AC_C_INLINE
 357 AC_C_LONG_DOUBLE
 358
 359 AC_TYPE_SIGNAL
 360 AC_TYPE_UID_T
 361 AC_CHECK_TYPES([mode_t,off_t,size_t,pid_t,id_t])
 362 AC_TYPE_GETGROUPS
 363 AC_CHECK_MEMBERS([struct stat.st_rdev])
 364
 365 TYPE_SOCKLEN_T
 366
 367 AC_CACHE_CHECK([for errno in errno.h],rsync_cv_errno, [
 368     AC_TRY_COMPILE([#include <errno.h>],[int i = errno],
 369         rsync_cv_errno=yes,rsync_cv_have_errno_decl=no)])
 370 if test x"$rsync_cv_errno" = x"yes"; then
 371    AC_DEFINE(HAVE_ERRNO_DECL, 1, [Define to 1 if errno is declared in errno.h])
 372 fi
 373
 374 # The following test taken from the cvs sources
 375 # If we can't find connect, try looking in -lsocket, -lnsl, and -linet.
 376 # These need checks to be before checks for any other functions that
 377 #    might be in the same libraries.
 378 # The Irix 5 libc.so has connect and gethostbyname, but Irix 5 also has
 379 # libsocket.so which has a bad implementation of gethostbyname (it
 380 # only looks in /etc/hosts), so we only look for -lsocket if we need
 381 # it.
 382 AC_CHECK_FUNCS(connect)
 383 if test x"$ac_cv_func_connect" = x"no"; then
 384     case "$LIBS" in
 385     *-lnsl*) ;;
 386     *) AC_CHECK_LIB(nsl_s, printf) ;;
 387     esac
 388     case "$LIBS" in
 389     *-lnsl*) ;;
 390     *) AC_CHECK_LIB(nsl, printf) ;;
 391     esac
 392     case "$LIBS" in
 393     *-lsocket*) ;;
 394     *) AC_CHECK_LIB(socket, connect) ;;
 395     esac
 396     case "$LIBS" in
 397     *-linet*) ;;
 398     *) AC_CHECK_LIB(inet, connect) ;;
 399     esac
 400     dnl We can't just call AC_CHECK_FUNCS(connect) here, because the value
 401     dnl has been cached.
 402     if test x"$ac_cv_lib_socket_connect" = x"yes" ||
 403        test x"$ac_cv_lib_inet_connect" = x"yes"; then
 404         # ac_cv_func_connect=yes
 405         # don't!  it would cause AC_CHECK_FUNC to succeed next time configure is run
 406         AC_DEFINE(HAVE_CONNECT, 1, [Define to 1 if you have the "connect" function])
 407     fi
 408 fi
 409
 410 AC_SEARCH_LIBS(inet_ntop, resolv)
 411
 412 # Solaris and HP-UX weirdness:
 413 # Search for libiconv_open (not iconv_open) to discover if -liconv is needed!
 414 AC_SEARCH_LIBS(libiconv_open, iconv)
 415
 416 AC_MSG_CHECKING([for iconv declaration])
 417 AC_CACHE_VAL(am_cv_proto_iconv, [
 418     AC_TRY_COMPILE([
 419 #include <stdlib.h>
 420 #include <iconv.h>
 421 extern
 422 #ifdef __cplusplus
 423 "C"
 424 #endif
 425 #if defined(__STDC__) || defined(__cplusplus)
 426 size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 427 #else
 428 size_t iconv();
 429 #endif
 430 ], [], am_cv_proto_iconv_arg1="", am_cv_proto_iconv_arg1="const")
 431       am_cv_proto_iconv="extern size_t iconv (iconv_t cd, $am_cv_proto_iconv_arg1 char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);"])
 432     am_cv_proto_iconv=`echo "[$]am_cv_proto_iconv" | tr -s ' ' | sed -e 's/( /(/'`
 433 AC_MSG_RESULT([$]{ac_t:-
 434          }[$]am_cv_proto_iconv)
 435 AC_DEFINE_UNQUOTED(ICONV_CONST, $am_cv_proto_iconv_arg1,
 436                    [Define as const if the declaration of iconv() needs const.])
 437
 438 dnl AC_MSG_NOTICE([Looking in libraries: $LIBS])
 439
 440 AC_CHECK_FUNCS(inet_ntop, , [AC_LIBOBJ(lib/inet_ntop)])
 441 AC_CHECK_FUNCS(inet_pton, , [AC_LIBOBJ(lib/inet_pton)])
 442
 443 AC_HAVE_TYPE([struct addrinfo], [#include <netdb.h>])
 444 AC_HAVE_TYPE([struct sockaddr_storage], [#include <sys/types.h>
 445 #include <sys/socket.h>])
 446
 447 # Irix 6.5 has getaddrinfo but not the corresponding defines, so use
 448 #   builtin getaddrinfo if one of the defines don't exist
 449 AC_CACHE_CHECK([whether defines needed by getaddrinfo exist],
 450                rsync_cv_HAVE_GETADDR_DEFINES,[
 451                         AC_EGREP_CPP(yes, [
 452                         #include <sys/types.h>
 453                         #include <sys/socket.h>
 454                         #include <netdb.h>
 455                         #ifdef AI_PASSIVE
 456                         yes
 457                         #endif],
 458                         rsync_cv_HAVE_GETADDR_DEFINES=yes,
 459                         rsync_cv_HAVE_GETADDR_DEFINES=no)])
 460 if test x"$rsync_cv_HAVE_GETADDR_DEFINES" = x"yes" -a x"$ac_cv_type_struct_addrinfo" = x"yes"; then
 461         # Tru64 UNIX has getaddrinfo() but has it renamed in libc as
 462         # something else so we must include <netdb.h> to get the
 463         # redefinition.
 464         AC_CHECK_FUNCS(getaddrinfo, ,
 465                 [AC_MSG_CHECKING([for getaddrinfo by including <netdb.h>])
 466                 AC_TRY_LINK([#include <sys/types.h>
 467                 #include <sys/socket.h>
 468                 #include <netdb.h>],[getaddrinfo(NULL, NULL, NULL, NULL);],
 469                         [AC_MSG_RESULT([yes])
 470                         AC_DEFINE(HAVE_GETADDRINFO, 1,
 471                                 [Define to 1 if you have the "getaddrinfo" function and required types.])],
 472                         [AC_MSG_RESULT([no])
 473                         AC_LIBOBJ(lib/getaddrinfo)])])
 474 else
 475         AC_LIBOBJ(lib/getaddrinfo)
 476 fi
 477
 478 AC_CHECK_MEMBER([struct sockaddr.sa_len],
 479                 [ AC_DEFINE(HAVE_SOCKADDR_LEN, 1, [Do we have sockaddr.sa_len?]) ],
 480                 [],
 481                 [
 482 #include <sys/types.h>
 483 #include <sys/socket.h>
 484 ])
 485
 486 AC_CHECK_MEMBER([struct sockaddr_in.sin_len],
 487                 [ AC_DEFINE(HAVE_SOCKADDR_IN_LEN, 1, [Do we have sockaddr_in.sin_len?]) ],
 488                 [],
 489                 [
 490 #include <sys/types.h>
 491 #include <sys/socket.h>
 492 #include <netinet/in.h>
 493 ])
 494
 495 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
 496                 [ AC_DEFINE(HAVE_SOCKADDR_UN_LEN, 1, [Do we have sockaddr_un.sun_len?]) ],
 497                 [],
 498                 [
 499 #include <sys/types.h>
 500 #include <sys/socket.h>
 501 #include <netinet/in.h>
 502 ])
 503
 504 AC_CHECK_MEMBER([struct sockaddr_in6.sin6_scope_id],
 505                 [ AC_DEFINE(HAVE_SOCKADDR_IN6_SCOPE_ID, 1, [Do we have sockaddr_in6.sin6_scope_id?]) ],
 506                 [],
 507                 [
 508 #include <sys/types.h>
 509 #include <sys/socket.h>
 510 #include <netinet/in.h>
 511 ])
 512
 513 AC_HAVE_TYPE([struct stat64], [#include <stdio.h>
 514 #if HAVE_SYS_TYPES_H
 515 # include <sys/types.h>
 516 #endif
 517 #if HAVE_SYS_STAT_H
 518 # include <sys/stat.h>
 519 #endif
 520 #if STDC_HEADERS
 521 # include <stdlib.h>
 522 # include <stddef.h>
 523 #else
 524 # if HAVE_STDLIB_H
 525 #  include <stdlib.h>
 526 # endif
 527 #endif
 528 ])
 529
 530 # if we can't find strcasecmp, look in -lresolv (for Unixware at least)
 531 #
 532 AC_CHECK_FUNCS(strcasecmp)
 533 if test x"$ac_cv_func_strcasecmp" = x"no"; then
 534     AC_CHECK_LIB(resolv, strcasecmp)
 535 fi
 536
 537 AC_CHECK_FUNCS(aclsort)
 538 if test x"$ac_cv_func_aclsort" = x"no"; then
 539     AC_CHECK_LIB(sec, aclsort)
 540 fi
 541
 542 dnl At the moment we don't test for a broken memcmp(), because all we
 543 dnl need to do is test for equality, not comparison, and it seems that
 544 dnl every platform has a memcmp that can do at least that.
 545 dnl AC_FUNC_MEMCMP
 546
 547 AC_FUNC_UTIME_NULL
 548 AC_FUNC_ALLOCA
 549 AC_CHECK_FUNCS(waitpid wait4 getcwd strdup chown chmod lchmod mknod mkfifo \
 550     fchmod fstat ftruncate strchr readlink link utime utimes lutimes strftime \
 551     memmove lchown vsnprintf snprintf vasprintf asprintf setsid glob strpbrk \
 552     strlcat strlcpy strtol mallinfo getgroups setgroups geteuid getegid \
 553     setlocale setmode open64 lseek64 mkstemp64 mtrace va_copy __va_copy \
 554     strerror putenv iconv_open locale_charset nl_langinfo getxattr \
 555     extattr_get_link sigaction sigprocmask setattrlist)
 556
 557 AC_CHECK_FUNCS(getpgrp tcgetpgrp)
 558 if test $ac_cv_func_getpgrp = yes; then
 559     AC_FUNC_GETPGRP
 560 fi
 561
 562 AC_ARG_ENABLE(iconv,
 563     AC_HELP_STRING([--disable-iconv],
 564             [disable rsync's --iconv option]),
 565     [], [enable_iconv=$ac_cv_func_iconv_open])
 566 AH_TEMPLATE([ICONV_OPTION],
 567 [Define if you want the --iconv option.  Specifing a value will set the
 568 default iconv setting (a NULL means no --iconv processing by default).])
 569 if test x"$enable_iconv" != x"no"; then
 570         if test x"$enable_iconv" = x"yes"; then
 571                 AC_DEFINE(ICONV_OPTION, NULL)
 572         else
 573                 AC_DEFINE_UNQUOTED(ICONV_OPTION, "$enable_iconv")
 574         fi
 575         AC_DEFINE(UTF8_CHARSET, "UTF-8", [String to pass to iconv() for the UTF-8 charset.])
 576 fi
 577
 578 AC_CACHE_CHECK([whether chown() modifies symlinks],rsync_cv_chown_modifies_symlink,[
 579   AC_TRY_RUN([
 580 #if HAVE_UNISTD_H
 581 # include <unistd.h>
 582 #endif
 583 #include <stdlib.h>
 584 #include <errno.h>
 585     main() {
 586         char const *dangling_symlink = "conftest.dangle";
 587         unlink(dangling_symlink);
 588         if (symlink("conftest.no-such", dangling_symlink) < 0) abort();
 589         if (chown(dangling_symlink, getuid(), getgid()) < 0 && errno == ENOENT) exit(1);
 590         exit(0);
 591     }],
 592   rsync_cv_chown_modifies_symlink=yes,rsync_cv_chown_modifies_symlink=no,rsync_cv_chown_modifies_symlink=no)])
 593 if test $rsync_cv_chown_modifies_symlink = yes; then
 594   AC_DEFINE(CHOWN_MODIFIES_SYMLINK, 1, [Define to 1 if chown modifies symlinks.])
 595 fi
 596
 597 AC_CACHE_CHECK([whether link() can hard-link symlinks],rsync_cv_can_hardlink_symlink,[
 598   AC_TRY_RUN([
 599 #if HAVE_UNISTD_H
 600 # include <unistd.h>
 601 #endif
 602 #include <stdlib.h>
 603 #include <errno.h>
 604 #define FILENAME "conftest.dangle"
 605     main() {
 606         unlink(FILENAME);
 607         if (symlink("conftest.no-such", FILENAME) < 0) abort();
 608         if (link(FILENAME, FILENAME "2") < 0) exit(1);
 609         exit(0);
 610     }],
 611   rsync_cv_can_hardlink_symlink=yes,rsync_cv_can_hardlink_symlink=no,rsync_cv_can_hardlink_symlink=no)])
 612 if test $rsync_cv_can_hardlink_symlink = yes; then
 613   AC_DEFINE(CAN_HARDLINK_SYMLINK, 1, [Define to 1 if link() can hard-link symlinks.])
 614 fi
 615
 616 AC_CACHE_CHECK([whether link() can hard-link special files],rsync_cv_can_hardlink_special,[
 617   AC_TRY_RUN([
 618 #if HAVE_UNISTD_H
 619 # include <unistd.h>
 620 #endif
 621 #include <stdlib.h>
 622 #include <errno.h>
 623 #define FILENAME "conftest.fifi"
 624     main() {
 625         unlink(FILENAME);
 626         if (mkfifo(FILENAME, 0777) < 0) abort();
 627         if (link(FILENAME, FILENAME "2") < 0) exit(1);
 628         exit(0);
 629     }],
 630   rsync_cv_can_hardlink_special=yes,rsync_cv_can_hardlink_special=no,rsync_cv_can_hardlink_special=no)])
 631 if test $rsync_cv_can_hardlink_special = yes; then
 632     AC_DEFINE(CAN_HARDLINK_SPECIAL, 1, [Define to 1 if link() can hard-link special files.])
 633 fi
 634
 635 AC_CACHE_CHECK([for working socketpair],rsync_cv_HAVE_SOCKETPAIR,[
 636 AC_TRY_RUN([
 637 #include <sys/types.h>
 638 #include <sys/socket.h>
 639
 640 main() {
 641        int fd[2];
 642        exit((socketpair(AF_UNIX, SOCK_STREAM, 0, fd) != -1) ? 0 : 1);
 643 }],
 644 rsync_cv_HAVE_SOCKETPAIR=yes,rsync_cv_HAVE_SOCKETPAIR=no,rsync_cv_HAVE_SOCKETPAIR=cross)])
 645 if test x"$rsync_cv_HAVE_SOCKETPAIR" = x"yes"; then
 646     AC_DEFINE(HAVE_SOCKETPAIR, 1, [Define to 1 if you have the "socketpair" function])
 647 fi
 648
 649 if test x"$with_included_popt" != x"yes"; then
 650     AC_CHECK_LIB(popt, poptGetContext, , [with_included_popt=yes])
 651 fi
 652
 653 AC_MSG_CHECKING([whether to use included libpopt])
 654 if test x"$with_included_popt" = x"yes"; then
 655     AC_MSG_RESULT($srcdir/popt)
 656     BUILD_POPT='$(popt_OBJS)'
 657     CFLAGS="$CFLAGS -I$srcdir/popt"
 658     if test x"$ALLOCA" != x
 659     then
 660         # this can be removed when/if we add an included alloca.c;
 661         #  see autoconf documentation on AC_FUNC_ALLOCA
 662         AC_MSG_WARN([included libpopt will use malloc, not alloca (which wastes a small amount of memory)])
 663     fi
 664 else
 665     AC_MSG_RESULT(no)
 666 fi
 667
 668 AC_CACHE_CHECK([for unsigned char],rsync_cv_SIGNED_CHAR_OK,[
 669 AC_TRY_COMPILE([],[signed char *s = ""],
 670 rsync_cv_SIGNED_CHAR_OK=yes,rsync_cv_SIGNED_CHAR_OK=no)])
 671 if test x"$rsync_cv_SIGNED_CHAR_OK" = x"yes"; then
 672     AC_DEFINE(SIGNED_CHAR_OK, 1, [Define to 1 if "signed char" is a valid type])
 673 fi
 674
 675 AC_CACHE_CHECK([for broken readdir],rsync_cv_HAVE_BROKEN_READDIR,[
 676 AC_TRY_RUN([#include <sys/types.h>
 677 #include <dirent.h>
 678 main() { struct dirent *di; DIR *d = opendir("."); di = readdir(d);
 679 if (di && di->d_name[-2] == '.' && di->d_name[-1] == 0 &&
 680 di->d_name[0] == 0) exit(0); exit(1);} ],
 681 rsync_cv_HAVE_BROKEN_READDIR=yes,rsync_cv_HAVE_BROKEN_READDIR=no,rsync_cv_HAVE_BROKEN_READDIR=cross)])
 682 if test x"$rsync_cv_HAVE_BROKEN_READDIR" = x"yes"; then
 683     AC_DEFINE(HAVE_BROKEN_READDIR, 1, [Define to 1 if readdir() is broken])
 684 fi
 685
 686 AC_CACHE_CHECK([for utimbuf],rsync_cv_HAVE_STRUCT_UTIMBUF,[
 687 AC_TRY_COMPILE([#include <sys/types.h>
 688 #include <utime.h>],
 689 [struct utimbuf tbuf;  tbuf.actime = 0; tbuf.modtime = 1; exit(utime("foo.c",&tbuf));],
 690 rsync_cv_HAVE_STRUCT_UTIMBUF=yes,rsync_cv_HAVE_STRUCT_UTIMBUF=no)])
 691 if test x"$rsync_cv_HAVE_STRUCT_UTIMBUF" = x"yes"; then
 692     AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if you have the "struct utimbuf" type])
 693 fi
 694
 695 AC_CACHE_CHECK([if gettimeofday takes tz argument],rsync_cv_HAVE_GETTIMEOFDAY_TZ,[
 696 AC_TRY_COMPILE([#include <sys/time.h>
 697 #include <unistd.h>],
 698 [struct timeval tv; exit(gettimeofday(&tv, NULL));],
 699 rsync_cv_HAVE_GETTIMEOFDAY_TZ=yes,rsync_cv_HAVE_GETTIMEOFDAY_TZ=no)])
 700 if test x"$rsync_cv_HAVE_GETTIMEOFDAY_TZ" != x"no"; then
 701     AC_DEFINE(HAVE_GETTIMEOFDAY_TZ, 1, [Define to 1 if gettimeofday() takes a time-zone arg])
 702 fi
 703
 704 AC_CACHE_CHECK([for C99 vsnprintf],rsync_cv_HAVE_C99_VSNPRINTF,[
 705 AC_TRY_RUN([
 706 #include <sys/types.h>
 707 #include <stdarg.h>
 708 void foo(const char *format, ...) {
 709        va_list ap;
 710        int len;
 711        char buf[5];
 712
 713        va_start(ap, format);
 714        len = vsnprintf(0, 0, format, ap);
 715        va_end(ap);
 716        if (len != 5) exit(1);
 717
 718        if (snprintf(buf, 3, "hello") != 5 || strcmp(buf, "he") != 0) exit(1);
 719
 720        exit(0);
 721 }
 722 main() { foo("hello"); }
 723 ],
 724 rsync_cv_HAVE_C99_VSNPRINTF=yes,rsync_cv_HAVE_C99_VSNPRINTF=no,rsync_cv_HAVE_C99_VSNPRINTF=cross)])
 725 if test x"$rsync_cv_HAVE_C99_VSNPRINTF" = x"yes"; then
 726     AC_DEFINE(HAVE_C99_VSNPRINTF, 1, [Define to 1 if vsprintf has a C99-compatible return value])
 727 fi
 728
 729
 730 AC_CACHE_CHECK([for secure mkstemp],rsync_cv_HAVE_SECURE_MKSTEMP,[
 731 AC_TRY_RUN([#include <stdlib.h>
 732 #include <sys/types.h>
 733 #include <sys/stat.h>
 734 #include <unistd.h>
 735 main() {
 736   struct stat st;
 737   char tpl[20]="/tmp/test.XXXXXX";
 738   int fd = mkstemp(tpl);
 739   if (fd == -1) exit(1);
 740   unlink(tpl);
 741   if (fstat(fd, &st) != 0) exit(1);
 742   if ((st.st_mode & 0777) != 0600) exit(1);
 743   exit(0);
 744 }],
 745 rsync_cv_HAVE_SECURE_MKSTEMP=yes,
 746 rsync_cv_HAVE_SECURE_MKSTEMP=no,
 747 rsync_cv_HAVE_SECURE_MKSTEMP=cross)])
 748 if test x"$rsync_cv_HAVE_SECURE_MKSTEMP" = x"yes"; then
 749     case $target_os in
 750     hpux*)
 751         dnl HP-UX has a broken mkstemp() implementation they refuse to fix,
 752         dnl so we noisily skip using it.  See HP change request JAGaf34426
 753         dnl for details. (sbonds)
 754         AC_MSG_WARN(Skipping broken HP-UX mkstemp() -- using mktemp() instead)
 755         ;;
 756     *)
 757         AC_DEFINE(HAVE_SECURE_MKSTEMP, 1, [Define to 1 if mkstemp() is available and works right])
 758         ;;
 759     esac
 760 fi
 761
 762
 763 AC_CACHE_CHECK([if mknod creates FIFOs],rsync_cv_MKNOD_CREATES_FIFOS,[
 764 AC_TRY_RUN([
 765 #include <stdio.h>
 766 #include <sys/stat.h>
 767 #include <errno.h>
 768 main() { int rc, ec; char *fn = "fifo-test";
 769 unlink(fn); rc = mknod(fn,S_IFIFO,0600); ec = errno; unlink(fn);
 770 if (rc) {printf("(%d %d) ",rc,ec); return ec;}
 771 return 0;}],
 772            rsync_cv_MKNOD_CREATES_FIFOS=yes,rsync_cv_MKNOD_CREATES_FIFOS=no,rsync_cv_MKNOD_CREATES_FIFOS=cross)])
 773 if test x"$rsync_cv_MKNOD_CREATES_FIFOS" = x"yes"; then
 774     AC_DEFINE(MKNOD_CREATES_FIFOS, 1, [Define to 1 if mknod() can create FIFOs.])
 775 fi
 776
 777 AC_CACHE_CHECK([if mknod creates sockets],rsync_cv_MKNOD_CREATES_SOCKETS,[
 778 AC_TRY_RUN([
 779 #include <stdio.h>
 780 #include <sys/stat.h>
 781 #include <errno.h>
 782 main() { int rc, ec; char *fn = "sock-test";
 783 unlink(fn); rc = mknod(fn,S_IFSOCK,0600); ec = errno; unlink(fn);
 784 if (rc) {printf("(%d %d) ",rc,ec); return ec;}
 785 return 0;}],
 786            rsync_cv_MKNOD_CREATES_SOCKETS=yes,rsync_cv_MKNOD_CREATES_SOCKETS=no,rsync_cv_MKNOD_CREATES_SOCKETS=cross)])
 787 if test x"$rsync_cv_MKNOD_CREATES_SOCKETS" = x"yes"; then
 788     AC_DEFINE(MKNOD_CREATES_SOCKETS, 1, [Define to 1 if mknod() can create sockets.])
 789 fi
 790
 791 #
 792 # The following test was mostly taken from the tcl/tk plus patches
 793 #
 794 AC_CACHE_CHECK([whether -c -o works],rsync_cv_DASHC_WORKS_WITH_DASHO,[
 795 rm -rf conftest*
 796 cat > conftest.$ac_ext <<EOF
 797 int main() { return 0; }
 798 EOF
 799 ${CC-cc} -c -o conftest..o conftest.$ac_ext
 800 if test -f conftest..o; then
 801     rsync_cv_DASHC_WORKS_WITH_DASHO=yes
 802 else
 803     rsync_cv_DASHC_WORKS_WITH_DASHO=no
 804 fi
 805 rm -rf conftest*
 806 ])
 807 if test x"$rsync_cv_DASHC_WORKS_WITH_DASHO" = x"yes"; then
 808     OBJ_SAVE="#"
 809     OBJ_RESTORE="#"
 810     CC_SHOBJ_FLAG='-o $@'
 811 else
 812     OBJ_SAVE='  @b=`basename $@ .o`;rm -f $$b.o.sav;if test -f $$b.o; then mv $$b.o $$b.o.sav;fi;'
 813     OBJ_RESTORE='       @b=`basename $@ .o`;if test "$$b.o" != "$@"; then mv $$b.o $@; if test -f $$b.o.sav; then mv $$b.o.sav $$b.o; fi; fi'
 814     CC_SHOBJ_FLAG=""
 815 fi
 816
 817 AC_SUBST(OBJ_SAVE)
 818 AC_SUBST(OBJ_RESTORE)
 819 AC_SUBST(CC_SHOBJ_FLAG)
 820 AC_SUBST(BUILD_POPT)
 821 AC_SUBST(MAKE_MAN)
 822
 823 AC_CHECK_HEADERS(sys/acl.h acl/libacl.h)
 824 AC_CHECK_FUNCS(_acl __acl _facl __facl)
 825 #################################################
 826 # check for ACL support
 827
 828 AC_MSG_CHECKING([whether to support ACLs])
 829 AC_ARG_ENABLE(acl-support,
 830         AC_HELP_STRING([--disable-acl-support],
 831                        [disable ACL support]))
 832
 833 if test x"$enable_acl_support" = x"no"; then
 834     AC_MSG_RESULT(no)
 835 else
 836     case "$host_os" in
 837     *sysv5*)
 838         AC_MSG_RESULT(Using UnixWare ACLs)
 839         AC_DEFINE(HAVE_UNIXWARE_ACLS, 1, [true if you have UnixWare ACLs])
 840         AC_DEFINE(SUPPORT_ACLS, 1, [Define to 1 to add support for ACLs])
 841         ;;
 842     *solaris*|*cygwin*)
 843         AC_MSG_RESULT(Using solaris ACLs)
 844         AC_DEFINE(HAVE_SOLARIS_ACLS, 1, [true if you have solaris ACLs])
 845         AC_DEFINE(SUPPORT_ACLS, 1)
 846         ;;
 847     *hpux*)
 848         AC_MSG_RESULT(Using HPUX ACLs)
 849         AC_DEFINE(HAVE_HPUX_ACLS, 1, [true if you have HPUX ACLs])
 850         AC_DEFINE(SUPPORT_ACLS, 1)
 851         ;;
 852     *irix*)
 853         AC_MSG_RESULT(Using IRIX ACLs)
 854         AC_DEFINE(HAVE_IRIX_ACLS, 1, [true if you have IRIX ACLs])
 855         AC_DEFINE(SUPPORT_ACLS, 1)
 856         ;;
 857     *aix*)
 858         AC_MSG_RESULT(Using AIX ACLs)
 859         AC_DEFINE(HAVE_AIX_ACLS, 1, [true if you have AIX ACLs])
 860         AC_DEFINE(SUPPORT_ACLS, 1)
 861         ;;
 862     *osf*)
 863         AC_MSG_RESULT(Using Tru64 ACLs)
 864         AC_DEFINE(HAVE_TRU64_ACLS, 1, [true if you have Tru64 ACLs])
 865         AC_DEFINE(SUPPORT_ACLS, 1)
 866         LIBS="$LIBS -lpacl"
 867         ;;
 868     darwin*)
 869         AC_MSG_RESULT(Using OS X ACLs)
 870         AC_DEFINE(HAVE_OSX_ACLS, 1, [true if you have Mac OS X ACLs])
 871         AC_DEFINE(SUPPORT_ACLS, 1)
 872         ;;
 873     *)
 874         AC_MSG_RESULT(running tests:)
 875         AC_CHECK_LIB(acl,acl_get_file)
 876             AC_CACHE_CHECK([for ACL support],samba_cv_HAVE_POSIX_ACLS,[
 877             AC_TRY_LINK([#include <sys/types.h>
 878 #include <sys/acl.h>],
 879 [ acl_t acl; int entry_id; acl_entry_t *entry_p; return acl_get_entry( acl, entry_id, entry_p);],
 880 samba_cv_HAVE_POSIX_ACLS=yes,samba_cv_HAVE_POSIX_ACLS=no)])
 881         AC_MSG_CHECKING(ACL test results)
 882         if test x"$samba_cv_HAVE_POSIX_ACLS" = x"yes"; then
 883             AC_MSG_RESULT(Using posix ACLs)
 884             AC_DEFINE(HAVE_POSIX_ACLS, 1, [true if you have posix ACLs])
 885             AC_DEFINE(SUPPORT_ACLS, 1)
 886             AC_CACHE_CHECK([for acl_get_perm_np],samba_cv_HAVE_ACL_GET_PERM_NP,[
 887                 AC_TRY_LINK([#include <sys/types.h>
 888 #include <sys/acl.h>],
 889 [ acl_permset_t permset_d; acl_perm_t perm; return acl_get_perm_np( permset_d, perm);],
 890 samba_cv_HAVE_ACL_GET_PERM_NP=yes,samba_cv_HAVE_ACL_GET_PERM_NP=no)])
 891             if test x"$samba_cv_HAVE_ACL_GET_PERM_NP" = x"yes"; then
 892                 AC_DEFINE(HAVE_ACL_GET_PERM_NP, 1, [true if you have acl_get_perm_np])
 893             fi
 894         else
 895             if test x"$enable_acl_support" = x"yes"; then
 896                 AC_MSG_ERROR(Failed to find ACL support)
 897             else
 898                 AC_MSG_RESULT(No ACL support found)
 899             fi
 900         fi
 901         ;;
 902     esac
 903 fi
 904
 905 AC_CHECK_HEADERS(attr/xattr.h)
 906 AC_CHECK_HEADERS(sys/xattr.h)
 907 AC_CHECK_HEADERS(sys/extattr.h)
 908
 909 #################################################
 910 # check for extended attribute support
 911 AC_MSG_CHECKING(whether to support extended attributes)
 912 AC_ARG_ENABLE(xattr-support,
 913     AC_HELP_STRING([--disable-xattr-support],
 914             [disable extended attributes]),
 915     [], [case "$ac_cv_func_getxattr$ac_cv_func_extattr_get_link" in
 916         *yes*) enable_xattr_support=maybe ;;
 917         *) enable_xattr_support=no ;;
 918         esac])
 919 AH_TEMPLATE([SUPPORT_XATTRS],
 920 [Define to 1 to add support for extended attributes])
 921 if test x"$enable_xattr_support" = x"no"; then
 922     AC_MSG_RESULT(no)
 923 else
 924     case "$host_os" in
 925     *linux*)
 926         AC_MSG_RESULT(Using Linux xattrs)
 927         AC_DEFINE(HAVE_LINUX_XATTRS, 1, [True if you have Linux xattrs])
 928         AC_DEFINE(SUPPORT_XATTRS, 1)
 929         ;;
 930     darwin*)
 931         AC_MSG_RESULT(Using OS X xattrs)
 932         AC_DEFINE(HAVE_OSX_XATTRS, 1, [True if you have Mac OS X xattrs])
 933         AC_DEFINE(SUPPORT_XATTRS, 1)
 934         ;;
 935     freebsd*)
 936         AC_MSG_RESULT(Using FreeBSD extattrs)
 937         AC_DEFINE(HAVE_FREEBSD_XATTRS, 1, [True if you have FreeBSD xattrs])
 938         AC_DEFINE(SUPPORT_XATTRS, 1)
 939         ;;
 940     *)
 941         if test x"$enable_xattr_support" = x"yes"; then
 942             AC_MSG_ERROR(Failed to find extended attribute support)
 943         else
 944             AC_MSG_RESULT(No extended attribute support found)
 945         fi
 946         ;;
 947     esac
 948 fi
 949
 950 AC_CONFIG_FILES([Makefile lib/dummy zlib/dummy popt/dummy shconfig])
 951 AC_OUTPUT
 952
 953 AC_MSG_RESULT()
 954 AC_MSG_RESULT([    rsync ${RSYNC_VERSION} configuration successful])
 955 AC_MSG_RESULT()